configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix],
   6   [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
   7   [bug-guix@gnu.org], [guix],
   8   [https://www.gnu.org/software/guix/])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10
  11 AM_INIT_AUTOMAKE([1.14 gnu silent-rules subdir-objects \
  12  color-tests parallel-tests -Woverride -Wno-portability])
  13
  14 # Enable silent rules by default.
  15 AM_SILENT_RULES([yes])
  16
  17 AC_CONFIG_SRCDIR([guix.scm])
  18 AC_CONFIG_MACRO_DIR([m4])
  19
  20 dnl For the C++ code.  This must be used early.
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23 AM_GNU_GETTEXT([external])
  24 AM_GNU_GETTEXT_VERSION([0.18.1])
  25
  26 GUIX_SYSTEM_TYPE
  27 GUIX_ASSERT_SUPPORTED_SYSTEM
  28
  29 AC_ARG_WITH(store-dir,
  30   AC_HELP_STRING([--with-store-dir=PATH],
  31     [file name of the store (defaults to /gnu/store)]),
  32   [storedir="$withval"],
  33   [storedir="/gnu/store"])
  34 AC_SUBST(storedir)
  35
  36 AC_ARG_WITH([bash-completion-dir],
  37   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  38     [name of the Bash completion directory]),
  39   [bashcompletiondir="$withval"],
  40   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  41 AC_SUBST([bashcompletiondir])
  42
  43 AC_ARG_WITH([zsh-completion-dir],
  44   AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  45     [name of the Zsh completion directory]),
  46   [zshcompletiondir="$withval"],
  47   [zshcompletiondir='${datadir}/zsh/site-functions'])
  48 AC_SUBST([zshcompletiondir])
  49
  50 AC_ARG_WITH([fish-completion-dir],
  51   AC_HELP_STRING([--with-fish-completion-dir=DIR],
  52     [name of the Fish completion directory]),
  53   [fishcompletiondir="$withval"],
  54   [fishcompletiondir='${datadir}/fish/vendor_completions.d'])
  55 AC_SUBST([fishcompletiondir])
  56
  57 dnl Better be verbose.
  58 AC_MSG_CHECKING([for the store directory])
  59 AC_MSG_RESULT([$storedir])
  60
  61 AC_ARG_ENABLE([daemon],
  62   [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
  63   [guix_build_daemon="$enableval"],
  64   [guix_build_daemon="yes"])
  65
  66 # Prepare a version of $localstatedir & co. that does not contain references
  67 # to shell variables.
  68 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  69 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  70 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  71 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  72 AC_SUBST([guix_localstatedir])
  73 AC_SUBST([guix_sysconfdir])
  74 AC_SUBST([guix_sbindir])
  75
  76 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  77 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  78
  79 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  80 dnl Make sure they are available.
  81 m4_pattern_forbid([PKG_CHECK_MODULES])
  82 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  83 m4_pattern_forbid([^GUILE_P$])
  84
  85 dnl Search for 'guile' and 'guild'.  This macro defines
  86 dnl 'GUILE_EFFECTIVE_VERSION'.
  87 GUILE_PKG([2.2 2.0])
  88 GUILE_PROGS
  89 if test "x$GUILD" = "x"; then
  90    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  91 fi
  92
  93 if test "x$GUILE_EFFECTIVE_VERSION" = "x2.0"; then
  94   PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.9])
  95 fi
  96
  97 dnl Installation directories for .scm and .go files.
  98 guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
  99 guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
 100 AC_SUBST([guilemoduledir])
 101 AC_SUBST([guileobjectdir])
 102
 103 dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
 104 dnl pull', among other things.
 105 GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
 106 if test "x$have_gnutls" != "xyes"; then
 107   AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
 108 fi
 109
 110 dnl Check for Guile-Git.
 111 GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
 112 if test "x$have_guile_git" != "xyes"; then
 113   AC_MSG_ERROR([Guile-Git is missing; please install it.])
 114 fi
 115
 116 dnl Guile-JSON is used in various places.
 117 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
 118 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
 119
 120 dnl Make sure we have a full-fledged Guile.
 121 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
 122
 123 dnl Make sure we don't suffer from the bug in 'equal?' wrt. syntax objects
 124 dnl found in 2.2.1.  See <https://bugs.gnu.org/29903>.
 125 GUIX_ASSERT_SYNTAX_OBJECT_EQUAL
 126
 127 dnl Decompressors, for use by the substituter and other modules.
 128 AC_PATH_PROG([GZIP], [gzip])
 129 AC_PATH_PROG([BZIP2], [bzip2])
 130 AC_PATH_PROG([XZ], [xz])
 131 AC_SUBST([GZIP])
 132 AC_SUBST([BZIP2])
 133 AC_SUBST([XZ])
 134
 135 AC_ARG_WITH([nix-prefix],
 136   [AS_HELP_STRING([--with-nix-prefix=DIR],
 137     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 138   [case "$withval" in
 139     yes|no) ;;
 140     *)
 141       NIX_PREFIX="$withval"
 142       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 143       AC_SUBST([NIX_PREFIX])
 144       ;;
 145    esac],
 146   [])
 147
 148 AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
 149 AC_PATH_PROG([NIX_HASH], [nix-hash])
 150 if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
 151    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 152 fi
 153
 154 if test "x$NIX_INSTANTIATE" = "x"; then
 155    # This program is an optional dependency, so we just want it to be
 156    # taken from $PATH if it's not available right now.
 157    NIX_INSTANTIATE="nix-instantiate"
 158 fi
 159
 160 AC_ARG_WITH([nixpkgs],
 161   [AS_HELP_STRING([--with-nixpkgs=DIR],
 162     [search for Nixpkgs in DIR (for testing purposes only)])],
 163   [case "$withval" in
 164     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 165     *)      NIXPKGS="$withval";;
 166    esac],
 167   [])
 168
 169 AC_MSG_CHECKING([for Nixpkgs source tree])
 170 if test -f "$NIXPKGS/default.nix"; then
 171    AC_MSG_RESULT([$NIXPKGS])
 172    AC_SUBST([NIXPKGS])
 173 else
 174    AC_MSG_RESULT([not found])
 175 fi
 176
 177 LIBGCRYPT="libgcrypt"
 178 LIBGCRYPT_LIBDIR="no"
 179 LIBGCRYPT_PREFIX="no"
 180
 181 AC_ARG_WITH([libgcrypt-prefix],
 182   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 183   [case "$withval" in
 184     yes|no)
 185       ;;
 186     *)
 187       LIBGCRYPT="$withval/lib/libgcrypt"
 188       LIBGCRYPT_PREFIX="$withval"
 189       LIBGCRYPT_LIBDIR="$withval/lib"
 190       ;;
 191    esac])
 192
 193 AC_ARG_WITH([libgcrypt-libdir],
 194   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 195      [search for GNU libgcrypt's shared library in DIR])],
 196   [case "$withval" in
 197     yes|no)
 198       LIBGCRYPT="libgcrypt"
 199       LIBGCRYPT_LIBDIR="no"
 200       ;;
 201     *)
 202       LIBGCRYPT="$withval/libgcrypt"
 203       LIBGCRYPT_LIBDIR="$withval"
 204       ;;
 205    esac])
 206
 207 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 208 dnl absolute file name of libgcrypt.so.
 209 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 210   xnono)
 211     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 212     if test "x$LIBGCRYPT_LIBDIR" != x; then
 213       LIBGCRYPT="$LIBGCRYPT_LIBDIR/libgcrypt"
 214     else
 215       dnl 'config-daemon.ac' expects "no" in this case.
 216       LIBGCRYPT_LIBDIR="no"
 217     fi
 218     ;;
 219 esac
 220
 221 dnl Library name suitable for `dynamic-link'.
 222 AC_MSG_CHECKING([for libgcrypt shared library name])
 223 AC_MSG_RESULT([$LIBGCRYPT])
 224 AC_SUBST([LIBGCRYPT])
 225 AC_SUBST([LIBGCRYPT_PREFIX])
 226 AC_SUBST([LIBGCRYPT_LIBDIR])
 227
 228 GUIX_ASSERT_LIBGCRYPT_USABLE
 229
 230 dnl Library name of zlib suitable for 'dynamic-link'.
 231 GUIX_LIBZ_LIBDIR([libz_libdir])
 232 if test "x$libz_libdir" = "x"; then
 233   LIBZ="libz"
 234 else
 235   LIBZ="$libz_libdir/libz"
 236 fi
 237 AC_MSG_CHECKING([for zlib's shared library name])
 238 AC_MSG_RESULT([$LIBZ])
 239 AC_SUBST([LIBZ])
 240
 241 dnl Check for Guile-SSH, for the (guix ssh) module.
 242 GUIX_CHECK_GUILE_SSH
 243 AM_CONDITIONAL([HAVE_GUILE_SSH],
 244   [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
 245
 246 AC_CACHE_SAVE
 247
 248 m4_include([config-daemon.ac])
 249
 250 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 251 dnl See `Building from Git' in the manual for more info.
 252 AM_MISSING_PROG([DOT], [dot])
 253
 254 dnl Manual pages.
 255 AM_MISSING_PROG([HELP2MAN], [help2man])
 256
 257 dnl Emacs (optional), for 'etc/indent-package.el'.
 258 AC_PATH_PROG([EMACS], [emacs], [/usr/bin/emacs])
 259 AC_SUBST([EMACS])
 260
 261 case "$storedir" in
 262   /gnu/store)
 263     ;;
 264   *)
 265     AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
 266     AC_MSG_WARN([from downloading substitutes from gnu.org.])
 267     ;;
 268 esac
 269
 270 AC_CONFIG_FILES([Makefile
 271                  po/guix/Makefile.in
 272                  po/packages/Makefile.in
 273                  guix/config.scm])
 274
 275 AC_CONFIG_FILES([scripts/guix], [chmod +x scripts/guix])
 276 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 277 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 278   [chmod +x pre-inst-env])
 279 AC_CONFIG_FILES([etc/indent-code.el], [chmod +x etc/indent-code.el])
 280
 281 AC_OUTPUT