configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix],
   6   [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
   7   [bug-guix@gnu.org], [guix],
   8   [https://www.gnu.org/software/guix/])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10
  11 AM_INIT_AUTOMAKE([1.14 gnu silent-rules subdir-objects \
  12  color-tests parallel-tests -Woverride -Wno-portability])
  13
  14 # Enable silent rules by default.
  15 AM_SILENT_RULES([yes])
  16
  17 AC_CONFIG_SRCDIR([guix.scm])
  18 AC_CONFIG_MACRO_DIR([m4])
  19
  20 dnl For the C++ code.  This must be used early.
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23 AM_GNU_GETTEXT([external])
  24 AM_GNU_GETTEXT_VERSION([0.18.1])
  25
  26 GUIX_SYSTEM_TYPE
  27 GUIX_ASSERT_SUPPORTED_SYSTEM
  28
  29 AC_ARG_WITH(store-dir,
  30   AC_HELP_STRING([--with-store-dir=PATH],
  31     [file name of the store (defaults to /gnu/store)]),
  32   [storedir="$withval"],
  33   [storedir="/gnu/store"])
  34 AC_SUBST(storedir)
  35
  36 AC_ARG_WITH([bash-completion-dir],
  37   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  38     [name of the Bash completion directory]),
  39   [bashcompletiondir="$withval"],
  40   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  41 AC_SUBST([bashcompletiondir])
  42
  43 AC_ARG_WITH([zsh-completion-dir],
  44   AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  45     [name of the Zsh completion directory]),
  46   [zshcompletiondir="$withval"],
  47   [zshcompletiondir='${datadir}/zsh/site-functions'])
  48 AC_SUBST([zshcompletiondir])
  49
  50 AC_ARG_WITH([fish-completion-dir],
  51   AC_HELP_STRING([--with-fish-completion-dir=DIR],
  52     [name of the Fish completion directory]),
  53   [fishcompletiondir="$withval"],
  54   [fishcompletiondir='${datadir}/fish/vendor_completions.d'])
  55 AC_SUBST([fishcompletiondir])
  56
  57 AC_ARG_WITH([selinux-policy-dir],
  58   AC_HELP_STRING([--with-selinux-policy-dir=DIR],
  59     [name of the SELinux policy directory]),
  60   [selinux_policydir="$withval"],
  61   [selinux_policydir='${datadir}/selinux/'])
  62 AC_SUBST([selinux_policydir])
  63
  64 dnl Better be verbose.
  65 AC_MSG_CHECKING([for the store directory])
  66 AC_MSG_RESULT([$storedir])
  67
  68 AC_ARG_ENABLE([daemon],
  69   [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
  70   [guix_build_daemon="$enableval"],
  71   [guix_build_daemon="yes"])
  72
  73 # Prepare a version of $localstatedir & co. that does not contain references
  74 # to shell variables.
  75 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  76 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  77 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  78 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  79 AC_SUBST([guix_localstatedir])
  80 AC_SUBST([guix_sysconfdir])
  81 AC_SUBST([guix_sbindir])
  82
  83 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  84 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  85
  86 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  87 dnl Make sure they are available.
  88 m4_pattern_forbid([PKG_CHECK_MODULES])
  89 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  90 m4_pattern_forbid([^GUILE_P])
  91 m4_pattern_allow([^GUILE_PKG_ERRORS])
  92 m4_pattern_forbid([^GUIX_])
  93
  94 dnl Search for 'guile' and 'guild'.  This macro defines
  95 dnl 'GUILE_EFFECTIVE_VERSION'.
  96 GUILE_PKG([3.0 2.2])
  97 GUILE_PROGS
  98 if test "x$GUILD" = "x"; then
  99    AC_MSG_ERROR(['guild' binary not found; please check your Guile installation.])
 100 fi
 101
 102 if test "x$GUILE_EFFECTIVE_VERSION" = "x2.2"; then
 103   PKG_CHECK_MODULES([GUILE], [guile-2.2 >= 2.2.3])
 104 fi
 105
 106 dnl Installation directories for .scm and .go files.
 107 guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
 108 guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
 109 AC_SUBST([guilemoduledir])
 110 AC_SUBST([guileobjectdir])
 111
 112 dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
 113 dnl pull', among other things.
 114 GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
 115 if test "x$have_gnutls" != "xyes"; then
 116   AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
 117 fi
 118
 119 dnl Check for Guile-Git.
 120 GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
 121 if test "x$have_guile_git" != "xyes"; then
 122   AC_MSG_ERROR([Guile-Git is missing; please install it.])
 123 fi
 124
 125 dnl Check for Guile-JSON.
 126 GUIX_CHECK_GUILE_JSON
 127 if test "x$guix_cv_have_recent_guile_json" != "xyes"; then
 128   AC_MSG_ERROR([Guile-JSON is missing; please install it.])
 129 fi
 130
 131 dnl Guile-Sqlite3 is used by the (guix store ...) modules.
 132 GUIX_CHECK_GUILE_SQLITE3
 133 if test "x$guix_cv_have_recent_guile_sqlite3" != "xyes"; then
 134   AC_MSG_ERROR([A recent Guile-SQLite3 could not be found; please install it.])
 135 fi
 136
 137 GUILE_MODULE_AVAILABLE([have_guile_gcrypt], [(gcrypt hash)])
 138 if test "x$have_guile_gcrypt" != "xyes"; then
 139   AC_MSG_ERROR([Guile-Gcrypt could not be found; please install it.])
 140 fi
 141
 142 dnl Guile-newt is used by the graphical installer.
 143 GUILE_MODULE_AVAILABLE([have_guile_newt], [(newt)])
 144
 145 AC_ARG_ENABLE([installer],
 146     AS_HELP_STRING([--enable-installer], [Build the graphical installer sources.]))
 147
 148 AS_IF([test "x$enable_installer" = "xyes"], [
 149 if test "x$have_guile_newt" != "xyes"; then
 150   AC_MSG_ERROR([Guile-newt could not be found; please install it.])
 151 fi
 152 ])
 153
 154 AM_CONDITIONAL([ENABLE_INSTALLER],
 155   [test "x$enable_installer" = "xyes"])
 156
 157 dnl Make sure we have a full-fledged Guile.
 158 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
 159
 160 dnl Make sure we don't suffer from the bug in 'equal?' wrt. syntax objects
 161 dnl found in 2.2.1.  See <https://bugs.gnu.org/29903>.
 162 GUIX_ASSERT_SYNTAX_OBJECT_EQUAL
 163
 164 AC_PROG_SED
 165
 166 dnl Decompressors, for use by the substituter and other modules.
 167 AC_PATH_PROG([GZIP], [gzip])
 168 AC_PATH_PROG([BZIP2], [bzip2])
 169 AC_PATH_PROG([XZ], [xz])
 170 AC_SUBST([GZIP])
 171 AC_SUBST([BZIP2])
 172 AC_SUBST([XZ])
 173
 174 AC_ARG_WITH([nix-prefix],
 175   [AS_HELP_STRING([--with-nix-prefix=DIR],
 176     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 177   [case "$withval" in
 178     yes|no) ;;
 179     *)
 180       NIX_PREFIX="$withval"
 181       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 182       AC_SUBST([NIX_PREFIX])
 183       ;;
 184    esac],
 185   [])
 186
 187 AC_PATH_PROG([NIX_HASH], [nix-hash])
 188 if test "x$guix_build_daemon$NIX_HASH" = "xno"; then
 189    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 190 fi
 191
 192 AC_ARG_WITH([nixpkgs],
 193   [AS_HELP_STRING([--with-nixpkgs=DIR],
 194     [search for Nixpkgs in DIR (for testing purposes only)])],
 195   [case "$withval" in
 196     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 197     *)      NIXPKGS="$withval";;
 198    esac],
 199   [])
 200
 201 AC_MSG_CHECKING([for Nixpkgs source tree])
 202 if test -f "$NIXPKGS/default.nix"; then
 203    AC_MSG_RESULT([$NIXPKGS])
 204    AC_SUBST([NIXPKGS])
 205 else
 206    AC_MSG_RESULT([not found])
 207 fi
 208
 209 LIBGCRYPT_LIBDIR="no"
 210 LIBGCRYPT_PREFIX="no"
 211
 212 AC_ARG_WITH([libgcrypt-prefix],
 213   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 214   [case "$withval" in
 215     yes|no)
 216       ;;
 217     *)
 218       LIBGCRYPT_PREFIX="$withval"
 219       LIBGCRYPT_LIBDIR="$withval/lib"
 220       ;;
 221    esac])
 222
 223 AC_ARG_WITH([libgcrypt-libdir],
 224   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 225      [search for GNU libgcrypt's shared library in DIR])],
 226   [case "$withval" in
 227     yes|no)
 228       LIBGCRYPT_LIBDIR="no"
 229       ;;
 230     *)
 231       LIBGCRYPT_LIBDIR="$withval"
 232       ;;
 233    esac])
 234
 235 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 236 dnl the library directory.
 237 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 238   xnono)
 239     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 240     ;;
 241 esac
 242
 243 AC_SUBST([LIBGCRYPT_PREFIX])
 244 AC_SUBST([LIBGCRYPT_LIBDIR])
 245
 246 dnl Library name of zlib suitable for 'dynamic-link'.
 247 GUIX_LIBZ_LIBDIR([libz_libdir])
 248 if test "x$libz_libdir" = "x"; then
 249   LIBZ="libz"
 250 else
 251   LIBZ="$libz_libdir/libz"
 252 fi
 253 AC_MSG_CHECKING([for zlib's shared library name])
 254 AC_MSG_RESULT([$LIBZ])
 255 AC_SUBST([LIBZ])
 256
 257 dnl Library name of lzlib suitable for 'dynamic-link'.
 258 GUIX_LIBLZ_FILE_NAME([LIBLZ])
 259 if test "x$LIBLZ" = "x"; then
 260   LIBLZ="liblz"
 261 else
 262   # Strip the .so or .so.1 extension since that's what 'dynamic-link' expects.
 263   LIBLZ="`echo $LIBLZ | sed -es'/\.so\(\.[[0-9.]]\+\)\?//g'`"
 264 fi
 265 AC_SUBST([LIBLZ])
 266
 267 dnl Check for Guile-SSH, for the (guix ssh) module.
 268 GUIX_CHECK_GUILE_SSH
 269 AM_CONDITIONAL([HAVE_GUILE_SSH],
 270   [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
 271
 272 AC_CACHE_SAVE
 273
 274 m4_include([config-daemon.ac])
 275
 276 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 277 dnl See `Building from Git' in the manual for more info.
 278 AM_MISSING_PROG([DOT], [dot])
 279
 280 dnl Manual pages.
 281 AM_MISSING_PROG([HELP2MAN], [help2man])
 282
 283 dnl Documentation translation.
 284 AM_MISSING_PROG([PO4A_TRANSLATE], [po4a-translate])
 285 AM_MISSING_PROG([PO4A_UPDATEPO], [po4a-updatepo])
 286
 287 dnl Emacs (optional), for 'etc/indent-code.el'.
 288 AC_PATH_PROG([EMACS], [emacs])
 289 if test "x$EMACS" = x; then
 290     AC_MSG_WARN([Please install GNU Emacs to use etc/indent-code.el.])
 291 else
 292     AC_SUBST([EMACS])
 293     AC_CONFIG_FILES([etc/indent-code.el], [chmod +x etc/indent-code.el])
 294 fi
 295
 296 case "$storedir" in
 297   /gnu/store)
 298     ;;
 299   *)
 300     AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
 301     AC_MSG_WARN([from downloading substitutes from gnu.org.])
 302     ;;
 303 esac
 304
 305 AC_CONFIG_FILES([Makefile
 306                  po/guix/Makefile.in
 307                  po/packages/Makefile.in
 308                  etc/guix-daemon.cil
 309                  guix/config.scm])
 310
 311 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 312 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 313   [chmod +x pre-inst-env])
 314
 315 AC_OUTPUT