configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.69])
   5 AC_INIT([GNU Guix],
   6   [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
   7   [bug-guix@gnu.org], [guix],
   8   [https://www.gnu.org/software/guix/])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10
  11 AM_INIT_AUTOMAKE([1.14 gnu tar-ustar silent-rules subdir-objects \
  12  color-tests parallel-tests -Woverride -Wno-portability])
  13
  14 # Enable silent rules by default.
  15 AM_SILENT_RULES([yes])
  16
  17 AC_CONFIG_SRCDIR([guix.scm])
  18 AC_CONFIG_MACRO_DIR([m4])
  19
  20 dnl For the C++ code.  This must be used early.
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23 AM_GNU_GETTEXT([external])
  24 AM_GNU_GETTEXT_VERSION([0.19.1])
  25
  26 GUIX_SYSTEM_TYPE
  27 GUIX_ASSERT_SUPPORTED_SYSTEM
  28 GUIX_CHANNEL_METADATA
  29
  30 AM_CONDITIONAL([CROSS_COMPILING], [test "x$cross_compiling" = "xyes"])
  31
  32 AC_ARG_WITH(store-dir,
  33   AS_HELP_STRING([--with-store-dir=PATH],
  34     [file name of the store (defaults to /gnu/store)]),
  35   [storedir="$withval"],
  36   [storedir="/gnu/store"])
  37 AC_SUBST(storedir)
  38
  39 AC_ARG_WITH([bash-completion-dir],
  40   AS_HELP_STRING([--with-bash-completion-dir=DIR],
  41     [name of the Bash completion directory]),
  42   [bashcompletiondir="$withval"],
  43   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  44 AC_SUBST([bashcompletiondir])
  45
  46 AC_ARG_WITH([zsh-completion-dir],
  47   AS_HELP_STRING([--with-zsh-completion-dir=DIR],
  48     [name of the Zsh completion directory]),
  49   [zshcompletiondir="$withval"],
  50   [zshcompletiondir='${datadir}/zsh/site-functions'])
  51 AC_SUBST([zshcompletiondir])
  52
  53 AC_ARG_WITH([fish-completion-dir],
  54   AS_HELP_STRING([--with-fish-completion-dir=DIR],
  55     [name of the Fish completion directory]),
  56   [fishcompletiondir="$withval"],
  57   [fishcompletiondir='${datadir}/fish/vendor_completions.d'])
  58 AC_SUBST([fishcompletiondir])
  59
  60 AC_ARG_WITH([selinux-policy-dir],
  61   AS_HELP_STRING([--with-selinux-policy-dir=DIR],
  62     [name of the SELinux policy directory]),
  63   [selinux_policydir="$withval"],
  64   [selinux_policydir='${datadir}/selinux/'])
  65 AC_SUBST([selinux_policydir])
  66
  67 dnl Better be verbose.
  68 AC_MSG_CHECKING([for the store directory])
  69 AC_MSG_RESULT([$storedir])
  70
  71 AC_ARG_ENABLE([daemon],
  72   [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
  73   [guix_build_daemon="$enableval"],
  74   [guix_build_daemon="yes"])
  75
  76 # Prepare a version of $localstatedir & co. that does not contain references
  77 # to shell variables.
  78 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  79 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  80 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  81 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  82 AC_SUBST([guix_localstatedir])
  83 AC_SUBST([guix_sysconfdir])
  84 AC_SUBST([guix_sbindir])
  85
  86 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  87 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  88
  89 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  90 dnl Make sure they are available.
  91 m4_pattern_forbid([PKG_CHECK_MODULES])
  92 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  93 m4_pattern_forbid([^GUILE_P])
  94 m4_pattern_allow([^GUILE_PKG_ERRORS])
  95 m4_pattern_forbid([^GUIX_])
  96
  97 dnl Search for 'guile' and 'guild'.  This macro defines
  98 dnl 'GUILE_EFFECTIVE_VERSION'.
  99 GUILE_PKG([3.0])
 100 GUILE_PROGS
 101 if test "x$GUILD" = "x"; then
 102    AC_MSG_ERROR(['guild' binary not found; please check your Guile installation.])
 103 fi
 104
 105 dnl (guix ui), notably, requires 'default-optimization-level' added in 3.0.3.
 106 PKG_CHECK_MODULES([GUILE], [guile-3.0 >= 3.0.3])
 107
 108 dnl Get CFLAGS and LDFLAGS for libguile.
 109 GUILE_FLAGS
 110
 111 dnl Installation directories for .scm and .go files.
 112 guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
 113 guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
 114 AC_SUBST([guilemoduledir])
 115 AC_SUBST([guileobjectdir])
 116
 117 dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
 118 dnl pull', among other things.
 119 GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
 120 if test "x$have_gnutls" != "xyes"; then
 121   AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
 122 fi
 123
 124 dnl Check for Guile-Git.
 125 GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
 126 if test "x$have_guile_git" != "xyes"; then
 127   AC_MSG_ERROR([Guile-Git is missing; please install it.])
 128 fi
 129
 130 dnl Check for Guile-JSON.
 131 GUIX_CHECK_GUILE_JSON
 132 if test "x$guix_cv_have_recent_guile_json" != "xyes"; then
 133   AC_MSG_ERROR([Guile-JSON is missing; please install it.])
 134 fi
 135
 136 dnl Guile-Sqlite3 is used by the (guix store ...) modules.
 137 GUIX_CHECK_GUILE_SQLITE3
 138 if test "x$guix_cv_have_recent_guile_sqlite3" != "xyes"; then
 139   AC_MSG_ERROR([A recent Guile-SQLite3 could not be found; please install it.])
 140 fi
 141
 142 GUIX_CHECK_GUILE_GCRYPT
 143 if test "x$guix_cv_have_recent_guile_gcrypt" != "xyes"; then
 144   AC_MSG_ERROR([A recent Guile-Gcrypt could not be found; please install it.])
 145 fi
 146
 147 GUIX_CHECK_GUILE_GIT
 148 if test "x$guix_cv_have_recent_guile_git" != "xyes"; then
 149   AC_MSG_ERROR([A recent Guile-Git could not be found; please install it.])
 150 fi
 151
 152 dnl Check for the optional Guile-Lib.
 153 GUILE_MODULE_EXPORTS([have_guile_lib], [(htmlprag)], [%strict-tokenizer?])
 154 AM_CONDITIONAL([HAVE_GUILE_LIB], [test "x$have_guile_lib" = "xyes"])
 155 AM_COND_IF(HAVE_GUILE_LIB,,
 156   [AC_MSG_WARN([The Guile-Lib requirement was not satisfied (>= 0.2.7);
 157 Some features such as the Go importer will not be usable.])])
 158
 159 dnl Check for Guile-zlib.
 160 GUIX_CHECK_GUILE_ZLIB
 161 if test "x$guix_cv_have_recent_guile_zlib" != "xyes"; then
 162   AC_MSG_ERROR([A recent Guile-zlib could not be found; please install it.])
 163 fi
 164
 165 dnl Check for Guile-lzlib.
 166 GUILE_MODULE_AVAILABLE([have_guile_lzlib], [(lzlib)])
 167 if test "x$have_guile_lzlib" != "xyes"; then
 168   AC_MSG_ERROR([Guile-lzlib is missing; please install it.])
 169 fi
 170
 171 dnl Check for Guile-Avahi.
 172 GUILE_MODULE_AVAILABLE([have_guile_avahi], [(avahi)])
 173 AM_CONDITIONAL([HAVE_GUILE_AVAHI],
 174   [test "x$have_guile_avahi" = "xyes"])
 175
 176 dnl Guile-newt is used by the graphical installer.
 177 GUILE_MODULE_AVAILABLE([have_guile_newt], [(newt)])
 178
 179 AC_ARG_ENABLE([installer],
 180     AS_HELP_STRING([--enable-installer], [Build the graphical installer sources.]))
 181
 182 AS_IF([test "x$enable_installer" = "xyes"], [
 183 if test "x$have_guile_newt" != "xyes"; then
 184   AC_MSG_ERROR([Guile-newt could not be found; please install it.])
 185 fi
 186 ])
 187
 188 AM_CONDITIONAL([ENABLE_INSTALLER],
 189   [test "x$enable_installer" = "xyes"])
 190
 191 dnl Make sure we have a full-fledged Guile.
 192 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
 193
 194 AC_PROG_SED
 195
 196 dnl Decompressors, for use by the substituter and other modules.
 197 AC_PATH_PROG([GZIP], [gzip])
 198 AC_PATH_PROG([BZIP2], [bzip2])
 199 AC_PATH_PROG([XZ], [xz])
 200 AC_SUBST([GZIP])
 201 AC_SUBST([BZIP2])
 202 AC_SUBST([XZ])
 203
 204 LIBGCRYPT_LIBDIR="no"
 205 LIBGCRYPT_PREFIX="no"
 206
 207 AC_ARG_WITH([libgcrypt-prefix],
 208   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 209   [case "$withval" in
 210     yes|no)
 211       ;;
 212     *)
 213       LIBGCRYPT_PREFIX="$withval"
 214       LIBGCRYPT_LIBDIR="$withval/lib"
 215       ;;
 216    esac])
 217
 218 AC_ARG_WITH([libgcrypt-libdir],
 219   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 220      [search for GNU libgcrypt's shared library in DIR])],
 221   [case "$withval" in
 222     yes|no)
 223       LIBGCRYPT_LIBDIR="no"
 224       ;;
 225     *)
 226       LIBGCRYPT_LIBDIR="$withval"
 227       ;;
 228    esac])
 229
 230 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 231 dnl the library directory.
 232 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 233   xnono)
 234     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 235     ;;
 236 esac
 237
 238 AC_SUBST([LIBGCRYPT_PREFIX])
 239 AC_SUBST([LIBGCRYPT_LIBDIR])
 240
 241 dnl Check for Guile-SSH, for the (guix ssh) module.
 242 GUIX_CHECK_GUILE_SSH
 243 AM_CONDITIONAL([HAVE_GUILE_SSH],
 244   [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
 245
 246 AC_CACHE_SAVE
 247
 248 m4_include([config-daemon.ac])
 249
 250 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 251 dnl See `Building from Git' in the manual for more info.
 252 AM_MISSING_PROG([DOT], [dot])
 253
 254 dnl Manual pages.
 255 AM_MISSING_PROG([HELP2MAN], [help2man])
 256
 257 dnl Documentation translation.
 258 AM_MISSING_PROG([PO4A_TRANSLATE], [po4a-translate])
 259 AM_MISSING_PROG([PO4A_UPDATEPO], [po4a-updatepo])
 260
 261 case "$storedir" in
 262   /gnu/store)
 263     ;;
 264   *)
 265     AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
 266     AC_MSG_WARN([from downloading substitutes from gnu.org.])
 267     ;;
 268 esac
 269
 270 AC_CONFIG_FILES([Makefile
 271                  po/guix/Makefile.in
 272                  po/packages/Makefile.in
 273                  etc/guix-daemon.cil
 274                  guix/config.scm])
 275
 276 AC_CONFIG_FILES([etc/committer.scm], [chmod +x etc/committer.scm])
 277 AC_CONFIG_FILES([etc/teams.scm], [chmod +x etc/teams.scm])
 278 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 279 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 280   [chmod +x pre-inst-env])
 281
 282 AC_OUTPUT