gnu/system.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014, 2015, 2016, 2017, 2018, 2019, 2020 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2015 Mark H Weaver <mhw@netris.org>
   4 ;;; Copyright © 2015, 2016 Alex Kost <alezost@gmail.com>
   5 ;;; Copyright © 2016 Chris Marusich <cmmarusich@gmail.com>
   6 ;;; Copyright © 2017 Mathieu Othacehe <m.othacehe@gmail.com>
   7 ;;; Copyright © 2019 Meiyo Peng <meiyo.peng@gmail.com>
   8 ;;; Copyright © 2020 Danny Milosavljevic <dannym@scratchpost.org>
   9 ;;; Copyright © 2020 Brice Waegeneire <brice@waegenei.re>
  10 ;;; Copyright © 2020 Florian Pelz <pelzflorian@pelzflorian.de>
  11 ;;; Copyright © 2020 Maxim Cournoyer <maxim.cournoyer@gmail.com>
  12 ;;; Copyright © 2020 Jan (janneke) Nieuwenhuizen <jannek@gnu.org>
  13 ;;;
  14 ;;; This file is part of GNU Guix.
  15 ;;;
  16 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  17 ;;; under the terms of the GNU General Public License as published by
  18 ;;; the Free Software Foundation; either version 3 of the License, or (at
  19 ;;; your option) any later version.
  20 ;;;
  21 ;;; GNU Guix is distributed in the hope that it will be useful, but
  22 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  23 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 ;;; GNU General Public License for more details.
  25 ;;;
  26 ;;; You should have received a copy of the GNU General Public License
  27 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  28
  29 (define-module (gnu system)
  30   #:use-module (guix inferior)
  31   #:use-module (guix store)
  32   #:use-module (guix monads)
  33   #:use-module (guix gexp)
  34   #:use-module (guix records)
  35   #:use-module (guix packages)
  36   #:use-module (guix derivations)
  37   #:use-module (guix profiles)
  38   #:use-module (guix ui)
  39   #:use-module (guix utils)
  40   #:use-module (gnu packages base)
  41   #:use-module (gnu packages bash)
  42   #:use-module (gnu packages cross-base)
  43   #:use-module (gnu packages guile)
  44   #:use-module (gnu packages guile-xyz)
  45   #:use-module (gnu packages admin)
  46   #:use-module (gnu packages hurd)
  47   #:use-module (gnu packages linux)
  48   #:use-module (gnu packages pciutils)
  49   #:use-module (gnu packages package-management)
  50   #:use-module (gnu packages less)
  51   #:use-module (gnu packages zile)
  52   #:use-module (gnu packages nano)
  53   #:use-module (gnu packages gawk)
  54   #:use-module (gnu packages man)
  55   #:use-module (gnu packages texinfo)
  56   #:use-module (gnu packages compression)
  57   #:use-module (gnu packages firmware)
  58   #:use-module (gnu services)
  59   #:use-module (gnu services shepherd)
  60   #:use-module (gnu services base)
  61   #:use-module (gnu bootloader)
  62   #:use-module (gnu system shadow)
  63   #:use-module (gnu system nss)
  64   #:use-module (gnu system locale)
  65   #:use-module (gnu system pam)
  66   #:use-module (gnu system linux-initrd)
  67   #:use-module (gnu system uuid)
  68   #:use-module (gnu system file-systems)
  69   #:use-module (gnu system mapped-devices)
  70   #:use-module (ice-9 match)
  71   #:use-module (srfi srfi-1)
  72   #:use-module (srfi srfi-26)
  73   #:use-module (srfi srfi-34)
  74   #:use-module (srfi srfi-35)
  75   #:use-module (rnrs bytevectors)
  76   #:export (operating-system
  77             operating-system?
  78             this-operating-system
  79
  80             operating-system-bootloader
  81             operating-system-services
  82             operating-system-essential-services
  83             operating-system-default-essential-services
  84             operating-system-user-services
  85             operating-system-packages
  86             operating-system-host-name
  87             operating-system-hosts-file
  88             operating-system-hurd
  89             operating-system-kernel
  90             operating-system-kernel-file
  91             operating-system-kernel-arguments
  92             operating-system-label
  93             operating-system-default-label
  94             operating-system-initrd-modules
  95             operating-system-initrd
  96             operating-system-users
  97             operating-system-groups
  98             operating-system-issue
  99             operating-system-timezone
 100             operating-system-locale
 101             operating-system-locale-definitions
 102             operating-system-locale-libcs
 103             operating-system-mapped-devices
 104             operating-system-file-systems
 105             operating-system-store-file-system
 106             operating-system-user-mapped-devices
 107             operating-system-boot-mapped-devices
 108             operating-system-activation-script
 109             operating-system-user-accounts
 110             operating-system-shepherd-service-names
 111             operating-system-user-kernel-arguments
 112             operating-system-firmware
 113             operating-system-keyboard-layout
 114             operating-system-name-service-switch
 115             operating-system-pam-services
 116             operating-system-setuid-programs
 117             operating-system-skeletons
 118             operating-system-sudoers-file
 119             operating-system-swap-devices
 120             operating-system-kernel-loadable-modules
 121
 122             operating-system-derivation
 123             operating-system-profile
 124             operating-system-bootcfg
 125             operating-system-etc-directory
 126             operating-system-locale-directory
 127             operating-system-boot-script
 128             operating-system-uuid
 129
 130             system-linux-image-file-name
 131             operating-system-with-gc-roots
 132             operating-system-with-provenance
 133
 134             hurd-default-essential-services
 135
 136             boot-parameters
 137             boot-parameters?
 138             boot-parameters-label
 139             boot-parameters-root-device
 140             boot-parameters-bootloader-name
 141             boot-parameters-bootloader-menu-entries
 142             boot-parameters-store-device
 143             boot-parameters-store-mount-point
 144             boot-parameters-kernel
 145             boot-parameters-kernel-arguments
 146             boot-parameters-initrd
 147             boot-parameters-multiboot-modules
 148             read-boot-parameters
 149             read-boot-parameters-file
 150             boot-parameters->menu-entry
 151
 152             local-host-aliases
 153             %root-account
 154             %setuid-programs
 155             %sudoers-specification
 156             %base-packages
 157             %base-packages-interactive
 158             %base-packages-linux
 159             %base-packages-networking
 160             %base-packages-utils
 161             %base-firmware
 162             %default-kernel-arguments))
 163
 164 ;;; Commentary:
 165 ;;;
 166 ;;; This module supports whole-system configuration.
 167 ;;;
 168 ;;; Code:
 169
 170 (define (bootable-kernel-arguments system root-device)
 171   "Return a list of kernel arguments (gexps) to boot SYSTEM from ROOT-DEVICE."
 172   (list (string-append "--root="
 173                        ;; Note: Always use the DCE format because that's what
 174                        ;; (gnu build linux-boot) expects for the '--root'
 175                        ;; kernel command-line option.
 176                        (file-system-device->string root-device
 177                                                    #:uuid-type 'dce))
 178         #~(string-append "--system=" #$system)
 179         #~(string-append "--load=" #$system "/boot")))
 180
 181 ;; System-wide configuration.
 182 ;; TODO: Add per-field docstrings/stexi.
 183 (define-record-type* <operating-system> operating-system
 184   make-operating-system
 185   operating-system?
 186   this-operating-system
 187
 188   (kernel operating-system-kernel                 ; package
 189           (default linux-libre))
 190   (kernel-loadable-modules operating-system-kernel-loadable-modules
 191                     (default '()))                ; list of packages
 192   (kernel-arguments operating-system-user-kernel-arguments
 193                     (default %default-kernel-arguments)) ; list of gexps/strings
 194   (hurd operating-system-hurd
 195         (default #f))                             ; package
 196   (bootloader operating-system-bootloader)        ; <bootloader-configuration>
 197   (label operating-system-label                   ; string
 198          (thunked)
 199          (default (operating-system-default-label this-operating-system)))
 200
 201   (keyboard-layout operating-system-keyboard-layout ;#f | <keyboard-layout>
 202                    (default #f))
 203   (initrd operating-system-initrd                 ; (list fs) -> file-like
 204           (default base-initrd))
 205   (initrd-modules operating-system-initrd-modules ; list of strings
 206                   (thunked)                       ; it's system-dependent
 207                   (default %base-initrd-modules))
 208
 209   (firmware operating-system-firmware             ; list of packages
 210             (default %base-firmware))
 211
 212   (host-name operating-system-host-name)          ; string
 213   (hosts-file operating-system-hosts-file         ; file-like | #f
 214               (default #f))
 215
 216   (mapped-devices operating-system-mapped-devices ; list of <mapped-device>
 217                   (default '()))
 218   (file-systems operating-system-file-systems)    ; list of fs
 219   (swap-devices operating-system-swap-devices     ; list of strings
 220                 (default '()))
 221
 222   (users operating-system-users                   ; list of user accounts
 223          (default %base-user-accounts))
 224   (groups operating-system-groups                 ; list of user groups
 225           (default %base-groups))
 226
 227   (skeletons operating-system-skeletons           ; list of name/file-like value
 228              (default (default-skeletons)))
 229   (issue operating-system-issue                   ; string
 230          (default %default-issue))
 231
 232   (packages operating-system-packages             ; list of (PACKAGE OUTPUT...)
 233             (default %base-packages))             ; or just PACKAGE
 234
 235   (timezone operating-system-timezone)            ; string
 236   (locale   operating-system-locale               ; string
 237             (default "en_US.utf8"))
 238   (locale-definitions operating-system-locale-definitions ; list of <locale-definition>
 239                       (default %default-locale-definitions))
 240   (locale-libcs operating-system-locale-libcs     ; list of <packages>
 241                 (default %default-locale-libcs))
 242   (name-service-switch operating-system-name-service-switch ; <name-service-switch>
 243                        (default %default-nss))
 244
 245   (essential-services operating-system-essential-services ; list of services
 246                       (thunked)
 247                       (default (operating-system-default-essential-services
 248                                 this-operating-system)))
 249   (services operating-system-user-services        ; list of services
 250             (default %base-services))
 251
 252   (pam-services operating-system-pam-services     ; list of PAM services
 253                 (default (base-pam-services)))
 254   (setuid-programs operating-system-setuid-programs
 255                    (default %setuid-programs))    ; list of string-valued gexps
 256
 257   (sudoers-file operating-system-sudoers-file     ; file-like
 258                 (default %sudoers-specification)))
 259
 260 (define (operating-system-kernel-arguments os root-device)
 261   "Return all the kernel arguments, including the ones not specified
 262 directly by the user."
 263   (append (bootable-kernel-arguments os root-device)
 264           (operating-system-user-kernel-arguments os)))
 265
 266 \f
 267 ;;;
 268 ;;; Boot parameters
 269 ;;;
 270
 271 (define-record-type* <boot-parameters>
 272   boot-parameters make-boot-parameters boot-parameters?
 273   (label            boot-parameters-label)
 274   ;; Because we will use the 'store-device' to create the GRUB search command,
 275   ;; the 'store-device' has slightly different semantics than 'root-device'.
 276   ;; The 'store-device' can be a file system uuid, a file system label, or #f,
 277   ;; but it cannot be a device path such as "/dev/sda3", since GRUB would not
 278   ;; understand that.  The 'root-device', on the other hand, corresponds
 279   ;; exactly to the device field of the <file-system> object representing the
 280   ;; OS's root file system, so it might be a device path like "/dev/sda3".
 281   (root-device      boot-parameters-root-device)
 282   (bootloader-name  boot-parameters-bootloader-name)
 283   (bootloader-menu-entries                        ;list of <menu-entry>
 284    boot-parameters-bootloader-menu-entries)
 285   (store-device     boot-parameters-store-device)
 286   (store-mount-point boot-parameters-store-mount-point)
 287   (kernel           boot-parameters-kernel)
 288   (kernel-arguments boot-parameters-kernel-arguments)
 289   (initrd           boot-parameters-initrd)
 290   (multiboot-modules boot-parameters-multiboot-modules))
 291
 292 (define (ensure-not-/dev device)
 293   "If DEVICE starts with a slash, return #f.  This is meant to filter out
 294 Linux device names such as /dev/sda, and to preserve GRUB device names and
 295 file system labels."
 296   (if (and (string? device) (string-prefix? "/" device))
 297       #f
 298       device))
 299
 300 (define (read-boot-parameters port)
 301   "Read boot parameters from PORT and return the corresponding
 302 <boot-parameters> object or #f if the format is unrecognized."
 303   (define device-sexp->device
 304     (match-lambda
 305       (('uuid (? symbol? type) (? bytevector? bv))
 306        (bytevector->uuid bv type))
 307       (('file-system-label (? string? label))
 308        (file-system-label label))
 309       ((? bytevector? bv)                         ;old format
 310        (bytevector->uuid bv 'dce))
 311       ((? string? device)
 312        ;; It used to be that we would not distinguish between labels and
 313        ;; device names.  Try to infer the right thing here.
 314        (if (string-prefix? "/dev/" device)
 315            device
 316            (file-system-label device)))))
 317
 318   (match (read port)
 319     (('boot-parameters ('version 0)
 320                        ('label label) ('root-device root)
 321                        ('kernel kernel)
 322                        rest ...)
 323      (boot-parameters
 324       (label label)
 325       (root-device (device-sexp->device root))
 326
 327       (bootloader-name
 328        (match (assq 'bootloader-name rest)
 329          ((_ args) args)
 330          (#f       'grub))) ; for compatibility reasons.
 331
 332       (bootloader-menu-entries
 333        (match (assq 'bootloader-menu-entries rest)
 334          ((_ entries) (map sexp->menu-entry entries))
 335          (#f          '())))
 336
 337       ;; In the past, we would store the directory name of linux instead of
 338       ;; the absolute file name of its image.  Detect that and correct it.
 339       (kernel (if (string=? kernel (direct-store-path kernel))
 340                   (string-append kernel "/"
 341                                  (system-linux-image-file-name))
 342                   kernel))
 343
 344       (kernel-arguments
 345        (match (assq 'kernel-arguments rest)
 346          ((_ args) args)
 347          (#f       '())))                         ;the old format
 348
 349       (initrd
 350        (match (assq 'initrd rest)
 351          (('initrd ('string-append directory file)) ;the old format
 352           (string-append directory file))
 353          (('initrd (? string? file))
 354           file)))
 355
 356       (multiboot-modules (or (assq 'multiboot-modules rest) '()))
 357
 358       (store-device
 359        ;; Linux device names like "/dev/sda1" are not suitable GRUB device
 360        ;; identifiers, so we just filter them out.
 361        (ensure-not-/dev
 362         (match (assq 'store rest)
 363           (('store ('device #f) _ ...)
 364            root-device)
 365           (('store ('device device) _ ...)
 366            (device-sexp->device device))
 367           (_                                      ;the old format
 368            root-device))))
 369
 370       (store-mount-point
 371        (match (assq 'store rest)
 372          (('store ('device _) ('mount-point mount-point) _ ...)
 373           mount-point)
 374          (_                                       ;the old format
 375           "/")))))
 376     (x                                            ;unsupported format
 377      (warning (G_ "unrecognized boot parameters at '~a'~%")
 378               (port-filename port))
 379      #f)))
 380
 381 (define (read-boot-parameters-file system)
 382   "Read boot parameters from SYSTEM's (system or generation) \"parameters\"
 383 file and returns the corresponding <boot-parameters> object or #f if the
 384 format is unrecognized.
 385 The object has its kernel-arguments extended in order to make it bootable."
 386   (let* ((file (string-append system "/parameters"))
 387          (params (call-with-input-file file read-boot-parameters))
 388          (root (boot-parameters-root-device params)))
 389     (boot-parameters
 390      (inherit params)
 391      (kernel-arguments (append (bootable-kernel-arguments system root)
 392                                (boot-parameters-kernel-arguments params))))))
 393
 394 (define (boot-parameters->menu-entry conf)
 395   (let* ((kernel (boot-parameters-kernel conf))
 396          (multiboot-modules (boot-parameters-multiboot-modules conf))
 397          (multiboot? (pair? multiboot-modules)))
 398     (menu-entry
 399      (label (boot-parameters-label conf))
 400      (device (boot-parameters-store-device conf))
 401      (device-mount-point (boot-parameters-store-mount-point conf))
 402      (linux (and (not multiboot?) kernel))
 403      (linux-arguments (if (not multiboot?) '
 404                           (boot-parameters-kernel-arguments conf)
 405                           '()))
 406      (initrd (boot-parameters-initrd conf))
 407      (multiboot-kernel (and multiboot? kernel))
 408      (multiboot-arguments (if multiboot?
 409                               (boot-parameters-kernel-arguments conf)
 410                               '()))
 411      (multiboot-modules (if multiboot?
 412                             (boot-parameters-multiboot-modules conf)
 413                             '())))))
 414
 415 \f
 416 ;;;
 417 ;;; Services.
 418 ;;;
 419
 420 (define (non-boot-file-system-service os)
 421   "Return the file system service for the file systems of OS that are not
 422 marked as 'needed-for-boot'."
 423   (define file-systems
 424     (remove file-system-needed-for-boot?
 425             (operating-system-file-systems os)))
 426
 427   (define mapped-devices-for-boot
 428     (operating-system-boot-mapped-devices os))
 429
 430   (define (device-mappings fs)
 431     (let ((device (file-system-device fs)))
 432       (if (string? device)                        ;title is 'device
 433           (filter (lambda (md)
 434                     (string=? (string-append "/dev/mapper/"
 435                                              (mapped-device-target md))
 436                               device))
 437                   (operating-system-mapped-devices os))
 438           '())))
 439
 440   (define (add-dependencies fs)
 441     ;; Add the dependencies due to device mappings to FS.
 442     (file-system
 443       (inherit fs)
 444       (dependencies
 445        (delete-duplicates
 446         (remove (cut member <> mapped-devices-for-boot)
 447                 (append (device-mappings fs)
 448                         (file-system-dependencies fs)))
 449         eq?))))
 450
 451   (service file-system-service-type
 452            (map add-dependencies file-systems)))
 453
 454 (define (mapped-device-users device file-systems)
 455   "Return the subset of FILE-SYSTEMS that use DEVICE."
 456   (let ((target (string-append "/dev/mapper/" (mapped-device-target device))))
 457     (filter (lambda (fs)
 458               (or (member device (file-system-dependencies fs))
 459                   (and (string? (file-system-device fs))
 460                        (string=? (file-system-device fs) target))))
 461             file-systems)))
 462
 463 (define (operating-system-user-mapped-devices os)
 464   "Return the subset of mapped devices that can be installed in
 465 user-land--i.e., those not needed during boot."
 466   (let ((devices      (operating-system-mapped-devices os))
 467         (file-systems (operating-system-file-systems os)))
 468    (filter (lambda (md)
 469              (let ((users (mapped-device-users md file-systems)))
 470                (not (any file-system-needed-for-boot? users))))
 471            devices)))
 472
 473 (define (operating-system-boot-mapped-devices os)
 474   "Return the subset of mapped devices that must be installed during boot,
 475 from the initrd."
 476   (let ((devices      (operating-system-mapped-devices os))
 477         (file-systems (operating-system-file-systems os)))
 478    (filter (lambda (md)
 479              (let ((users (mapped-device-users md file-systems)))
 480                (any file-system-needed-for-boot? users)))
 481            devices)))
 482
 483 (define (device-mapping-services os)
 484   "Return the list of device-mapping services for OS as a list."
 485   (map device-mapping-service
 486        (operating-system-user-mapped-devices os)))
 487
 488 (define (swap-services os)
 489   "Return the list of swap services for OS."
 490   (map swap-service (operating-system-swap-devices os)))
 491
 492 (define* (system-linux-image-file-name #:optional
 493                                        (target (or (%current-target-system)
 494                                                    (%current-system))))
 495   "Return the basename of the kernel image file for TARGET."
 496   (cond
 497    ((string-prefix? "arm" target) "zImage")
 498    ((string-prefix? "mips" target) "vmlinuz")
 499    ((string-prefix? "aarch64" target) "Image")
 500    (else "bzImage")))
 501
 502 (define (operating-system-kernel-file os)
 503   "Return an object representing the absolute file name of the kernel image of
 504 OS."
 505   (if (operating-system-hurd os)
 506       (file-append (operating-system-kernel os) "/boot/gnumach")
 507       (file-append (operating-system-kernel os)
 508                       "/" (system-linux-image-file-name))))
 509
 510 (define (package-for-kernel target-kernel module-package)
 511   "Return a package like MODULE-PACKAGE, adapted for TARGET-KERNEL, if
 512 possible (that is if there's a LINUX keyword argument in the build system)."
 513   (package
 514     (inherit module-package)
 515     (arguments
 516      (substitute-keyword-arguments (package-arguments module-package)
 517        ((#:linux kernel #f)
 518         target-kernel)))))
 519
 520 (define %default-modprobe-blacklist
 521   ;; List of kernel modules to blacklist by default.
 522   '("usbmouse" ;races with bcm5974, see <https://bugs.gnu.org/35574>
 523     "usbkbd")) ;races with usbhid, see <https://issues.guix.gnu.org/35574#18>
 524
 525 (define %default-kernel-arguments
 526   ;; Default arguments passed to the kernel.
 527   (list (string-append "modprobe.blacklist="
 528                        (string-join %default-modprobe-blacklist ","))
 529         "quiet"))
 530
 531 (define* (operating-system-directory-base-entries os)
 532   "Return the basic entries of the 'system' directory of OS for use as the
 533 value of the SYSTEM-SERVICE-TYPE service."
 534   (let* ((locale  (operating-system-locale-directory os))
 535          (kernel  (operating-system-kernel os))
 536          (modules (operating-system-kernel-loadable-modules os))
 537          (kernel  (profile
 538                    (content (packages->manifest
 539                              (cons kernel
 540                                    (map (lambda (module)
 541                                           (if (package? module)
 542                                               (package-for-kernel kernel
 543                                                                   module)
 544                                               module))
 545                                         modules))))
 546                    (hooks (list linux-module-database))))
 547          (initrd  (operating-system-initrd-file os))
 548          (params  (operating-system-boot-parameters-file os)))
 549     `(("kernel" ,kernel)
 550       ("parameters" ,params)
 551       ("initrd" ,initrd)
 552       ("locale" ,locale))))   ;used by libc
 553
 554 (define (operating-system-default-essential-services os)
 555   "Return the list of essential services for OS.  These are special services
 556 that implement part of what's declared in OS are responsible for low-level
 557 bookkeeping."
 558   (define known-fs
 559     (map file-system-mount-point (operating-system-file-systems os)))
 560
 561   (let* ((mappings  (device-mapping-services os))
 562          (root-fs   (root-file-system-service))
 563          (other-fs  (non-boot-file-system-service os))
 564          (swaps     (swap-services os))
 565          (procs     (service user-processes-service-type))
 566          (host-name (host-name-service (operating-system-host-name os)))
 567          (entries   (operating-system-directory-base-entries os)))
 568     (cons* (service system-service-type entries)
 569            %boot-service
 570
 571            ;; %SHEPHERD-ROOT-SERVICE must come last so that the gexp that
 572            ;; execs shepherd comes last in the boot script (XXX).  Likewise,
 573            ;; the cleanup service must come first so that its gexp runs before
 574            ;; activation code.
 575            (service cleanup-service-type #f)
 576            %activation-service
 577            %shepherd-root-service
 578
 579            (pam-root-service (operating-system-pam-services os))
 580            (account-service (append (operating-system-accounts os)
 581                                     (operating-system-groups os))
 582                             (operating-system-skeletons os))
 583            (operating-system-etc-service os)
 584            (service fstab-service-type
 585                     (filter file-system-needed-for-boot?
 586                             (operating-system-file-systems os)))
 587            (session-environment-service
 588             (operating-system-environment-variables os))
 589            host-name procs root-fs
 590            (service setuid-program-service-type
 591                     (operating-system-setuid-programs os))
 592            (service profile-service-type
 593                     (operating-system-packages os))
 594            other-fs
 595            (append mappings swaps
 596
 597                    ;; Add the firmware service.
 598                    (list %linux-bare-metal-service
 599                          (service firmware-service-type
 600                                   (operating-system-firmware os)))))))
 601
 602 (define (hurd-default-essential-services os)
 603   (list (service system-service-type '())
 604         (service profile-service-type '())))
 605
 606 (define* (operating-system-services os)
 607   "Return all the services of OS, including \"essential\" services."
 608   (instantiate-missing-services
 609    (append (operating-system-user-services os)
 610            (operating-system-essential-services os))))
 611
 612 (define (operating-system-with-gc-roots os roots)
 613   "Return a variant of OS where ROOTS are registered as GC roots."
 614   (operating-system
 615     (inherit os)
 616
 617     ;; We use this procedure for the installation OS, which already defines GC
 618     ;; roots.  Add ROOTS to those.
 619     (services (cons (simple-service 'extra-root
 620                                     gc-root-service-type roots)
 621                     (operating-system-user-services os)))))
 622
 623 (define* (operating-system-with-provenance os #:optional config-file)
 624   "Return a variant of OS that stores its own provenance information,
 625 including CONFIG-FILE, if available.  This is achieved by adding an instance
 626 of PROVENANCE-SERVICE-TYPE to its services."
 627   (operating-system
 628     (inherit os)
 629     (services (cons (service provenance-service-type config-file)
 630                     (operating-system-user-services os)))))
 631
 632 \f
 633 ;;;
 634 ;;; /etc.
 635 ;;;
 636
 637 (define %base-firmware
 638   ;; Firmware usable by default.
 639   (list ath9k-htc-firmware
 640         openfwwf-firmware))
 641
 642 (define %base-packages-utils
 643   ;; Default set of  utilities packages.
 644  (cons* procps psmisc which
 645         (@ (gnu packages admin) shadow) ;for 'passwd'
 646
 647         guile-3.0
 648
 649         ;; The packages below are also in %FINAL-INPUTS, so take them from
 650         ;; there to avoid duplication.
 651         (list bash coreutils findutils grep sed
 652               diffutils patch gawk tar gzip bzip2 xz lzip)))
 653
 654 (define %base-packages-linux
 655   ;; Default set of linux specific packages.
 656   (list pciutils usbutils
 657         util-linux+udev
 658         ;; Get 'insmod' & co. from kmod, not module-init-tools, since udev
 659         ;; already depends on it anyway.
 660         kmod eudev))
 661
 662 (define %base-packages-interactive
 663   ;; Default set of common interactive packages.
 664   (list less zile nano
 665         man-db
 666         info-reader                     ;the standalone Info reader (no Perl)
 667         bash-completion
 668         kbd
 669         ;; The 'sudo' command is already in %SETUID-PROGRAMS, but we also
 670         ;; want the other commands and the man pages (notably because
 671         ;; auto-completion in Emacs shell relies on man pages.)
 672         sudo
 673         guile-readline guile-colorized))
 674
 675 (define %base-packages-networking
 676   ;; Default set of networking packages.
 677   (list inetutils isc-dhcp
 678         iproute
 679         ;; wireless-tools is deprecated in favor of iw, but it's still what
 680         ;; many people are familiar with, so keep it around.
 681         iw wireless-tools))
 682
 683 (define %base-packages
 684   ;; Default set of packages globally visible.  It should include anything
 685   ;; required for basic administrator tasks.
 686   (append (list e2fsprogs)
 687           %base-packages-interactive
 688           %base-packages-linux
 689           %base-packages-networking
 690           %base-packages-utils))
 691
 692 (define %default-issue
 693   ;; Default contents for /etc/issue.
 694   "
 695 This is the GNU system.  Welcome.\n")
 696
 697 (define (local-host-aliases host-name)
 698   "Return aliases for HOST-NAME, to be used in /etc/hosts."
 699   (string-append "127.0.0.1 localhost " host-name "\n"
 700                  "::1       localhost " host-name "\n"))
 701
 702 (define (default-/etc/hosts host-name)
 703   "Return the default /etc/hosts file."
 704   (plain-file "hosts" (local-host-aliases host-name)))
 705
 706 (define* (operating-system-etc-service os)
 707   "Return a <service> that builds containing the static part of the /etc
 708 directory."
 709   (let ((login.defs
 710           (plain-file "login.defs"
 711                       (string-append
 712                         "# Default paths for non-login shells started by su(1).\n"
 713                         "ENV_PATH    /run/setuid-programs:"
 714                         "/run/current-system/profile/bin:"
 715                         "/run/current-system/profile/sbin\n"
 716                         "ENV_SUPATH  /run/setuid-programs:"
 717                         "/run/current-system/profile/bin:"
 718                         "/run/current-system/profile/sbin\n")))
 719
 720         (issue      (plain-file "issue" (operating-system-issue os)))
 721         (nsswitch   (plain-file "nsswitch.conf"
 722                                 (name-service-switch->string
 723                                  (operating-system-name-service-switch os))))
 724
 725         ;; Startup file for POSIX-compliant login shells, which set system-wide
 726         ;; environment variables.
 727         (profile    (mixed-text-file "profile"  "\
 728 # Crucial variables that could be missing in the profiles' 'etc/profile'
 729 # because they would require combining both profiles.
 730 # FIXME: See <http://bugs.gnu.org/20255>.
 731 export MANPATH=$HOME/.guix-profile/share/man:/run/current-system/profile/share/man
 732 export INFOPATH=$HOME/.guix-profile/share/info:/run/current-system/profile/share/info
 733 export XDG_DATA_DIRS=$HOME/.guix-profile/share:/run/current-system/profile/share
 734 export XDG_CONFIG_DIRS=$HOME/.guix-profile/etc/xdg:/run/current-system/profile/etc/xdg
 735
 736 # Make sure libXcursor finds cursors installed into user or system profiles.  See <http://bugs.gnu.org/24445>
 737 export XCURSOR_PATH=$HOME/.icons:$HOME/.guix-profile/share/icons:/run/current-system/profile/share/icons
 738
 739 # Ignore the default value of 'PATH'.
 740 unset PATH
 741
 742 # Load the system profile's settings.
 743 GUIX_PROFILE=/run/current-system/profile ; \\
 744 . /run/current-system/profile/etc/profile
 745
 746 # Since 'lshd' does not use pam_env, /etc/environment must be explicitly
 747 # loaded when someone logs in via SSH.  See <http://bugs.gnu.org/22175>.
 748 # We need 'PATH' to be defined here, for 'cat' and 'cut'.  Do this before
 749 # reading the user's 'etc/profile' to allow variables to be overridden.
 750 if [ -f /etc/environment -a -n \"$SSH_CLIENT\" \\
 751      -a -z \"$LINUX_MODULE_DIRECTORY\" ]
 752 then
 753   . /etc/environment
 754   export `cat /etc/environment | cut -d= -f1`
 755 fi
 756
 757 # Arrange so that ~/.config/guix/current comes first.
 758 for profile in \"$HOME/.guix-profile\" \"$HOME/.config/guix/current\"
 759 do
 760   if [ -f \"$profile/etc/profile\" ]
 761   then
 762     # Load the user profile's settings.
 763     GUIX_PROFILE=\"$profile\" ; \\
 764     . \"$profile/etc/profile\"
 765   else
 766     # At least define this one so that basic things just work
 767     # when the user installs their first package.
 768     export PATH=\"$profile/bin:$PATH\"
 769   fi
 770 done
 771
 772 # Prepend setuid programs.
 773 export PATH=/run/setuid-programs:$PATH
 774
 775 # Arrange so that ~/.config/guix/current/share/info comes first.
 776 export INFOPATH=\"$HOME/.config/guix/current/share/info:$INFOPATH\"
 777
 778 # Set the umask, notably for users logging in via 'lsh'.
 779 # See <http://bugs.gnu.org/22650>.
 780 umask 022
 781
 782 # Allow Hunspell-based applications (IceCat, LibreOffice, etc.) to
 783 # find dictionaries.
 784 export DICPATH=\"$HOME/.guix-profile/share/hunspell:/run/current-system/profile/share/hunspell\"
 785
 786 # Allow GStreamer-based applications to find plugins.
 787 export GST_PLUGIN_PATH=\"$HOME/.guix-profile/lib/gstreamer-1.0\"
 788
 789 if [ -n \"$BASH_VERSION\" -a -f /etc/bashrc ]
 790 then
 791   # Load Bash-specific initialization code.
 792   . /etc/bashrc
 793 fi
 794 "))
 795
 796         (bashrc    (plain-file "bashrc" "\
 797 # Bash-specific initialization.
 798
 799 # The 'bash-completion' package.
 800 if [ -f /run/current-system/profile/etc/profile.d/bash_completion.sh ]
 801 then
 802   # Bash-completion sources ~/.bash_completion.  It installs a dynamic
 803   # completion loader that searches its own completion files as well
 804   # as those in ~/.guix-profile and /run/current-system/profile.
 805   source /run/current-system/profile/etc/profile.d/bash_completion.sh
 806 fi\n")))
 807     (etc-service
 808      `(("services" ,(file-append net-base "/etc/services"))
 809        ("protocols" ,(file-append net-base "/etc/protocols"))
 810        ("rpc" ,(file-append net-base "/etc/rpc"))
 811        ("login.defs" ,#~#$login.defs)
 812        ("issue" ,#~#$issue)
 813        ("nsswitch.conf" ,#~#$nsswitch)
 814        ("profile" ,#~#$profile)
 815        ("bashrc" ,#~#$bashrc)
 816        ("hosts" ,#~#$(or (operating-system-hosts-file os)
 817                          (default-/etc/hosts (operating-system-host-name os))))
 818        ;; Write the operating-system-host-name to /etc/hostname to prevent
 819        ;; NetworkManager from changing the system's hostname when connecting
 820        ;; to certain networks.  Some discussion at
 821        ;; https://lists.gnu.org/archive/html/help-guix/2017-09/msg00037.html
 822        ("hostname" ,(plain-file "hostname" (operating-system-host-name os)))
 823        ;; Some programs (e.g., GLib) look at /etc/timezone to find the
 824        ;; name of the current timezone.  For details, see
 825        ;; https://lists.gnu.org/archive/html/guix-devel/2019-07/msg00166.html
 826        ("timezone" ,(plain-file "timezone" (operating-system-timezone os)))
 827        ("localtime" ,(file-append tzdata "/share/zoneinfo/"
 828                                   (operating-system-timezone os)))
 829        ("sudoers" ,(operating-system-sudoers-file os))))))
 830
 831 (define %root-account
 832   ;; Default root account.
 833   (user-account
 834    (name "root")
 835    (password "")
 836    (uid 0) (group "root")
 837    (comment "System administrator")
 838    (home-directory "/root")))
 839
 840 (define (operating-system-accounts os)
 841   "Return the user accounts for OS, including an obligatory 'root' account,
 842 and excluding accounts requested by services."
 843   ;; Make sure there's a root account.
 844   (if (find (lambda (user)
 845               (and=> (user-account-uid user) zero?))
 846             (operating-system-users os))
 847       (operating-system-users os)
 848       (cons %root-account (operating-system-users os))))
 849
 850 (define (maybe-string->file file-name thing)
 851   "If THING is a string, return a <plain-file> with THING as its content.
 852 Otherwise just return THING.
 853
 854 This is for backward-compatibility of fields that used to be strings and are
 855 now file-like objects.."
 856   (match thing
 857     ((? string?)
 858      (warning (G_ "using a string for file '~a' is deprecated; \
 859 use 'plain-file' instead~%")
 860               file-name)
 861      (plain-file file-name thing))
 862     (x
 863      x)))
 864
 865 (define (maybe-file->monadic file-name thing)
 866   "If THING is a value in %STORE-MONAD, return it as is; otherwise return
 867 THING in the %STORE-MONAD.
 868
 869 This is for backward-compatibility of fields that used to be monadic values
 870 and are now file-like objects."
 871   (with-monad %store-monad
 872     (match thing
 873       ((? procedure?)
 874        (warning (G_ "using a monadic value for '~a' is deprecated; \
 875 use 'plain-file' instead~%")
 876                 file-name)
 877        thing)
 878       (x
 879        (return x)))))
 880
 881 (define (operating-system-etc-directory os)
 882   "Return that static part of the /etc directory of OS."
 883   (etc-directory
 884    (fold-services (operating-system-services os)
 885                   #:target-type etc-service-type)))
 886
 887 (define (operating-system-environment-variables os)
 888   "Return the environment variables of OS for
 889 @var{session-environment-service-type}, to be used in @file{/etc/environment}."
 890   `(("LANG" . ,(operating-system-locale os))
 891     ;; Note: No need to set 'TZ' since (1) we provide /etc/localtime, and (2)
 892     ;; it doesn't work for setuid binaries.  See <https://bugs.gnu.org/29212>.
 893     ("TZDIR" . ,(file-append tzdata "/share/zoneinfo"))
 894     ;; Tell 'modprobe' & co. where to look for modules.
 895     ("LINUX_MODULE_DIRECTORY" . "/run/booted-system/kernel/lib/modules")
 896     ;; These variables are honored by OpenSSL (libssl) and Git.
 897     ("SSL_CERT_DIR" . "/etc/ssl/certs")
 898     ("SSL_CERT_FILE" . "/etc/ssl/certs/ca-certificates.crt")
 899     ("GIT_SSL_CAINFO" . "/etc/ssl/certs/ca-certificates.crt")
 900
 901     ;; 'GTK_DATA_PREFIX' must name one directory where GTK+ themes are
 902     ;; searched for.
 903     ("GTK_DATA_PREFIX" . "/run/current-system/profile")
 904
 905     ;; By default, applications that use D-Bus, such as Emacs, abort at startup
 906     ;; when /etc/machine-id is missing.  Make sure these warnings are non-fatal.
 907     ("DBUS_FATAL_WARNINGS" . "0")
 908
 909     ;; XXX: Normally we wouldn't need to do this, but our glibc@2.23 package
 910     ;; used to look things up in 'PREFIX/lib/locale' instead of
 911     ;; '/run/current-system/locale' as was intended.  Keep this hack around so
 912     ;; that people who still have glibc@2.23-using packages in their profiles
 913     ;; can use them correctly.
 914     ;; TODO: Remove when glibc@2.23 is long gone.
 915     ("GUIX_LOCPATH" . "/run/current-system/locale")))
 916
 917 (define %setuid-programs
 918   ;; Default set of setuid-root programs.
 919   (let ((shadow (@ (gnu packages admin) shadow)))
 920     (list (file-append shadow "/bin/passwd")
 921           (file-append shadow "/bin/su")
 922           (file-append shadow "/bin/newuidmap")
 923           (file-append shadow "/bin/newgidmap")
 924           (file-append inetutils "/bin/ping")
 925           (file-append inetutils "/bin/ping6")
 926           (file-append sudo "/bin/sudo")
 927           (file-append sudo "/bin/sudoedit")
 928           (file-append fuse "/bin/fusermount")
 929
 930           ;; To allow mounts with the "user" option, "mount" and "umount" must
 931           ;; be setuid-root.
 932           (file-append util-linux "/bin/mount")
 933           (file-append util-linux "/bin/umount"))))
 934
 935 (define %sudoers-specification
 936   ;; Default /etc/sudoers contents: 'root' and all members of the 'wheel'
 937   ;; group can do anything.  See
 938   ;; <http://www.sudo.ws/sudo/man/1.8.10/sudoers.man.html>.
 939   ;; TODO: Add a declarative API.
 940   (plain-file "sudoers" "\
 941 root ALL=(ALL) ALL
 942 %wheel ALL=(ALL) ALL\n"))
 943
 944 (define* (operating-system-activation-script os)
 945   "Return the activation script for OS---i.e., the code that \"activates\" the
 946 stateful part of OS, including user accounts and groups, special directories,
 947 etc."
 948   (let* ((services   (operating-system-services os))
 949          (activation (fold-services services
 950                                     #:target-type activation-service-type)))
 951     (activation-service->script activation)))
 952
 953 (define* (operating-system-boot-script os)
 954   "Return the boot script for OS---i.e., the code started by the initrd once
 955 we're running in the final root."
 956   (let* ((services (operating-system-services os))
 957          (boot     (fold-services services #:target-type boot-service-type)))
 958     (service-value boot)))
 959
 960 (define (operating-system-user-accounts os)
 961   "Return the list of user accounts of OS."
 962   (let* ((services (operating-system-services os))
 963          (account  (fold-services services
 964                                   #:target-type account-service-type)))
 965     (filter user-account?
 966             (service-value account))))
 967
 968 (define (operating-system-shepherd-service-names os)
 969   "Return the list of Shepherd service names for OS."
 970   (append-map shepherd-service-provision
 971               (service-value
 972                (fold-services (operating-system-services os)
 973                               #:target-type
 974                               shepherd-root-service-type))))
 975
 976 (define* (operating-system-derivation os)
 977   "Return a derivation that builds OS."
 978   (let* ((services (operating-system-services os))
 979          (system   (fold-services services)))
 980     ;; SYSTEM contains the derivation as a monadic value.
 981     (service-value system)))
 982
 983 (define* (operating-system-profile os)
 984   "Return a derivation that builds the system profile of OS."
 985   (mlet* %store-monad
 986       ((services -> (operating-system-services os))
 987        (profile (fold-services services
 988                                #:target-type profile-service-type)))
 989     (match profile
 990       (("profile" profile)
 991        (return profile)))))
 992
 993 (define (operating-system-root-file-system os)
 994   "Return the root file system of OS."
 995   (find (lambda (fs)
 996           (string=? "/" (file-system-mount-point fs)))
 997         (operating-system-file-systems os)))
 998
 999 (define (operating-system-initrd-file os)
1000   "Return a gexp denoting the initrd file of OS."
1001   (define boot-file-systems
1002     (filter file-system-needed-for-boot?
1003             (operating-system-file-systems os)))
1004
1005   (define mapped-devices
1006     (operating-system-boot-mapped-devices os))
1007
1008   (define make-initrd
1009     (operating-system-initrd os))
1010
1011   (make-initrd boot-file-systems
1012                #:linux (operating-system-kernel os)
1013                #:linux-modules
1014                (operating-system-initrd-modules os)
1015                #:mapped-devices mapped-devices
1016                #:keyboard-layout (operating-system-keyboard-layout os)))
1017
1018 (define* (operating-system-uuid os #:optional (type 'dce))
1019   "Compute UUID object with a deterministic \"UUID\" for OS, of the given
1020 TYPE (one of 'iso9660 or 'dce).  Return a UUID object."
1021   ;; Note: For this to be deterministic, we must not hash things that contains
1022   ;; (directly or indirectly) procedures, for example.  That rules out
1023   ;; anything that contains gexps, thunk or delayed record fields, etc.
1024
1025   (define service-name
1026     (compose service-type-name service-kind))
1027
1028   (define (file-system-digest fs)
1029     ;; Return a hashable digest that does not contain 'dependencies' since
1030     ;; this field can contain procedures.
1031     (let ((device (file-system-device fs)))
1032       (list (file-system-mount-point fs)
1033             (file-system-type fs)
1034             (file-system-device->string device)
1035             (file-system-options fs))))
1036
1037   (if (eq? type 'iso9660)
1038       (let ((pad (compose (cut string-pad <> 2 #\0)
1039                           number->string))
1040             (h   (hash (map service-name (operating-system-services os))
1041                        3600)))
1042         (bytevector->uuid
1043          (string->iso9660-uuid
1044           (string-append "1970-01-01-"
1045                          (pad (hash (operating-system-host-name os) 24)) "-"
1046                          (pad (quotient h 60)) "-"
1047                          (pad (modulo h 60)) "-"
1048                          (pad (hash (map file-system-digest
1049                                          (operating-system-file-systems os))
1050                                     100))))
1051          'iso9660))
1052       (bytevector->uuid
1053        (uint-list->bytevector
1054         (list (hash (map file-system-digest
1055                          (operating-system-file-systems os))
1056                     (- (expt 2 32) 1))
1057               (hash (operating-system-host-name os)
1058                     (- (expt 2 32) 1))
1059               (hash (map service-name (operating-system-services os))
1060                     (- (expt 2 32) 1))
1061               (hash (map file-system-digest (operating-system-file-systems os))
1062                     (- (expt 2 32) 1)))
1063         (endianness little)
1064         4)
1065        type)))
1066
1067 (define (locale-name->definition* name)
1068   "Variant of 'locale-name->definition' that raises an error upon failure."
1069   (match (locale-name->definition name)
1070     (#f
1071      (raise (condition
1072              (&message
1073               (message (format #f (G_ "~a: invalid locale name") name))))))
1074     (def def)))
1075
1076 (define (operating-system-locale-directory os)
1077   "Return the directory containing the locales compiled for the definitions
1078 listed in OS.  The C library expects to find it under
1079 /run/current-system/locale."
1080   (define name
1081     (operating-system-locale os))
1082
1083   (define definitions
1084     ;; While we're at it, check whether NAME is defined and add it if needed.
1085     (if (member name (map locale-definition-name
1086                           (operating-system-locale-definitions os)))
1087         (operating-system-locale-definitions os)
1088         (cons (locale-name->definition* name)
1089               (operating-system-locale-definitions os))))
1090
1091   (locale-directory definitions
1092                     #:libcs (operating-system-locale-libcs os)))
1093
1094 (define (kernel->boot-label kernel)
1095   "Return a label for the bootloader menu entry that boots KERNEL."
1096   (cond ((package? kernel)
1097          (string-append "GNU with "
1098                         (string-titlecase (package-name kernel)) " "
1099                         (package-version kernel)))
1100         ((inferior-package? kernel)
1101          (string-append "GNU with "
1102                         (string-titlecase (inferior-package-name kernel)) " "
1103                         (inferior-package-version kernel)))
1104         (else "GNU")))
1105
1106 (define (operating-system-default-label os)
1107   "Return the default label for OS, as it will appear in the bootloader menu
1108 entry."
1109   (kernel->boot-label (operating-system-kernel os)))
1110
1111 (define (store-file-system file-systems)
1112   "Return the file system object among FILE-SYSTEMS that contains the store."
1113   (match (filter (lambda (fs)
1114                    (and (file-system-mount? fs)
1115                         (not (memq 'bind-mount (file-system-flags fs)))
1116                         (string-prefix? (file-system-mount-point fs)
1117                                         (%store-prefix))))
1118                  file-systems)
1119     ((and candidates (head . tail))
1120      (reduce (lambda (fs1 fs2)
1121                (if (> (string-length (file-system-mount-point fs1))
1122                       (string-length (file-system-mount-point fs2)))
1123                    fs1
1124                    fs2))
1125              head
1126              candidates))))
1127
1128 (define (operating-system-store-file-system os)
1129   "Return the file system that contains the store of OS."
1130   (store-file-system (operating-system-file-systems os)))
1131
1132 (define* (operating-system-bootcfg os #:optional (old-entries '()))
1133   "Return the bootloader configuration file for OS.  Use OLD-ENTRIES,
1134 a list of <menu-entry>, to populate the \"old entries\" menu."
1135   (let* ((file-systems    (operating-system-file-systems os))
1136          (root-fs         (operating-system-root-file-system os))
1137          (root-device     (file-system-device root-fs))
1138          (params          (operating-system-boot-parameters
1139                            os root-device
1140                            #:system-kernel-arguments? #t))
1141          (entry           (boot-parameters->menu-entry params))
1142          (bootloader-conf (operating-system-bootloader os)))
1143
1144     (define generate-config-file
1145       (bootloader-configuration-file-generator
1146        (bootloader-configuration-bootloader bootloader-conf)))
1147
1148     (generate-config-file bootloader-conf (list entry)
1149                           #:old-entries old-entries
1150                           #:store-directory-prefix
1151                           (btrfs-store-subvolume-file-name file-systems))))
1152
1153 (define (operating-system-multiboot-modules os)
1154   (if (operating-system-hurd os) (hurd-multiboot-modules os) '()))
1155
1156 (define (hurd-multiboot-modules os)
1157   (let* ((hurd (operating-system-hurd os))
1158          (root-file-system-command
1159           (list (file-append hurd "/hurd/ext2fs.static")
1160                 "ext2fs"
1161                 "--multiboot-command-line='${kernel-command-line}'"
1162                 "--host-priv-port='${host-port}'"
1163                 "--device-master-port='${device-port}'"
1164                 "--exec-server-task='${exec-task}'"
1165                 "--store-type=typed"
1166                 "'${root}'" "'$(task-create)'" "'$(task-resume)'"))
1167          (target (%current-target-system))
1168          (libc (if target
1169                    (with-parameters ((%current-target-system #f))
1170                      ;; TODO: cross-libc has extra patches for the Hurd;
1171                      ;; remove in next rebuild cycle
1172                      (cross-libc target))
1173                    glibc))
1174          (exec-server-command
1175           (list (file-append libc "/lib/ld.so.1") "exec"
1176                 (file-append hurd "/hurd/exec") "'$(exec-task=task-create)'")))
1177     (list root-file-system-command exec-server-command)))
1178
1179 (define* (operating-system-boot-parameters os root-device
1180                                            #:key system-kernel-arguments?)
1181   "Return a monadic <boot-parameters> record that describes the boot
1182 parameters of OS.  When SYSTEM-KERNEL-ARGUMENTS? is true, add kernel arguments
1183 such as '--root' and '--load' to <boot-parameters>."
1184   (let* ((initrd          (and (not (hurd-target?))
1185                                (operating-system-initrd-file os)))
1186          (store           (operating-system-store-file-system os))
1187          (bootloader      (bootloader-configuration-bootloader
1188                            (operating-system-bootloader os)))
1189          (bootloader-name (bootloader-name bootloader))
1190          (label           (operating-system-label os))
1191          (multiboot-modules (operating-system-multiboot-modules os)))
1192     (boot-parameters
1193      (label label)
1194      (root-device root-device)
1195      (kernel (operating-system-kernel-file os))
1196      (kernel-arguments
1197       (if system-kernel-arguments?
1198           (operating-system-kernel-arguments os root-device)
1199           (operating-system-user-kernel-arguments os)))
1200      (initrd initrd)
1201      (multiboot-modules multiboot-modules)
1202      (bootloader-name bootloader-name)
1203      (bootloader-menu-entries
1204       (bootloader-configuration-menu-entries (operating-system-bootloader os)))
1205      (store-device (ensure-not-/dev (file-system-device store)))
1206      (store-mount-point (file-system-mount-point store)))))
1207
1208 (define (device->sexp device)
1209   "Serialize DEVICE as an sexp (really, as an object with a read syntax.)"
1210   (match device
1211     ((? uuid? uuid)
1212      `(uuid ,(uuid-type uuid) ,(uuid-bytevector uuid)))
1213     ((? file-system-label? label)
1214      `(file-system-label ,(file-system-label->string label)))
1215     (_
1216      device)))
1217
1218 (define* (operating-system-boot-parameters-file os
1219                                                 #:key system-kernel-arguments?)
1220    "Return a file that describes the boot parameters of OS.  The primary use of
1221 this file is the reconstruction of GRUB menu entries for old configurations.
1222
1223 When SYSTEM-KERNEL-ARGUMENTS? is true, add kernel arguments such as '--root'
1224 and '--load' to the returned file (since the returned file is then usually
1225 stored into the content-addressed \"system\" directory, it's usually not a
1226 good idea to give it because the content hash would change by the content hash
1227 being stored into the \"parameters\" file)."
1228    (let* ((root   (operating-system-root-file-system os))
1229           (device (file-system-device root))
1230           (params (operating-system-boot-parameters
1231                    os device
1232                    #:system-kernel-arguments?
1233                    system-kernel-arguments?)))
1234      (scheme-file "parameters"
1235                   #~(boot-parameters
1236                      (version 0)
1237                      (label #$(boot-parameters-label params))
1238                      (root-device
1239                       #$(device->sexp
1240                          (boot-parameters-root-device params)))
1241                      (kernel #$(boot-parameters-kernel params))
1242                      (kernel-arguments
1243                       #$(boot-parameters-kernel-arguments params))
1244                      (initrd #$(boot-parameters-initrd params))
1245                      (bootloader-name #$(boot-parameters-bootloader-name params))
1246                      (bootloader-menu-entries
1247                       #$(map menu-entry->sexp
1248                              (or (and=> (operating-system-bootloader os)
1249                                         bootloader-configuration-menu-entries)
1250                                  '())))
1251                      (store
1252                       (device
1253                        #$(device->sexp (boot-parameters-store-device params)))
1254                       (mount-point #$(boot-parameters-store-mount-point
1255                                       params))))
1256                   #:set-load-path? #f)))
1257
1258 (define-gexp-compiler (operating-system-compiler (os <operating-system>)
1259                                                  system target)
1260   ((store-lift
1261     (lambda (store)
1262       ;; XXX: This is not super elegant but we can't pass SYSTEM and TARGET to
1263       ;; 'operating-system-derivation'.
1264       (run-with-store store (operating-system-derivation os)
1265                       #:system system
1266                       #:target target)))))
1267
1268 ;;; system.scm ends here