gnu/services.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2015-2022 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2016 Chris Marusich <cmmarusich@gmail.com>
   4 ;;; Copyright © 2020 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
   5 ;;; Copyright © 2020, 2021 Ricardo Wurmus <rekado@elephly.net>
   6 ;;; Copyright © 2021 raid5atemyhomework <raid5atemyhomework@protonmail.com>
   7 ;;; Copyright © 2020 Christine Lemmer-Webber <cwebber@dustycloud.org>
   8 ;;; Copyright © 2020, 2021 Brice Waegeneire <brice@waegenei.re>
   9 ;;;
  10 ;;; This file is part of GNU Guix.
  11 ;;;
  12 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  13 ;;; under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 3 of the License, or (at
  15 ;;; your option) any later version.
  16 ;;;
  17 ;;; GNU Guix is distributed in the hope that it will be useful, but
  18 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 (define-module (gnu services)
  26   #:use-module (guix gexp)
  27   #:use-module (guix monads)
  28   #:use-module (guix store)
  29   #:use-module (guix records)
  30   #:use-module (guix profiles)
  31   #:use-module (guix discovery)
  32   #:use-module (guix combinators)
  33   #:use-module (guix channels)
  34   #:use-module (guix describe)
  35   #:use-module (guix sets)
  36   #:use-module (guix ui)
  37   #:use-module (guix diagnostics)
  38   #:autoload   (guix openpgp) (openpgp-format-fingerprint)
  39   #:use-module (guix modules)
  40   #:use-module (guix packages)
  41   #:use-module (guix utils)
  42   #:use-module (gnu packages base)
  43   #:use-module (gnu packages bash)
  44   #:use-module (gnu packages hurd)
  45   #:use-module (gnu system setuid)
  46   #:use-module (srfi srfi-1)
  47   #:use-module (srfi srfi-9)
  48   #:use-module (srfi srfi-9 gnu)
  49   #:use-module (srfi srfi-26)
  50   #:use-module (srfi srfi-34)
  51   #:use-module (srfi srfi-35)
  52   #:use-module (ice-9 vlist)
  53   #:use-module (ice-9 match)
  54   #:autoload   (ice-9 pretty-print) (pretty-print)
  55   #:export (service-extension
  56             service-extension?
  57             service-extension-target
  58             service-extension-compute
  59
  60             service-type
  61             service-type?
  62             service-type-name
  63             service-type-extensions
  64             service-type-compose
  65             service-type-extend
  66             service-type-default-value
  67             service-type-description
  68             service-type-location
  69
  70             %service-type-path
  71             fold-service-types
  72             lookup-service-types
  73
  74             service
  75             service?
  76             service-kind
  77             service-value
  78             service-parameters                    ;deprecated
  79
  80             simple-service
  81             modify-services
  82             service-back-edges
  83             instantiate-missing-services
  84             fold-services
  85
  86             service-error?
  87             missing-value-service-error?
  88             missing-value-service-error-type
  89             missing-value-service-error-location
  90             missing-target-service-error?
  91             missing-target-service-error-service
  92             missing-target-service-error-target-type
  93             ambiguous-target-service-error?
  94             ambiguous-target-service-error-service
  95             ambiguous-target-service-error-target-type
  96
  97             system-service-type
  98             provenance-service-type
  99             sexp->system-provenance
 100             system-provenance
 101             boot-service-type
 102             cleanup-service-type
 103             activation-service-type
 104             activation-service->script
 105             %linux-bare-metal-service
 106             %hurd-rc-script
 107             %hurd-startup-service
 108             special-files-service-type
 109             extra-special-file
 110             etc-service-type
 111             etc-directory
 112             setuid-program-service-type
 113             profile-service-type
 114             firmware-service-type
 115             gc-root-service-type
 116             linux-builder-service-type
 117             linux-builder-configuration
 118             linux-builder-configuration?
 119             linux-builder-configuration-kernel
 120             linux-builder-configuration-modules
 121             linux-loadable-module-service-type
 122
 123             %boot-service
 124             %activation-service
 125             etc-service)
 126   #:re-export (;; Note: Re-export 'delete' to allow for proper syntax matching
 127                ;; in 'modify-services' forms.  See
 128                ;; <https://debbugs.gnu.org/cgi/bugreport.cgi?bug=26805#16>.
 129                delete))
 130
 131 ;;; Comment:
 132 ;;;
 133 ;;; This module defines a broad notion of "service types" and "services."
 134 ;;;
 135 ;;; A service type describe how its instances extend instances of other
 136 ;;; service types.  For instance, some services extend the instance of
 137 ;;; ACCOUNT-SERVICE-TYPE by providing it with accounts and groups to create;
 138 ;;; others extend SHEPHERD-ROOT-SERVICE-TYPE by passing it instances of
 139 ;;; <shepherd-service>.
 140 ;;;
 141 ;;; When applicable, the service type defines how it can itself be extended,
 142 ;;; by providing one procedure to compose extensions, and one procedure to
 143 ;;; extend itself.
 144 ;;;
 145 ;;; A notable service type is SYSTEM-SERVICE-TYPE, which has a single
 146 ;;; instance, which is the root of the service DAG.  Its value is the
 147 ;;; derivation that produces the 'system' directory as returned by
 148 ;;; 'operating-system-derivation'.
 149 ;;;
 150 ;;; The 'fold-services' procedure can be passed a list of procedures, which it
 151 ;;; "folds" by propagating extensions down the graph; it returns the root
 152 ;;; service after the applying all its extensions.
 153 ;;;
 154 ;;; Code:
 155
 156 (define-record-type <service-extension>
 157   (service-extension target compute)
 158   service-extension?
 159   (target  service-extension-target)              ;<service-type>
 160   (compute service-extension-compute))            ;params -> params
 161
 162 (define &no-default-value
 163   ;; Value used to denote service types that have no associated default value.
 164   '(no default value))
 165
 166 (define-record-type* <service-type> service-type make-service-type
 167   service-type?
 168   (name       service-type-name)                  ;symbol (for debugging)
 169
 170   ;; Things extended by services of this type.
 171   (extensions service-type-extensions)            ;list of <service-extensions>
 172
 173   ;; Given a list of extensions, "compose" them.
 174   (compose    service-type-compose                ;list of Any -> Any
 175               (default #f))
 176
 177   ;; Extend the services' own parameters with the extension composition.
 178   (extend     service-type-extend                 ;list of Any -> parameters
 179               (default #f))
 180
 181   ;; Optional default value for instances of this type.
 182   (default-value service-type-default-value       ;Any
 183                  (default &no-default-value))
 184
 185   ;; Meta-data.
 186   (description  service-type-description)         ;string
 187   (location     service-type-location             ;<location>
 188                 (default (and=> (current-source-location)
 189                                 source-properties->location))
 190                 (innate)))
 191
 192 (define (write-service-type type port)
 193   (format port "#<service-type ~a ~a>"
 194           (service-type-name type)
 195           (number->string (object-address type) 16)))
 196
 197 (set-record-type-printer! <service-type> write-service-type)
 198
 199 (define %distro-root-directory
 200   ;; Absolute file name of the module hierarchy.
 201   (dirname (search-path %load-path "guix.scm")))
 202
 203 (define %service-type-path
 204   ;; Search path for service types.
 205   (make-parameter `((,%distro-root-directory . "gnu/services")
 206                     (,%distro-root-directory . "gnu/system"))))
 207
 208 (define (all-service-modules)
 209   "Return the default set of service modules."
 210   (cons (resolve-interface '(gnu services))
 211         (all-modules (%service-type-path)
 212                      #:warn warn-about-load-error)))
 213
 214 (define* (fold-service-types proc seed
 215                              #:optional
 216                              (modules (all-service-modules)))
 217   "For each service type exported by one of MODULES, call (PROC RESULT).  SEED
 218 is used as the initial value of RESULT."
 219   (fold-module-public-variables (lambda (object result)
 220                                   (if (service-type? object)
 221                                       (proc object result)
 222                                       result))
 223                                 seed
 224                                 modules))
 225
 226 (define lookup-service-types
 227   (let ((table
 228          (delay (fold-service-types (lambda (type result)
 229                                       (vhash-consq (service-type-name type)
 230                                                    type result))
 231                                     vlist-null))))
 232     (lambda (name)
 233       "Return the list of services with the given NAME (a symbol)."
 234       (vhash-foldq* cons '() name (force table)))))
 235
 236 ;; Services of a given type.
 237 (define-record-type <service>
 238   (make-service type value)
 239   service?
 240   (type       service-kind)
 241   (value      service-value))
 242
 243 (define-syntax service
 244   (syntax-rules ()
 245     "Return a service instance of TYPE.  The service value is VALUE or, if
 246 omitted, TYPE's default value."
 247     ((_ type value)
 248      (make-service type value))
 249     ((_ type)
 250      (%service-with-default-value (current-source-location)
 251                                   type))))
 252
 253 (define (%service-with-default-value location type)
 254   "Return a instance of service type TYPE with its default value, if any.  If
 255 TYPE does not have a default value, an error is raised."
 256   ;; TODO: Currently this is a run-time error but with a little bit macrology
 257   ;; we could turn it into an expansion-time error.
 258   (let ((default (service-type-default-value type)))
 259     (if (eq? default &no-default-value)
 260         (let ((location (source-properties->location location)))
 261           (raise
 262            (make-compound-condition
 263             (condition
 264              (&missing-value-service-error (type type) (location location)))
 265             (formatted-message (G_ "~a: no value specified \
 266 for service of type '~a'")
 267                                (location->string location)
 268                                (service-type-name type)))))
 269         (service type default))))
 270
 271 (define-condition-type &service-error &error
 272   service-error?)
 273
 274 (define-condition-type &missing-value-service-error &service-error
 275   missing-value-service-error?
 276   (type     missing-value-service-error-type)
 277   (location missing-value-service-error-location))
 278
 279
 280 \f
 281 ;;;
 282 ;;; Helpers.
 283 ;;;
 284
 285 (define service-parameters
 286   ;; Deprecated alias.
 287   service-value)
 288
 289 (define (simple-service name target value)
 290   "Return a service that extends TARGET with VALUE.  This works by creating a
 291 singleton service type NAME, of which the returned service is an instance."
 292   (let* ((extension (service-extension target identity))
 293          (type      (service-type (name name)
 294                                   (extensions (list extension))
 295                                   (description "This is a simple service."))))
 296     (service type value)))
 297
 298 (define-syntax %modify-service
 299   (syntax-rules (=> delete)
 300     ((_ svc (delete kind) clauses ...)
 301      (if (eq? (service-kind svc) kind)
 302          #f
 303          (%modify-service svc clauses ...)))
 304     ((_ service)
 305      service)
 306     ((_ svc (kind param => exp ...) clauses ...)
 307      (if (eq? (service-kind svc) kind)
 308          (let ((param (service-value svc)))
 309            (service (service-kind svc)
 310                     (begin exp ...)))
 311          (%modify-service svc clauses ...)))))
 312
 313 (define-syntax modify-services
 314   (syntax-rules ()
 315     "Modify the services listed in SERVICES according to CLAUSES and return
 316 the resulting list of services.  Each clause must have the form:
 317
 318   (TYPE VARIABLE => BODY)
 319
 320 where TYPE is a service type, such as 'guix-service-type', and VARIABLE is an
 321 identifier that is bound within BODY to the value of the service of that
 322 TYPE.
 323
 324 Clauses can also remove services of a given type:
 325
 326   (delete TYPE)
 327
 328 Consider this example:
 329
 330   (modify-services %base-services
 331     (guix-service-type config =>
 332                        (guix-configuration
 333                         (inherit config)
 334                         (use-substitutes? #f)
 335                         (extra-options '(\"--gc-keep-derivations\"))))
 336     (mingetty-service-type config =>
 337                            (mingetty-configuration
 338                             (inherit config)
 339                             (motd (plain-file \"motd\" \"Hi there!\"))))
 340     (delete udev-service-type))
 341
 342 It changes the configuration of the GUIX-SERVICE-TYPE instance, and that of
 343 all the MINGETTY-SERVICE-TYPE instances, and it deletes instances of the
 344 UDEV-SERVICE-TYPE.
 345
 346 This is a shorthand for (filter-map (lambda (svc) ...) %base-services)."
 347     ((_ services clauses ...)
 348      (filter-map (lambda (service)
 349                    (%modify-service service clauses ...))
 350                  services))))
 351
 352 \f
 353 ;;;
 354 ;;; Core services.
 355 ;;;
 356
 357 (define (system-derivation entries mextensions)
 358   "Return as a monadic value the derivation of the 'system' directory
 359 containing the given entries."
 360   (mlet %store-monad ((extensions (mapm/accumulate-builds identity
 361                                                           mextensions)))
 362     (lower-object
 363      (file-union "system"
 364                  (append entries (concatenate extensions))))))
 365
 366 (define system-service-type
 367   ;; This is the ultimate service type, the root of the service DAG.  The
 368   ;; service of this type is extended by monadic name/item pairs.  These items
 369   ;; end up in the "system directory" as returned by
 370   ;; 'operating-system-derivation'.
 371   (service-type (name 'system)
 372                 (extensions '())
 373                 (compose identity)
 374                 (extend system-derivation)
 375                 (description
 376                  "Build the operating system top-level directory, which in
 377 turn refers to everything the operating system needs: its kernel, initrd,
 378 system profile, boot script, and so on.")))
 379
 380 (define (compute-boot-script _ gexps)
 381   ;; Reverse GEXPS so that extensions appear in the boot script in the right
 382   ;; order.  That is, user extensions would come first, and extensions added
 383   ;; by 'essential-services' (e.g., running shepherd) are guaranteed to come
 384   ;; last.
 385   (gexp->file "boot"
 386               ;; Clean up and activate the system, then spawn shepherd.
 387               #~(begin #$@(reverse gexps))))
 388
 389 (define (boot-script-entry mboot)
 390   "Return, as a monadic value, an entry for the boot script in the system
 391 directory."
 392   (mlet %store-monad ((boot mboot))
 393     (return `(("boot" ,boot)))))
 394
 395 (define boot-service-type
 396   ;; The service of this type is extended by being passed gexps.  It
 397   ;; aggregates them in a single script, as a monadic value, which becomes its
 398   ;; value.
 399   (service-type (name 'boot)
 400                 (extensions
 401                  (list (service-extension system-service-type
 402                                           boot-script-entry)))
 403                 (compose identity)
 404                 (extend compute-boot-script)
 405                 (description
 406                  "Produce the operating system's boot script, which is spawned
 407 by the initrd once the root file system is mounted.")))
 408
 409 (define %boot-service
 410   ;; The service that produces the boot script.
 411   (service boot-service-type #t))
 412
 413 \f
 414 ;;;
 415 ;;; Provenance tracking.
 416 ;;;
 417
 418 (define (object->pretty-string obj)
 419   "Like 'object->string', but using 'pretty-print'."
 420   (call-with-output-string
 421     (lambda (port)
 422       (pretty-print obj port))))
 423
 424 (define (channel->code channel)
 425   "Return code to build CHANNEL, ready to be dropped in a 'channels.scm'
 426 file."
 427   ;; Since the 'introduction' field is backward-incompatible, and since it's
 428   ;; optional when using the "official" 'guix channel, include it if and only
 429   ;; if we're referring to a different channel.
 430   (let ((intro (and (not (equal? (list channel) %default-channels))
 431                     (channel-introduction channel))))
 432     `(channel (name ',(channel-name channel))
 433               (url ,(channel-url channel))
 434               (branch ,(channel-branch channel))
 435               (commit ,(channel-commit channel))
 436               ,@(if intro
 437                     `((introduction
 438                        (make-channel-introduction
 439                         ,(channel-introduction-first-signed-commit intro)
 440                         (openpgp-fingerprint
 441                          ,(openpgp-format-fingerprint
 442                            (channel-introduction-first-commit-signer
 443                             intro))))))
 444                     '()))))
 445
 446 (define (channel->sexp channel)
 447   "Return an sexp describing CHANNEL.  The sexp is _not_ code and is meant to
 448 be parsed by tools; it's potentially more future-proof than code."
 449   ;; TODO: Add CHANNEL's introduction.  Currently we can't do that because
 450   ;; older 'guix system describe' expect exactly name/url/branch/commit
 451   ;; without any additional fields.
 452   `(channel (name ,(channel-name channel))
 453             (url ,(channel-url channel))
 454             (branch ,(channel-branch channel))
 455             (commit ,(channel-commit channel))))
 456
 457 (define (sexp->channel sexp)
 458   "Return the channel corresponding to SEXP, an sexp as found in the
 459 \"provenance\" file produced by 'provenance-service-type'."
 460   (match sexp
 461     (('channel ('name name)
 462                ('url url)
 463                ('branch branch)
 464                ('commit commit)
 465                rest ...)
 466      ;; XXX: In the future REST may include a channel introduction.
 467      (channel (name name) (url url)
 468               (branch branch) (commit commit)))))
 469
 470 (define (provenance-file channels config-file)
 471   "Return a 'provenance' file describing CHANNELS, a list of channels, and
 472 CONFIG-FILE, which can be either #f or a <local-file> containing the OS
 473 configuration being used."
 474   (scheme-file "provenance"
 475                #~(provenance
 476                   (version 0)
 477                   (channels #+@(if channels
 478                                    (map channel->sexp channels)
 479                                    '()))
 480                   (configuration-file #+config-file))))
 481
 482 (define (provenance-entry config-file)
 483   "Return system entries describing the operating system provenance: the
 484 channels in use and CONFIG-FILE, if it is true."
 485   (define profile
 486     (current-profile))
 487
 488   (define channels
 489     (and=> profile profile-channels))
 490
 491   (mbegin %store-monad
 492     (let ((config-file (cond ((string? config-file)
 493                               ;; CONFIG-FILE has been passed typically via
 494                               ;; 'guix system reconfigure CONFIG-FILE' so we
 495                               ;; can assume it's valid: tell 'local-file' to
 496                               ;; not emit a warning.
 497                               (local-file (assume-valid-file-name config-file)
 498                                           "configuration.scm"))
 499                              ((not config-file)
 500                               #f)
 501                              (else
 502                               config-file))))
 503       (return `(("provenance" ,(provenance-file channels config-file))
 504                 ,@(if channels
 505                       `(("channels.scm"
 506                          ,(plain-file "channels.scm"
 507                                       (object->pretty-string
 508                                        `(list
 509                                          ,@(map channel->code channels))))))
 510                       '())
 511                 ,@(if config-file
 512                       `(("configuration.scm" ,config-file))
 513                       '()))))))
 514
 515 (define provenance-service-type
 516   (service-type (name 'provenance)
 517                 (extensions
 518                  (list (service-extension system-service-type
 519                                           provenance-entry)))
 520                 (default-value #f)                ;the OS config file
 521                 (description
 522                  "Store provenance information about the system in the system
 523 itself: the channels used when building the system, and its configuration
 524 file, when available.")))
 525
 526 (define (sexp->system-provenance sexp)
 527   "Parse SEXP, an s-expression read from /run/current-system/provenance or
 528 similar, and return two values: the list of channels listed therein, and the
 529 OS configuration file or #f."
 530   (match sexp
 531     (('provenance ('version 0)
 532                   ('channels channels ...)
 533                   ('configuration-file config-file))
 534      (values (map sexp->channel channels)
 535              config-file))
 536     (_
 537      (values '() #f))))
 538
 539 (define (system-provenance system)
 540   "Given SYSTEM, the file name of a system generation, return two values: the
 541 list of channels SYSTEM is built from, and its configuration file.  If that
 542 information is missing, return the empty list (for channels) and possibly
 543 #false (for the configuration file)."
 544   (catch 'system-error
 545     (lambda ()
 546       (sexp->system-provenance
 547        (call-with-input-file (string-append system "/provenance")
 548          read)))
 549     (lambda _
 550       (values '() #f))))
 551 \f
 552 ;;;
 553 ;;; Cleanup.
 554 ;;;
 555
 556 (define (cleanup-gexp _)
 557   "Return a gexp to clean up /tmp and similar places upon boot."
 558   (with-imported-modules '((guix build utils))
 559     #~(begin
 560         (use-modules (guix build utils))
 561
 562         ;; Clean out /tmp and /var/run.
 563         ;;
 564         ;; XXX This needs to happen before service activations, so it
 565         ;; has to be here, but this also implicitly assumes that /tmp
 566         ;; and /var/run are on the root partition.
 567         (letrec-syntax ((fail-safe (syntax-rules ()
 568                                      ((_ exp rest ...)
 569                                       (begin
 570                                         (catch 'system-error
 571                                           (lambda () exp)
 572                                           (const #f))
 573                                         (fail-safe rest ...)))
 574                                      ((_)
 575                                       #t))))
 576           ;; Ignore I/O errors so the system can boot.
 577           (fail-safe
 578            ;; Remove stale Shadow lock files as they would lead to
 579            ;; failures of 'useradd' & co.
 580            (delete-file "/etc/group.lock")
 581            (delete-file "/etc/passwd.lock")
 582            (delete-file "/etc/.pwd.lock")         ;from 'lckpwdf'
 583
 584            ;; Force file names to be decoded as UTF-8.  See
 585            ;; <https://bugs.gnu.org/26353>.
 586            (setenv "GUIX_LOCPATH"
 587                    #+(file-append glibc-utf8-locales "/lib/locale"))
 588            (setlocale LC_CTYPE "en_US.utf8")
 589            (delete-file-recursively "/tmp")
 590            (delete-file-recursively "/var/run")
 591
 592            (mkdir "/tmp")
 593            (chmod "/tmp" #o1777)
 594            (mkdir "/var/run")
 595            (chmod "/var/run" #o755)
 596            (delete-file-recursively "/run/udev/watch.old"))))))
 597
 598 (define cleanup-service-type
 599   ;; Service that cleans things up in /tmp and similar.
 600   (service-type (name 'cleanup)
 601                 (extensions
 602                  (list (service-extension boot-service-type
 603                                           cleanup-gexp)))
 604                 (description
 605                  "Delete files from @file{/tmp}, @file{/var/run}, and other
 606 temporary locations at boot time.")))
 607
 608 (define* (activation-service->script service)
 609   "Return as a monadic value the activation script for SERVICE, a service of
 610 ACTIVATION-SCRIPT-TYPE."
 611   (activation-script (service-value service)))
 612
 613 (define (activation-script gexps)
 614   "Return the system's activation script, which evaluates GEXPS."
 615   (define actions
 616     (map (cut program-file "activate-service.scm" <>) gexps))
 617
 618   (program-file "activate.scm"
 619                 (with-imported-modules (source-module-closure
 620                                         '((gnu build activation)
 621                                           (guix build utils)))
 622                   #~(begin
 623                       (use-modules (gnu build activation)
 624                                    (guix build utils))
 625
 626                       ;; Make sure the user accounting database exists.  If it
 627                       ;; does not exist, 'setutxent' does not create it and
 628                       ;; thus there is no accounting at all.
 629                       (close-port (open-file "/var/run/utmpx" "a0"))
 630
 631                       ;; Same for 'wtmp', which is populated by mingetty et
 632                       ;; al.
 633                       (mkdir-p "/var/log")
 634                       (close-port (open-file "/var/log/wtmp" "a0"))
 635
 636                       ;; Set up /run/current-system.  Among other things this
 637                       ;; sets up locales, which the activation snippets
 638                       ;; executed below may expect.
 639                       (activate-current-system)
 640
 641                       ;; Run the services' activation snippets.
 642                       ;; TODO: Use 'load-compiled'.
 643                       (for-each primitive-load '#$actions)))))
 644
 645 (define (gexps->activation-gexp gexps)
 646   "Return a gexp that runs the activation script containing GEXPS."
 647   #~(primitive-load #$(activation-script gexps)))
 648
 649 (define (activation-profile-entry gexps)
 650   "Return, as a monadic value, an entry for the activation script in the
 651 system directory."
 652   (mlet %store-monad ((activate (lower-object (activation-script gexps))))
 653     (return `(("activate" ,activate)))))
 654
 655 (define (second-argument a b) b)
 656
 657 (define activation-service-type
 658   (service-type (name 'activate)
 659                 (extensions
 660                  (list (service-extension boot-service-type
 661                                           gexps->activation-gexp)
 662                        (service-extension system-service-type
 663                                           activation-profile-entry)))
 664                 (compose identity)
 665                 (extend second-argument)
 666                 (description
 667                  "Run @dfn{activation} code at boot time and upon
 668 @command{guix system reconfigure} completion.")))
 669
 670 (define %activation-service
 671   ;; The activation service produces the activation script from the gexps it
 672   ;; receives.
 673   (service activation-service-type #t))
 674
 675 (define %modprobe-wrapper
 676   ;; Wrapper for the 'modprobe' command that knows where modules live.
 677   ;;
 678   ;; This wrapper is typically invoked by the Linux kernel ('call_modprobe',
 679   ;; in kernel/kmod.c), a situation where the 'LINUX_MODULE_DIRECTORY'
 680   ;; environment variable is not set---hence the need for this wrapper.
 681   (let ((modprobe "/run/current-system/profile/bin/modprobe"))
 682     (program-file "modprobe"
 683                   #~(begin
 684                       (setenv "LINUX_MODULE_DIRECTORY"
 685                               "/run/booted-system/kernel/lib/modules")
 686                       ;; FIXME: Remove this crutch when the patch #40422,
 687                       ;; updating to kmod 27 is merged.
 688                       (setenv "MODPROBE_OPTIONS"
 689                               "-C /etc/modprobe.d")
 690                       (apply execl #$modprobe
 691                              (cons #$modprobe (cdr (command-line))))))))
 692
 693 (define %linux-kernel-activation
 694   ;; Activation of the Linux kernel running on the bare metal (as opposed to
 695   ;; running in a container.)
 696   #~(begin
 697       ;; Tell the kernel to use our 'modprobe' command.
 698       (activate-modprobe #$%modprobe-wrapper)
 699
 700       ;; Let users debug their own processes!
 701       (activate-ptrace-attach)))
 702
 703 (define %linux-bare-metal-service
 704   ;; The service that does things that are needed on the "bare metal", but not
 705   ;; necessary or impossible in a container.
 706   (simple-service 'linux-bare-metal
 707                   activation-service-type
 708                   %linux-kernel-activation))
 709
 710 (define %hurd-rc-script
 711   ;; The RC script to be started upon boot.
 712   (program-file "rc"
 713                 (with-imported-modules (source-module-closure
 714                                         '((guix build utils)
 715                                           (gnu build hurd-boot)
 716                                           (guix build syscalls)))
 717                   #~(begin
 718                       (use-modules (guix build utils)
 719                                    (gnu build hurd-boot)
 720                                    (guix build syscalls)
 721                                    (ice-9 match)
 722                                    (system repl repl)
 723                                    (srfi srfi-1)
 724                                    (srfi srfi-26))
 725                       (boot-hurd-system)))))
 726
 727 (define (hurd-rc-entry rc)
 728   "Return, as a monadic value, an entry for the RC script in the system
 729 directory."
 730   (mlet %store-monad ((rc (lower-object rc)))
 731     (return `(("rc" ,rc)))))
 732
 733 (define hurd-startup-service-type
 734   ;; The service that creates the initial SYSTEM/rc startup file.
 735   (service-type (name 'startup)
 736                 (extensions
 737                  (list (service-extension system-service-type hurd-rc-entry)))
 738                 (default-value %hurd-rc-script)
 739                 (description "This service creates an @file{rc} script in the
 740 system; that script is responsible for booting the Hurd.")))
 741
 742 (define %hurd-startup-service
 743   ;; The service that produces the RC script.
 744   (service hurd-startup-service-type %hurd-rc-script))
 745
 746 (define special-files-service-type
 747   ;; Service to install "special files" such as /bin/sh and /usr/bin/env.
 748   (service-type
 749    (name 'special-files)
 750    (extensions
 751     (list (service-extension activation-service-type
 752                              (lambda (files)
 753                                #~(activate-special-files '#$files)))))
 754    (compose concatenate)
 755    (extend append)
 756    (description
 757     "Add special files to the root file system---e.g.,
 758 @file{/usr/bin/env}.")))
 759
 760 (define (extra-special-file file target)
 761   "Use TARGET as the \"special file\" FILE.  For example, TARGET might be
 762   (file-append coreutils \"/bin/env\")
 763 and FILE could be \"/usr/bin/env\"."
 764   (simple-service (string->symbol (string-append "special-file-" file))
 765                   special-files-service-type
 766                   `((,file ,target))))
 767
 768 (define (etc-directory service)
 769   "Return the directory for SERVICE, a service of type ETC-SERVICE-TYPE."
 770   (files->etc-directory (service-value service)))
 771
 772 (define (files->etc-directory files)
 773   (define (assert-no-duplicates files)
 774     (let loop ((files files)
 775                (seen (set)))
 776       (match files
 777         (() #t)
 778         (((file _) rest ...)
 779          (when (set-contains? seen file)
 780            (raise (formatted-message (G_ "duplicate '~a' entry for /etc")
 781                                      file)))
 782          (loop rest (set-insert file seen))))))
 783
 784   ;; Detect duplicates early instead of letting them through, eventually
 785   ;; leading to a build failure of "etc.drv".
 786   (assert-no-duplicates files)
 787
 788   (file-union "etc" files))
 789
 790 (define (etc-entry files)
 791   "Return an entry for the /etc directory consisting of FILES in the system
 792 directory."
 793   (with-monad %store-monad
 794     (return `(("etc" ,(files->etc-directory files))))))
 795
 796 (define etc-service-type
 797   (service-type (name 'etc)
 798                 (extensions
 799                  (list
 800                   (service-extension activation-service-type
 801                                      (lambda (files)
 802                                        (let ((etc
 803                                               (files->etc-directory files)))
 804                                          #~(activate-etc #$etc))))
 805                   (service-extension system-service-type etc-entry)))
 806                 (compose concatenate)
 807                 (extend append)
 808                 (description "Populate the @file{/etc} directory.")))
 809
 810 (define (etc-service files)
 811   "Return a new service of ETC-SERVICE-TYPE that populates /etc with FILES.
 812 FILES must be a list of name/file-like object pairs."
 813   (service etc-service-type files))
 814
 815 (define (setuid-program->activation-gexp programs)
 816   "Return an activation gexp for setuid-program from PROGRAMS."
 817   (let ((programs (map (lambda (program)
 818                          ;; FIXME This is really ugly, I didn't managed to use
 819                          ;; "inherit"
 820                          (let ((program-name (setuid-program-program program))
 821                                (setuid?      (setuid-program-setuid? program))
 822                                (setgid?      (setuid-program-setgid? program))
 823                                (user         (setuid-program-user program))
 824                                (group        (setuid-program-group program)) )
 825                            #~(setuid-program
 826                               (setuid? #$setuid?)
 827                               (setgid? #$setgid?)
 828                               (user    #$user)
 829                               (group   #$group)
 830                               (program #$program-name))))
 831                        programs)))
 832     (with-imported-modules (source-module-closure
 833                             '((gnu system setuid)))
 834       #~(begin
 835           (use-modules (gnu system setuid))
 836
 837           (activate-setuid-programs (list #$@programs))))))
 838
 839 (define setuid-program-service-type
 840   (service-type (name 'setuid-program)
 841                 (extensions
 842                  (list (service-extension activation-service-type
 843                                           setuid-program->activation-gexp)))
 844                 (compose concatenate)
 845                 (extend (lambda (config extensions)
 846                           (append config extensions)))
 847                 (description
 848                  "Populate @file{/run/setuid-programs} with the specified
 849 executables, making them setuid-root.")))
 850
 851 (define (packages->profile-entry packages)
 852   "Return a system entry for the profile containing PACKAGES."
 853   ;; XXX: 'mlet' is needed here for one reason: to get the proper
 854   ;; '%current-target' and '%current-target-system' bindings when
 855   ;; 'packages->manifest' is called, and thus when the 'package-inputs'
 856   ;; etc. procedures are called on PACKAGES.  That way, conditionals in those
 857   ;; inputs see the "correct" value of these two parameters.  See
 858   ;; <https://issues.guix.gnu.org/44952>.
 859   (mlet %store-monad ((_ (current-target-system)))
 860     (return `(("profile" ,(profile
 861                            (content (packages->manifest
 862                                      (delete-duplicates packages eq?)))))))))
 863
 864 (define profile-service-type
 865   ;; The service that populates the system's profile---i.e.,
 866   ;; /run/current-system/profile.  It is extended by package lists.
 867   (service-type (name 'profile)
 868                 (extensions
 869                  (list (service-extension system-service-type
 870                                           packages->profile-entry)))
 871                 (compose concatenate)
 872                 (extend append)
 873                 (description
 874                  "This is the @dfn{system profile}, available as
 875 @file{/run/current-system/profile}.  It contains packages that the sysadmin
 876 wants to be globally available to all the system users.")))
 877
 878 (define (firmware->activation-gexp firmware)
 879   "Return a gexp to make the packages listed in FIRMWARE loadable by the
 880 kernel."
 881   (let ((directory (directory-union "firmware" firmware)))
 882     ;; Tell the kernel where firmware is.
 883     #~(activate-firmware (string-append #$directory "/lib/firmware"))))
 884
 885 (define firmware-service-type
 886   ;; The service that collects firmware.
 887   (service-type (name 'firmware)
 888                 (extensions
 889                  (list (service-extension activation-service-type
 890                                           firmware->activation-gexp)))
 891                 (compose concatenate)
 892                 (extend append)
 893                 (description
 894                  "Make ``firmware'' files loadable by the operating system
 895 kernel.  Firmware may then be uploaded to some of the machine's devices, such
 896 as Wifi cards.")))
 897
 898 (define (gc-roots->system-entry roots)
 899   "Return an entry in the system's output containing symlinks to ROOTS."
 900   (mlet %store-monad ((entry (gexp->derivation
 901                               "gc-roots"
 902                               #~(let ((roots '#$roots))
 903                                   (mkdir #$output)
 904                                   (chdir #$output)
 905                                   (for-each symlink
 906                                             roots
 907                                             (map number->string
 908                                                  (iota (length roots))))))))
 909     (return (if (null? roots)
 910                 '()
 911                 `(("gc-roots" ,entry))))))
 912
 913 (define gc-root-service-type
 914   ;; A service to associate extra garbage-collector roots to the system.  This
 915   ;; is a simple hack that guarantees that the system retains references to
 916   ;; the given list of roots.  Roots must be "lowerable" objects like
 917   ;; packages, or derivations.
 918   (service-type (name 'gc-roots)
 919                 (extensions
 920                  (list (service-extension system-service-type
 921                                           gc-roots->system-entry)))
 922                 (compose concatenate)
 923                 (extend append)
 924                 (description
 925                  "Register garbage-collector roots---i.e., store items that
 926 will not be reclaimed by the garbage collector.")
 927                 (default-value '())))
 928
 929 ;; Configuration for the Linux kernel builder.
 930 (define-record-type* <linux-builder-configuration>
 931   linux-builder-configuration
 932   make-linux-builder-configuration
 933   linux-builder-configuration?
 934   this-linux-builder-configuration
 935
 936   (kernel   linux-builder-configuration-kernel)                   ; package
 937   (modules  linux-builder-configuration-modules  (default '())))  ; list of packages
 938
 939 (define (package-for-kernel target-kernel module-package)
 940   "Return a package like MODULE-PACKAGE, adapted for TARGET-KERNEL, if
 941 possible (that is if there's a LINUX keyword argument in the build system)."
 942   (package
 943     (inherit module-package)
 944     (arguments
 945      (substitute-keyword-arguments (package-arguments module-package)
 946        ((#:linux kernel #f)
 947         target-kernel)))))
 948
 949 (define (linux-builder-configuration->system-entry config)
 950   "Return the kernel entry of the 'system' directory."
 951   (let* ((kernel  (linux-builder-configuration-kernel config))
 952          (modules (linux-builder-configuration-modules config))
 953          (kernel  (profile
 954                     (content (packages->manifest
 955                               (cons kernel
 956                                     (map (lambda (module)
 957                                            (cond
 958                                              ((package? module)
 959                                               (package-for-kernel kernel module))
 960                                              ;; support (,package "kernel-module-output")
 961                                              ((and (list? module) (package? (car module)))
 962                                               (cons (package-for-kernel kernel
 963                                                                         (car module))
 964                                                     (cdr module)))
 965                                              (else
 966                                               module)))
 967                                          modules))))
 968                     (hooks (list linux-module-database)))))
 969     (with-monad %store-monad
 970       (return `(("kernel" ,kernel))))))
 971
 972 (define linux-builder-service-type
 973   (service-type (name 'linux-builder)
 974                 (extensions
 975                   (list (service-extension system-service-type
 976                                            linux-builder-configuration->system-entry)))
 977                 (default-value '())
 978                 (compose identity)
 979                 (extend (lambda (config modifiers)
 980                           (if (null? modifiers)
 981                               config
 982                               ((apply compose modifiers) config))))
 983                 (description "Builds the linux-libre kernel profile, containing
 984 the kernel itself and any linux-loadable kernel modules.  This can be extended
 985 with a function that accepts the current configuration and returns a new
 986 configuration.")))
 987
 988 (define (linux-loadable-module-builder-modifier modules)
 989   "Extends linux-builder-service-type by appending the given MODULES to the
 990 configuration of linux-builder-service-type."
 991   (lambda (config)
 992     (linux-builder-configuration
 993       (inherit config)
 994       (modules (append (linux-builder-configuration-modules config)
 995                        modules)))))
 996
 997 (define linux-loadable-module-service-type
 998   (service-type (name 'linux-loadable-modules)
 999                 (extensions
1000                   (list (service-extension linux-builder-service-type
1001                                            linux-loadable-module-builder-modifier)))
1002                 (default-value '())
1003                 (compose concatenate)
1004                 (extend append)
1005                 (description "Adds packages and package outputs as modules
1006 included in the booted linux-libre profile.  Other services can extend this
1007 service type to add particular modules to the set of linux-loadable modules.")))
1008
1009
1010 \f
1011 ;;;
1012 ;;; Service folding.
1013 ;;;
1014
1015 (define-condition-type &missing-target-service-error &service-error
1016   missing-target-service-error?
1017   (service      missing-target-service-error-service)
1018   (target-type  missing-target-service-error-target-type))
1019
1020 (define-condition-type &ambiguous-target-service-error &service-error
1021   ambiguous-target-service-error?
1022   (service      ambiguous-target-service-error-service)
1023   (target-type  ambiguous-target-service-error-target-type))
1024
1025 (define (missing-target-error service target-type)
1026   (raise
1027    (condition (&missing-target-service-error
1028                (service service)
1029                (target-type target-type))
1030               (&message
1031                (message
1032                 (format #f (G_ "no target of type '~a' for service '~a'")
1033                         (service-type-name target-type)
1034                         (service-type-name
1035                          (service-kind service))))))))
1036
1037 (define (service-back-edges services)
1038   "Return a procedure that, when passed a <service>, returns the list of
1039 <service> objects that depend on it."
1040   (define (add-edges service edges)
1041     (define (add-edge extension edges)
1042       (let ((target-type (service-extension-target extension)))
1043         (match (filter (lambda (service)
1044                          (eq? (service-kind service) target-type))
1045                        services)
1046           ((target)
1047            (vhash-consq target service edges))
1048           (()
1049            (missing-target-error service target-type))
1050           (x
1051            (raise
1052             (condition (&ambiguous-target-service-error
1053                         (service service)
1054                         (target-type target-type))
1055                        (&message
1056                         (message
1057                          (format #f
1058                                  (G_ "more than one target service of type '~a'")
1059                                  (service-type-name target-type))))))))))
1060
1061     (fold add-edge edges (service-type-extensions (service-kind service))))
1062
1063   (let ((edges (fold add-edges vlist-null services)))
1064     (lambda (node)
1065       (reverse (vhash-foldq* cons '() node edges)))))
1066
1067 (define (instantiate-missing-services services)
1068   "Return SERVICES, a list, augmented with any services targeted by extensions
1069 and missing from SERVICES.  Only service types with a default value can be
1070 instantiated; other missing services lead to a
1071 '&missing-target-service-error'."
1072   (define (adjust-service-list svc result instances)
1073     (fold2 (lambda (extension result instances)
1074              (define target-type
1075                (service-extension-target extension))
1076
1077              (match (vhash-assq target-type instances)
1078                (#f
1079                 (let ((default (service-type-default-value target-type)))
1080                   (if (eq? &no-default-value default)
1081                       (missing-target-error svc target-type)
1082                       (let ((new (service target-type)))
1083                         (values (cons new result)
1084                                 (vhash-consq target-type new instances))))))
1085                (_
1086                 (values result instances))))
1087            result
1088            instances
1089            (service-type-extensions (service-kind svc))))
1090
1091   (let loop ((services services))
1092     (define instances
1093       (fold (lambda (service result)
1094               (vhash-consq (service-kind service) service
1095                            result))
1096             vlist-null services))
1097
1098     (define adjusted
1099       (fold2 adjust-service-list
1100              services instances
1101              services))
1102
1103     ;; If we instantiated services, they might in turn depend on missing
1104     ;; services.  Loop until we've reached fixed point.
1105     (if (= (length adjusted) (vlist-length instances))
1106         adjusted
1107         (loop adjusted))))
1108
1109 (define* (fold-services services
1110                         #:key (target-type system-service-type))
1111   "Fold SERVICES by propagating their extensions down to the root of type
1112 TARGET-TYPE; return the root service adjusted accordingly."
1113   (define dependents
1114     (service-back-edges services))
1115
1116   (define (matching-extension target)
1117     (let ((target (service-kind target)))
1118       (match-lambda
1119         (($ <service-extension> type)
1120          (eq? type target)))))
1121
1122   (define (apply-extension target)
1123     (lambda (service)
1124       (match (find (matching-extension target)
1125                    (service-type-extensions (service-kind service)))
1126         (($ <service-extension> _ compute)
1127          (compute (service-value service))))))
1128
1129   (match (filter (lambda (service)
1130                    (eq? (service-kind service) target-type))
1131                  services)
1132     ((sink)
1133      ;; Use the state monad to keep track of already-visited services in the
1134      ;; graph and to memoize their value once folded.
1135      (run-with-state
1136          (let loop ((sink sink))
1137            (mlet %state-monad ((visited (current-state)))
1138              (match (vhash-assq sink visited)
1139                (#f
1140                 (mlet* %state-monad
1141                     ((dependents (mapm %state-monad loop (dependents sink)))
1142                      (visited    (current-state))
1143                      (extensions -> (map (apply-extension sink) dependents))
1144                      (extend     -> (service-type-extend (service-kind sink)))
1145                      (compose    -> (service-type-compose (service-kind sink)))
1146                      (params     -> (service-value sink))
1147                      (service
1148                       ->
1149                       ;; Distinguish COMPOSE and EXTEND because PARAMS typically
1150                       ;; has a different type than the elements of EXTENSIONS.
1151                       (if extend
1152                           (service (service-kind sink)
1153                                    (extend params (compose extensions)))
1154                           sink)))
1155                   (mbegin %state-monad
1156                     (set-current-state (vhash-consq sink service visited))
1157                     (return service))))
1158                ((_ . service)                     ;SINK was already visited
1159                 (return service)))))
1160        vlist-null))
1161     (()
1162      (raise
1163       (make-compound-condition
1164        (condition (&missing-target-service-error
1165                    (service #f)
1166                    (target-type target-type)))
1167        (formatted-message (G_ "service of type '~a' not found")
1168                           (service-type-name target-type)))))
1169     (x
1170      (raise
1171       (condition (&ambiguous-target-service-error
1172                   (service #f)
1173                   (target-type target-type))
1174                  (&message
1175                   (message
1176                    (format #f
1177                            (G_ "more than one target service of type '~a'")
1178                            (service-type-name target-type)))))))))
1179
1180 ;;; services.scm ends here.