gnu/packages/lsof.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013 Andreas Enge <andreas@enge.fr>
   3 ;;; Copyright © 2017 Efraim Flashner <efraim@flashner.co.il>
   4 ;;; Copyright © 2018, 2020 Tobias Geerinckx-Rice <me@tobias.gr>
   5 ;;; Copyright © 2018, 2019 Ludovic Courtès <ludo@gnu.org>
   6 ;;;
   7 ;;; This file is part of GNU Guix.
   8 ;;;
   9 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  10 ;;; under the terms of the GNU General Public License as published by
  11 ;;; the Free Software Foundation; either version 3 of the License, or (at
  12 ;;; your option) any later version.
  13 ;;;
  14 ;;; GNU Guix is distributed in the hope that it will be useful, but
  15 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;;; GNU General Public License for more details.
  18 ;;;
  19 ;;; You should have received a copy of the GNU General Public License
  20 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 (define-module (gnu packages lsof)
  23   #:use-module ((guix licenses) #:prefix license:)
  24   #:use-module (guix packages)
  25   #:use-module (guix git-download)
  26   #:use-module (guix build-system gnu)
  27   #:use-module (gnu packages groff)
  28   #:use-module (gnu packages perl))
  29
  30 (define-public lsof
  31   (package
  32    (name "lsof")
  33    (version "4.94.0")
  34    (source
  35     (origin
  36       (method git-fetch)
  37       (uri (git-reference
  38             (url "https://github.com/lsof-org/lsof")
  39             (commit version)))
  40       (file-name (git-file-name name version))
  41       (sha256
  42        (base32 "0yxv2jg6rnzys49lyrz9yjb4knamah4xvlqj596y6ix3vm4k3chp"))))
  43    (build-system gnu-build-system)
  44    (native-inputs
  45     `(("groff" ,groff)                  ; for soelim
  46       ("perl" ,perl)))
  47    (arguments
  48     `(#:phases
  49       (modify-phases %standard-phases
  50         (replace 'configure
  51           (lambda _
  52             (setenv "LSOF_CC" "gcc")
  53             (setenv "LSOF_MAKE" "make")
  54
  55             ;; By default, the makefile captures the output of 'uname -a'.
  56             ;; Provide a fixed output instead to make builds reproducible.
  57             (setenv "LSOF_SYSINFO"
  58                     (string-append "GNU/" (utsname:sysname (uname))
  59                                    " (GNU Guix)"))
  60
  61             (invoke "./Configure" "linux")
  62             #t))
  63         (add-after 'configure 'patch-timestamps
  64           (lambda _
  65             (substitute* "Makefile"
  66               (("`date`") "`date --date=@1`"))
  67             #t))
  68         (add-after 'build 'build-man-page
  69           (lambda _
  70             (with-output-to-file "lsof.8"
  71               (lambda _ (invoke "soelim" "Lsof.8")))
  72             #t))
  73         (add-before 'check 'disable-failing-tests
  74           (lambda _
  75             (substitute* "tests/Makefile"
  76               ;; Fails with ‘ERROR!!! client gethostbyaddr() failure’.
  77               (("(STDTST=.*) LTsock" _ prefix) prefix)
  78               ;; Fails without access to a remote NFS server.
  79               (("(OPTTST=.*) LTnfs"  _ prefix) prefix))
  80             #t))
  81         (replace 'check
  82           (lambda* (#:key tests? #:allow-other-keys)
  83             (when tests?
  84               (with-directory-excursion "tests"
  85                 ;; Tests refuse to run on ‘unvalidated’ platforms.
  86                 (make-file-writable "TestDB")
  87                 (invoke "./Add2TestDB")
  88
  89                 ;; The ‘standard’ tests suggest running ‘optional’ ones as well.
  90                 (invoke "make" "standard" "optional")))
  91             #t))
  92         (replace 'install
  93           (lambda* (#:key outputs #:allow-other-keys)
  94             (let ((out (assoc-ref outputs "out")))
  95               (install-file "lsof" (string-append out "/bin"))
  96               (install-file "lsof.8" (string-append out "/share/man/man8")))
  97             #t)))))
  98    (synopsis "Display information about open files")
  99    (description
 100     "Lsof stands for LiSt Open Files, and it does just that.
 101 It lists information about files that are open by the processes running
 102 on the system.")
 103    (license (license:fsf-free
 104              "file://00FAQ"
 105              "License inspired by zlib, see point 1.9 of 00FAQ in the distribution."))
 106    (home-page "https://people.freebsd.org/~abe/")))