configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix],
   6   [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
   7   [bug-guix@gnu.org], [guix],
   8   [https://www.gnu.org/software/guix/])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10
  11 AM_INIT_AUTOMAKE([1.12 gnu silent-rules subdir-objects \
  12  color-tests parallel-tests -Woverride -Wno-portability])
  13
  14 # Enable silent rules by default.
  15 AM_SILENT_RULES([yes])
  16
  17 AC_CONFIG_SRCDIR([guix.scm])
  18 AC_CONFIG_MACRO_DIR([m4])
  19
  20 dnl For the C++ code.  This must be used early.
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23 AM_GNU_GETTEXT([external])
  24 AM_GNU_GETTEXT_VERSION([0.18.1])
  25
  26 GUIX_SYSTEM_TYPE
  27 GUIX_ASSERT_SUPPORTED_SYSTEM
  28
  29 AC_ARG_WITH(store-dir,
  30   AC_HELP_STRING([--with-store-dir=PATH],
  31     [file name of the store (defaults to /gnu/store)]),
  32   [storedir="$withval"],
  33   [storedir="/gnu/store"])
  34 AC_SUBST(storedir)
  35
  36 AC_ARG_WITH([bash-completion-dir],
  37   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  38     [name of the Bash completion directory]),
  39   [bashcompletiondir="$withval"],
  40   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  41 AC_SUBST([bashcompletiondir])
  42
  43 AC_ARG_WITH([zsh-completion-dir],
  44   AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  45     [name of the Zsh completion directory]),
  46   [zshcompletiondir="$withval"],
  47   [zshcompletiondir='${datadir}/zsh/site-functions'])
  48 AC_SUBST([zshcompletiondir])
  49
  50 dnl Better be verbose.
  51 AC_MSG_CHECKING([for the store directory])
  52 AC_MSG_RESULT([$storedir])
  53
  54 AC_ARG_ENABLE([daemon],
  55   [AS_HELP_STRING([--disable-daemon], [build the Nix daemon (C++)])],
  56   [guix_build_daemon="$enableval"],
  57   [guix_build_daemon="yes"])
  58
  59 # Prepare a version of $localstatedir & co. that does not contain references
  60 # to shell variables.
  61 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  62 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  63 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  64 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  65 AC_SUBST([guix_localstatedir])
  66 AC_SUBST([guix_sysconfdir])
  67 AC_SUBST([guix_sbindir])
  68
  69 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  70 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  71
  72 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  73 dnl Make sure they are available.
  74 m4_pattern_forbid([PKG_CHECK_MODULES])
  75 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  76 m4_pattern_forbid([^GUILE_P$])
  77
  78 dnl Search for 'guile' and 'guild'.  This macro defines
  79 dnl 'GUILE_EFFECTIVE_VERSION'.
  80 GUILE_PKG([2.2 2.0])
  81 GUILE_PROGS
  82 if test "x$GUILD" = "x"; then
  83    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  84 fi
  85
  86 if test "x$GUILE_EFFECTIVE_VERSION" = "x2.0"; then
  87   PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.9])
  88 fi
  89
  90 dnl Installation directories for .scm and .go files.
  91 guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
  92 guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
  93 AC_SUBST([guilemoduledir])
  94 AC_SUBST([guileobjectdir])
  95
  96 dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
  97 dnl pull', among other things.
  98 GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
  99 if test "x$have_gnutls" != "xyes"; then
 100   AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
 101 fi
 102
 103 dnl Guile-JSON is used in various places.
 104 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
 105 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
 106
 107 dnl Check for Guile-Git.
 108 GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
 109 AM_CONDITIONAL([HAVE_GUILE_GIT], [test "x$have_guile_git" = "xyes"])
 110
 111 dnl Make sure we have a full-fledged Guile.
 112 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
 113
 114 dnl Check whether (srfi srfi-37) works, and provide our own if it doesn't.
 115 GUIX_CHECK_SRFI_37
 116 AM_CONDITIONAL([INSTALL_SRFI_37], [test "x$ac_cv_guix_srfi_37_broken" = xyes])
 117
 118 dnl Decompressors, for use by the substituter and other modules.
 119 AC_PATH_PROG([GZIP], [gzip])
 120 AC_PATH_PROG([BZIP2], [bzip2])
 121 AC_PATH_PROG([XZ], [xz])
 122 AC_SUBST([GZIP])
 123 AC_SUBST([BZIP2])
 124 AC_SUBST([XZ])
 125
 126 AC_ARG_WITH([nix-prefix],
 127   [AS_HELP_STRING([--with-nix-prefix=DIR],
 128     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 129   [case "$withval" in
 130     yes|no) ;;
 131     *)
 132       NIX_PREFIX="$withval"
 133       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 134       AC_SUBST([NIX_PREFIX])
 135       ;;
 136    esac],
 137   [])
 138
 139 AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
 140 AC_PATH_PROG([NIX_HASH], [nix-hash])
 141 if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
 142    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 143 fi
 144
 145 if test "x$NIX_INSTANTIATE" = "x"; then
 146    # This program is an optional dependency, so we just want it to be
 147    # taken from $PATH if it's not available right now.
 148    NIX_INSTANTIATE="nix-instantiate"
 149 fi
 150
 151 AC_ARG_WITH([nixpkgs],
 152   [AS_HELP_STRING([--with-nixpkgs=DIR],
 153     [search for Nixpkgs in DIR (for testing purposes only)])],
 154   [case "$withval" in
 155     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 156     *)      NIXPKGS="$withval";;
 157    esac],
 158   [])
 159
 160 AC_MSG_CHECKING([for Nixpkgs source tree])
 161 if test -f "$NIXPKGS/default.nix"; then
 162    AC_MSG_RESULT([$NIXPKGS])
 163    AC_SUBST([NIXPKGS])
 164 else
 165    AC_MSG_RESULT([not found])
 166 fi
 167
 168 LIBGCRYPT="libgcrypt"
 169 LIBGCRYPT_LIBDIR="no"
 170 LIBGCRYPT_PREFIX="no"
 171
 172 AC_ARG_WITH([libgcrypt-prefix],
 173   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 174   [case "$withval" in
 175     yes|no)
 176       ;;
 177     *)
 178       LIBGCRYPT="$withval/lib/libgcrypt"
 179       LIBGCRYPT_PREFIX="$withval"
 180       LIBGCRYPT_LIBDIR="$withval/lib"
 181       ;;
 182    esac])
 183
 184 AC_ARG_WITH([libgcrypt-libdir],
 185   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 186      [search for GNU libgcrypt's shared library in DIR])],
 187   [case "$withval" in
 188     yes|no)
 189       LIBGCRYPT="libgcrypt"
 190       LIBGCRYPT_LIBDIR="no"
 191       ;;
 192     *)
 193       LIBGCRYPT="$withval/libgcrypt"
 194       LIBGCRYPT_LIBDIR="$withval"
 195       ;;
 196    esac])
 197
 198 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 199 dnl absolute file name of libgcrypt.so.
 200 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 201   xnono)
 202     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 203     if test "x$LIBGCRYPT_LIBDIR" != x; then
 204       LIBGCRYPT="$LIBGCRYPT_LIBDIR/libgcrypt"
 205     else
 206       dnl 'config-daemon.ac' expects "no" in this case.
 207       LIBGCRYPT_LIBDIR="no"
 208     fi
 209     ;;
 210 esac
 211
 212 dnl Library name suitable for `dynamic-link'.
 213 AC_MSG_CHECKING([for libgcrypt shared library name])
 214 AC_MSG_RESULT([$LIBGCRYPT])
 215 AC_SUBST([LIBGCRYPT])
 216 AC_SUBST([LIBGCRYPT_PREFIX])
 217 AC_SUBST([LIBGCRYPT_LIBDIR])
 218
 219 GUIX_ASSERT_LIBGCRYPT_USABLE
 220
 221 dnl Library name of zlib suitable for 'dynamic-link'.
 222 GUIX_LIBZ_LIBDIR([libz_libdir])
 223 if test "x$libz_libdir" = "x"; then
 224   LIBZ="libz"
 225 else
 226   LIBZ="$libz_libdir/libz"
 227 fi
 228 AC_MSG_CHECKING([for zlib's shared library name])
 229 AC_MSG_RESULT([$LIBZ])
 230 AC_SUBST([LIBZ])
 231
 232 dnl Check for Guile-SSH, for the (guix ssh) module.
 233 GUIX_CHECK_GUILE_SSH
 234 AM_CONDITIONAL([HAVE_GUILE_SSH],
 235   [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
 236
 237 AC_CACHE_SAVE
 238
 239 m4_include([config-daemon.ac])
 240
 241 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 242 dnl See `Building from Git' in the manual for more info.
 243 AM_MISSING_PROG([DOT], [dot])
 244
 245 dnl Manual pages.
 246 AM_MISSING_PROG([HELP2MAN], [help2man])
 247
 248 dnl Emacs (optional), for 'etc/indent-package.el'.
 249 AC_PATH_PROG([EMACS], [emacs], [/usr/bin/emacs])
 250 AC_SUBST([EMACS])
 251
 252 case "$storedir" in
 253   /gnu/store)
 254     ;;
 255   *)
 256     AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
 257     AC_MSG_WARN([from downloading substitutes from gnu.org.])
 258     ;;
 259 esac
 260
 261 AC_CONFIG_FILES([Makefile
 262                  po/guix/Makefile.in
 263                  po/packages/Makefile.in
 264                  guix/config.scm])
 265
 266 AC_CONFIG_FILES([scripts/guix], [chmod +x scripts/guix])
 267 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 268 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 269   [chmod +x pre-inst-env])
 270 AC_CONFIG_FILES([etc/indent-code.el], [chmod +x etc/indent-code.el])
 271
 272 AC_OUTPUT