configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix], [0.12.0], [bug-guix@gnu.org], [guix],
   6   [http://www.gnu.org/software/guix/])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AM_INIT_AUTOMAKE([1.12 gnu silent-rules subdir-objects \
  10  color-tests parallel-tests -Woverride -Wno-portability])
  11
  12 # Enable silent rules by default.
  13 AM_SILENT_RULES([yes])
  14
  15 AC_CONFIG_SRCDIR([guix.scm])
  16 AC_CONFIG_MACRO_DIR([m4])
  17
  18 dnl For the C++ code.  This must be used early.
  19 AC_USE_SYSTEM_EXTENSIONS
  20
  21 AM_GNU_GETTEXT([external])
  22 AM_GNU_GETTEXT_VERSION([0.18.1])
  23
  24 GUIX_SYSTEM_TYPE
  25 GUIX_ASSERT_SUPPORTED_SYSTEM
  26
  27 AC_ARG_WITH(store-dir,
  28   AC_HELP_STRING([--with-store-dir=PATH],
  29     [file name of the store (defaults to /gnu/store)]),
  30   [storedir="$withval"],
  31   [storedir="/gnu/store"])
  32 AC_SUBST(storedir)
  33
  34 AC_ARG_WITH([bash-completion-dir],
  35   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  36     [name of the Bash completion directory]),
  37   [bashcompletiondir="$withval"],
  38   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  39 AC_SUBST([bashcompletiondir])
  40
  41 AC_ARG_WITH([zsh-completion-dir],
  42   AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  43     [name of the Zsh completion directory]),
  44   [zshcompletiondir="$withval"],
  45   [zshcompletiondir='${datadir}/zsh/site-functions'])
  46 AC_SUBST([zshcompletiondir])
  47
  48 dnl Better be verbose.
  49 AC_MSG_CHECKING([for the store directory])
  50 AC_MSG_RESULT([$storedir])
  51
  52 AC_ARG_ENABLE([daemon],
  53   [AS_HELP_STRING([--disable-daemon], [build the Nix daemon (C++)])],
  54   [guix_build_daemon="$enableval"],
  55   [guix_build_daemon="yes"])
  56
  57 # Prepare a version of $localstatedir & co. that does not contain references
  58 # to shell variables.
  59 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  60 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  61 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  62 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  63 AC_SUBST([guix_localstatedir])
  64 AC_SUBST([guix_sysconfdir])
  65 AC_SUBST([guix_sbindir])
  66
  67 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  68 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  69
  70 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  71 dnl Make sure they are available.
  72 m4_pattern_forbid([PKG_CHECK_MODULES])
  73 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  74 m4_pattern_forbid([^GUILE_P$])
  75
  76 dnl Search for 'guile' and 'guild'.  This macro defines
  77 dnl 'GUILE_EFFECTIVE_VERSION'.
  78 GUILE_PKG([2.2 2.0])
  79 GUILE_PROGS
  80 if test "x$GUILD" = "x"; then
  81    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  82 fi
  83
  84 if test "x$GUILE_EFFECTIVE_VERSION" = "x2.0"; then
  85   PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.7])
  86 fi
  87
  88 dnl Installation directory for .scm and .go files.
  89 guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
  90 AC_SUBST([guilemoduledir])
  91
  92 dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
  93 dnl pull', among other things.
  94 GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
  95 if test "x$have_gnutls" != "xyes"; then
  96   AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
  97 fi
  98
  99 dnl Guile-JSON is used in various places.
 100 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
 101 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
 102
 103 dnl Make sure we have a full-fledged Guile.
 104 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
 105
 106 dnl Check whether (srfi srfi-37) works, and provide our own if it doesn't.
 107 GUIX_CHECK_SRFI_37
 108 AM_CONDITIONAL([INSTALL_SRFI_37], [test "x$ac_cv_guix_srfi_37_broken" = xyes])
 109
 110 dnl Decompressors, for use by the substituter and other modules.
 111 AC_PATH_PROG([GZIP], [gzip])
 112 AC_PATH_PROG([BZIP2], [bzip2])
 113 AC_PATH_PROG([XZ], [xz])
 114 AC_SUBST([GZIP])
 115 AC_SUBST([BZIP2])
 116 AC_SUBST([XZ])
 117
 118 AC_ARG_WITH([nix-prefix],
 119   [AS_HELP_STRING([--with-nix-prefix=DIR],
 120     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 121   [case "$withval" in
 122     yes|no) ;;
 123     *)
 124       NIX_PREFIX="$withval"
 125       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 126       AC_SUBST([NIX_PREFIX])
 127       ;;
 128    esac],
 129   [])
 130
 131 AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
 132 AC_PATH_PROG([NIX_HASH], [nix-hash])
 133 if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
 134    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 135 fi
 136
 137 if test "x$NIX_INSTANTIATE" = "x"; then
 138    # This program is an optional dependency, so we just want it to be
 139    # taken from $PATH if it's not available right now.
 140    NIX_INSTANTIATE="nix-instantiate"
 141 fi
 142
 143 AC_ARG_WITH([nixpkgs],
 144   [AS_HELP_STRING([--with-nixpkgs=DIR],
 145     [search for Nixpkgs in DIR (for testing purposes only)])],
 146   [case "$withval" in
 147     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 148     *)      NIXPKGS="$withval";;
 149    esac],
 150   [])
 151
 152 AC_MSG_CHECKING([for Nixpkgs source tree])
 153 if test -f "$NIXPKGS/default.nix"; then
 154    AC_MSG_RESULT([$NIXPKGS])
 155    AC_SUBST([NIXPKGS])
 156 else
 157    AC_MSG_RESULT([not found])
 158 fi
 159
 160 LIBGCRYPT="libgcrypt"
 161 LIBGCRYPT_LIBDIR="no"
 162 LIBGCRYPT_PREFIX="no"
 163
 164 AC_ARG_WITH([libgcrypt-prefix],
 165   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 166   [case "$withval" in
 167     yes|no)
 168       ;;
 169     *)
 170       LIBGCRYPT="$withval/lib/libgcrypt"
 171       LIBGCRYPT_PREFIX="$withval"
 172       LIBGCRYPT_LIBDIR="$withval/lib"
 173       ;;
 174    esac])
 175
 176 AC_ARG_WITH([libgcrypt-libdir],
 177   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 178      [search for GNU libgcrypt's shared library in DIR])],
 179   [case "$withval" in
 180     yes|no)
 181       LIBGCRYPT="libgcrypt"
 182       LIBGCRYPT_LIBDIR="no"
 183       ;;
 184     *)
 185       LIBGCRYPT="$withval/libgcrypt"
 186       LIBGCRYPT_LIBDIR="$withval"
 187       ;;
 188    esac])
 189
 190 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 191 dnl absolute file name of libgcrypt.so.
 192 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 193   xnono)
 194     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 195     if test "x$LIBGCRYPT_LIBDIR" != x; then
 196       LIBGCRYPT="$LIBGCRYPT_LIBDIR/libgcrypt"
 197     else
 198       dnl 'config-daemon.ac' expects "no" in this case.
 199       LIBGCRYPT_LIBDIR="no"
 200     fi
 201     ;;
 202 esac
 203
 204 dnl Library name suitable for `dynamic-link'.
 205 AC_MSG_CHECKING([for libgcrypt shared library name])
 206 AC_MSG_RESULT([$LIBGCRYPT])
 207 AC_SUBST([LIBGCRYPT])
 208 AC_SUBST([LIBGCRYPT_PREFIX])
 209 AC_SUBST([LIBGCRYPT_LIBDIR])
 210
 211 GUIX_ASSERT_LIBGCRYPT_USABLE
 212
 213 dnl Library name of zlib suitable for 'dynamic-link'.
 214 GUIX_LIBZ_LIBDIR([libz_libdir])
 215 if test "x$libz_libdir" = "x"; then
 216   LIBZ="libz"
 217 else
 218   LIBZ="$libz_libdir/libz"
 219 fi
 220 AC_MSG_CHECKING([for zlib's shared library name])
 221 AC_MSG_RESULT([$LIBZ])
 222 AC_SUBST([LIBZ])
 223
 224 dnl Check for Guile-SSH, for the (guix ssh) module.
 225 GUIX_CHECK_GUILE_SSH
 226 AM_CONDITIONAL([HAVE_GUILE_SSH],
 227   [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
 228
 229 AC_CACHE_SAVE
 230
 231 m4_include([config-daemon.ac])
 232
 233 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 234 dnl See `Building from Git' in the manual for more info.
 235 AM_MISSING_PROG([DOT], [dot])
 236
 237 dnl Manual pages.
 238 AM_MISSING_PROG([HELP2MAN], [help2man])
 239
 240 dnl Emacs (optional), for 'etc/indent-package.el'.
 241 AC_PATH_PROG([EMACS], [emacs], [/usr/bin/emacs])
 242 AC_SUBST([EMACS])
 243
 244 case "$storedir" in
 245   /gnu/store)
 246     ;;
 247   *)
 248     AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
 249     AC_MSG_WARN([from downloading substitutes from gnu.org.])
 250     ;;
 251 esac
 252
 253 AC_CONFIG_FILES([Makefile
 254                  po/guix/Makefile.in
 255                  po/packages/Makefile.in
 256                  guix/config.scm])
 257
 258 AC_CONFIG_FILES([scripts/guix], [chmod +x scripts/guix])
 259 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 260 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 261   [chmod +x pre-inst-env])
 262 AC_CONFIG_FILES([etc/indent-code.el], [chmod +x etc/indent-code.el])
 263
 264 AC_OUTPUT