guix/build-system/clojure.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2018 Alex Vong <alexvong1995@gmail.com>
   3 ;;;
   4 ;;; This file is part of GNU Guix.
   5 ;;;
   6 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or (at
   9 ;;; your option) any later version.
  10 ;;;
  11 ;;; GNU Guix is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (guix build-system clojure)
  20   #:use-module (guix build clojure-utils)
  21   #:use-module (guix build-system)
  22   #:use-module (guix build-system ant)
  23   #:use-module ((guix build-system gnu)
  24                 #:select (standard-packages)
  25                 #:prefix gnu:)
  26
  27   #:use-module (guix derivations)
  28   #:use-module (guix packages)
  29   #:use-module ((guix search-paths)
  30                 #:select
  31                 ((search-path-specification->sexp . search-path-spec->sexp)))
  32   #:use-module (guix utils)
  33
  34   #:use-module (ice-9 match)
  35   #:export (%clojure-build-system-modules
  36             clojure-build
  37             clojure-build-system))
  38
  39 ;; Commentary:
  40 ;;
  41 ;; Standard build procedure for Clojure packages.
  42 ;;
  43 ;; Code:
  44
  45 (define-with-docs %clojure-build-system-modules
  46   "Build-side modules imported and used by default."
  47   `((guix build clojure-build-system)
  48     (guix build clojure-utils)
  49     (guix build guile-build-system)
  50     ,@%ant-build-system-modules))
  51
  52 (define-with-docs %default-clojure
  53   "The default Clojure package."
  54   (delay (@* (gnu packages clojure) clojure)))
  55
  56 (define-with-docs %default-jdk
  57   "The default JDK package."
  58   (delay (@* (gnu packages java) icedtea)))
  59
  60 (define-with-docs %default-zip
  61   "The default ZIP package."
  62   (delay (@* (gnu packages compression) zip)))
  63
  64 (define* (lower name
  65                 #:key
  66                 source target
  67                 inputs native-inputs
  68                 (clojure (force %default-clojure))
  69                 (jdk (force %default-jdk))
  70                 (zip (force %default-zip))
  71                 outputs system
  72                 #:allow-other-keys
  73                 #:rest arguments)
  74   "Return a bag for NAME."
  75   (let ((private-keywords '(#:source #:target
  76                             #:inputs #:native-inputs
  77                             #:clojure #:jdk #:zip)))
  78
  79     (if target
  80         (error "No cross-compilation for clojure-build-system yet: LOWER"
  81                target) ; FIXME
  82         (bag (name name)
  83              (system system)
  84              (host-inputs `(,@(if source
  85                                   `(("source" ,source))
  86                                   '())
  87                             ,@inputs
  88                             ,@(gnu:standard-packages)))
  89              (build-inputs `(("clojure" ,clojure)
  90                              ("jdk" ,jdk "jdk")
  91                              ("zip" ,zip)
  92                              ,@native-inputs))
  93              (outputs outputs)
  94              (build clojure-build)
  95              (arguments (strip-keyword-arguments private-keywords
  96                                                  arguments))))))
  97
  98 (define-with-docs source->output-path
  99   "Convert source input to output path."
 100   (match-lambda
 101     (((? derivation? source))
 102      (derivation->output-path source))
 103     ((source)
 104      source)
 105     (source
 106      source)))
 107
 108 (define-with-docs maybe-guile->guile
 109   "Find the right guile."
 110   (match-lambda
 111     ((and maybe-guile (? package?))
 112      maybe-guile)
 113     (#f ; default
 114      (@* (gnu packages commencement) guile-final))))
 115
 116 (define* (clojure-build store name inputs
 117                         #:key
 118                         (source-dirs `',%source-dirs)
 119                         (test-dirs `',%test-dirs)
 120                         (compile-dir %compile-dir)
 121
 122                         (jar-names `',(package-name->jar-names name))
 123                         (main-class %main-class)
 124                         (omit-source? %omit-source?)
 125
 126                         (aot-include `',%aot-include)
 127                         (aot-exclude `',%aot-exclude)
 128
 129                         doc-dirs ; no sensible default
 130                         (doc-regex %doc-regex)
 131
 132                         (tests? %tests?)
 133                         (test-include `',%test-include)
 134                         (test-exclude `',%test-exclude)
 135
 136                         (phases '(@ (guix build clojure-build-system)
 137                                     %standard-phases))
 138                         (outputs '("out"))
 139                         (search-paths '())
 140                         (system (%current-system))
 141                         (guile #f)
 142
 143                         (imported-modules %clojure-build-system-modules)
 144                         (modules %clojure-build-system-modules))
 145   "Build SOURCE with INPUTS."
 146   (let ((builder `(begin
 147                     (use-modules ,@modules)
 148                     (clojure-build #:name ,name
 149                                    #:source ,(source->output-path
 150                                               (assoc-ref inputs "source"))
 151
 152                                    #:source-dirs ,source-dirs
 153                                    #:test-dirs ,test-dirs
 154                                    #:compile-dir ,compile-dir
 155
 156                                    #:jar-names ,jar-names
 157                                    #:main-class ,main-class
 158                                    #:omit-source? ,omit-source?
 159
 160                                    #:aot-include ,aot-include
 161                                    #:aot-exclude ,aot-exclude
 162
 163                                    #:doc-dirs ,doc-dirs
 164                                    #:doc-regex ,doc-regex
 165
 166                                    #:tests? ,tests?
 167                                    #:test-include ,test-include
 168                                    #:test-exclude ,test-exclude
 169
 170                                    #:phases ,phases
 171                                    #:outputs %outputs
 172                                    #:search-paths ',(map search-path-spec->sexp
 173                                                          search-paths)
 174                                    #:system ,system
 175                                    #:inputs %build-inputs)))
 176
 177         (guile-for-build (package-derivation store
 178                                              (maybe-guile->guile guile)
 179                                              system
 180                                              #:graft? #f)))
 181
 182     (build-expression->derivation store name builder
 183                                   #:inputs inputs
 184                                   #:system system
 185                                   #:modules imported-modules
 186                                   #:outputs outputs
 187                                   #:guile-for-build guile-for-build)))
 188
 189 (define clojure-build-system
 190   (build-system
 191     (name 'clojure)
 192     (description "Simple Clojure build system using plain old 'compile'")
 193     (lower lower)))
 194
 195 ;;; clojure.scm ends here