configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix], [0.12.0], [bug-guix@gnu.org], [guix],
   6   [http://www.gnu.org/software/guix/])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AM_INIT_AUTOMAKE([1.12 gnu silent-rules subdir-objects \
  10  color-tests parallel-tests -Woverride -Wno-portability])
  11
  12 # Enable silent rules by default.
  13 AM_SILENT_RULES([yes])
  14
  15 AC_CONFIG_SRCDIR([guix.scm])
  16 AC_CONFIG_MACRO_DIR([m4])
  17
  18 dnl For the C++ code.  This must be used early.
  19 AC_USE_SYSTEM_EXTENSIONS
  20
  21 AM_GNU_GETTEXT([external])
  22 AM_GNU_GETTEXT_VERSION([0.18.1])
  23
  24 GUIX_SYSTEM_TYPE
  25 GUIX_ASSERT_SUPPORTED_SYSTEM
  26
  27 AC_ARG_WITH(store-dir,
  28   AC_HELP_STRING([--with-store-dir=PATH],
  29     [file name of the store (defaults to /gnu/store)]),
  30   [storedir="$withval"],
  31   [storedir="/gnu/store"])
  32 AC_SUBST(storedir)
  33
  34 AC_ARG_WITH([bash-completion-dir],
  35   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  36     [name of the Bash completion directory]),
  37   [bashcompletiondir="$withval"],
  38   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  39 AC_SUBST([bashcompletiondir])
  40
  41 AC_ARG_WITH([zsh-completion-dir],
  42   AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  43     [name of the Zsh completion directory]),
  44   [zshcompletiondir="$withval"],
  45   [zshcompletiondir='${datadir}/zsh/site-functions'])
  46 AC_SUBST([zshcompletiondir])
  47
  48 dnl Better be verbose.
  49 AC_MSG_CHECKING([for the store directory])
  50 AC_MSG_RESULT([$storedir])
  51
  52 AC_ARG_ENABLE([daemon],
  53   [AS_HELP_STRING([--disable-daemon], [build the Nix daemon (C++)])],
  54   [guix_build_daemon="$enableval"],
  55   [guix_build_daemon="yes"])
  56
  57 # Prepare a version of $localstatedir & co. that does not contain references
  58 # to shell variables.
  59 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  60 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  61 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  62 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  63 AC_SUBST([guix_localstatedir])
  64 AC_SUBST([guix_sysconfdir])
  65 AC_SUBST([guix_sbindir])
  66
  67 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  68 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  69
  70 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  71 dnl Make sure they are available.
  72 m4_pattern_forbid([PKG_CHECK_MODULES])
  73 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  74 m4_pattern_forbid([^GUILE_P$])
  75
  76 dnl Search for 'guile' and 'guild'.  Prefer 2.0 until the 2.2 upgrade is
  77 dnl complete.  This macro defines 'GUILE_EFFECTIVE_VERSION'.
  78 GUILE_PKG([2.0 2.2])
  79 GUILE_PROGS
  80 if test "x$GUILD" = "x"; then
  81    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  82 fi
  83
  84 if test "x$GUILE_EFFECTIVE_VERSION" = "x2.0"; then
  85   PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.7])
  86 else
  87   AC_MSG_WARN([Guile $GUILE_EFFECTIVE_VERSION is not fully supported!])
  88 fi
  89
  90 dnl Installation directory for .scm and .go files.
  91 guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
  92 AC_SUBST([guilemoduledir])
  93
  94 dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
  95 dnl pull', among other things.
  96 GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
  97 if test "x$have_gnutls" != "xyes"; then
  98   AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
  99 fi
 100
 101 dnl Guile-JSON is used in various places.
 102 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
 103 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
 104
 105 dnl Make sure we have a full-fledged Guile.
 106 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
 107
 108 dnl Check whether (srfi srfi-37) works, and provide our own if it doesn't.
 109 GUIX_CHECK_SRFI_37
 110 AM_CONDITIONAL([INSTALL_SRFI_37], [test "x$ac_cv_guix_srfi_37_broken" = xyes])
 111
 112 dnl Decompressors, for use by the substituter and other modules.
 113 AC_PATH_PROG([GZIP], [gzip])
 114 AC_PATH_PROG([BZIP2], [bzip2])
 115 AC_PATH_PROG([XZ], [xz])
 116 AC_SUBST([GZIP])
 117 AC_SUBST([BZIP2])
 118 AC_SUBST([XZ])
 119
 120 AC_ARG_WITH([nix-prefix],
 121   [AS_HELP_STRING([--with-nix-prefix=DIR],
 122     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 123   [case "$withval" in
 124     yes|no) ;;
 125     *)
 126       NIX_PREFIX="$withval"
 127       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 128       AC_SUBST([NIX_PREFIX])
 129       ;;
 130    esac],
 131   [])
 132
 133 AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
 134 AC_PATH_PROG([NIX_HASH], [nix-hash])
 135 if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
 136    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 137 fi
 138
 139 if test "x$NIX_INSTANTIATE" = "x"; then
 140    # This program is an optional dependency, so we just want it to be
 141    # taken from $PATH if it's not available right now.
 142    NIX_INSTANTIATE="nix-instantiate"
 143 fi
 144
 145 AC_ARG_WITH([nixpkgs],
 146   [AS_HELP_STRING([--with-nixpkgs=DIR],
 147     [search for Nixpkgs in DIR (for testing purposes only)])],
 148   [case "$withval" in
 149     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 150     *)      NIXPKGS="$withval";;
 151    esac],
 152   [])
 153
 154 AC_MSG_CHECKING([for Nixpkgs source tree])
 155 if test -f "$NIXPKGS/default.nix"; then
 156    AC_MSG_RESULT([$NIXPKGS])
 157    AC_SUBST([NIXPKGS])
 158 else
 159    AC_MSG_RESULT([not found])
 160 fi
 161
 162 LIBGCRYPT="libgcrypt"
 163 LIBGCRYPT_LIBDIR="no"
 164 LIBGCRYPT_PREFIX="no"
 165
 166 AC_ARG_WITH([libgcrypt-prefix],
 167   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 168   [case "$withval" in
 169     yes|no)
 170       ;;
 171     *)
 172       LIBGCRYPT="$withval/lib/libgcrypt"
 173       LIBGCRYPT_PREFIX="$withval"
 174       LIBGCRYPT_LIBDIR="$withval/lib"
 175       ;;
 176    esac])
 177
 178 AC_ARG_WITH([libgcrypt-libdir],
 179   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 180      [search for GNU libgcrypt's shared library in DIR])],
 181   [case "$withval" in
 182     yes|no)
 183       LIBGCRYPT="libgcrypt"
 184       LIBGCRYPT_LIBDIR="no"
 185       ;;
 186     *)
 187       LIBGCRYPT="$withval/libgcrypt"
 188       LIBGCRYPT_LIBDIR="$withval"
 189       ;;
 190    esac])
 191
 192 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 193 dnl absolute file name of libgcrypt.so.
 194 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 195   xnono)
 196     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 197     if test "x$LIBGCRYPT_LIBDIR" != x; then
 198       LIBGCRYPT="$LIBGCRYPT_LIBDIR/libgcrypt"
 199     else
 200       dnl 'config-daemon.ac' expects "no" in this case.
 201       LIBGCRYPT_LIBDIR="no"
 202     fi
 203     ;;
 204 esac
 205
 206 dnl Library name suitable for `dynamic-link'.
 207 AC_MSG_CHECKING([for libgcrypt shared library name])
 208 AC_MSG_RESULT([$LIBGCRYPT])
 209 AC_SUBST([LIBGCRYPT])
 210 AC_SUBST([LIBGCRYPT_PREFIX])
 211 AC_SUBST([LIBGCRYPT_LIBDIR])
 212
 213 GUIX_ASSERT_LIBGCRYPT_USABLE
 214
 215 dnl Library name of zlib suitable for 'dynamic-link'.
 216 GUIX_LIBZ_LIBDIR([libz_libdir])
 217 if test "x$libz_libdir" = "x"; then
 218   LIBZ="libz"
 219 else
 220   LIBZ="$libz_libdir/libz"
 221 fi
 222 AC_MSG_CHECKING([for zlib's shared library name])
 223 AC_MSG_RESULT([$LIBZ])
 224 AC_SUBST([LIBZ])
 225
 226 dnl Check for Guile-SSH, for the (guix ssh) module.
 227 GUIX_CHECK_GUILE_SSH
 228 AM_CONDITIONAL([HAVE_GUILE_SSH],
 229   [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
 230
 231 AC_CACHE_SAVE
 232
 233 m4_include([config-daemon.ac])
 234
 235 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 236 dnl See `Building from Git' in the manual for more info.
 237 AM_MISSING_PROG([DOT], [dot])
 238
 239 dnl Manual pages.
 240 AM_MISSING_PROG([HELP2MAN], [help2man])
 241
 242 dnl Emacs (optional), for 'etc/indent-package.el'.
 243 AC_PATH_PROG([EMACS], [emacs], [/usr/bin/emacs])
 244 AC_SUBST([EMACS])
 245
 246 case "$storedir" in
 247   /gnu/store)
 248     ;;
 249   *)
 250     AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
 251     AC_MSG_WARN([from downloading substitutes from gnu.org.])
 252     ;;
 253 esac
 254
 255 AC_CONFIG_FILES([Makefile
 256                  po/guix/Makefile.in
 257                  po/packages/Makefile.in
 258                  guix/config.scm])
 259
 260 AC_CONFIG_FILES([scripts/guix], [chmod +x scripts/guix])
 261 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 262 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 263   [chmod +x pre-inst-env])
 264 AC_CONFIG_FILES([etc/indent-code.el], [chmod +x etc/indent-code.el])
 265
 266 AC_OUTPUT