gnu/services/databases.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2015 David Thompson <davet@gnu.org>
   3 ;;; Copyright © 2015, 2016 Ludovic Courtès <ludo@gnu.org>
   4 ;;; Copyright © 2016 Leo Famulari <leo@famulari.name>
   5 ;;; Copyright © 2017 Christopher Baines <mail@cbaines.net>
   6 ;;; Copyright © 2018 Clément Lassieur <clement@lassieur.org>
   7 ;;; Copyright © 2018 Julien Lepiller <julien@lepiller.eu>
   8 ;;; Copyright © 2019 Robert Vollmert <rob@vllmrt.net>
   9 ;;;
  10 ;;; This file is part of GNU Guix.
  11 ;;;
  12 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  13 ;;; under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 3 of the License, or (at
  15 ;;; your option) any later version.
  16 ;;;
  17 ;;; GNU Guix is distributed in the hope that it will be useful, but
  18 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 (define-module (gnu services databases)
  26   #:use-module (gnu services)
  27   #:use-module (gnu services shepherd)
  28   #:use-module (gnu system shadow)
  29   #:use-module (gnu packages admin)
  30   #:use-module (gnu packages databases)
  31   #:use-module (guix build-system trivial)
  32   #:use-module (guix build union)
  33   #:use-module (guix modules)
  34   #:use-module (guix packages)
  35   #:use-module (guix records)
  36   #:use-module (guix gexp)
  37   #:use-module (srfi srfi-1)
  38   #:use-module (ice-9 match)
  39   #:export (<postgresql-config-file>
  40             postgresql-config-file
  41             postgresql-config-file?
  42             postgresql-config-file-log-destination
  43             postgresql-config-file-hba-file
  44             postgresql-config-file-ident-file
  45             postgresql-config-file-extra-config
  46
  47             <postgresql-configuration>
  48             postgresql-configuration
  49             postgresql-configuration?
  50             postgresql-configuration-postgresql
  51             postgresql-configuration-port
  52             postgresql-configuration-locale
  53             postgresql-configuration-file
  54             postgresql-configuration-data-directory
  55
  56             postgresql-service
  57             postgresql-service-type
  58
  59             memcached-service-type
  60             <memcached-configuration>
  61             memcached-configuration
  62             memcached-configuration?
  63             memcached-configuration-memecached
  64             memcached-configuration-interfaces
  65             memcached-configuration-tcp-port
  66             memcached-configuration-udp-port
  67             memcached-configuration-additional-options
  68
  69             <mongodb-configuration>
  70             mongodb-configuration
  71             mongodb-configuration?
  72             mongodb-configuration-mongodb
  73             mongodb-configuration-config-file
  74             mongodb-configuration-data-directory
  75             mongodb-service-type
  76
  77             mysql-service
  78             mysql-service-type
  79             mysql-configuration
  80             mysql-configuration?
  81
  82             redis-configuration
  83             redis-configuration?
  84             redis-service-type))
  85
  86 ;;; Commentary:
  87 ;;;
  88 ;;; Database services.
  89 ;;;
  90 ;;; Code:
  91
  92 (define %default-postgres-hba
  93   (plain-file "pg_hba.conf"
  94               "
  95 local   all     all                     peer
  96 host    all     all     127.0.0.1/32    md5
  97 host    all     all     ::1/128         md5"))
  98
  99 (define %default-postgres-ident
 100   (plain-file "pg_ident.conf"
 101               "# MAPNAME       SYSTEM-USERNAME         PG-USERNAME"))
 102
 103 (define-record-type* <postgresql-config-file>
 104   postgresql-config-file make-postgresql-config-file
 105   postgresql-config-file?
 106   (log-destination postgresql-config-file-log-destination
 107                    (default "syslog"))
 108   (hba-file        postgresql-config-file-hba-file
 109                    (default %default-postgres-hba))
 110   (ident-file      postgresql-config-file-ident-file
 111                    (default %default-postgres-ident))
 112   (extra-config    postgresql-config-file-extra-config
 113                    (default '())))
 114
 115 (define-gexp-compiler (postgresql-config-file-compiler
 116                        (file <postgresql-config-file>) system target)
 117   (match file
 118     (($ <postgresql-config-file> log-destination hba-file
 119                                  ident-file extra-config)
 120      (define (single-quote string)
 121        (if string
 122            (list "'" string "'")
 123            '()))
 124
 125      (define contents
 126        (append-map
 127         (match-lambda
 128           ((key) '())
 129           ((key . #f) '())
 130           ((key values ...) `(,key " = " ,@values "\n")))
 131
 132         `(("log_destination" ,@(single-quote log-destination))
 133           ("hba_file" ,@(single-quote hba-file))
 134           ("ident_file" ,@(single-quote ident-file))
 135           ,@extra-config)))
 136
 137      (gexp->derivation
 138       "postgresql.conf"
 139       #~(call-with-output-file (ungexp output "out")
 140           (lambda (port)
 141             (display
 142              (string-append #$@contents)
 143              port)))
 144       #:local-build? #t))))
 145
 146 (define-record-type* <postgresql-configuration>
 147   postgresql-configuration make-postgresql-configuration
 148   postgresql-configuration?
 149   (postgresql         postgresql-configuration-postgresql ;<package>
 150                       (default postgresql))
 151   (port               postgresql-configuration-port
 152                       (default 5432))
 153   (locale             postgresql-configuration-locale
 154                       (default "en_US.utf8"))
 155   (config-file        postgresql-configuration-file
 156                       (default (postgresql-config-file)))
 157   (data-directory     postgresql-configuration-data-directory
 158                       (default "/var/lib/postgresql/data"))
 159   (extension-packages postgresql-configuration-extension-packages
 160                       (default '())))
 161
 162 (define %postgresql-accounts
 163   (list (user-group (name "postgres") (system? #t))
 164         (user-account
 165          (name "postgres")
 166          (group "postgres")
 167          (system? #t)
 168          (comment "PostgreSQL server user")
 169          (home-directory "/var/empty")
 170          (shell (file-append shadow "/sbin/nologin")))))
 171
 172 (define (final-postgresql postgresql extension-packages)
 173   (if (null? extension-packages)
 174     postgresql
 175     (package
 176       (inherit postgresql)
 177       (source #f)
 178       (build-system trivial-build-system)
 179       (arguments
 180        `(#:modules ((guix build utils) (guix build union))
 181          #:builder
 182          (begin
 183            (use-modules (guix build utils) (guix build union) (srfi srfi-26))
 184            (union-build (assoc-ref %outputs "out") (map (lambda (input) (cdr input)) %build-inputs))
 185            #t)))
 186       (inputs
 187        `(("postgresql" ,postgresql)
 188          ,@(map (lambda (extension) (list "extension" extension))
 189                 extension-packages))))))
 190
 191 (define postgresql-activation
 192   (match-lambda
 193     (($ <postgresql-configuration> postgresql port locale config-file data-directory
 194         extension-packages)
 195      #~(begin
 196          (use-modules (guix build utils)
 197                       (ice-9 match))
 198
 199          (let ((user (getpwnam "postgres"))
 200                (initdb (string-append #$(final-postgresql postgresql extension-packages)
 201                                       "/bin/initdb"))
 202                (initdb-args
 203                 (append
 204                  (if #$locale
 205                      (list (string-append "--locale=" #$locale))
 206                      '()))))
 207            ;; Create db state directory.
 208            (mkdir-p #$data-directory)
 209            (chown #$data-directory (passwd:uid user) (passwd:gid user))
 210
 211            ;; Drop privileges and init state directory in a new
 212            ;; process.  Wait for it to finish before proceeding.
 213            (match (primitive-fork)
 214              (0
 215               ;; Exit with a non-zero status code if an exception is thrown.
 216               (dynamic-wind
 217                 (const #t)
 218                 (lambda ()
 219                   (setgid (passwd:gid user))
 220                   (setuid (passwd:uid user))
 221                   (primitive-exit
 222                    (apply system*
 223                           initdb
 224                           "-D"
 225                           #$data-directory
 226                           initdb-args)))
 227                 (lambda ()
 228                   (primitive-exit 1))))
 229              (pid (waitpid pid))))))))
 230
 231 (define postgresql-shepherd-service
 232   (match-lambda
 233     (($ <postgresql-configuration> postgresql port locale config-file data-directory
 234         extension-packages)
 235      (let* ((pg_ctl-wrapper
 236              ;; Wrapper script that switches to the 'postgres' user before
 237              ;; launching daemon.
 238              (program-file
 239               "pg_ctl-wrapper"
 240               #~(begin
 241                   (use-modules (ice-9 match)
 242                                (ice-9 format))
 243                   (match (command-line)
 244                     ((_ mode)
 245                      (let ((user (getpwnam "postgres"))
 246                            (pg_ctl #$(file-append (final-postgresql postgresql extension-packages)
 247                                                   "/bin/pg_ctl"))
 248                            (options (format #f "--config-file=~a -p ~d"
 249                                             #$config-file #$port)))
 250                        (setgid (passwd:gid user))
 251                        (setuid (passwd:uid user))
 252                        (execl pg_ctl pg_ctl "-D" #$data-directory "-o" options
 253                               mode)))))))
 254             (pid-file (in-vicinity data-directory "postmaster.pid"))
 255             (action (lambda args
 256                       #~(lambda _
 257                           (invoke #$pg_ctl-wrapper #$@args)
 258                           (match '#$args
 259                             (("start")
 260                              (call-with-input-file #$pid-file read))
 261                             (_ #t))))))
 262        (list (shepherd-service
 263               (provision '(postgres))
 264               (documentation "Run the PostgreSQL daemon.")
 265               (requirement '(user-processes loopback syslogd))
 266               (modules `((ice-9 match)
 267                          ,@%default-modules))
 268               (start (action "start"))
 269               (stop (action "stop"))))))))
 270
 271 (define postgresql-service-type
 272   (service-type (name 'postgresql)
 273                 (extensions
 274                  (list (service-extension shepherd-root-service-type
 275                                           postgresql-shepherd-service)
 276                        (service-extension activation-service-type
 277                                           postgresql-activation)
 278                        (service-extension account-service-type
 279                                           (const %postgresql-accounts))))
 280                 (default-value (postgresql-configuration))))
 281
 282 (define* (postgresql-service #:key (postgresql postgresql)
 283                              (port 5432)
 284                              (locale "en_US.utf8")
 285                              (config-file (postgresql-config-file))
 286                              (data-directory "/var/lib/postgresql/data")
 287                              (extension-packages '()))
 288   "Return a service that runs @var{postgresql}, the PostgreSQL database server.
 289
 290 The PostgreSQL daemon loads its runtime configuration from @var{config-file}
 291 and stores the database cluster in @var{data-directory}."
 292   (service postgresql-service-type
 293            (postgresql-configuration
 294             (postgresql postgresql)
 295             (port port)
 296             (locale locale)
 297             (config-file config-file)
 298             (data-directory data-directory)
 299             (extension-packages extension-packages))))
 300
 301 \f
 302 ;;;
 303 ;;; Memcached
 304 ;;;
 305
 306 (define-record-type* <memcached-configuration>
 307   memcached-configuration make-memcached-configuration
 308   memcached-configuration?
 309   (memcached          memcached-configuration-memcached ;<package>
 310                       (default memcached))
 311   (interfaces         memcached-configuration-interfaces
 312                       (default '("0.0.0.0")))
 313   (tcp-port           memcached-configuration-tcp-port
 314                       (default 11211))
 315   (udp-port           memcached-configuration-udp-port
 316                       (default 11211))
 317   (additional-options memcached-configuration-additional-options
 318                       (default '())))
 319
 320 (define %memcached-accounts
 321   (list (user-group (name "memcached") (system? #t))
 322         (user-account
 323          (name "memcached")
 324          (group "memcached")
 325          (system? #t)
 326          (comment "Memcached server user")
 327          (home-directory "/var/empty")
 328          (shell (file-append shadow "/sbin/nologin")))))
 329
 330 (define memcached-activation
 331   #~(begin
 332       (use-modules (guix build utils))
 333       (let ((user (getpwnam "memcached")))
 334         (mkdir-p "/var/run/memcached")
 335         (chown "/var/run/memcached"
 336                (passwd:uid user) (passwd:gid user)))))
 337
 338 (define memcached-shepherd-service
 339   (match-lambda
 340     (($ <memcached-configuration> memcached interfaces tcp-port udp-port
 341                                   additional-options)
 342      (with-imported-modules (source-module-closure
 343                              '((gnu build shepherd)))
 344        (list (shepherd-service
 345               (provision '(memcached))
 346               (documentation "Run the Memcached daemon.")
 347               (requirement '(user-processes loopback))
 348               (modules '((gnu build shepherd)))
 349               (start #~(make-forkexec-constructor
 350                         `(#$(file-append memcached "/bin/memcached")
 351                           "-l" #$(string-join interfaces ",")
 352                           "-p" #$(number->string tcp-port)
 353                           "-U" #$(number->string udp-port)
 354                           "--daemon"
 355                           ;; Memcached changes to the memcached user prior to
 356                           ;; writing the pid file, so write it to a directory
 357                           ;; that memcached owns.
 358                           "-P" "/var/run/memcached/pid"
 359                           "-u" "memcached"
 360                           ,#$@additional-options)
 361                         #:log-file "/var/log/memcached"
 362                         #:pid-file "/var/run/memcached/pid"))
 363               (stop #~(make-kill-destructor))))))))
 364
 365 (define memcached-service-type
 366   (service-type (name 'memcached)
 367                 (extensions
 368                  (list (service-extension shepherd-root-service-type
 369                                           memcached-shepherd-service)
 370                        (service-extension activation-service-type
 371                                           (const memcached-activation))
 372                        (service-extension account-service-type
 373                                           (const %memcached-accounts))))
 374                 (default-value (memcached-configuration))))
 375
 376 \f
 377 ;;;
 378 ;;; MongoDB
 379 ;;;
 380
 381 (define %default-mongodb-configuration-file
 382   (plain-file
 383    "mongodb.yaml"
 384    "# GNU Guix: MongoDB default configuration file
 385 processManagement:
 386   pidFilePath: /var/run/mongodb/pid
 387 storage:
 388   dbPath: /var/lib/mongodb
 389 "))
 390
 391
 392 (define-record-type* <mongodb-configuration>
 393   mongodb-configuration make-mongodb-configuration
 394   mongodb-configuration?
 395   (mongodb             mongodb-configuration-mongodb
 396                        (default mongodb))
 397   (config-file         mongodb-configuration-config-file
 398                        (default %default-mongodb-configuration-file))
 399   (data-directory      mongodb-configuration-data-directory
 400                        (default "/var/lib/mongodb")))
 401
 402 (define %mongodb-accounts
 403   (list (user-group (name "mongodb") (system? #t))
 404         (user-account
 405          (name "mongodb")
 406          (group "mongodb")
 407          (system? #t)
 408          (comment "Mongodb server user")
 409          (home-directory "/var/lib/mongodb")
 410          (shell (file-append shadow "/sbin/nologin")))))
 411
 412 (define mongodb-activation
 413   (match-lambda
 414     (($ <mongodb-configuration> mongodb config-file data-directory)
 415      #~(begin
 416          (use-modules (guix build utils))
 417          (let ((user (getpwnam "mongodb")))
 418            (for-each
 419             (lambda (directory)
 420               (mkdir-p directory)
 421               (chown directory
 422                      (passwd:uid user) (passwd:gid user)))
 423             '("/var/run/mongodb" #$data-directory)))))))
 424
 425 (define mongodb-shepherd-service
 426   (match-lambda
 427     (($ <mongodb-configuration> mongodb config-file data-directory)
 428      (shepherd-service
 429       (provision '(mongodb))
 430       (documentation "Run the Mongodb daemon.")
 431       (requirement '(user-processes loopback))
 432       (start #~(make-forkexec-constructor
 433                 `(,(string-append #$mongodb "/bin/mongod")
 434                   "--config"
 435                   ,#$config-file)
 436                 #:user "mongodb"
 437                 #:group "mongodb"
 438                 #:pid-file "/var/run/mongodb/pid"
 439                 #:log-file "/var/log/mongodb.log"))
 440       (stop #~(make-kill-destructor))))))
 441
 442 (define mongodb-service-type
 443   (service-type
 444    (name 'mongodb)
 445    (description "Run the MongoDB document database server.")
 446    (extensions
 447     (list (service-extension shepherd-root-service-type
 448                              (compose list
 449                                       mongodb-shepherd-service))
 450           (service-extension activation-service-type
 451                              mongodb-activation)
 452           (service-extension account-service-type
 453                              (const %mongodb-accounts))))
 454    (default-value
 455      (mongodb-configuration))))
 456
 457 \f
 458 ;;;
 459 ;;; MySQL.
 460 ;;;
 461
 462 (define-record-type* <mysql-configuration>
 463   mysql-configuration make-mysql-configuration
 464   mysql-configuration?
 465   (mysql mysql-configuration-mysql (default mariadb))
 466   (port mysql-configuration-port (default 3306))
 467   (extra-content mysql-configuration-extra-content (default "")))
 468
 469 (define %mysql-accounts
 470   (list (user-group
 471          (name "mysql")
 472          (system? #t))
 473         (user-account
 474          (name "mysql")
 475          (group "mysql")
 476          (system? #t)
 477          (home-directory "/var/empty")
 478          (shell (file-append shadow "/sbin/nologin")))))
 479
 480 (define mysql-configuration-file
 481   (match-lambda
 482     (($ <mysql-configuration> mysql port extra-content)
 483      (mixed-text-file "my.cnf" "[mysqld]
 484 datadir=/var/lib/mysql
 485 socket=/run/mysqld/mysqld.sock
 486 port=" (number->string port) "
 487 " extra-content "
 488 "))))
 489
 490 (define (%mysql-activation config)
 491   "Return an activation gexp for the MySQL or MariaDB database server."
 492   (let ((mysql  (mysql-configuration-mysql config))
 493         (my.cnf (mysql-configuration-file config)))
 494     #~(begin
 495         (use-modules (ice-9 popen)
 496                      (guix build utils))
 497         (let* ((mysqld  (string-append #$mysql "/bin/mysqld"))
 498                (user    (getpwnam "mysql"))
 499                (uid     (passwd:uid user))
 500                (gid     (passwd:gid user))
 501                (datadir "/var/lib/mysql")
 502                (rundir  "/run/mysqld"))
 503           (mkdir-p datadir)
 504           (chown datadir uid gid)
 505           (mkdir-p rundir)
 506           (chown rundir uid gid)
 507           ;; Initialize the database when it doesn't exist.
 508           (when (not (file-exists? (string-append datadir "/mysql")))
 509             (if (string-prefix? "mysql-" (strip-store-file-name #$mysql))
 510                 ;; For MySQL.
 511                 (system* mysqld
 512                          (string-append "--defaults-file=" #$my.cnf)
 513                          "--initialize"
 514                          "--user=mysql")
 515                 ;; For MariaDB.
 516                 ;; XXX: The 'mysql_install_db' script doesn't work directly
 517                 ;;      due to missing 'mkdir' in PATH.
 518                 (let ((p (open-pipe* OPEN_WRITE mysqld
 519                                      (string-append
 520                                       "--defaults-file=" #$my.cnf)
 521                                      "--bootstrap"
 522                                      "--user=mysql")))
 523                   ;; Create the system database, as does by 'mysql_install_db'.
 524                   (display "create database mysql;\n" p)
 525                   (display "use mysql;\n" p)
 526                   (for-each
 527                    (lambda (sql)
 528                      (call-with-input-file
 529                          (string-append #$mysql:lib "/share/mysql/" sql)
 530                        (lambda (in) (dump-port in p))))
 531                    '("mysql_system_tables.sql"
 532                      "mysql_performance_tables.sql"
 533                      "mysql_system_tables_data.sql"
 534                      "fill_help_tables.sql"))
 535                   ;; Remove the anonymous user and disable root access from
 536                   ;; remote machines, as does by 'mysql_secure_installation'.
 537                   (display "
 538 DELETE FROM user WHERE User='';
 539 DELETE FROM user WHERE User='root' AND
 540   Host NOT IN  ('localhost', '127.0.0.1', '::1');
 541 FLUSH PRIVILEGES;
 542 " p)
 543                   (close-pipe p))))))))
 544
 545 (define (mysql-shepherd-service config)
 546   (list (shepherd-service
 547          (provision '(mysql))
 548          (documentation "Run the MySQL server.")
 549          (start (let ((mysql  (mysql-configuration-mysql config))
 550                       (my.cnf (mysql-configuration-file config)))
 551                   #~(make-forkexec-constructor
 552                      (list (string-append #$mysql "/bin/mysqld")
 553                            (string-append "--defaults-file=" #$my.cnf))
 554                      #:user "mysql" #:group "mysql")))
 555          (stop #~(make-kill-destructor)))))
 556
 557 (define mysql-service-type
 558   (service-type
 559    (name 'mysql)
 560    (extensions
 561     (list (service-extension account-service-type
 562                              (const %mysql-accounts))
 563           (service-extension activation-service-type
 564                              %mysql-activation)
 565           (service-extension shepherd-root-service-type
 566                              mysql-shepherd-service)))
 567    (default-value (mysql-configuration))))
 568
 569 (define* (mysql-service #:key (config (mysql-configuration)))
 570   "Return a service that runs @command{mysqld}, the MySQL or MariaDB
 571 database server.
 572
 573 The optional @var{config} argument specifies the configuration for
 574 @command{mysqld}, which should be a @code{<mysql-configuration>} object."
 575   (service mysql-service-type config))
 576
 577 \f
 578 ;;;
 579 ;;; Redis
 580 ;;;
 581
 582 (define-record-type* <redis-configuration>
 583   redis-configuration make-redis-configuration
 584   redis-configuration?
 585   (redis             redis-configuration-redis ;<package>
 586                      (default redis))
 587   (bind              redis-configuration-bind
 588                      (default "127.0.0.1"))
 589   (port              redis-configuration-port
 590                      (default 6379))
 591   (working-directory redis-configuration-working-directory
 592                      (default "/var/lib/redis"))
 593   (config-file       redis-configuration-config-file
 594                      (default #f)))
 595
 596 (define (default-redis.conf bind port working-directory)
 597   (mixed-text-file "redis.conf"
 598                    "bind " bind "\n"
 599                    "port " (number->string port) "\n"
 600                    "dir " working-directory "\n"
 601                    "daemonize no\n"))
 602
 603 (define %redis-accounts
 604   (list (user-group (name "redis") (system? #t))
 605         (user-account
 606          (name "redis")
 607          (group "redis")
 608          (system? #t)
 609          (comment "Redis server user")
 610          (home-directory "/var/empty")
 611          (shell (file-append shadow "/sbin/nologin")))))
 612
 613 (define redis-activation
 614   (match-lambda
 615     (($ <redis-configuration> redis bind port working-directory config-file)
 616      #~(begin
 617          (use-modules (guix build utils)
 618                       (ice-9 match))
 619
 620          (let ((user (getpwnam "redis")))
 621            (mkdir-p #$working-directory)
 622            (chown #$working-directory (passwd:uid user) (passwd:gid user)))))))
 623
 624 (define redis-shepherd-service
 625   (match-lambda
 626     (($ <redis-configuration> redis bind port working-directory config-file)
 627      (let ((config-file
 628             (or config-file
 629                 (default-redis.conf bind port working-directory))))
 630        (list (shepherd-service
 631               (provision '(redis))
 632               (documentation "Run the Redis daemon.")
 633               (requirement '(user-processes syslogd))
 634               (start #~(make-forkexec-constructor
 635                         '(#$(file-append redis "/bin/redis-server")
 636                           #$config-file)
 637                         #:user "redis"
 638                         #:group "redis"))
 639               (stop #~(make-kill-destructor))))))))
 640
 641 (define redis-service-type
 642   (service-type (name 'redis)
 643                 (extensions
 644                  (list (service-extension shepherd-root-service-type
 645                                           redis-shepherd-service)
 646                        (service-extension activation-service-type
 647                                           redis-activation)
 648                        (service-extension account-service-type
 649                                           (const %redis-accounts))))
 650                 (default-value (redis-configuration))))