gnu/packages/ebook.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2015, 2016 Andreas Enge <andreas@enge.fr>
   3 ;;; Copyright © 2016, 2018 Efraim Flashner <efraim@flashner.co.il>
   4 ;;; Copyright © 2016, 2017 Alex Griffin <a@ajgrf.com>
   5 ;;; Copyright © 2017, 2019, 2020, 2021 Brendan Tildesley <mail@brendan.scot>
   6 ;;; Copyright © 2017 Roel Janssen <roel@gnu.org>
   7 ;;; Copyright © 2018–2021 Tobias Geerinckx-Rice <me@tobias.gr>
   8 ;;; Copyright © 2020 Marius Bakke <mbakke@fastmail.com>
   9 ;;; Copyright © 2020, 2021 Vinicius Monego <monego@posteo.net>
  10 ;;; Copyright © 2020 Zheng Junjie <873216071@qq.com>
  11 ;;; Copyright © 2021 la snesne <lasnesne@lagunposprasihopre.org>
  12 ;;;
  13 ;;; This file is part of GNU Guix.
  14 ;;;
  15 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  16 ;;; under the terms of the GNU General Public License as published by
  17 ;;; the Free Software Foundation; either version 3 of the License, or (at
  18 ;;; your option) any later version.
  19 ;;;
  20 ;;; GNU Guix is distributed in the hope that it will be useful, but
  21 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;;; GNU General Public License for more details.
  24 ;;;
  25 ;;; You should have received a copy of the GNU General Public License
  26 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 (define-module (gnu packages ebook)
  29   #:use-module ((guix licenses) #:prefix license:)
  30   #:use-module (guix packages)
  31   #:use-module (guix download)
  32   #:use-module (guix utils)
  33   #:use-module (guix git-download)
  34   #:use-module (guix build-system cmake)
  35   #:use-module (guix build-system gnu)
  36   #:use-module (guix build-system meson)
  37   #:use-module (guix build-system python)
  38   #:use-module (gnu packages)
  39   #:use-module (gnu packages autotools)
  40   #:use-module (gnu packages compression)
  41   #:use-module (gnu packages curl)
  42   #:use-module (gnu packages databases)
  43   #:use-module (gnu packages file)
  44   #:use-module (gnu packages fonts)
  45   #:use-module (gnu packages fontutils)
  46   #:use-module (gnu packages freedesktop)
  47   #:use-module (gnu packages fribidi)
  48   #:use-module (gnu packages gcc)
  49   #:use-module (gnu packages gettext)
  50   #:use-module (gnu packages gtk)
  51   #:use-module (gnu packages gnome)
  52   #:use-module (gnu packages glib)
  53   #:use-module (gnu packages gstreamer)
  54   #:use-module (gnu packages icu4c)
  55   #:use-module (gnu packages image)
  56   #:use-module (gnu packages javascript)
  57   #:use-module (gnu packages libusb)
  58   #:use-module (gnu packages libreoffice)
  59   #:use-module (gnu packages music)
  60   #:use-module (gnu packages pantheon)
  61   #:use-module (gnu packages pdf)
  62   #:use-module (gnu packages pkg-config)
  63   #:use-module (gnu packages python)
  64   #:use-module (gnu packages python-build)
  65   #:use-module (gnu packages python-compression)
  66   #:use-module (gnu packages python-crypto)
  67   #:use-module (gnu packages python-web)
  68   #:use-module (gnu packages python-xyz)
  69   #:use-module (gnu packages qt)
  70   #:use-module (gnu packages serialization)
  71   #:use-module (gnu packages speech)
  72   #:use-module (gnu packages sqlite)
  73   #:use-module (gnu packages time)
  74   #:use-module (gnu packages tls)
  75   #:use-module (gnu packages web)
  76   #:use-module (gnu packages xml)
  77   #:use-module (gnu packages xorg)
  78   #:use-module (gnu packages wxwidgets))
  79
  80 (define-public chmlib
  81   (package
  82     (name "chmlib")
  83     (version "0.40")
  84     (source (origin
  85              (method url-fetch)
  86              (uri (string-append "http://www.jedrea.com/chmlib/chmlib-"
  87                                  version ".tar.bz2"))
  88              (sha256
  89                (base32
  90                 "18zzb4x3z0d7fjh1x5439bs62dmgsi4c1pg3qyr7h5gp1i5xcj9l"))
  91              (patches (search-patches "chmlib-inttypes.patch"))))
  92     (build-system gnu-build-system)
  93     (home-page "http://www.jedrea.com/chmlib/")
  94     (synopsis "Library for CHM files")
  95     (description "CHMLIB is a library for dealing with ITSS/CHM format files.")
  96     (license license:lgpl2.1+)))
  97
  98 (define-public python-pychm
  99   (package
 100     (name "python-pychm")
 101     (version "0.8.6")
 102     (source
 103      (origin
 104        (method url-fetch)
 105        (uri (pypi-uri "pychm" version))
 106        (sha256
 107         (base32
 108          "0wpn9ijlsmrpyiwg3drmgz4dms1i1i347adgqw37bkrh3vn6yq16"))))
 109     (build-system python-build-system)
 110     (inputs
 111      `(("chmlib" ,chmlib)))
 112     (home-page "https://github.com/dottedmag/pychm")
 113     (synopsis "Handle CHM files")
 114     (description "This package provides a Python module for interacting
 115 with Microsoft Compiled HTML (CHM) files")
 116     (license license:gpl2+)))
 117
 118 (define-public calibre
 119   (package
 120     (name "calibre")
 121     (version "5.21.0")
 122     (source
 123       (origin
 124         (method url-fetch)
 125         (uri (string-append "http://download.calibre-ebook.com/"
 126                             version "/calibre-"
 127                             version ".tar.xz"))
 128         (sha256
 129          (base32
 130           "0mq2w8blq6ykaml812axakwkqcw85qcpfwijdikn7kvbrhnnp2s5"))
 131         (modules '((guix build utils)))
 132         (snippet
 133           '(begin
 134              ;; Unbundle python2-odfpy.
 135              (delete-file-recursively "src/odf")
 136              ;; Disable test that attempts to load it.
 137              (substitute* "setup/test.py"
 138                ((".*SRC, 'odf'.*")
 139                 ""))
 140
 141              ;; Remove unneeded resources.
 142              (delete-file "resources/mozilla-ca-certs.pem")
 143              (delete-file "resources/calibre-portable.bat")
 144              (delete-file "resources/calibre-portable.sh")
 145              #t))
 146         (patches (search-patches "calibre-no-updates-dialog.patch"
 147                                  "calibre-remove-test-sqlite.patch" ; TODO: fix test.
 148                                  "calibre-remove-test-unrar.patch"))))
 149     (build-system python-build-system)
 150     (native-inputs
 151      `(("pkg-config" ,pkg-config)
 152        ("qtbase" ,qtbase-5) ; for qmake
 153        ("python-flake8" ,python-flake8)
 154        ("python-pyqt-builder" ,python-pyqt-builder)
 155        ("xdg-utils" ,xdg-utils)))
 156     (inputs
 157      `(("fontconfig" ,fontconfig)
 158        ("font-liberation" ,font-liberation)
 159        ("glib" ,glib)
 160        ("hunspell" ,hunspell)
 161        ("hyphen" ,hyphen)
 162        ("icu4c" ,icu4c)
 163        ("libmtp" ,libmtp)
 164        ("libpng" ,libpng)
 165        ("libjpeg" ,libjpeg-turbo)
 166        ("libjxr" ,libjxr)
 167        ("libusb" ,libusb)
 168        ("openssl" ,openssl)
 169        ("optipng" ,optipng)
 170        ("podofo" ,podofo)
 171        ("poppler" ,poppler)
 172        ("python-apsw" ,python-apsw)
 173        ("python-beautifulsoup4" ,python-beautifulsoup4)
 174        ("python-cchardet" ,python-cchardet)
 175        ("python-css-parser" ,python-css-parser)
 176        ("python-cssselect" ,python-cssselect)
 177        ("python-dateutil" ,python-dateutil)
 178        ("python-dbus" ,python-dbus)
 179        ("python-dnspython" ,python-dnspython-1.16)
 180        ("python-dukpy" ,python-dukpy)
 181        ("python-feedparser" ,python-feedparser)
 182        ("python-html2text" ,python-html2text)
 183        ("python-html5-parser" ,python-html5-parser)
 184        ("python-html5lib" ,python-html5lib)
 185        ("python-lxml" ,python-lxml)
 186        ("python-markdown" ,python-markdown)
 187        ("python-mechanize" ,python-mechanize)
 188        ;; python-msgpack is needed for the network content server to work.
 189        ("python-msgpack" ,python-msgpack)
 190        ("python-netifaces" ,python-netifaces)
 191        ("python-odfpy" ,python-odfpy)
 192        ("python-pillow" ,python-pillow)
 193        ("python-psutil" ,python-psutil)
 194        ("python-py7zr" ,python-py7zr)
 195        ("python-pychm" ,python-pychm)
 196        ("python-pycryptodome" ,python-pycryptodome)
 197        ("python-pygments" ,python-pygments)
 198        ("python-pyqt" ,python-pyqt)
 199        ("python-pyqtwebengine" ,python-pyqtwebengine)
 200        ("python-regex" ,python-regex)
 201        ("python-speechd" ,speech-dispatcher)
 202        ("python-zeroconf" ,python-zeroconf)
 203        ("qtwebengine" ,qtwebengine)
 204        ("sqlite" ,sqlite)))
 205     (arguments
 206      `(;; Calibre is using setuptools by itself, but the setup.py is not
 207        ;; compatible with the shim wrapper (taken from pip) we are using.
 208        #:use-setuptools? #f
 209        #:phases
 210        (modify-phases %standard-phases
 211          (add-after 'unpack 'patch-source
 212            (lambda _
 213              (substitute* "src/calibre/linux.py"
 214                ;; We can't use the uninstaller in Guix. Don't build it.
 215                (("self\\.create_uninstaller()") ""))
 216              #t))
 217          (add-after 'patch-source-shebangs 'patch-more-shebangs
 218            (lambda _
 219              ;; Patch various inline shebangs.
 220              (substitute* '("src/calibre/gui2/preferences/tweaks.py"
 221                             "src/calibre/gui2/dialogs/custom_recipes.py"
 222                             "setup/install.py"
 223                             "setup/linux-installer.sh")
 224                (("#!/usr/bin/env python")
 225                 (string-append "#!" (which "python")))
 226                (("#!/bin/sh")
 227                 (string-append "#!" (which "sh"))))
 228              #t))
 229          (add-after 'unpack 'dont-load-remote-icons
 230            (lambda _
 231              (substitute* "setup/plugins_mirror.py"
 232                (("href=\"//calibre-ebook.com/favicon.ico\"")
 233                 "href=\"favicon.ico\""))
 234              #t))
 235          (add-before 'build 'configure
 236           (lambda* (#:key inputs outputs #:allow-other-keys)
 237             (let ((podofo (assoc-ref inputs "podofo"))
 238                   (pyqt (assoc-ref inputs "python-pyqt"))
 239                   (python-sip (assoc-ref inputs "python-sip"))
 240                   (out (assoc-ref outputs "out")))
 241               (substitute* "setup/build.py"
 242                 (("\\[tool.sip.bindings.pictureflow\\]")
 243                  "[tool.sip.bindings.pictureflow]
 244 tags = [\"WS_X11\"]")
 245                 (("\\[tool.sip.project\\]")
 246                  (string-append "[tool.sip.project]
 247 sip-include-dirs = [\"" pyqt "/share/sip" "\"]")))
 248               (substitute* "src/calibre/ebooks/pdf/pdftohtml.py"
 249                 (("PDFTOHTML = 'pdftohtml'")
 250                  (string-append "PDFTOHTML = \"" (assoc-ref inputs "poppler")
 251                                 "/bin/pdftohtml\"")))
 252               ;; get_exe_path looks in poppler's output for these binaries. Make
 253               ;; it not do that.
 254               (substitute* "src/calibre/utils/img.py"
 255                 (("get_exe_path..jpegtran..") (string-append "'" (which "jpegtran") "'"))
 256                 (("get_exe_path..cjpeg..") (string-append "'" (which "cjpeg") "'"))
 257                 (("get_exe_path..optipng..") (string-append "'" (which "optipng") "'"))
 258                 (("get_exe_path..JxrDecApp..") (string-append "'" (which "JxrDecApp") "'")))
 259               ;; Calibre thinks we are installing desktop files into a home
 260               ;; directory, but here we butcher the script in to installing
 261               ;; to calibres /share directory.
 262               (setenv "XDG_DATA_HOME" (string-append out "/share"))
 263               (substitute* "src/calibre/linux.py"
 264                 (("'~/.local/share'") "''"))
 265
 266               ;; 'python setup.py rapydscript' uses QtWebEngine, which
 267               ;; needs to create temporary files in $HOME.
 268               (setenv "HOME" "/tmp")
 269
 270               ;; XXX: QtWebEngine will fail if no fonts are available.  This
 271               ;; can likely be removed when fontconfig has been patched to
 272               ;; include TrueType fonts by default.
 273               (symlink (string-append (assoc-ref inputs "font-liberation")
 274                                       "/share/fonts")
 275                        "/tmp/.fonts")
 276
 277               (setenv "PODOFO_INC_DIR" (string-append podofo "/include/podofo"))
 278               (setenv "PODOFO_LIB_DIR" (string-append podofo "/lib"))
 279               ;; This informs the tests we are a continuous integration
 280               ;; environment and thus have no networking.
 281               (setenv "CI" "true")
 282               ;; The Qt test complains about being unable to load all image plugins, and I
 283               ;; notice the available plugins list it shows lacks 'svg'. Adding qtsvg doesn't
 284               ;; fix it, so I'm not sure how to fix it.  TODO: Fix test and remove this.
 285               (setenv "SKIP_QT_BUILD_TEST" "true")
 286               #t)))
 287          (add-after 'install 'install-rapydscript
 288            (lambda* (#:key inputs #:allow-other-keys)
 289               ;; Unset so QtWebengine doesn't dump temporary files here.
 290              (unsetenv "XDG_DATA_HOME")
 291              (invoke "python" "setup.py" "rapydscript")
 292              #t))
 293          (add-after 'install 'install-man-pages
 294            (lambda* (#:key outputs #:allow-other-keys)
 295              (copy-recursively
 296               "man-pages"
 297               (string-append (assoc-ref outputs "out") "/share/man"))
 298              #t))
 299          ;; The font TTF files are used in some miscellaneous tests, so we
 300          ;; unbundle them here to avoid patching the tests.
 301          (add-after 'install 'unbundle-font-liberation
 302            (lambda* (#:key inputs outputs #:allow-other-keys)
 303              (let ((font-dest (string-append (assoc-ref outputs "out")
 304                                              "/share/calibre/fonts/liberation"))
 305                    (font-src (string-append (assoc-ref inputs "font-liberation")
 306                                             "/share/fonts/truetype")))
 307                (delete-file-recursively font-dest)
 308                (symlink font-src font-dest))
 309              #t))
 310          ;; Make run-time dependencies available to the binaries.
 311          (add-after 'wrap 'wrap-program
 312            (lambda* (#:key inputs outputs #:allow-other-keys)
 313              (let ((out (assoc-ref outputs "out"))
 314                    (qtwebengine (assoc-ref inputs "qtwebengine")))
 315                (with-directory-excursion (string-append out "/bin")
 316                  (for-each
 317                   (lambda (binary)
 318                     (wrap-program binary
 319                       ;; Make QtWebEngineProcess available.
 320                       `("QTWEBENGINEPROCESS_PATH" =
 321                         ,(list (string-append
 322                                 qtwebengine
 323                                 "/lib/qt5/libexec/QtWebEngineProcess")))))
 324                   ;; Wrap all the binaries shipping with the package, except
 325                   ;; for the wrappings created during the 'wrap standard
 326                   ;; phase.  This extends existing .calibre-real wrappers
 327                   ;; rather than create ..calibre-real-real-s.  For more
 328                   ;; information see: https://issues.guix.gnu.org/43249.
 329                   (find-files "." (lambda (file stat)
 330                                     (not (wrapper? file)))))))
 331              #t)))))
 332     (home-page "https://calibre-ebook.com/")
 333     (synopsis "E-book library management software")
 334     (description "Calibre is an e-book library manager.  It can view, convert
 335 and catalog e-books in most of the major e-book formats.  It can also talk
 336 to many e-book reader devices.  It can go out to the Internet and fetch
 337 metadata for books.  It can download newspapers and convert them into
 338 e-books for convenient reading.")
 339     ;; Calibre is largely GPL3+, but includes a number of components covered
 340     ;; by other licenses. See COPYRIGHT for more details.
 341     (license (list license:gpl3+
 342                    license:gpl2+
 343                    license:lgpl2.1+
 344                    license:lgpl2.1
 345                    license:bsd-3
 346                    license:expat
 347                    license:zpl2.1
 348                    license:asl2.0
 349                    license:public-domain
 350                    license:silofl1.1
 351                    license:cc-by-sa3.0))))
 352
 353 (define-public ebook-tools
 354   (package
 355     (name "ebook-tools")
 356     (version "0.2.2")
 357     (source
 358      (origin
 359        (method url-fetch)
 360        (uri (string-append "mirror://sourceforge/ebook-tools/ebook-tools/"
 361                            version "/ebook-tools-" version ".tar.gz"))
 362        (sha256
 363         (base32
 364          "1bi7wsz3p5slb43kj7lgb3r6lb91lvb6ldi556k4y50ix6b5khyb"))))
 365     (arguments
 366      `(#:tests? #f)) ; No 'test' target
 367     (build-system cmake-build-system)
 368     (native-inputs
 369      `(("pkg-config" ,pkg-config)))
 370     (inputs
 371      `(("libzip" ,libzip)
 372        ("libxml2" ,libxml2)))
 373     (home-page "http://ebook-tools.sourceforge.net")
 374     (synopsis "Tools and library for dealing with various ebook file formats")
 375     (description "This package provides command-line tools and a library for
 376 accessing and converting various ebook file formats.")
 377     (license license:expat)))
 378
 379 (define-public liblinebreak
 380   (package
 381     (name "liblinebreak")
 382     (version "2.1")
 383     (source (origin
 384               (method url-fetch)
 385               (uri (string-append "mirror://sourceforge/vimgadgets"
 386                                   "/liblinebreak/" version
 387                                   "/liblinebreak-" version ".tar.gz"))
 388               (sha256
 389                (base32
 390                 "1f36dbq7nc77lln1by2n1yl050g9dc63viawhs3gc3169mavm36x"))))
 391     (build-system gnu-build-system)
 392     (home-page "http://vimgadgets.sourceforge.net/liblinebreak/")
 393     (synopsis "Library for detecting where linebreaks are allowed in text")
 394     (description "@code{liblinebreak} is an implementation of the line
 395 breaking algorithm as described in Unicode 6.0.0 Standard Annex 14,
 396 Revision 26.  It breaks lines that contain Unicode characters.  It is
 397 designed to be used in a generic text renderer.")
 398     (license license:zlib)))
 399
 400 (define-public fbreader
 401   (package
 402     (name "fbreader")
 403     (version "0.99.6")
 404     (source (origin
 405               (method git-fetch)
 406               (uri (git-reference
 407                      (url "https://github.com/geometer/FBReader")
 408                      (commit (string-append version "-freebsdport"))))
 409               (file-name (git-file-name name version))
 410               (sha256
 411                (base32
 412                 "0c0s4silpax74kwfz3dfmzn4lkv6jsyb800vfak166vii0hvbv3d"))
 413               (patches (search-patches "fbreader-curl-7.62.patch"))))
 414     (build-system gnu-build-system)
 415     (inputs
 416      `(("curl" ,curl)
 417        ("expat" ,expat)
 418        ("fribidi" ,fribidi)
 419        ("glib" ,glib)
 420        ("gtk+-2" ,gtk+-2)
 421        ("libjpeg" ,libjpeg-turbo)
 422        ("liblinebreak" ,liblinebreak)
 423        ("libxft" ,libxft)
 424        ("sqlite" ,sqlite)
 425        ("zlib" ,zlib)))
 426     (native-inputs
 427      `(("gcc@5" ,gcc-5)
 428        ("pkg-config" ,pkg-config)))
 429     (arguments
 430      `(#:tests? #f ; No tests exist.
 431        #:make-flags `("CC=gcc" "TARGET_ARCH=desktop" "UI_TYPE=gtk"
 432                       "TARGET_STATUS=release"
 433                       ,(string-append "INSTALLDIR="
 434                                       (assoc-ref %outputs "out"))
 435                       ,(string-append "LDFLAGS=-Wl,-rpath="
 436                                       (assoc-ref %outputs "out") "/lib"))
 437        #:phases
 438        (modify-phases %standard-phases
 439          (add-after 'set-paths 'augment-CPLUS_INCLUDE_PATH
 440            (lambda* (#:key inputs #:allow-other-keys)
 441              ;; Hide the default GCC from CPLUS_INCLUDE_PATH to prevent a header
 442              ;; conflict with the GCC provided in native-inputs.
 443              (let ((gcc (assoc-ref inputs "gcc")))
 444                (setenv "CPLUS_INCLUDE_PATH"
 445                        (string-join
 446                         (delete (string-append gcc "/include/c++")
 447                                 (string-split (getenv "CPLUS_INCLUDE_PATH")
 448                                               #\:))
 449                         ":"))
 450                #t)))
 451          (delete 'configure)
 452          (add-after 'unpack 'fix-install-locations
 453            (lambda* (#:key outputs #:allow-other-keys)
 454              (let ((out (assoc-ref outputs "out")))
 455                (substitute* "fbreader/desktop/Makefile"
 456                  (("/usr") out))
 457                #t))))))
 458     (home-page "https://fbreader.org/")
 459     (synopsis "E-Book reader")
 460     (description "@code{fbreader} is an E-Book reader.  It supports the
 461 following formats:
 462
 463 @enumerate
 464 @item CHM
 465 @item Docbook
 466 @item FB2
 467 @item HTML
 468 @item OEB
 469 @item PDB
 470 @item RTF
 471 @item TCR
 472 @item TXT
 473 @item XHTML
 474 @end enumerate")
 475     (license license:gpl2+)))
 476
 477 (define-public cozy
 478   (package
 479     (name "cozy")
 480     (version "1.1.2")
 481     (source
 482      (origin
 483        (method git-fetch)
 484        (uri (git-reference
 485              (url "https://github.com/geigi/cozy")
 486              (commit version)))
 487        (file-name (git-file-name name version))
 488        (sha256
 489         (base32 "0hifzzhhf0ww6iar9gswjfndy3i54s6jc41zaazlx4scc7r6fhs0"))))
 490     (build-system meson-build-system)
 491     (arguments
 492      `(#:glib-or-gtk? #t
 493        #:phases
 494        (modify-phases %standard-phases
 495          (add-after 'unpack 'patch-desktop-file
 496            (lambda _
 497              (substitute* "data/com.github.geigi.cozy.desktop"
 498                (("Exec=com.github.geigi.cozy") "Exec=cozy"))))
 499          (add-after 'install 'patch-executable-name
 500            (lambda* (#:key outputs #:allow-other-keys)
 501              (with-directory-excursion
 502                  (string-append (assoc-ref outputs "out") "/bin")
 503                (rename-file "com.github.geigi.cozy" "cozy"))))
 504          (add-after 'wrap 'wrap-libs
 505            (lambda* (#:key outputs #:allow-other-keys)
 506              (let* ((out               (assoc-ref outputs "out"))
 507                     (pylib             (string-append
 508                                         out "/lib/python"
 509                                         ,(version-major+minor
 510                                           (package-version python))
 511                                         "/site-packages"))
 512                     (gi-typelib-path   (getenv "GI_TYPELIB_PATH"))
 513                     (gst-plugin-path   (getenv "GST_PLUGIN_SYSTEM_PATH"))
 514                     (libmagic-path     (string-append
 515                                         (assoc-ref %build-inputs "file")
 516                                         "/lib"))
 517                     (python-path     (getenv "PYTHONPATH")))
 518                (wrap-program (string-append out "/bin/cozy")
 519                  `("LD_LIBRARY_PATH" ":" prefix (,libmagic-path))
 520                  `("GI_TYPELIB_PATH" ":" prefix (,gi-typelib-path))
 521                  `("GST_PLUGIN_SYSTEM_PATH" ":" prefix (,gst-plugin-path))
 522                  `("PYTHONPATH" ":" prefix (,python-path ,pylib)))))))))
 523     (native-inputs
 524      `(("desktop-file-utils" ,desktop-file-utils)
 525        ("gettext" ,gettext-minimal)
 526        ("glib:bin" ,glib "bin")
 527        ("gobject-introspection" ,gobject-introspection)
 528        ("gtk+:bin" ,gtk+ "bin")
 529        ("pkg-config" ,pkg-config)
 530        ("python" ,python-wrapper)))
 531     (inputs
 532      `(("file" ,file)
 533        ("granite" ,granite)
 534        ("gsettings-desktop-schemas" ,gsettings-desktop-schemas)
 535        ("gst-libav" ,gst-libav)
 536        ("gst-plugins-bad" ,gst-plugins-bad)
 537        ("gst-plugins-good" ,gst-plugins-good)
 538        ("gst-plugins-ugly" ,gst-plugins-ugly)
 539        ("gtk+" ,gtk+)
 540        ("libdazzle" ,libdazzle)
 541        ("libgee" ,libgee)
 542        ("libhandy" ,libhandy)
 543        ("python-distro" ,python-distro)
 544        ("python-gst" ,python-gst)
 545        ("python-mutagen" ,python-mutagen)
 546        ("python-packaging" ,python-packaging)
 547        ("python-peewee" ,python-peewee)
 548        ("python-pycairo" ,python-pycairo)
 549        ("python-pygobject" ,python-pygobject)
 550        ("python-pytz" ,python-pytz)
 551        ("python-requests" ,python-requests)))
 552     (home-page "https://cozy.geigi.de/")
 553     (synopsis "Modern audiobook player using GTK+")
 554     (description
 555      "Cozy is a modern audiobook player written in GTK+.
 556
 557 Some of the current features:
 558
 559 @itemize
 560 @item Import your audiobooks into Cozy to browse them comfortably
 561 @item Sort your audio books by author, reader & name
 562 @item Remembers your playback position
 563 @item Sleep timer
 564 @item Playback speed control
 565 @item Search your library
 566 @item Offline mode
 567 @item Add multiple storage locations
 568 @item Drag & Drop to import new audio books
 569 @item Support for DRM free mp3, m4a (aac, ALAC, …), flac, ogg, opus, wav files
 570 @item Mpris integration (Media keys & playback info for desktop environment)
 571 @end itemize")
 572     ;; TODO: Unbundle python-inject.
 573     (license (list license:gpl3+ ;cozy
 574                    license:asl2.0)))) ;python-inject (bundled dependency)
 575
 576 (define-public xchm
 577   (package
 578     (name "xchm")
 579     (version "1.32")
 580     (source (origin
 581               (method url-fetch)
 582               (uri (string-append "https://github.com/rzvncj/xCHM"
 583                                   "/releases/download/"
 584                                   version "/xchm-" version ".tar.gz"))
 585               (sha256
 586                (base32
 587                 "0b12ym7cn65wy268kbksyhakicwb053c8xfn76q2dawrvbras9dj"))))
 588     (build-system gnu-build-system)
 589     (inputs
 590      `(("wxwidgets" ,wxwidgets)
 591        ("chmlib" ,chmlib)))
 592     (native-inputs
 593      `(("pkg-config" ,pkg-config)))
 594     (home-page "https://github.com/rzvncj/xCHM")
 595     (synopsis "CHM file viewer")
 596     (description "xCHM is a graphical CHM file viewer.  It is a frontend to
 597 the CHM library CHMLIB.")
 598     (license license:gpl2+)))
 599
 600 (define-public libmobi
 601   (package
 602     (name "libmobi")
 603     (version "0.6")
 604     (source (origin
 605               (method git-fetch)
 606               (uri (git-reference
 607                     (url "https://github.com/bfabiszewski/libmobi/")
 608                     (commit (string-append "v" version))))
 609               (file-name (git-file-name name version))
 610               (sha256
 611                (base32
 612                 "0yps72cm609xn2k7alflkdhp9kgr1w7zzyxjygz0n1kqrdcplihh"))))
 613     (build-system gnu-build-system)
 614     (native-inputs
 615      `(("autoconf" ,autoconf)
 616        ("automake" ,automake)
 617        ("libtool" ,libtool)))
 618     (inputs
 619      `(("zlib" ,zlib)
 620        ("libxml2" ,libxml2)))
 621     (home-page "https://github.com/bfabiszewski/libmobi/")
 622     (synopsis "C library for handling MOBI formats")
 623     (description "Libmobi is a C library for handling MOBI ebook
 624 format documents, with the following features:
 625
 626 @itemize
 627 @item reading and parsing:
 628 @itemize
 629 @item some older text Palmdoc formats (pdb),
 630 @item Mobipocket files (prc, mobi),
 631 @item newer MOBI files including KF8 format (azw, azw3),
 632 @item Replica Print files (azw4)
 633 @end itemize
 634 @item recreating source files using indices
 635 @item reconstructing references (links and embedded) in html files
 636 @item reconstructing source structure that can be fed back to kindlegen
 637 @item reconstructing dictionary markup (orth, infl tags)
 638 @item writing back loaded documents
 639 @item metadata editing
 640 @item handling encrypted documents
 641 @end itemize\n")
 642     (license license:lgpl3+)))