gnu: tor: Update to 0.4.5.9 [security fixes].
[jackhill/guix/guix.git] / configure.ac
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
3
4 AC_PREREQ([2.69])
5 AC_INIT([GNU Guix],
6 [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
7 [bug-guix@gnu.org], [guix],
8 [https://www.gnu.org/software/guix/])
9 AC_CONFIG_AUX_DIR([build-aux])
10
11 AM_INIT_AUTOMAKE([1.14 gnu silent-rules subdir-objects \
12 color-tests parallel-tests -Woverride -Wno-portability])
13
14 # Enable silent rules by default.
15 AM_SILENT_RULES([yes])
16
17 AC_CONFIG_SRCDIR([guix.scm])
18 AC_CONFIG_MACRO_DIR([m4])
19
20 dnl For the C++ code. This must be used early.
21 AC_USE_SYSTEM_EXTENSIONS
22
23 AM_GNU_GETTEXT([external])
24 AM_GNU_GETTEXT_VERSION([0.19.1])
25
26 GUIX_SYSTEM_TYPE
27 GUIX_ASSERT_SUPPORTED_SYSTEM
28 GUIX_CHANNEL_METADATA
29
30 AM_CONDITIONAL([CROSS_COMPILING], [test "x$cross_compiling" = "xyes"])
31
32 AC_ARG_WITH(store-dir,
33 AS_HELP_STRING([--with-store-dir=PATH],
34 [file name of the store (defaults to /gnu/store)]),
35 [storedir="$withval"],
36 [storedir="/gnu/store"])
37 AC_SUBST(storedir)
38
39 AC_ARG_WITH([bash-completion-dir],
40 AS_HELP_STRING([--with-bash-completion-dir=DIR],
41 [name of the Bash completion directory]),
42 [bashcompletiondir="$withval"],
43 [bashcompletiondir='${sysconfdir}/bash_completion.d'])
44 AC_SUBST([bashcompletiondir])
45
46 AC_ARG_WITH([zsh-completion-dir],
47 AS_HELP_STRING([--with-zsh-completion-dir=DIR],
48 [name of the Zsh completion directory]),
49 [zshcompletiondir="$withval"],
50 [zshcompletiondir='${datadir}/zsh/site-functions'])
51 AC_SUBST([zshcompletiondir])
52
53 AC_ARG_WITH([fish-completion-dir],
54 AS_HELP_STRING([--with-fish-completion-dir=DIR],
55 [name of the Fish completion directory]),
56 [fishcompletiondir="$withval"],
57 [fishcompletiondir='${datadir}/fish/vendor_completions.d'])
58 AC_SUBST([fishcompletiondir])
59
60 AC_ARG_WITH([selinux-policy-dir],
61 AS_HELP_STRING([--with-selinux-policy-dir=DIR],
62 [name of the SELinux policy directory]),
63 [selinux_policydir="$withval"],
64 [selinux_policydir='${datadir}/selinux/'])
65 AC_SUBST([selinux_policydir])
66
67 dnl Better be verbose.
68 AC_MSG_CHECKING([for the store directory])
69 AC_MSG_RESULT([$storedir])
70
71 AC_ARG_ENABLE([daemon],
72 [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
73 [guix_build_daemon="$enableval"],
74 [guix_build_daemon="yes"])
75
76 # Prepare a version of $localstatedir & co. that does not contain references
77 # to shell variables.
78 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
79 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
80 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
81 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
82 AC_SUBST([guix_localstatedir])
83 AC_SUBST([guix_sysconfdir])
84 AC_SUBST([guix_sbindir])
85
86 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
87 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
88
89 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
90 dnl Make sure they are available.
91 m4_pattern_forbid([PKG_CHECK_MODULES])
92 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
93 m4_pattern_forbid([^GUILE_P])
94 m4_pattern_allow([^GUILE_PKG_ERRORS])
95 m4_pattern_forbid([^GUIX_])
96
97 dnl Search for 'guile' and 'guild'. This macro defines
98 dnl 'GUILE_EFFECTIVE_VERSION'.
99 GUILE_PKG([3.0])
100 GUILE_PROGS
101 if test "x$GUILD" = "x"; then
102 AC_MSG_ERROR(['guild' binary not found; please check your Guile installation.])
103 fi
104
105 dnl Get CFLAGS and LDFLAGS for libguile.
106 GUILE_FLAGS
107
108 dnl Installation directories for .scm and .go files.
109 guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
110 guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
111 AC_SUBST([guilemoduledir])
112 AC_SUBST([guileobjectdir])
113
114 dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
115 dnl pull', among other things.
116 GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
117 if test "x$have_gnutls" != "xyes"; then
118 AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
119 fi
120
121 dnl Check for Guile-Git.
122 GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
123 if test "x$have_guile_git" != "xyes"; then
124 AC_MSG_ERROR([Guile-Git is missing; please install it.])
125 fi
126
127 dnl Check for Guile-JSON.
128 GUIX_CHECK_GUILE_JSON
129 if test "x$guix_cv_have_recent_guile_json" != "xyes"; then
130 AC_MSG_ERROR([Guile-JSON is missing; please install it.])
131 fi
132
133 dnl Guile-Sqlite3 is used by the (guix store ...) modules.
134 GUIX_CHECK_GUILE_SQLITE3
135 if test "x$guix_cv_have_recent_guile_sqlite3" != "xyes"; then
136 AC_MSG_ERROR([A recent Guile-SQLite3 could not be found; please install it.])
137 fi
138
139 GUIX_CHECK_GUILE_GCRYPT
140 if test "x$guix_cv_have_recent_guile_gcrypt" != "xyes"; then
141 AC_MSG_ERROR([A recent Guile-Gcrypt could not be found; please install it.])
142 fi
143
144 GUIX_CHECK_GUILE_GIT
145 if test "x$guix_cv_have_recent_guile_git" != "xyes"; then
146 AC_MSG_ERROR([A recent Guile-Git could not be found; please install it.])
147 fi
148
149 dnl Check for the optional Guile-Lib.
150 GUILE_MODULE_EXPORTS([have_guile_lib], [(htmlprag)], [%strict-tokenizer?])
151 AM_CONDITIONAL([HAVE_GUILE_LIB], [test "x$have_guile_lib" = "xyes"])
152 AM_COND_IF(HAVE_GUILE_LIB,,
153 [AC_MSG_WARN([The Guile-Lib requirement was not satisfied (>= 0.2.7);
154 Some features such as the Go importer will not be usable.])])
155
156 dnl Check for Guile-zlib.
157 GUIX_CHECK_GUILE_ZLIB
158 if test "x$guix_cv_have_recent_guile_zlib" != "xyes"; then
159 AC_MSG_ERROR([A recent Guile-zlib could not be found; please install it.])
160 fi
161
162 dnl Check for Guile-lzlib.
163 GUILE_MODULE_AVAILABLE([have_guile_lzlib], [(lzlib)])
164 if test "x$have_guile_lzlib" != "xyes"; then
165 AC_MSG_ERROR([Guile-lzlib is missing; please install it.])
166 fi
167
168 dnl Check for Guile-Avahi.
169 GUILE_MODULE_AVAILABLE([have_guile_avahi], [(avahi)])
170 AM_CONDITIONAL([HAVE_GUILE_AVAHI],
171 [test "x$have_guile_avahi" = "xyes"])
172
173 dnl Guile-newt is used by the graphical installer.
174 GUILE_MODULE_AVAILABLE([have_guile_newt], [(newt)])
175
176 AC_ARG_ENABLE([installer],
177 AS_HELP_STRING([--enable-installer], [Build the graphical installer sources.]))
178
179 AS_IF([test "x$enable_installer" = "xyes"], [
180 if test "x$have_guile_newt" != "xyes"; then
181 AC_MSG_ERROR([Guile-newt could not be found; please install it.])
182 fi
183 ])
184
185 AM_CONDITIONAL([ENABLE_INSTALLER],
186 [test "x$enable_installer" = "xyes"])
187
188 dnl Make sure we have a full-fledged Guile.
189 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
190
191 AC_PROG_SED
192
193 dnl Decompressors, for use by the substituter and other modules.
194 AC_PATH_PROG([GZIP], [gzip])
195 AC_PATH_PROG([BZIP2], [bzip2])
196 AC_PATH_PROG([XZ], [xz])
197 AC_SUBST([GZIP])
198 AC_SUBST([BZIP2])
199 AC_SUBST([XZ])
200
201 LIBGCRYPT_LIBDIR="no"
202 LIBGCRYPT_PREFIX="no"
203
204 AC_ARG_WITH([libgcrypt-prefix],
205 [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
206 [case "$withval" in
207 yes|no)
208 ;;
209 *)
210 LIBGCRYPT_PREFIX="$withval"
211 LIBGCRYPT_LIBDIR="$withval/lib"
212 ;;
213 esac])
214
215 AC_ARG_WITH([libgcrypt-libdir],
216 [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
217 [search for GNU libgcrypt's shared library in DIR])],
218 [case "$withval" in
219 yes|no)
220 LIBGCRYPT_LIBDIR="no"
221 ;;
222 *)
223 LIBGCRYPT_LIBDIR="$withval"
224 ;;
225 esac])
226
227 dnl If none of the --with-libgcrypt-* options was used, try to determine the
228 dnl the library directory.
229 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
230 xnono)
231 GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
232 ;;
233 esac
234
235 AC_SUBST([LIBGCRYPT_PREFIX])
236 AC_SUBST([LIBGCRYPT_LIBDIR])
237
238 dnl Check for Guile-SSH, for the (guix ssh) module.
239 GUIX_CHECK_GUILE_SSH
240 AM_CONDITIONAL([HAVE_GUILE_SSH],
241 [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
242
243 AC_CACHE_SAVE
244
245 m4_include([config-daemon.ac])
246
247 dnl `dot' (from the Graphviz package) is only needed for maintainers.
248 dnl See `Building from Git' in the manual for more info.
249 AM_MISSING_PROG([DOT], [dot])
250
251 dnl Manual pages.
252 AM_MISSING_PROG([HELP2MAN], [help2man])
253
254 dnl Documentation translation.
255 AM_MISSING_PROG([PO4A_TRANSLATE], [po4a-translate])
256 AM_MISSING_PROG([PO4A_UPDATEPO], [po4a-updatepo])
257
258 case "$storedir" in
259 /gnu/store)
260 ;;
261 *)
262 AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
263 AC_MSG_WARN([from downloading substitutes from gnu.org.])
264 ;;
265 esac
266
267 AC_CONFIG_FILES([Makefile
268 po/guix/Makefile.in
269 po/packages/Makefile.in
270 etc/guix-daemon.cil
271 guix/config.scm])
272
273 AC_CONFIG_FILES([etc/committer.scm], [chmod +x etc/committer.scm])
274 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
275 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
276 [chmod +x pre-inst-env])
277
278 AC_OUTPUT