gnu/packages/gcc.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2012, 2013, 2014, 2015 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2014, 2015 Mark H Weaver <mhw@netris.org>
   4 ;;; Copyright © 2014 Ricardo Wurmus <rekado@elephly.net>
   5 ;;; Copyright © 2015 Andreas Enge <andreas@enge.fr>
   6 ;;;
   7 ;;; This file is part of GNU Guix.
   8 ;;;
   9 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  10 ;;; under the terms of the GNU General Public License as published by
  11 ;;; the Free Software Foundation; either version 3 of the License, or (at
  12 ;;; your option) any later version.
  13 ;;;
  14 ;;; GNU Guix is distributed in the hope that it will be useful, but
  15 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;;; GNU General Public License for more details.
  18 ;;;
  19 ;;; You should have received a copy of the GNU General Public License
  20 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 (define-module (gnu packages gcc)
  23   #:use-module ((guix licenses)
  24                 #:select (gpl3+ gpl2+ lgpl2.1+ lgpl2.0+ fdl1.3+))
  25   #:use-module (gnu packages)
  26   #:use-module (gnu packages bootstrap)
  27   #:use-module (gnu packages compression)
  28   #:use-module (gnu packages multiprecision)
  29   #:use-module (gnu packages texinfo)
  30   #:use-module (gnu packages doxygen)
  31   #:use-module (gnu packages xml)
  32   #:use-module (gnu packages docbook)
  33   #:use-module (gnu packages graphviz)
  34   #:use-module (gnu packages elf)
  35   #:use-module (gnu packages perl)
  36   #:use-module (guix packages)
  37   #:use-module (guix download)
  38   #:use-module (guix build-system gnu)
  39   #:use-module (guix build-system trivial)
  40   #:use-module (guix utils)
  41   #:use-module (ice-9 regex))
  42
  43 (define %gcc-infrastructure
  44   ;; Base URL for GCC's infrastructure.
  45   "ftp://gcc.gnu.org/pub/gcc/infrastructure/")
  46
  47 (define (gcc-configure-flags-for-triplet target)
  48   "Return a list of additional GCC `configure' flags for TARGET, a GNU triplet.
  49
  50 The purpose of this procedure is to translate extended GNU triplets---e.g.,
  51 where the OS part is overloaded to denote a specific ABI---into GCC
  52 `configure' options.  We take extended GNU triplets that glibc recognizes."
  53   (cond ((string-match "^mips64el.*gnuabin?64$" target)
  54          ;; Triplets recognized by glibc as denoting the N64 ABI; see
  55          ;; ports/sysdeps/mips/preconfigure.
  56          '("--with-abi=64"))
  57
  58         ((string-match "^arm.*-gnueabihf$" target)
  59          '("--with-arch=armv7-a"
  60            "--with-float=hard"
  61            "--with-mode=thumb"
  62            "--with-fpu=neon"))
  63
  64         (else
  65          ;; TODO: Add `arm.*-gnueabi', etc.
  66          '())))
  67
  68 (define-public gcc-4.7
  69   (let* ((stripped? #t)      ;whether to strip the compiler, not the libraries
  70          (maybe-target-tools
  71           (lambda ()
  72             ;; Return the `_FOR_TARGET' variables that are needed when
  73             ;; cross-compiling GCC.
  74             (let ((target (%current-target-system)))
  75               (if target
  76                   (map (lambda (var tool)
  77                          (string-append (string-append var "_FOR_TARGET")
  78                                         "=" target "-" tool))
  79                        '("CC"  "CXX" "LD" "AR" "NM" "RANLIB" "STRIP")
  80                        '("gcc" "g++" "ld" "ar" "nm" "ranlib" "strip"))
  81                   '()))))
  82          (libdir
  83           (let ((base '(or (assoc-ref outputs "lib")
  84                            (assoc-ref outputs "out"))))
  85             (lambda ()
  86               ;; Return the directory that contains lib/libgcc_s.so et al.
  87               (if (%current-target-system)
  88                   `(string-append ,base "/" ,(%current-target-system))
  89                   base))))
  90          (configure-flags
  91           (lambda ()
  92             ;; This is terrible.  Since we have two levels of quasiquotation,
  93             ;; we have to do this convoluted thing just so we can insert the
  94             ;; contents of (maybe-target-tools).
  95             (list 'quasiquote
  96                   (append
  97                    '("--enable-plugin"
  98                      "--enable-languages=c,c++"
  99                      "--disable-multilib"
 100
 101                      ;; No pre-compiled libstdc++ headers, to save space.
 102                      "--disable-libstdcxx-pch"
 103
 104                      "--with-local-prefix=/no-gcc-local-prefix"
 105
 106                      ;; With a separate "lib" output, the build system
 107                      ;; incorrectly guesses GPLUSPLUS_INCLUDE_DIR, so force
 108                      ;; it.  (Don't use a versioned sub-directory, that's
 109                      ;; unnecessary.)
 110                      ,(string-append "--with-gxx-include-dir="
 111                                      (assoc-ref %outputs "out")
 112                                      "/include/c++")
 113
 114                      ,(let ((libc (assoc-ref %build-inputs "libc")))
 115                         (if libc
 116                             (string-append "--with-native-system-header-dir=" libc
 117                                            "/include")
 118                             "--without-headers")))
 119
 120                    ;; Pass the right options for the target triplet.
 121                    (let ((triplet
 122                           (or (%current-target-system)
 123                               (nix-system->gnu-triplet (%current-system)))))
 124                      (gcc-configure-flags-for-triplet triplet))
 125
 126                    (maybe-target-tools))))))
 127     (package
 128       (name "gcc")
 129       (version "4.7.4")
 130       (source (origin
 131                (method url-fetch)
 132                (uri (string-append "mirror://gnu/gcc/gcc-"
 133                                    version "/gcc-" version ".tar.bz2"))
 134                (sha256
 135                 (base32
 136                  "10k2k71kxgay283ylbbhhs51cl55zn2q38vj5pk4k950qdnirrlj"))))
 137       (build-system gnu-build-system)
 138
 139       ;; Separate out the run-time support libraries because all the
 140       ;; dynamic-linked objects depend on it.
 141       (outputs '("out"                    ;commands, etc. (60+ MiB)
 142                  "lib"                    ;libgcc_s, libgomp, etc. (15+ MiB)
 143                  "debug"))                ;debug symbols of run-time libraries
 144
 145       (inputs `(("gmp" ,gmp)
 146                 ("mpfr" ,mpfr)
 147                 ("mpc" ,mpc)
 148                 ("isl" ,isl)
 149                 ("cloog" ,cloog)
 150                 ("libelf" ,libelf)
 151                 ("zlib" ,zlib)))
 152
 153       ;; GCC is one of the few packages that doesn't ship .info files.
 154       (native-inputs `(("texinfo" ,texinfo)))
 155
 156       (arguments
 157        `(#:out-of-source? #t
 158          #:configure-flags ,(configure-flags)
 159          #:make-flags
 160          ;; None of the flags below are needed when doing a Canadian cross.
 161          ;; TODO: Simplify this.
 162          ,(if (%current-target-system)
 163               (if stripped?
 164                   ''("CFLAGS=-g0 -O2")
 165                   ''())
 166               `(let* ((libc        (assoc-ref %build-inputs "libc"))
 167                       (libc-native (or (assoc-ref %build-inputs "libc-native")
 168                                        libc)))
 169                  `(,@(if libc
 170                          (list (string-append "LDFLAGS_FOR_TARGET="
 171                                               "-B" libc "/lib "
 172                                               "-Wl,-dynamic-linker "
 173                                               "-Wl," libc
 174                                               ,(glibc-dynamic-linker)))
 175                          '())
 176
 177                    ;; Native programs like 'genhooks' also need that right.
 178                    ,(string-append "LDFLAGS="
 179                                    "-Wl,-rpath=" libc-native "/lib "
 180                                    "-Wl,-dynamic-linker "
 181                                    "-Wl," libc-native ,(glibc-dynamic-linker))
 182                    ,(string-append "BOOT_CFLAGS=-O2 "
 183                                    ,(if stripped? "-g0" "-g")))))
 184
 185          #:tests? #f
 186
 187          #:phases
 188          (alist-cons-before
 189           'configure 'pre-configure
 190           (lambda* (#:key inputs outputs #:allow-other-keys)
 191             (let ((libdir ,(libdir))
 192                   (libc   (assoc-ref inputs "libc")))
 193               (when libc
 194                 ;; The following is not performed for `--without-headers'
 195                 ;; cross-compiler builds.
 196
 197                 ;; Join multi-line definitions of GLIBC_DYNAMIC_LINKER* into a
 198                 ;; single line, to allow the next step to work properly.
 199                 (for-each
 200                  (lambda (x)
 201                    (substitute* (find-files "gcc/config"
 202                                             "^linux(64|-elf|-eabi)?\\.h$")
 203                      (("(#define GLIBC_DYNAMIC_LINKER.*)\\\\\n$" _ line)
 204                       line)))
 205                  '(1 2 3))
 206
 207                 ;; Fix the dynamic linker's file name.
 208                 (substitute* (find-files "gcc/config"
 209                                          "^linux(64|-elf|-eabi)?\\.h$")
 210                   (("#define GLIBC_DYNAMIC_LINKER([^ ]*).*$" _ suffix)
 211                    (format #f "#define GLIBC_DYNAMIC_LINKER~a \"~a\"~%"
 212                            suffix
 213                            (string-append libc ,(glibc-dynamic-linker)))))
 214
 215                 ;; Tell where to find libstdc++, libc, and `?crt*.o', except
 216                 ;; `crt{begin,end}.o', which come with GCC.
 217                 (substitute* (find-files "gcc/config"
 218                                          "^gnu-user.*\\.h$")
 219                   (("#define GNU_USER_TARGET_LIB_SPEC (.*)$" _ suffix)
 220                    ;; Help libgcc_s.so be found (see also below.)  Always use
 221                    ;; '-lgcc_s' so that libgcc_s.so is always found by those
 222                    ;; programs that use 'pthread_cancel' (glibc dlopens
 223                    ;; libgcc_s.so when pthread_cancel support is needed, but
 224                    ;; having it in the application's RUNPATH isn't enough; see
 225                    ;; <http://sourceware.org/ml/libc-help/2013-11/msg00023.html>.)
 226                    ;;
 227                    ;; NOTE: The '-lgcc_s' added below needs to be removed in a
 228                    ;; later phase of %gcc-static.  If you change the string
 229                    ;; below, make sure to update the relevant code in
 230                    ;; %gcc-static package as needed.
 231                    (format #f "#define GNU_USER_TARGET_LIB_SPEC \
 232 \"-L~a/lib %{!static:-rpath=~a/lib %{!static-libgcc:-rpath=~a/lib -lgcc_s}} \" ~a"
 233                            libc libc libdir suffix))
 234                   (("#define GNU_USER_TARGET_STARTFILE_SPEC.*$" line)
 235                    (format #f "#define STANDARD_STARTFILE_PREFIX_1 \"~a/lib\"
 236 #define STANDARD_STARTFILE_PREFIX_2 \"\"
 237 ~a"
 238                            libc line))))
 239
 240               ;; Don't retain a dependency on the build-time sed.
 241               (substitute* "fixincludes/fixincl.x"
 242                 (("static char const sed_cmd_z\\[\\] =.*;")
 243                  "static char const sed_cmd_z[] = \"sed\";"))
 244
 245               (when (file-exists? "libbacktrace")
 246                 ;; GCC 4.8+ comes with libbacktrace.  By default it builds
 247                 ;; with -Werror, which fails with a -Wcast-qual error in glibc
 248                 ;; 2.21's stdlib-bsearch.h.  Remove -Werror.
 249                 (substitute* "libbacktrace/configure"
 250                   (("WARN_FLAGS=(.*)-Werror" _ flags)
 251                    (string-append "WARN_FLAGS=" flags)))
 252
 253                 (when (file-exists? "libsanitizer/libbacktrace")
 254                   ;; Same in libsanitizer's bundled copy (!) found in 4.9+.
 255                   (substitute* "libsanitizer/libbacktrace/Makefile.in"
 256                     (("-Werror")
 257                      ""))))
 258
 259               ;; Add a RUNPATH to libstdc++.so so that it finds libgcc_s.
 260               ;; See <https://gcc.gnu.org/bugzilla/show_bug.cgi?id=32354>
 261               ;; and <http://bugs.gnu.org/20358>.
 262               (substitute* "libstdc++-v3/src/Makefile.in"
 263                 (("^OPT_LDFLAGS = ")
 264                  "OPT_LDFLAGS = -Wl,-rpath=$(libdir) "))
 265
 266               ;; Move libstdc++*-gdb.py to the "lib" output to avoid a
 267               ;; circularity between "out" and "lib".  (Note:
 268               ;; --with-python-dir is useless because it imposes $(prefix) as
 269               ;; the parent directory.)
 270               (substitute* "libstdc++-v3/python/Makefile.in"
 271                 (("pythondir = .*$")
 272                  (string-append "pythondir = " libdir "/share"
 273                                 "/gcc-$(gcc_version)/python\n")))
 274
 275               ;; Avoid another circularity between the outputs: this #define
 276               ;; ends up in auto-host.h in the "lib" output, referring to
 277               ;; "out".  (This variable is used to augment cpp's search path,
 278               ;; but there's nothing useful to look for here.)
 279               (substitute* "gcc/config.in"
 280                 (("PREFIX_INCLUDE_DIR")
 281                  "PREFIX_INCLUDE_DIR_isnt_necessary_here"))))
 282
 283           (alist-cons-after
 284            'configure 'post-configure
 285            (lambda _
 286              ;; Don't store configure flags, to avoid retaining references to
 287              ;; build-time dependencies---e.g., `--with-ppl=/gnu/store/xxx'.
 288              (substitute* "Makefile"
 289                (("^TOPLEVEL_CONFIGURE_ARGUMENTS=(.*)$" _ rest)
 290                 "TOPLEVEL_CONFIGURE_ARGUMENTS=\n")))
 291            %standard-phases))))
 292
 293       (native-search-paths
 294        (list (search-path-specification
 295               (variable "CPATH")
 296               (files '("include")))
 297              (search-path-specification
 298               (variable "LIBRARY_PATH")
 299               (files '("lib" "lib64")))))
 300
 301       (properties `((gcc-libc . ,(assoc-ref inputs "libc"))))
 302       (synopsis "GNU Compiler Collection")
 303       (description
 304        "GCC is the GNU Compiler Collection.  It provides compiler front-ends
 305 for several languages, including C, C++, Objective-C, Fortran, Java, Ada, and
 306 Go.  It also includes runtime support libraries for these languages.")
 307       (license gpl3+)
 308       (home-page "http://gcc.gnu.org/"))))
 309
 310 (define-public gcc-4.8
 311   (package (inherit gcc-4.7)
 312     (version "4.8.5")
 313     (source (origin
 314               (method url-fetch)
 315               (uri (string-append "mirror://gnu/gcc/gcc-"
 316                                   version "/gcc-" version ".tar.bz2"))
 317               (sha256
 318                (base32
 319                 "08yggr18v373a1ihj0rg2vd6psnic42b518xcgp3r9k81xz1xyr2"))
 320               (patches (list (search-patch "gcc-arm-link-spec-fix.patch")))))))
 321
 322 (define-public gcc-4.9
 323   (package (inherit gcc-4.8)
 324     (version "4.9.3")
 325     (source (origin
 326               (method url-fetch)
 327               (uri (string-append "mirror://gnu/gcc/gcc-"
 328                                   version "/gcc-" version ".tar.bz2"))
 329               (sha256
 330                (base32
 331                 "0zmnm00d2a1hsd41g34bhvxzvxisa2l584q3p447bd91lfjv4ci3"))
 332               (patches (list (search-patch "gcc-libvtv-runpath.patch")))))))
 333
 334 (define-public gcc-5.1
 335   (package (inherit gcc-4.9)
 336     (version "5.1.0")
 337     (source (origin
 338               (method url-fetch)
 339               (uri (string-append "mirror://gnu/gcc/gcc-"
 340                                   version "/gcc-" version ".tar.bz2"))
 341               (sha256
 342                (base32
 343                 "1bd5vj4px3s8nlakbgrh38ynxq4s654m6nxz7lrj03mvkkwgvnmp"))
 344               (patches (map search-patch
 345                             '("gcc-arm-link-spec-fix.patch"
 346                               "gcc-5.0-libvtv-runpath.patch")))))))
 347
 348 (define-public gcc gcc-4.9)
 349
 350 (define-public (make-libstdc++ gcc)
 351   "Return a libstdc++ package based on GCC.  The primary use case is when
 352 using compilers other than GCC."
 353   (package
 354     (inherit gcc)
 355     (name "libstdc++")
 356     (arguments
 357      `(#:out-of-source? #t
 358        #:phases (alist-cons-before
 359                  'configure 'chdir
 360                  (lambda _
 361                    (chdir "libstdc++-v3"))
 362                  %standard-phases)
 363        #:configure-flags `("--disable-libstdcxx-pch"
 364                            ,(string-append "--with-gxx-include-dir="
 365                                            (assoc-ref %outputs "out")
 366                                            "/include"))))
 367     (outputs '("out" "debug"))
 368     (inputs '())
 369     (native-inputs '())
 370     (propagated-inputs '())
 371     (synopsis "GNU C++ standard library")))
 372
 373 (define-public libstdc++-4.9
 374   (make-libstdc++ gcc-4.9))
 375
 376 (define (make-libiberty gcc)
 377   "Return a libiberty package based on GCC."
 378   (package
 379     (inherit gcc)
 380     (name "libiberty")
 381     (arguments
 382      `(#:out-of-source? #t
 383        #:phases
 384        (modify-phases %standard-phases
 385          (add-before 'configure 'chdir
 386                      (lambda _
 387                        (chdir "libiberty")
 388                        #t))
 389          (replace
 390           'install
 391           (lambda* (#:key outputs #:allow-other-keys)
 392             (let* ((out     (assoc-ref outputs "out"))
 393                    (lib     (string-append out "/lib/"))
 394                    (include (string-append out "/include/")))
 395               (mkdir-p lib)
 396               (mkdir-p include)
 397               (copy-file "libiberty.a"
 398                          (string-append lib "libiberty.a"))
 399               (copy-file "../include/libiberty.h"
 400                          (string-append include "libiberty.h"))
 401               #t))))))
 402     (inputs '())
 403     (outputs '("out"))
 404     (native-inputs '())
 405     (propagated-inputs '())
 406     (synopsis "Collection of subroutines used by various GNU programs")))
 407
 408 (define-public libiberty
 409   (make-libiberty gcc))
 410
 411 (define* (custom-gcc gcc name languages #:key (separate-lib-output? #t))
 412   "Return a custom version of GCC that supports LANGUAGES."
 413   (package (inherit gcc)
 414     (name name)
 415     (outputs (if separate-lib-output?
 416                  (package-outputs gcc)
 417                  (delete "lib" (package-outputs gcc))))
 418     (arguments
 419      (substitute-keyword-arguments `(#:modules ((guix build gnu-build-system)
 420                                                 (guix build utils)
 421                                                 (ice-9 regex)
 422                                                 (srfi srfi-1)
 423                                                 (srfi srfi-26))
 424                                                ,@(package-arguments gcc))
 425        ((#:configure-flags flags)
 426         `(cons (string-append "--enable-languages="
 427                               ,(string-join languages ","))
 428                (remove (cut string-match "--enable-languages.*" <>)
 429                        ,flags)))))))
 430
 431 (define-public gfortran-4.8
 432   (custom-gcc gcc-4.8 "gfortran" '("fortran")))
 433
 434 (define-public gfortran-4.9
 435   (custom-gcc gcc-4.9 "gfortran" '("fortran")))
 436
 437 (define-public gfortran
 438   (custom-gcc gcc "gfortran" '("fortran")))
 439
 440 (define-public gccgo-4.8
 441   (custom-gcc gcc-4.8 "gccgo" '("go")
 442               ;; Suppress the separate "lib" output, because otherwise the
 443               ;; "lib" and "out" outputs would refer to each other, creating
 444               ;; a cyclic dependency.  <http://debbugs.gnu.org/18101>
 445               #:separate-lib-output? #f))
 446
 447 (define javac.in
 448   (origin
 449     (method url-fetch)
 450     (uri (string-append "http://sources.gentoo.org/cgi-bin/viewvc.cgi/"
 451                         "gentoo-x86/dev-java/gcj-jdk/files/javac.in?revision=1.1"))
 452     (file-name "javac.in")
 453     (sha256 (base32
 454               "1c3dk4z5yfj6ic2fn3lyxs27n6pmn2wy9k0r1s17lnkf1bzkrciv"))))
 455
 456 (define-public gcj-4.8
 457   (package (inherit gcc-4.8)
 458     (name "gcj")
 459     (inputs
 460      `(("fastjar" ,fastjar)
 461        ("perl" ,perl)
 462        ("javac.in" ,javac.in)
 463        ("ecj-bootstrap" ,ecj-bootstrap-4.8)
 464        ,@(package-inputs gcc-4.8)))
 465     ;; Suppress the separate "lib" output, because otherwise the
 466     ;; "lib" and "out" outputs would refer to each other, creating
 467     ;; a cyclic dependency.  <http://debbugs.gnu.org/18101>
 468     (outputs
 469      (delete "lib" (package-outputs gcc-4.8)))
 470     (arguments
 471      (substitute-keyword-arguments `(#:modules ((guix build gnu-build-system)
 472                                                 (guix build utils)
 473                                                 (ice-9 regex)
 474                                                 (srfi srfi-1)
 475                                                 (srfi srfi-26))
 476                                                ,@(package-arguments gcc-4.8))
 477        ((#:configure-flags flags)
 478         `(let ((ecj (assoc-ref %build-inputs "ecj-bootstrap")))
 479            `("--enable-java-home"
 480              "--enable-gjdoc"
 481              ,(string-append "--with-ecj-jar=" ecj)
 482              "--enable-languages=java"
 483              ,@(remove (cut string-match "--enable-languages.*" <>)
 484                        ,flags))))
 485        ((#:phases phases)
 486         `(modify-phases ,phases
 487            (add-after
 488             'unpack 'add-lib-output-to-rpath
 489             (lambda _
 490               (substitute* "libjava/Makefile.in"
 491                 (("libgcj_bc_dummy_LINK = .* -shared" line)
 492                  (string-append line " -Wl,-rpath=$(libdir)"))
 493                 (("libgcj(_bc)?_la_LDFLAGS =" ldflags _)
 494                  (string-append ldflags " -Wl,-rpath=$(libdir)")))))
 495            (add-after
 496             'install 'install-javac-and-javap-wrappers
 497             (lambda _
 498               (let* ((javac  (assoc-ref %build-inputs "javac.in"))
 499                      (ecj    (assoc-ref %build-inputs "ecj-bootstrap"))
 500                      (gcj    (assoc-ref %outputs "out"))
 501                      (gcjbin (string-append gcj "/bin/"))
 502                      (jvm    (string-append gcj "/lib/jvm/"))
 503                      (target (string-append jvm "/bin/javac")))
 504
 505                 (symlink (string-append gcjbin "jcf-dump")
 506                          (string-append jvm "/bin/javap"))
 507
 508                 (copy-file ecj (string-append gcj "/share/java/ecj.jar"))
 509
 510                 ;; Create javac wrapper from the template javac.in by
 511                 ;; replacing the @VARIABLES@ with paths.
 512                 (copy-file javac target)
 513                 (patch-shebang target)
 514                 (substitute* target
 515                   (("@JAVA@")
 516                    (string-append jvm "/bin/java"))
 517                   (("@ECJ_JAR@")
 518                    (string-append gcj "/share/java/ecj.jar"))
 519                   (("@RT_JAR@")
 520                    (string-append jvm "/jre/lib/rt.jar"))
 521                   (("@TOOLS_JAR@")
 522                    (string-append jvm "/lib/tools.jar")))
 523                 (chmod target #o755)
 524                 #t)))
 525            (add-after
 526             'install 'remove-broken-or-conflicting-files
 527             (lambda _
 528               (let ((out (assoc-ref %outputs "out")))
 529                 (for-each
 530                  delete-file
 531                  (append (find-files (string-append out "/lib/jvm/jre/lib")
 532                                      "libjawt.so")
 533                          (find-files (string-append out "/bin")
 534                                      ".*(c\\+\\+|cpp|g\\+\\+|gcc.*)"))))
 535               #t))))))))
 536
 537 (define ecj-bootstrap-4.8
 538   (origin
 539     (method url-fetch)
 540     (uri "ftp://sourceware.org/pub/java/ecj-4.8.jar")
 541     (sha256
 542      (base32
 543       "10fpqfbdzff1zcbxzh66xc8xbij9saykcj4xzm19wk9p3n7i5zcq"))))
 544
 545 (define-public gcc-objc-4.8
 546   (custom-gcc gcc-4.8 "gcc-objc" '("objc")))
 547
 548 (define-public gcc-objc++-4.8
 549   (custom-gcc gcc-4.8 "gcc-objc++" '("obj-c++")))
 550
 551 (define (make-libstdc++-doc gcc)
 552   "Return a package with the libstdc++ documentation for GCC."
 553   (package
 554     (inherit gcc)
 555     (name "libstdc++-doc")
 556     (version (package-version gcc))
 557     (synopsis "GNU libstdc++ documentation")
 558     (outputs '("out"))
 559     (native-inputs `(("doxygen" ,doxygen)
 560                      ("texinfo" ,texinfo)
 561                      ("libxml2" ,libxml2)
 562                      ("libxslt" ,libxslt)
 563                      ("docbook-xml" ,docbook-xml)
 564                      ("docbook-xsl" ,docbook-xsl)
 565                      ("graphviz" ,graphviz))) ;for 'dot', invoked by 'doxygen'
 566     (inputs '())
 567     (propagated-inputs '())
 568     (arguments
 569      '(#:out-of-source? #t
 570        #:tests? #f                                ;it's just documentation
 571        #:phases (modify-phases %standard-phases
 572                   (add-before 'configure 'chdir
 573                               (lambda _
 574                                 (chdir "libstdc++-v3")))
 575                   (add-before 'configure 'set-xsl-directory
 576                               (lambda* (#:key inputs #:allow-other-keys)
 577                                 (let ((docbook (assoc-ref inputs "docbook-xsl")))
 578                                   (substitute* (find-files "doc"
 579                                                            "^Makefile\\.in$")
 580                                     (("@XSL_STYLE_DIR@")
 581                                      (string-append
 582                                       docbook "/xml/xsl/"
 583                                       (string-drop
 584                                        docbook
 585                                        (+ 34
 586                                           (string-length
 587                                            (%store-directory))))))))))
 588                   (replace 'build
 589                            (lambda _
 590                              ;; XXX: There's also a 'doc-info' target, but it
 591                              ;; relies on docbook2X, which itself relies on
 592                              ;; DocBook 4.1.2, which is not really usable
 593                              ;; (lacks a catalog.xml.)
 594                              (zero? (system* "make"
 595                                              "doc-html"
 596                                              "doc-man"))))
 597                   (replace 'install
 598                            (lambda* (#:key outputs #:allow-other-keys)
 599                              (let ((out (assoc-ref outputs "out")))
 600                                (zero? (system* "make"
 601                                                "doc-install-html"
 602                                                "doc-install-man"))))))))))
 603
 604 (define-public libstdc++-doc-4.9
 605   (make-libstdc++-doc gcc-4.9))
 606
 607 (define-public libstdc++-doc-5.1
 608   (make-libstdc++-doc gcc-5.1))
 609
 610 (define-public isl
 611   (package
 612     (name "isl")
 613     (version "0.11.1")
 614     (source (origin
 615              (method url-fetch)
 616              (uri (list (string-append
 617                          "http://isl.gforge.inria.fr/isl-"
 618                          version
 619                          ".tar.bz2")
 620                         (string-append %gcc-infrastructure
 621                                        name "-" version ".tar.gz")))
 622              (sha256
 623               (base32
 624                "13d9cqa5rzhbjq0xf0b2dyxag7pqa72xj9dhsa03m8ccr1a4npq9"))))
 625     (build-system gnu-build-system)
 626     (inputs `(("gmp" ,gmp)))
 627     (home-page "http://isl.gforge.inria.fr/")
 628     (synopsis
 629      "Manipulating sets and relations of integer points \
 630 bounded by linear constraints")
 631     (description
 632      "isl is a library for manipulating sets and relations of integer points
 633 bounded by linear constraints.  Supported operations on sets include
 634 intersection, union, set difference, emptiness check, convex hull, (integer)
 635 affine hull, integer projection, computing the lexicographic minimum using
 636 parametric integer programming, coalescing and parametric vertex
 637 enumeration.  It also includes an ILP solver based on generalized basis
 638 reduction, transitive closures on maps (which may encode infinite graphs),
 639 dependence analysis and bounds on piecewise step-polynomials.")
 640     (license lgpl2.1+)))
 641
 642 (define-public cloog
 643   (package
 644     (name "cloog")
 645     (version "0.18.0")
 646     (source
 647      (origin
 648       (method url-fetch)
 649       (uri (list (string-append
 650                   "http://www.bastoul.net/cloog/pages/download/count.php3?url=cloog-"
 651                   version
 652                   ".tar.gz")
 653                  (string-append %gcc-infrastructure
 654                                 name "-" version ".tar.gz")))
 655       (sha256
 656        (base32
 657         "0a12rwfwp22zd0nlld0xyql11cj390rrq1prw35yjsw8wzfshjhw"))
 658       (file-name (string-append name "-" version ".tar.gz"))))
 659     (build-system gnu-build-system)
 660     (inputs `(("gmp" ,gmp)
 661               ("isl" ,isl)))
 662     (arguments '(#:configure-flags '("--with-isl=system")))
 663     (home-page "http://www.cloog.org/")
 664     (synopsis "Library to generate code for scanning Z-polyhedra")
 665     (description
 666      "CLooG is a free software library to generate code for scanning
 667 Z-polyhedra.  That is, it finds a code (e.g., in C, FORTRAN...) that
 668 reaches each integral point of one or more parameterized polyhedra.
 669 CLooG has been originally written to solve the code generation problem
 670 for optimizing compilers based on the polytope model.  Nevertheless it
 671 is used now in various area e.g., to build control automata for
 672 high-level synthesis or to find the best polynomial approximation of a
 673 function.  CLooG may help in any situation where scanning polyhedra
 674 matters.  While the user has full control on generated code quality,
 675 CLooG is designed to avoid control overhead and to produce a very
 676 effective code.")
 677     (license gpl2+)))
 678
 679 (define-public gnu-c-manual
 680   (package
 681     (name "gnu-c-manual")
 682     (version "0.2.4")
 683     (source (origin
 684               (method url-fetch)
 685               (uri (string-append "mirror://gnu/gnu-c-manual/gnu-c-manual-"
 686                                   version ".tar.gz"))
 687               (sha256
 688                (base32
 689                 "0cf4503shr7hxkbrjfi9dky6q2lqk95bgbgbjmvj2s2x312kakd9"))))
 690     (build-system gnu-build-system)
 691     (native-inputs `(("texinfo" ,texinfo)))
 692     (arguments
 693      '(#:phases (modify-phases %standard-phases
 694                   (delete 'configure)
 695                   (delete 'check)
 696                   (replace 'build
 697                            (lambda _
 698                              (zero? (system* "make"
 699                                              "gnu-c-manual.info"
 700                                              "gnu-c-manual.html"))))
 701                   (replace 'install
 702                            (lambda* (#:key outputs #:allow-other-keys)
 703                              (let* ((out (assoc-ref outputs "out"))
 704                                     (info (string-append out "/share/info"))
 705                                     (html (string-append
 706                                            out "/share/doc/gnu-c-manual")))
 707                                (mkdir-p info)
 708                                (mkdir-p html)
 709
 710                                (for-each (lambda (file)
 711                                            (copy-file file
 712                                                       (string-append info "/"
 713                                                                      file)))
 714                                          (find-files "." "\\.info(-[0-9])?$"))
 715                                (for-each (lambda (file)
 716                                            (copy-file file
 717                                                       (string-append html "/"
 718                                                                      file)))
 719                                          (find-files "." "\\.html$"))
 720                                #t))))))
 721     (synopsis "Reference manual for the C programming language")
 722     (description
 723      "This is a reference manual for the C programming language, as
 724 implemented by the GNU C Compiler (gcc).  As a reference, it is not intended
 725 to be a tutorial of the language.  Rather, it outlines all of the constructs
 726 of the language.  Library functions are not included.")
 727     (home-page "http://www.gnu.org/software/gnu-c-manual")
 728     (license fdl1.3+)))