gnu/services/ci.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2018, 2019, 2020, 2021 Christopher Baines <mail@cbaines.net>
   3 ;;; Copyright © 2021 Arun Isaac <arunisaac@systemreboot.net>
   4 ;;;
   5 ;;; This file is part of GNU Guix.
   6 ;;;
   7 ;;; GNU Guix is free software; you can redistribute it and/or modify
   8 ;;; it under the terms of the GNU General Public License as published by
   9 ;;; the Free Software Foundation, either version 3 of the License, or
  10 ;;; (at your option) any later version.
  11 ;;;
  12 ;;; GNU Guix is distributed in the hope that it will be useful,
  13 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;;; GNU General Public License for more details.
  16 ;;;
  17 ;;; You should have received a copy of the GNU General Public License
  18 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (define-module (gnu services ci)
  21   #:use-module (guix gexp)
  22   #:use-module (guix records)
  23   #:use-module (gnu packages admin)
  24   #:use-module (gnu packages ci)
  25   #:use-module (gnu services)
  26   #:use-module (gnu services base)
  27   #:use-module (gnu services shepherd)
  28   #:use-module (gnu services admin)
  29   #:use-module (gnu system shadow)
  30   #:use-module (ice-9 match)
  31   #:export (laminar-configuration
  32             laminar-configuration?
  33             laminar-configuration-home-directory
  34             laminar-configuration-bind-http
  35             laminar-configuration-bind-rpc
  36             laminar-configuration-title
  37             laminar-configuration-keep-rundirs
  38             laminar-configuration-archive-url
  39             laminar-configuration-base-url
  40
  41             laminar-service-type))
  42
  43 ;;;; Commentary:
  44 ;;;
  45 ;;; This module implements a service that to run instances of Laminar, a
  46 ;;; continuous integration tool.
  47 ;;;
  48 ;;;; Code:
  49
  50 (define-record-type* <laminar-configuration>
  51   laminar-configuration make-laminar-configuration
  52   laminar-configuration?
  53   (laminar          laminars-configuration-laminar
  54                     (default laminar))
  55   (home-directory   laminar-configuration-home-directory
  56                     (default "/var/lib/laminar"))
  57   (bind-http        laminar-configuration-bind-http
  58                     (default "*:8080"))
  59   (bind-rpc         laminar-configuration-bind-rpc
  60                     (default "unix-abstract:laminar"))
  61   (title            laminar-configuration-title
  62                     (default "Laminar"))
  63   (keep-rundirs     laminar-keep-rundirs
  64                     (default 0))
  65   (archive-url      laminar-archive-url
  66                     (default #f))
  67   (base-url         laminar-base-url
  68                     (default #f)))
  69
  70 (define laminar-shepherd-service
  71   (match-lambda
  72     (($ <laminar-configuration> laminar home-directory
  73                                 bind-http bind-rpc
  74                                 title keep-rundirs archive-url
  75                                 base-url)
  76      (list (shepherd-service
  77             (documentation "Run Laminar.")
  78             (provision '(laminar))
  79             (requirement '(networking))
  80             (start #~(make-forkexec-constructor
  81                       (list #$(file-append laminar "/sbin/laminard"))
  82                       #:environment-variables
  83                       `(,(string-append "LAMINAR_HOME="
  84                                         #$home-directory)
  85                         ,(string-append "LAMINAR_BIND_HTTP="
  86                                         #$bind-http)
  87                         ,(string-append "LAMINAR_TITLE="
  88                                         #$title)
  89                         ,(string-append "LAMINAR_KEEP_RUNDIRS="
  90                                         #$(number->string
  91                                            keep-rundirs))
  92                         ,@(if #$archive-url
  93                               (list
  94                                (string-append "LAMINAR_ARCHIVE_URL="
  95                                               #$archive-url))
  96                               '())
  97                         ,@(if #$base-url
  98                               (list
  99                                (string-append "LAMINAR_BASE_URL="
 100                                               #$base-url))
 101                               '()))
 102                       #:user "laminar"
 103                       #:group "laminar"))
 104             (stop #~(make-kill-destructor)))))))
 105
 106 (define (laminar-account config)
 107   "Return the user accounts and user groups for CONFIG."
 108   (list (user-group
 109          (name "laminar")
 110          (system? #t))
 111         (user-account
 112          (name "laminar")
 113          (group "laminar")
 114          (system? #t)
 115          (comment "Laminar privilege separation user")
 116          (home-directory (laminar-configuration-home-directory config))
 117          (shell #~(string-append #$shadow "/sbin/nologin")))))
 118
 119 (define (laminar-activation config)
 120   (let ((bind-http (laminar-configuration-bind-http config)))
 121     #~(begin
 122         ;; If listen is a unix socket, create its parent directory.
 123         (when (string-prefix? "unix:" #$bind-http)
 124           (let ((run-directory
 125                  (dirname (substring #$bind-http (string-length "unix:"))))
 126                 (user (getpw "laminar")))
 127             (mkdir-p run-directory)
 128             (chown run-directory (passwd:uid user) (passwd:gid user)))))))
 129
 130 (define laminar-service-type
 131   (service-type
 132    (name 'laminar)
 133    (extensions
 134     (list
 135      (service-extension shepherd-root-service-type laminar-shepherd-service)
 136      (service-extension account-service-type laminar-account)
 137      (service-extension activation-service-type laminar-activation)))
 138    (default-value (laminar-configuration))
 139    (description
 140     "Run the Laminar continuous integration service.")))