guix/grafts.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2014, 2015, 2016, 2017, 2018, 2019, 2020 Ludovic Courtès <ludo@gnu.org>
   3 ;;;
   4 ;;; This file is part of GNU Guix.
   5 ;;;
   6 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or (at
   9 ;;; your option) any later version.
  10 ;;;
  11 ;;; GNU Guix is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (guix grafts)
  20   #:use-module (guix store)
  21   #:use-module (guix monads)
  22   #:use-module (guix records)
  23   #:use-module (guix derivations)
  24   #:use-module ((guix utils) #:select (%current-system))
  25   #:use-module (guix sets)
  26   #:use-module (srfi srfi-1)
  27   #:use-module (srfi srfi-9 gnu)
  28   #:use-module (srfi srfi-26)
  29   #:use-module (srfi srfi-34)
  30   #:use-module (ice-9 match)
  31   #:use-module (ice-9 vlist)
  32   #:export (graft?
  33             graft
  34             graft-origin
  35             graft-replacement
  36             graft-origin-output
  37             graft-replacement-output
  38
  39             graft-derivation
  40             graft-derivation/shallow
  41
  42             %graft?
  43             set-grafting
  44             grafting?))
  45
  46 (define-record-type* <graft> graft make-graft
  47   graft?
  48   (origin             graft-origin)               ;derivation | store item
  49   (origin-output      graft-origin-output         ;string | #f
  50                       (default "out"))
  51   (replacement        graft-replacement)          ;derivation | store item
  52   (replacement-output graft-replacement-output    ;string | #f
  53                       (default "out")))
  54
  55 (define (write-graft graft port)
  56   "Write a concise representation of GRAFT to PORT."
  57   (define (->string thing output)
  58     (if (derivation? thing)
  59         (derivation->output-path thing output)
  60         thing))
  61
  62   (match graft
  63     (($ <graft> origin origin-output replacement replacement-output)
  64      (format port "#<graft ~a ==> ~a ~a>"
  65              (->string origin origin-output)
  66              (->string replacement replacement-output)
  67              (number->string (object-address graft) 16)))))
  68
  69 (set-record-type-printer! <graft> write-graft)
  70
  71 (define (graft-origin-file-name graft)
  72   "Return the output file name of the origin of GRAFT."
  73   (match graft
  74     (($ <graft> (? derivation? origin) output)
  75      (derivation->output-path origin output))
  76     (($ <graft> (? string? item))
  77      item)))
  78
  79 (define* (graft-derivation/shallow store drv grafts
  80                                    #:key
  81                                    (name (derivation-name drv))
  82                                    (outputs (derivation-output-names drv))
  83                                    (guile (%guile-for-build))
  84                                    (system (%current-system)))
  85   "Return a derivation called NAME, which applies GRAFTS to the specified
  86 OUTPUTS of DRV.  This procedure performs \"shallow\" grafting in that GRAFTS
  87 are not recursively applied to dependencies of DRV."
  88   ;; XXX: Someday rewrite using gexps.
  89   (define mapping
  90     ;; List of store item pairs.
  91     (map (match-lambda
  92           (($ <graft> source source-output target target-output)
  93            (cons (if (derivation? source)
  94                      (derivation->output-path source source-output)
  95                      source)
  96                  (if (derivation? target)
  97                      (derivation->output-path target target-output)
  98                      target))))
  99          grafts))
 100
 101   (define output-pairs
 102     (map (lambda (output)
 103            (cons output
 104                  (derivation-output-path
 105                   (assoc-ref (derivation-outputs drv) output))))
 106          outputs))
 107
 108   (define build
 109     `(begin
 110        (use-modules (guix build graft)
 111                     (guix build utils)
 112                     (ice-9 match))
 113
 114        (let* ((old-outputs ',output-pairs)
 115               (mapping (append ',mapping
 116                                (map (match-lambda
 117                                       ((name . file)
 118                                        (cons (assoc-ref old-outputs name)
 119                                              file)))
 120                                     %outputs))))
 121          (graft old-outputs %outputs mapping))))
 122
 123   (define add-label
 124     (cut cons "x" <>))
 125
 126   (define properties
 127     `((type . graft)
 128       (graft (count . ,(length grafts)))))
 129
 130   (match grafts
 131     ((($ <graft> sources source-outputs targets target-outputs) ...)
 132      (let ((sources (zip sources source-outputs))
 133            (targets (zip targets target-outputs)))
 134        (build-expression->derivation store name build
 135                                      #:system system
 136                                      #:guile-for-build guile
 137                                      #:modules '((guix build graft)
 138                                                  (guix build utils)
 139                                                  (guix build debug-link)
 140                                                  (guix elf))
 141                                      #:inputs `(,@(map (lambda (out)
 142                                                          `("x" ,drv ,out))
 143                                                        outputs)
 144                                                 ,@(append (map add-label sources)
 145                                                           (map add-label targets)))
 146                                      #:outputs outputs
 147
 148                                      ;; Grafts are computationally cheap so no
 149                                      ;; need to offload or substitute.
 150                                      #:local-build? #t
 151                                      #:substitutable? #f
 152
 153                                      #:properties properties)))))
 154
 155 (define (non-self-references references drv outputs)
 156   "Return the list of references of the OUTPUTS of DRV, excluding self
 157 references.  Call REFERENCES to get the list of references."
 158   (let ((refs (append-map (compose references
 159                                    (cut derivation->output-path drv <>))
 160                           outputs))
 161         (self (match (derivation->output-paths drv)
 162                 (((names . items) ...)
 163                  items))))
 164     (remove (cut member <> self) refs)))
 165
 166 (define (references-oracle store input)
 167   "Return a one-argument procedure that, when passed the output file names of
 168 INPUT, a derivation input, or their dependencies, returns the list of
 169 references of that item.  Build INPUT if it's not available."
 170   (define (references* items)
 171     ;; Return the references of ITEMS.
 172     (guard (c ((store-protocol-error? c)
 173                ;; ITEMS are not in store so build INPUT first.
 174                (and (build-derivations store (list input))
 175                     (map (cut references/cached store <>) items))))
 176       (map (cut references/cached store <>) items)))
 177
 178   (let loop ((items (derivation-input-output-paths input))
 179              (result vlist-null))
 180     (match items
 181       (()
 182        (lambda (item)
 183          (match (vhash-assoc item result)
 184            ((_ . refs) refs)
 185            (#f         #f))))
 186       (_
 187        (let* ((refs   (references* items))
 188               (result (fold vhash-cons result items refs)))
 189          (loop (remove (cut vhash-assoc <> result)
 190                        (delete-duplicates (concatenate refs) string=?))
 191                result))))))
 192
 193 (define-syntax-rule (with-cache key exp ...)
 194   "Cache the value of monadic expression EXP under KEY."
 195   (mlet %state-monad ((cache (current-state)))
 196     (match (vhash-assoc key cache)
 197       ((_ . result)                               ;cache hit
 198        (return result))
 199       (#f                                         ;cache miss
 200        (mlet %state-monad ((result (begin exp ...))
 201                            (cache  (current-state)))
 202          (mbegin %state-monad
 203            (set-current-state (vhash-cons key result cache))
 204            (return result)))))))
 205
 206 (define (reference-origin drv item)
 207   "Return the derivation/output pair among the inputs of DRV, recursively,
 208 that produces ITEM.  Return #f if ITEM is not produced by a derivation (i.e.,
 209 it's a content-addressed \"source\"), or if it's not produced by a dependency
 210 of DRV."
 211   ;; Perform a breadth-first traversal of the dependency graph of DRV in
 212   ;; search of the derivation that produces ITEM.
 213   (let loop ((drv (list drv))
 214              (visited (setq)))
 215     (match drv
 216       (()
 217        #f)
 218       ((drv . rest)
 219        (if (set-contains? visited drv)
 220            (loop rest visited)
 221            (let ((inputs (derivation-inputs drv)))
 222              (or (any (lambda (input)
 223                         (let ((drv (derivation-input-derivation input)))
 224                           (any (match-lambda
 225                                  ((output . file)
 226                                   (and (string=? file item)
 227                                        (cons drv output))))
 228                                (derivation->output-paths drv))))
 229                       inputs)
 230                  (loop (append rest (map derivation-input-derivation inputs))
 231                        (set-insert drv visited)))))))))
 232
 233 (define* (cumulative-grafts store drv grafts
 234                             references
 235                             #:key
 236                             (outputs (derivation-output-names drv))
 237                             (guile (%guile-for-build))
 238                             (system (%current-system)))
 239   "Augment GRAFTS with additional grafts resulting from the application of
 240 GRAFTS to the dependencies of DRV; REFERENCES must be a one-argument procedure
 241 that returns the list of references of the store item it is given.  Return the
 242 resulting list of grafts.
 243
 244 This is a monadic procedure in %STATE-MONAD where the state is a vhash mapping
 245 derivations to the corresponding set of grafts."
 246   (define (graft-origin? drv graft)
 247     ;; Return true if DRV corresponds to the origin of GRAFT.
 248     (match graft
 249       (($ <graft> (? derivation? origin) output)
 250        (match (assoc-ref (derivation->output-paths drv) output)
 251          ((? string? result)
 252           (string=? result
 253                     (derivation->output-path origin output)))
 254          (_
 255           #f)))
 256       (_
 257        #f)))
 258
 259   (define (dependency-grafts item)
 260     (match (reference-origin drv item)
 261       ((drv . output)
 262        ;; If GRAFTS already contains a graft from DRV, do not override it.
 263        (if (find (cut graft-origin? drv <>) grafts)
 264            (state-return grafts)
 265            (cumulative-grafts store drv grafts references
 266                               #:outputs (list output)
 267                               #:guile guile
 268                               #:system system)))
 269       (#f
 270        (state-return grafts))))
 271
 272   (with-cache (cons (derivation-file-name drv) outputs)
 273     (match (non-self-references references drv outputs)
 274       (()                                         ;no dependencies
 275        (return grafts))
 276       (deps                                       ;one or more dependencies
 277        (mlet %state-monad ((grafts (mapm %state-monad dependency-grafts deps)))
 278          (let ((grafts (delete-duplicates (concatenate grafts) equal?)))
 279            (match (filter (lambda (graft)
 280                             (member (graft-origin-file-name graft) deps))
 281                           grafts)
 282              (()
 283               (return grafts))
 284              ((applicable ..1)
 285               ;; Use APPLICABLE, the subset of GRAFTS that is really
 286               ;; applicable to DRV, to avoid creating several identical
 287               ;; grafted variants of DRV.
 288               (let* ((new    (graft-derivation/shallow store drv applicable
 289                                                        #:outputs outputs
 290                                                        #:guile guile
 291                                                        #:system system))
 292                      (grafts (append (map (lambda (output)
 293                                             (graft
 294                                               (origin drv)
 295                                               (origin-output output)
 296                                               (replacement new)
 297                                               (replacement-output output)))
 298                                           outputs)
 299                                      grafts)))
 300                 (return grafts))))))))))
 301
 302 (define* (graft-derivation store drv grafts
 303                            #:key
 304                            (guile (%guile-for-build))
 305                            (outputs (derivation-output-names drv))
 306                            (system (%current-system)))
 307   "Apply GRAFTS to the OUTPUTS of DRV and all their dependencies, recursively.
 308 That is, if GRAFTS apply only indirectly to DRV, graft the dependencies of
 309 DRV, and graft DRV itself to refer to those grafted dependencies."
 310
 311   ;; First, pre-compute the dependency tree of the outputs of DRV.  Do this
 312   ;; upfront to have as much parallelism as possible when querying substitute
 313   ;; info or when building DRV.
 314   (define references
 315     (references-oracle store (derivation-input drv outputs)))
 316
 317   (match (run-with-state
 318              (cumulative-grafts store drv grafts references
 319                                 #:outputs outputs
 320                                 #:guile guile #:system system)
 321            vlist-null)                            ;the initial cache
 322     ((first . rest)
 323      ;; If FIRST is not a graft for DRV, it means that GRAFTS are not
 324      ;; applicable to DRV and nothing needs to be done.
 325      (if (equal? drv (graft-origin first))
 326          (graft-replacement first)
 327          drv))))
 328
 329 \f
 330 ;; The following might feel more at home in (guix packages) but since (guix
 331 ;; gexp), which is a lower level, needs them, we put them here.
 332
 333 (define %graft?
 334   ;; Whether to honor package grafts by default.
 335   (make-parameter #t))
 336
 337 (define (set-grafting enable?)
 338   "This monadic procedure enables grafting when ENABLE? is true, and disables
 339 it otherwise.  It returns the previous setting."
 340   (lambda (store)
 341     (values (%graft? enable?) store)))
 342
 343 (define (grafting?)
 344   "Return a Boolean indicating whether grafting is enabled."
 345   (lambda (store)
 346     (values (%graft?) store)))
 347
 348 ;; Local Variables:
 349 ;; eval: (put 'with-cache 'scheme-indent-function 1)
 350 ;; End:
 351
 352 ;;; grafts.scm ends here