box_frame/inc/functions.scad

   1 // PRUSA iteration3
   2 // Functions used in many files
   3 // GNU GPL v3
   4 // Josef Průša <josefprusa@me.com>
   5 // Václav 'ax' Hůla <axtheb@gmail.com>
   6 // Vlnofka <>
   7 // http://www.reprap.org/wiki/Prusa_Mendel
   8 // http://github.com/josefprusa/Prusa3
   9
  10
  11 module nut(d,h,horizontal=true){
  12     cornerdiameter =  (d / 2) / cos (180 / 6);
  13     cylinder(h = h, r = cornerdiameter, $fn = 6);
  14     if(horizontal){
  15         for(i = [1:6]){
  16             rotate([0,0,60*i]) translate([-cornerdiameter-0.2,0,0]) rotate([0,0,-45]) cube([2,2,h]);
  17         }
  18     }
  19 }
  20
  21 module fillet(radius, height=100, $fn=0) {
  22     //this creates acutal fillet
  23     translate([-radius, -radius, -height / 2 - 0.02]) difference() {
  24         cube([radius * 2, radius * 2, height + 0.04]);
  25         if ($fn == 0 && (radius == 2 || radius == 3 || radius == 4)) {
  26             cylinder(r=radius, h=height + 0.04, $fn=4 * radius);
  27         } else {
  28             cylinder(r=radius, h=height + 0.04, $fn=$fn);
  29         }
  30
  31     }
  32 }
  33
  34 module cube_fillet(size, radius=-1, vertical=[3,3,3,3], top=[0,0,0,0], bottom=[0,0,0,0], center=false, $fn=0){
  35     //
  36     if (use_fillets == 1) {
  37         if (center) {
  38             cube_fillet_inside(size, radius, vertical, top, bottom, $fn);
  39         } else {
  40             translate([size[0]/2, size[1]/2, size[2]/2])
  41                 cube_fillet_inside(size, radius, vertical, top, bottom, $fn);
  42         }
  43     } else {
  44         if (use_fillets == 2) {
  45             if (center) {
  46                 cube_fillet_inside(size, radius, vertical, top, bottom, 4);
  47             } else {
  48                 translate([size[0]/2, size[1]/2, size[2]/2])
  49                     cube_fillet_inside(size, radius, vertical, top, bottom, 4);
  50             }
  51
  52         } else {
  53             cube(size, center);
  54         }
  55     }
  56
  57 }
  58
  59 module cube_negative_fillet(size, radius=-1, vertical=[3,3,3,3], top=[0,0,0,0], bottom=[0,0,0,0], $fn=0){
  60
  61     j=[1,0,1,0];
  62
  63     for (i=[0:3]) {
  64         if (radius > -1) {
  65             rotate([0, 0, 90*i]) translate([size[1-j[i]]/2, size[j[i]]/2, 0]) fillet(radius, size[2], $fn=$fn);
  66         } else {
  67             rotate([0, 0, 90*i]) translate([size[1-j[i]]/2, size[j[i]]/2, 0]) fillet(vertical[i], size[2], $fn=$fn);
  68         }
  69         rotate([90*i, -90, 0]) translate([size[2]/2, size[j[i]]/2, 0 ]) fillet(top[i], size[1-j[i]], $fn=$fn);
  70         rotate([90*(4-i), 90, 0]) translate([size[2]/2, size[j[i]]/2, 0]) fillet(bottom[i], size[1-j[i]], $fn=$fn);
  71
  72     }
  73 }
  74
  75 module cube_fillet_inside(size, radius=-1, vertical=[3,3,3,3], top=[0,0,0,0], bottom=[0,0,0,0], $fn=0){
  76     //makes CENTERED cube with round corners
  77     // if you give it radius, it will fillet vertical corners.
  78     //othervise use vertical, top, bottom arrays
  79     //when viewed from top, it starts in upper right corner (+x,+y quadrant) , goes counterclockwise
  80     //top/bottom fillet starts in direction of Y axis and goes CCW too
  81
  82
  83     if (radius == 0) {
  84         cube(size, center=true);
  85     } else {
  86         difference() {
  87             cube(size, center=true);
  88             cube_negative_fillet(size, radius, vertical, top, bottom, $fn);
  89         }
  90     }
  91 }
  92
  93
  94 module nema17(places=[1,1,1,1], size=15.5, h=10, holes=false, shadow=false, $fn=24){
  95     for (i=[0:3]) {
  96         if (places[i] == 1) {
  97             rotate([0, 0, 90*i]) translate([size, size, 0]) {
  98                 if (holes) {
  99                     rotate([0, 0, -90*i])  translate([0,0,-10]) screw(r=1.7, slant=false, head_drop=13, $fn=$fn, h=h+12);
 100                 } else {
 101                     rotate([0, 0, -90*i]) cylinder(h=h, r=5.5, $fn=$fn);
 102                 }
 103             }
 104         }
 105     }
 106     if (shadow != false) {
 107         %translate ([0, 0, shadow+21+3]) cube([42,42,42], center = true);
 108     //flange
 109         %translate ([0, 0, shadow+21+3-21-1]) cylinder(r=11,h=2, center = true, $fn=20);
 110     //shaft
 111         %translate ([0, 0, shadow+21+3-21-7]) cylinder(r=2.5,h=14, center = true);
 112     }
 113 }
 114
 115 module screw(h=20, r=2, r_head=3.5, head_drop=0, slant=i_am_box, poly=false, $fn=0){
 116     //makes screw with head
 117     //for substraction as screw hole
 118     if (poly) {
 119         cylinder_poly(h=h, r=r, $fn=$fn);
 120     } else {
 121         cylinder(h=h, r=r, $fn=$fn);
 122     }
 123     if (slant) {
 124         translate([0, 0, head_drop-0.01]) cylinder(h=r_head, r2=0, r1=r_head, $fn=$fn);
 125     }
 126
 127     if (head_drop > 0) {
 128         translate([0, 0, -0.01]) cylinder(h=head_drop+0.01, r=r_head, $fn=$fn);
 129     }
 130 }
 131
 132 module plate_screw(long=0) {
 133     if (i_am_box == 0) {
 134         translate([0, 0, -long]) screw(head_drop=14 + long, h=30 + long, r_head=3.6, r=1.7, $fn=24, slant=false);
 135     } else {
 136         translate([0, 0, -2 - long]) screw(head_drop=14 + long, h=30 + long, r_head=4.5, r=2, $fn=24, slant=true);
 137     }
 138 }
 139
 140 //radius of the idler assembly (to surface that touches belt, ignoring guide walls)
 141 function idler_assy_r_inner(idler_bearing) = (idler_bearing[0] / 2) + (6 * single_wall_width + 0.2) * idler_bearing[3];
 142 //outer radius of the idler assembly (to smooth side of belt)
 143 function idler_assy_r_outer(idler_bearing) = idler_assy_r_inner(idler_bearing) + belt_thickness + 1;
 144
 145
 146 module idler_assy(idler_bearing = [22, 7, 8, 1]) {
 147
 148     //bearing axle
 149     translate([0,0,-1]) cylinder(h = 120, r=(idler_bearing[2] + 1) / 2, $fn=small_hole_segments, center=true);
 150     //bearing shadow
 151     %cylinder(h = idler_bearing[1], r=idler_bearing[0]/2, center=true);
 152     //belt shadow
 153     %cylinder(h = belt_width, r=idler_assy_r_outer(idler_bearing), center=true);
 154
 155     cylinder(h = idler_width + 1, r=idler_assy_r_outer(idler_bearing) + 0.5, center=true);
 156 }
 157
 158 module belt(len, side = 0){
 159     //belt. To be substracted from model
 160     //len is in +Z, smooth side in +X, Y centered
 161     translate([-0.5, 0, 0]) maketeeth(len);
 162     translate([0, -4.5, -0.01]) cube([belt_thickness, 9, len + 0.02]);
 163     if (side != 0) {
 164     translate([0, -4.5 + side, -0.01]) cube_fillet([belt_thickness, 9, len + 0.02], vertical = [3, 0, 0, 0]);
 165     }
 166 }
 167
 168
 169 module maketeeth(len){
 170     //Belt teeth.
 171     for (i = [0 : len / belt_tooth_distance]) {
 172         translate([0, 0, i * belt_tooth_distance]) cube([2, 9, belt_tooth_distance * belt_tooth_ratio], center = true);
 173     }
 174 }