src/printer.lisp

   1 (in-package "PARENSCRIPT")
   2
   3 (defvar *ps-print-pretty* t)
   4 (defvar *indent-num-spaces* 4)
   5 (defvar *js-string-delimiter* #\'
   6   "Specifies which character should be used for delimiting strings.
   7
   8 This variable is used when you want to embed the resulting JavaScript
   9 in an html attribute delimited by #\\\" as opposed to #\\', or
  10 vice-versa.")
  11
  12 (defvar *indent-level*)
  13 (defvar *print-accumulator*)
  14
  15 (defmethod parenscript-print (form)
  16   (let ((*indent-level* 0)
  17         (*print-accumulator* ()))
  18     (if (and (listp form) (eq 'js:block (car form))) ; ignore top-level block
  19         (loop for (statement . remaining) on (cdr form) do
  20              (ps-print statement) (psw ";") (when remaining (psw #\Newline)))
  21         (ps-print form))
  22     (nreverse *print-accumulator*)))
  23
  24 (defun psw (obj)
  25   (push (if (characterp obj) (string obj) obj) *print-accumulator*))
  26
  27 (defgeneric ps-print% (special-form-name special-form-args))
  28
  29 (defmacro defprinter (special-form content-args &body body)
  30   "Given a special-form name and a destructuring lambda-list for its
  31 arguments, defines a printer for that form using the given body."
  32   (let ((sf (gensym))
  33         (sf-args (gensym)))
  34     `(defmethod ps-print% ((,sf (eql ',special-form)) ,sf-args)
  35       (declare (ignorable ,sf))
  36       (destructuring-bind ,content-args
  37           ,sf-args
  38         ,@body))))
  39
  40 (defgeneric ps-print (compiled-form))
  41
  42 (defmethod ps-print ((form null))) ; don't print top-level nils (ex: result of defining macros, etc.)
  43
  44 (defmethod ps-print ((s symbol))
  45   (assert (keywordp s))
  46   (ps-print (string-downcase s)))
  47
  48 (defmethod ps-print ((compiled-form cons))
  49   (ps-print% (car compiled-form) (cdr compiled-form)))
  50
  51 (defun newline-and-indent ()
  52   (if *ps-print-pretty*
  53       (progn (psw #\Newline)
  54              (loop repeat (* *indent-level* *indent-num-spaces*) do (psw #\Space)))
  55       (psw #\Space)))
  56
  57 (defparameter *js-lisp-escaped-chars*
  58   '((#\' . #\')
  59     (#\\ . #\\)
  60     (#\b . #\Backspace)
  61     (#\f . #.(code-char 12))
  62     (#\n . #\Newline)
  63     (#\r . #\Return)
  64     (#\t . #\Tab)))
  65
  66 (defmethod ps-print ((string string))
  67   (flet ((lisp-special-char-to-js (lisp-char)
  68            (car (rassoc lisp-char *js-lisp-escaped-chars*))))
  69     (psw *js-string-delimiter*)
  70     (loop for char across string
  71           for code = (char-code char)
  72           for special = (lisp-special-char-to-js char)
  73           do (cond (special (psw #\\) (psw special))
  74                    ((or (<= code #x1f) (>= code #x80)) (psw (format nil "\\u~4,'0x" code)))
  75                    (t (psw char))))
  76     (psw *js-string-delimiter*)))
  77
  78 (defmethod ps-print ((number number))
  79   (psw (format nil (if (integerp number) "~S" "~F") number)))
  80
  81 ;;; expression and operator precedence rules
  82
  83 (defun expression-precedence (expr)
  84   (if (consp expr)
  85       (case (car expr)
  86         ((js:slot-value js:aref) (op-precedence (car expr)))
  87         (js:= (op-precedence 'js:=))
  88         (js:? (op-precedence 'js:?))
  89         (js:unary-operator (op-precedence (second expr)))
  90         (operator (op-precedence (second expr)))
  91         (otherwise -1))
  92       -1))
  93
  94 (defprinter js:literal (str)
  95   (psw str))
  96
  97 (defun print-comma-delimited-list (ps-forms)
  98   (loop for (form . remaining) on ps-forms do
  99         (ps-print form) (when remaining (psw ", "))))
 100
 101 (defprinter js:array (&rest initial-contents)
 102   (psw #\[) (print-comma-delimited-list initial-contents) (psw #\]))
 103
 104 (defprinter js:aref (array indices)
 105   (if (>= (expression-precedence array) (op-precedence 'js:aref))
 106       (parenthesize-print array)
 107       (ps-print array))
 108   (loop for idx in indices do
 109         (psw #\[) (ps-print idx) (psw #\])))
 110
 111 (defprinter js:variable (var)
 112   (psw (symbol-to-js-string var)))
 113
 114 ;;; arithmetic operators
 115 (defun parenthesize-print (ps-form)
 116   (psw #\() (ps-print ps-form) (psw #\)))
 117
 118 (defprinter js:operator (op &rest args)
 119   (loop for (arg . remaining) on args
 120         with precedence = (op-precedence op) do
 121         (if (>= (expression-precedence arg) precedence)
 122             (parenthesize-print arg)
 123             (ps-print arg))
 124         (when remaining (psw (format nil " ~(~A~) " op)))))
 125
 126 (defprinter js:unary-operator (op arg &key prefix space)
 127   (when prefix (psw (format nil "~(~a~)~:[~; ~]" op space)))
 128   (if (> (expression-precedence arg)
 129          (op-precedence (case op
 130                           (+ 'unary+)
 131                           (- 'unary-)
 132                           (t op))))
 133       (parenthesize-print arg)
 134       (ps-print arg))
 135   (unless prefix (psw (format nil "~(~a~)" op))))
 136
 137 (defprinter js:funcall (fun-designator &rest args)
 138   (funcall (if (member (car fun-designator) '(js:variable js:aref js:slot-value js:funcall))
 139                #'ps-print
 140                #'parenthesize-print)
 141            fun-designator)
 142   (psw #\() (print-comma-delimited-list args) (psw #\)))
 143
 144 (defprinter js:|,| (&rest expressions)
 145   (psw #\()
 146   (loop for (exp . remaining) on expressions do
 147        (ps-print exp) (when remaining (psw ", ")))
 148   (psw #\)))
 149
 150 (defprinter js:block (&rest statements)
 151   (psw #\{)
 152   (incf *indent-level*)
 153   (dolist (statement statements)
 154     (newline-and-indent) (ps-print statement) (psw #\;))
 155   (decf *indent-level*)
 156   (newline-and-indent)
 157   (psw #\}))
 158
 159 (defprinter js:lambda (args body)
 160   (print-fun-def nil args body))
 161
 162 (defprinter js:defun (name args body)
 163   (print-fun-def name args body))
 164
 165 (defun print-fun-def (name args body-block)
 166   (psw (format nil "function ~:[~;~A~](" name (symbol-to-js-string name)))
 167   (loop for (arg . remaining) on args do
 168         (psw (symbol-to-js-string arg)) (when remaining (psw ", ")))
 169   (psw ") ")
 170   (ps-print body-block))
 171
 172 (defprinter js:object (&rest slot-defs)
 173   (psw "{ ")
 174   (loop for ((slot-name . slot-value) . remaining) on slot-defs do
 175        (ps-print slot-name) (psw " : ") (ps-print slot-value)
 176        (when remaining (psw ", ")))
 177   (psw " }"))
 178
 179 (defprinter js:slot-value (obj slot)
 180   (if (or (> (expression-precedence obj) (op-precedence 'js:slot-value))
 181           (numberp obj)
 182           (and (listp obj) (member (car obj) '(js:lambda js:object))))
 183       (parenthesize-print obj)
 184       (ps-print obj))
 185   (if (and (symbolp slot) (not (keywordp slot)))
 186       (progn (psw #\.) (psw (symbol-to-js-string slot)))
 187       (progn (psw #\[) (ps-print slot) (psw #\]))))
 188
 189 (defprinter js:if (test consequent &rest clauses)
 190   (psw "if (") (ps-print test) (psw ") ")
 191   (ps-print consequent)
 192   (loop while clauses do
 193        (ecase (car clauses)
 194          (:else-if (psw " else if (") (ps-print (cadr clauses)) (psw ") ")
 195                    (ps-print (caddr clauses))
 196                    (setf clauses (cdddr clauses)))
 197          (:else (psw " else ")
 198                 (ps-print (cadr clauses))
 199                 (return)))))
 200
 201 (defprinter js:? (test then else)
 202   (if (>= (expression-precedence test) (op-precedence 'js:?))
 203       (parenthesize-print test)
 204       (ps-print test))
 205   (psw " ? ")
 206   (if (>= (expression-precedence then) (op-precedence 'js:?))
 207       (parenthesize-print then)
 208       (ps-print then))
 209   (psw " : ")
 210   (if (>= (expression-precedence else) (op-precedence 'js:?))
 211       (parenthesize-print else)
 212       (ps-print else)))
 213
 214 (defprinter js:= (lhs rhs)
 215   (ps-print lhs) (psw " = ") (ps-print rhs))
 216
 217 (defprinter js:var (var-name &rest var-value)
 218   (psw "var ")
 219   (psw (symbol-to-js-string var-name))
 220   (when var-value
 221     (psw " = ")
 222     (ps-print (car var-value))))
 223
 224 (defprinter js:break (&optional label)
 225   (psw "break")
 226   (when label
 227     (psw " ")
 228     (psw (symbol-to-js-string label))))
 229
 230 (defprinter js:continue (&optional label)
 231   (psw "continue")
 232   (when label
 233     (psw " ")
 234     (psw (symbol-to-js-string label))))
 235
 236 ;;; iteration
 237 (defprinter js:for (label vars tests steps body-block)
 238   (when label (psw (symbol-to-js-string label)) (psw ": ") (newline-and-indent))
 239   (psw "for (")
 240   (loop for ((var-name . var-init) . remaining) on vars
 241         for decl = "var " then "" do
 242         (psw decl) (psw (symbol-to-js-string var-name)) (psw " = ") (ps-print var-init) (when remaining (psw ", ")))
 243   (psw "; ")
 244   (loop for (test . remaining) on tests do
 245        (ps-print test) (when remaining (psw ", ")))
 246   (psw "; ")
 247   (loop for (step . remaining) on steps do
 248        (ps-print step) (when remaining (psw ", ")))
 249   (psw ") ")
 250   (ps-print body-block))
 251
 252 (defprinter js:for-in (var object body-block)
 253   (psw "for (var ") (ps-print var) (psw " in ")
 254   (if (> (expression-precedence object) (op-precedence 'in))
 255       (parenthesize-print object)
 256       (ps-print object))
 257   (psw ") ")
 258   (ps-print body-block))
 259
 260 (defprinter js:while (test body-block)
 261   (psw "while (") (ps-print test) (psw ") ")
 262   (ps-print body-block))
 263
 264 (defprinter js:with (expression body-block)
 265   (psw "with (") (ps-print expression) (psw ") ")
 266   (ps-print body-block))
 267
 268 (defprinter js:switch (test clauses)
 269   (flet ((print-body-statements (body-statements)
 270            (incf *indent-level*)
 271            (loop for statement in body-statements do
 272                  (progn (newline-and-indent)
 273                         (ps-print statement)
 274                         (psw #\;)))
 275            (decf *indent-level*)))
 276     (psw "switch (") (ps-print test) (psw ") {")
 277     (loop for (val . statements) in clauses
 278           do (progn (newline-and-indent)
 279                     (if (eq val 'default)
 280                         (progn (psw "default: ")
 281                                (print-body-statements statements))
 282                         (progn (psw "case ")
 283                                (ps-print val)
 284                                (psw #\:)
 285                                (print-body-statements statements)))))
 286     (newline-and-indent)
 287     (psw #\})))
 288
 289 (defprinter js:try (body-block &key catch finally)
 290   (psw "try ")
 291   (ps-print body-block)
 292   (when catch
 293     (psw " catch (") (psw (symbol-to-js-string (first catch))) (psw ") ")
 294     (ps-print (second catch)))
 295   (when finally
 296     (psw " finally ")
 297     (ps-print finally)))
 298
 299 ;;; regex
 300 (defprinter js:regex (regex)
 301   (flet ((first-slash-p (string)
 302            (and (> (length string) 0) (char= (char string 0) #\/))))
 303     (let ((slash (unless (first-slash-p regex) "/")))
 304       (psw (format nil (concatenate 'string slash "~A" slash) regex)))))
 305
 306 ;;; conditional compilation
 307 (defprinter js:cc-if (test &rest body)
 308   (psw "/*@if ")
 309   (ps-print test)
 310   (incf *indent-level*)
 311   (dolist (form body)
 312     (newline-and-indent) (ps-print form) (psw #\;))
 313   (decf *indent-level*)
 314   (newline-and-indent)
 315   (psw "@end @*/"))
 316
 317 (defprinter js:instanceof (value type)
 318   (psw #\()
 319   (if (> (expression-precedence value) (op-precedence 'js:instanceof))
 320       (parenthesize-print value)
 321       (ps-print value))
 322   (psw " instanceof ")
 323   (if (> (expression-precedence type) (op-precedence 'js:instanceof))
 324       (parenthesize-print type)
 325       (ps-print type))
 326   (psw #\)))
 327
 328 (defprinter js:escape (literal-js)
 329   ;; literal-js should be a form that evaluates to a string containing valid JavaScript
 330   (psw literal-js))
 331
 332 ;;; named statements
 333 (defprinter js:throw (x)
 334   (psw "throw ") (ps-print x))
 335
 336 (defprinter js:return (x)
 337   (psw "return ") (ps-print x))