src/printer.lisp

   1 (in-package :parenscript)
   2
   3 (defvar *ps-print-pretty* t)
   4 (defvar *indent-num-spaces* 4)
   5 (defvar *js-string-delimiter* #\'
   6   "Specifies which character should be used for delimiting strings.
   7
   8 This variable is used when you want to embed the resulting JavaScript
   9 in an html attribute delimited by #\\\" as opposed to #\\', or
  10 vice-versa.")
  11
  12 (defvar *indent-level*)
  13 (defvar *print-accumulator*)
  14
  15 (defmethod parenscript-print (form)
  16   (let ((*indent-level* 0)
  17         (*print-accumulator* ()))
  18     (if (and (listp form) (eql 'js-block (car form))) ; ignore top-level block
  19         (loop for (statement . remaining) on (third form) do
  20              (ps-print statement) (psw ";") (when remaining (psw #\Newline)))
  21         (ps-print form))
  22     (reduce (lambda (acc next-token)
  23               (if (and (stringp next-token)
  24                        (stringp (car (last acc))))
  25                   (append (butlast acc) (list (concatenate 'string (car (last acc)) next-token)))
  26                   (append acc (list next-token))))
  27             (cons () (reverse *print-accumulator*)))))
  28
  29 (defun psw (obj)
  30   (push (if (characterp obj) (string obj) obj) *print-accumulator*))
  31
  32 (defgeneric ps-print% (special-form-name special-form-args))
  33
  34 (defmacro defprinter (special-form content-args &body body)
  35   "Given a special-form name and a destructuring lambda-list for its
  36 arguments, defines a printer for that form using the given body."
  37   (let ((sf (gensym))
  38         (sf-args (gensym)))
  39     `(defmethod ps-print% ((,sf (eql ',special-form)) ,sf-args)
  40       (declare (ignorable ,sf))
  41       (destructuring-bind ,content-args
  42           ,sf-args
  43         ,@body))))
  44
  45 (defgeneric ps-print (compiled-form))
  46
  47 (defmethod ps-print ((form null))) ; don't print top-level nils (ex: result of defining macros, etc.)
  48
  49 (defmethod ps-print ((s symbol))
  50   (assert (keywordp s))
  51   (ps-print (js-translate-symbol s)))
  52
  53 (defmethod ps-print ((compiled-form cons))
  54   (ps-print% (car compiled-form) (cdr compiled-form)))
  55
  56 (defun newline-and-indent ()
  57   (if *ps-print-pretty*
  58       (when (and (stringp (car *print-accumulator*))
  59                  (not (char= #\Newline (char (car *print-accumulator*) (1- (length (car *print-accumulator*))))))
  60                  (psw #\Newline))
  61         (loop repeat (* *indent-level* *indent-num-spaces*) do (psw #\Space)))
  62       (psw #\Space)))
  63
  64 (defparameter *js-lisp-escaped-chars*
  65   '((#\' . #\')
  66     (#\\ . #\\)
  67     (#\b . #\Backspace)
  68     (#\f . #.(code-char 12))
  69     (#\n . #\Newline)
  70     (#\r . #\Return)
  71     (#\t . #\Tab)))
  72
  73 (defmethod ps-print ((string string))
  74   (flet ((lisp-special-char-to-js (lisp-char)
  75            (car (rassoc lisp-char *js-lisp-escaped-chars*))))
  76     (psw *js-string-delimiter*)
  77     (loop for char across string
  78           for code = (char-code char)
  79           for special = (lisp-special-char-to-js char)
  80           do (cond (special (psw #\\) (psw special))
  81                    ((or (<= code #x1f) (>= code #x80)) (psw (format nil "\\u~4,'0x" code)))
  82                    (t (psw char))))
  83     (psw *js-string-delimiter*)))
  84
  85 (defmethod ps-print ((number number))
  86   (psw (format nil (if (integerp number) "~S" "~F") number)))
  87
  88 ;;; expression and operator precedence rules
  89
  90 (defun expression-precedence (expr)
  91   (if (consp expr)
  92       (case (car expr)
  93         ((js-slot-value js-aref) (op-precedence (car expr)))
  94         (js-assign (op-precedence '=))
  95         (js:? (op-precedence 'js:?))
  96         (unary-operator (op-precedence (second expr)))
  97         (operator (op-precedence (second expr)))
  98         (otherwise 0))
  99       0))
 100
 101 (eval-when (:compile-toplevel :load-toplevel :execute)
 102   (defparameter *op-precedence-hash* (make-hash-table :test 'eq))
 103
 104   (let ((precedence 1))
 105     (dolist (ops '((new js-slot-value js-aref)
 106                    (postfix++ postfix--)
 107                    (delete void typeof ++ -- unary+ unary- ~ !)
 108                    (* / %)
 109                    (+ -)
 110                    (<< >> >>>)
 111                    (< > <= >= js-instance-of in)
 112                    (== != === !== eql)
 113                    (&)
 114                    (^)
 115                    (\|)
 116                    (\&\& and)
 117                    (\|\| or)
 118                    (js:?)
 119                    (= *= /= %= += -= <<= >>= >>>= \&\= ^= \|= js-assign)
 120                    (comma)))
 121       (dolist (op ops)
 122         (setf (gethash op *op-precedence-hash*) precedence))
 123       (incf precedence)))
 124
 125   (defun op-precedence (op)
 126     (gethash op *op-precedence-hash*)))
 127
 128 (defprinter js-literal (str)
 129   (psw str))
 130
 131 (defun print-comma-delimited-list (ps-forms)
 132   (loop for (form . remaining) on ps-forms do
 133         (ps-print form) (when remaining (psw ", "))))
 134
 135 (defprinter array-literal (&rest initial-contents)
 136   (psw #\[) (print-comma-delimited-list initial-contents) (psw #\]))
 137
 138 (defprinter js-aref (array indices)
 139   (if (>= (expression-precedence array) #.(op-precedence 'js-aref))
 140       (parenthesize-print array)
 141       (ps-print array))
 142   (loop for idx in indices do
 143         (psw #\[) (ps-print idx) (psw #\])))
 144
 145 (defprinter js-variable (var)
 146   (psw (js-translate-symbol var)))
 147
 148 ;;; arithmetic operators
 149 (defun parenthesize-print (ps-form)
 150   (psw #\() (ps-print ps-form) (psw #\)))
 151
 152 (defprinter operator (op args)
 153   (loop for (arg . remaining) on args
 154         with precedence = (op-precedence op) do
 155         (if (>= (expression-precedence arg) precedence)
 156             (parenthesize-print arg)
 157             (ps-print arg))
 158         (when remaining (psw (format nil " ~(~A~) " op)))))
 159
 160 (defprinter unary-operator (op arg &key prefix space)
 161   (when prefix (psw (format nil "~(~a~)~:[~; ~]" op space)))
 162   (if (> (expression-precedence arg)
 163          (op-precedence (case op
 164                           (+ 'unary+)
 165                           (- 'unary-)
 166                           (t op))))
 167       (parenthesize-print arg)
 168       (ps-print arg))
 169   (unless prefix (psw (format nil "~(~a~)" op))))
 170
 171 (defprinter js-funcall (fun-designator args)
 172   (funcall (if (member (car fun-designator) '(js-variable js-aref js-slot-value js-funcall))
 173                #'ps-print
 174                #'parenthesize-print)
 175            fun-designator)
 176   (psw #\() (print-comma-delimited-list args) (psw #\)))
 177
 178 (defprinter js-block (block-type statements)
 179   (case block-type
 180     (:statement
 181      (psw #\{)
 182      (incf *indent-level*)
 183      (dolist (statement statements)
 184        (newline-and-indent) (ps-print statement) (psw #\;))
 185      (decf *indent-level*)
 186      (newline-and-indent)
 187      (psw #\}))
 188     (:expression
 189      (psw #\()
 190      (loop for (statement . remaining) on statements do
 191            (ps-print statement) (when remaining (psw ", ")))
 192      (psw #\)))))
 193
 194 (defprinter js-lambda (args body)
 195   (print-fun-def nil args body))
 196
 197 (defprinter js-defun (name args body)
 198   (print-fun-def name args body))
 199
 200 (defun print-fun-def (name args body-block)
 201   (psw (format nil "function ~:[~;~A~](" name (js-translate-symbol name)))
 202   (loop for (arg . remaining) on args do
 203         (psw (js-translate-symbol arg)) (when remaining (psw ", ")))
 204   (psw ") ")
 205   (ps-print body-block))
 206
 207 (defprinter js-object (slot-defs)
 208   (psw "{ ")
 209   (loop for ((slot-name . slot-value) . remaining) on slot-defs do
 210         (if (and (listp slot-name) (eq 'quote (car slot-name)) (symbolp (second slot-name)))
 211             (psw (js-translate-symbol (second slot-name)))
 212             (ps-print slot-name))
 213         (psw " : ")
 214         (ps-print slot-value)
 215         (when remaining (psw ", ")))
 216   (psw " }"))
 217
 218 (defprinter js-slot-value (obj slot)
 219   (if (or (> (expression-precedence obj) #.(op-precedence 'js-slot-value))
 220           (numberp obj)
 221           (and (listp obj) (member (car obj) '(js-lambda js-object))))
 222       (parenthesize-print obj)
 223       (ps-print obj))
 224   (if (symbolp slot)
 225       (progn (psw #\.) (psw (js-translate-symbol slot)))
 226       (progn (psw #\[) (ps-print slot) (psw #\]))))
 227
 228 (defprinter js-cond-statement (clauses)
 229   (loop for (test body-block) in clauses
 230         for start = "if (" then " else if (" do
 231         (if (equalp test "true")
 232             (psw " else ")
 233             (progn (psw start)
 234                    (ps-print test)
 235                    (psw ") ")))
 236         (ps-print body-block)))
 237
 238 (defprinter js:if (test then-block else-block)
 239   (psw "if (") (ps-print test) (psw ") ")
 240   (ps-print then-block)
 241   (when else-block
 242       (psw " else ")
 243       (ps-print else-block)))
 244
 245 (defprinter js:? (test then else)
 246   (ps-print test)
 247   (psw " ? ")
 248   (if (>= (expression-precedence then) (op-precedence 'js:?))
 249       (parenthesize-print then)
 250       (ps-print then))
 251   (psw " : ")
 252   (if (>= (expression-precedence else) (op-precedence 'js:?))
 253       (parenthesize-print else)
 254       (ps-print else)))
 255
 256 (defprinter js-assign (lhs rhs)
 257   (ps-print lhs) (psw " = ") (ps-print rhs))
 258
 259 (defprinter js-var (var-name &rest var-value)
 260   (psw "var ")
 261   (psw (js-translate-symbol var-name))
 262   (when var-value
 263     (psw " = ")
 264     (ps-print (car var-value))))
 265
 266 (defprinter js-break (&optional label)
 267   (psw "break")
 268   (when label
 269     (psw " ")
 270     (psw (js-translate-symbol label))))
 271
 272 (defprinter js-continue (&optional label)
 273   (psw "continue")
 274   (when label
 275     (psw " ")
 276     (psw (js-translate-symbol label))))
 277
 278 ;;; iteration
 279 (defprinter js-for (label vars tests steps body-block)
 280   (when label (psw (js-translate-symbol label)) (psw ": ") (newline-and-indent))
 281   (psw "for (")
 282   (loop for ((var-name . var-init) . remaining) on vars
 283         for decl = "var " then "" do
 284         (psw decl) (psw (js-translate-symbol var-name)) (psw " = ") (ps-print var-init) (when remaining (psw ", ")))
 285   (psw "; ")
 286   (loop for (test . remaining) on tests do
 287        (ps-print test) (when remaining (psw ", ")))
 288   (psw "; ")
 289   (loop for (step . remaining) on steps do
 290        (ps-print step) (when remaining (psw ", ")))
 291   (psw ") ")
 292   (ps-print body-block))
 293
 294 (defprinter js-for-in (var object body-block)
 295   (psw "for (") (ps-print var) (psw " in ")
 296   (if (> (expression-precedence object) (op-precedence 'in))
 297       (parenthesize-print object)
 298       (ps-print object))
 299   (psw ") ")
 300   (ps-print body-block))
 301
 302 (defprinter js-while (test body-block)
 303   (psw "while (") (ps-print test) (psw ") ")
 304   (ps-print body-block))
 305
 306 (defprinter js-with (expression body-block)
 307   (psw "with (") (ps-print expression) (psw ") ")
 308   (ps-print body-block))
 309
 310 (defprinter js-switch (test clauses)
 311   (flet ((print-body-statements (body-statements)
 312            (incf *indent-level*)
 313            (loop for statement in body-statements do
 314                  (progn (newline-and-indent)
 315                         (ps-print statement)
 316                         (psw #\;)))
 317            (decf *indent-level*)))
 318     (psw "switch (") (ps-print test) (psw ") {")
 319     (loop for (val . statements) in clauses
 320           do (progn (newline-and-indent)
 321                     (if (eq val 'default)
 322                         (progn (psw "default: ")
 323                                (print-body-statements statements))
 324                         (progn (psw "case ")
 325                                (ps-print val)
 326                                (psw #\:)
 327                                (print-body-statements statements)))))
 328     (newline-and-indent)
 329     (psw #\})))
 330
 331 (defprinter js-try (body-block &key catch finally)
 332   (psw "try ")
 333   (ps-print body-block)
 334   (when catch
 335     (psw " catch (") (psw (js-translate-symbol (first catch))) (psw ") ")
 336     (ps-print (second catch)))
 337   (when finally
 338     (psw " finally ")
 339     (ps-print finally)))
 340
 341 ;;; regex
 342 (defprinter js-regex (regex)
 343   (flet ((first-slash-p (string)
 344            (and (> (length string) 0) (char= (char string 0) #\/))))
 345     (let ((slash (unless (first-slash-p regex) "/")))
 346       (psw (format nil (concatenate 'string slash "~A" slash) regex)))))
 347
 348 ;;; conditional compilation
 349 (defprinter cc-if (test body-forms)
 350   (psw "/*@if ")
 351   (ps-print test)
 352   (incf *indent-level*)
 353   (dolist (form body-forms)
 354     (newline-and-indent) (ps-print form) (psw #\;))
 355   (decf *indent-level*)
 356   (newline-and-indent)
 357   (psw "@end @*/"))
 358
 359 (defprinter js-instanceof (value type)
 360   (psw #\()
 361   (if (> (expression-precedence value) (op-precedence 'js-instance-of))
 362       (parenthesize-print value)
 363       (ps-print value))
 364   (psw " instanceof ")
 365   (if (> (expression-precedence type) (op-precedence 'js-instance-of))
 366       (parenthesize-print type)
 367       (ps-print type))
 368   (psw #\)))
 369
 370 (defprinter js-escape (lisp-form)
 371   (psw `(ps1* ,lisp-form)))
 372
 373 ;;; named statements
 374 (macrolet ((def-stmt-printer (&rest stmts)
 375              `(progn ,@(mapcar (lambda (stmt)
 376                                  `(defprinter ,(intern (format nil "JS-~a" stmt)) (expr)
 377                                     (psw (format nil "~(~a~) " ',stmt))
 378                                     (ps-print expr)))
 379                                stmts))))
 380   (def-stmt-printer throw return))