rename upstream-man-pages to upstream-doc

[clinton/guile-figl.git] / upstream-doc / manglsl / xhtml / pmathml.xsl

<!-- saved from url=(0013)about:internet -->\r
<xsl:stylesheet\r
  version="1.0"\r
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"\r
  xmlns:mml="http://www.w3.org/1998/Math/MathML"\r
  xmlns:h="http://www.w3.org/1999/xhtml"\r
  xmlns="http://www.w3.org/1999/xhtml"\r
  xmlns:msxsl="urn:schemas-microsoft-com:xslt"\r
  xmlns:fns="http://www.w3.org/2002/Math/preference"\r
  xmlns:doc="http://www.dcarlisle.demon.co.uk/xsldoc"\r
  xmlns:ie5="http://www.w3.org/TR/WD-xsl"\r
  exclude-result-prefixes="h ie5 fns msxsl fns doc"\r
  extension-element-prefixes="msxsl fns doc"\r
>\r
\r
<!--\r
$Id: pmathml.xsl,v 1.8 2003/06/23 14:46:44 davidc Exp $\r
\r
Copyright David Carlisle 2001, 2002.\r
\r
Use and distribution of this code are permitted under the terms of the <a\r
href="http://www.w3.org/Consortium/Legal/copyright-software-19980720"\r
>W3C Software Notice and License</a>.\r
-->\r
\r
<!-- MathPlayer mpdialog code for contributed by\r
     Jack Dignan and Robert Miner, both of Design Science.\r
-->\r
\r
<xsl:output method="xml" omit-xml-declaration="yes"  />\r
\r
<ie5:if doc:id="iehack" test=".">\r
    <ie5:eval no-entities="t">'&lt;!--'</ie5:eval>\r
</ie5:if>\r
\r
\r
<fns:x name="mathplayer" o="MathPlayer.Factory.1">\r
<object id="mmlFactory"\r
	classid="clsid:32F66A20-7614-11D4-BD11-00104BD3F987">\r
</object>\r
<?import namespace="mml" implementation="#mmlFactory"?>\r
</fns:x>\r
\r
<fns:x name="techexplorer" o="techexplorer.AxTchExpCtrl.1">\r
<object id="mmlFactory" classid="clsid:0E76D59A-C088-11D4-9920-002035EFB1A4">\r
</object>\r
<?import namespace="mml" implementation="#mmlFactory"?>\r
</fns:x>\r
\r
\r
<!-- SCRIPT not script due to weird mozilla bug\r
http://bugzilla.mozilla.org/show_bug.cgi?id=158457\r
-->\r
\r
<fns:x name="css" o="Microsoft.FreeThreadedXMLDOM">\r
<SCRIPT for="window" event="onload">\r
var xsl = new ActiveXObject("Microsoft.FreeThreadedXMLDOM");\r
xsl.async = false;\r
xsl.validateOnParse = false;\r
xsl.load("pmathmlcss.xsl");\r
var xslTemplate = new ActiveXObject("MSXML2.XSLTemplate.3.0");\r
xslTemplate.stylesheet=xsl.documentElement;\r
var xslProc = xslTemplate.createProcessor();\r
xslProc.input = document.XMLDocument;\r
xslProc.transform();\r
var str = xslProc.output;\r
<!-- work around bug in IE6 under Win XP, RM 6/5/2002 -->\r
var repl = "replace";\r
if (window.navigator.appVersion.match(/Windows NT 5.1/)) { repl = ""; }\r
var newDoc = document.open("text/html", repl);\r
newDoc.write(str);\r
</SCRIPT>\r
</fns:x>\r
\r
\r
<h:p>\r
in mpdialog mode, we just write out some JavaScript to display\r
dialog to the reader asking whether they want to install MathPlayer\r
Depending on the response we get, we then instantiate an XSL processor\r
and reprocess the doc, passing $secondpass according to the\r
reader response.\r
</h:p>\r
<h:p>Using d-o-e is fairly horrible, but this code is only for IE\r
anyway, and we need to force HTML semantics in this case.</h:p>\r
\r
<xsl:variable name="mpdialog">\r
var cookieName = "MathPlayerInstall=";\r
function MPInstall(){\r
<!-- IE7 has native support for MathML, so exit early if IE7 detected -->\r
 if (typeof document.body.style.maxHeight != "undefined") return null;\r
 var showDialog=true;\r
 var c = document.cookie;\r
 var i = c.indexOf(cookieName);\r
 if (i >= 0) {\r
  if ( c.substr(i + cookieName.length, 1) >= 2) { showDialog=false; }\r
 }\r
 if (showDialog) {\r
  MPDialog();\r
  c = document.cookie;\r
  i = c.indexOf(cookieName);\r
 }\r
 if (i >= 0) return c.substr(i + cookieName.length, 1);\r
 else return null;\r
}\r
\r
function MPDialog() {\r
 var vArgs="";\r
 var sFeatures="dialogWidth:410px;dialogHeight:190px;help:off;status:no";\r
 var text = "";\r
 text += "javascript:document.write('"\r
 text += '&lt;script>'\r
 text += 'function fnClose(v) { '\r
 text += 'var exp = new Date();'\r
 text += 'var thirtyDays = exp.getTime() + (30 * 24 * 60 * 60 * 1000);'\r
 text += 'exp.setTime(thirtyDays);'\r
 text += 'var cookieProps = ";expires=" + exp.toGMTString();'\r
 text += 'if (document.forms[0].dontask.checked) v+=2;'\r
 text += 'document.cookie="' + cookieName + '"+v+cookieProps;'\r
 text += 'window.close();'\r
 text += '}'\r
 text += '&lt;/' + 'script>'\r
 text += '&lt;head>&lt;title>Install MathPlayer?&lt;/title>&lt;/head>'\r
 text += '&lt;body bgcolor="#D4D0C8">&lt;form>'\r
 text += '&lt;table cellpadding=10 style="font-family:Arial;font-size:10pt" border=0 width=100%>'\r
 text += '&lt;tr>&lt;td align=left>This page requires Design Science\\\'s MathPlayer&amp;trade;.&lt;br>'\r
 text += 'Do you want to download and install MathPlayer?&lt;/td>&lt;/tr>';\r
 text += '&lt;tr>&lt;td align=center>&lt;input type="checkbox" name="dontask">'\r
 text += 'Don\\\'t ask me again&lt;/td>&lt;/tr>'\r
 text += '&lt;tr>&lt;td align=center>&lt;input id=yes type="button" value=" Yes "'\r
 text += ' onClick="fnClose(1)">&amp;nbsp;&amp;nbsp;&amp;nbsp;'\r
 text += '&lt;input type="button" value="  No  " onClick="fnClose(0)">&lt;/td>&lt;/tr>'\r
 text += '&lt;/table>&lt;/form>';\r
 text += '&lt;/body>'\r
 text += "')"\r
 window.showModalDialog( text , vArgs, sFeatures );\r
}\r
\r
function WaitDialog() {\r
 var vArgs="";\r
 var sFeatures="dialogWidth:510px;dialogHeight:150px;help:off;status:no";\r
 var text = "";\r
 text += "javascript:document.write('"\r
 text += '&lt;script>'\r
 text += 'window.onload=fnLoad;'\r
 text += 'function fnLoad() {document.forms[0].yes.focus();}'\r
 text += 'function fnClose(v) { '\r
 text += 'window.returnValue=v;'\r
 text += 'window.close();'\r
 text += '}'\r
 text += '&lt;/' + 'script>'\r
 text += '&lt;head>&lt;title>Wait for Installation?&lt;/title>&lt;/head>'\r
 text += '&lt;body bgcolor="#D4D0C8" onload="fnLoad()">&lt;form>&lt;'\r
 text += 'table cellpadding=10 style="font-family:Arial;font-size:10pt" border=0 width=100%>'\r
 text += '&lt;tr>&lt;td align=left>Click OK once MathPlayer is installed '\r
 text += 'to refresh the page.&lt;br>'\r
 text += 'Click Cancel to view the page immediately without MathPlayer.&lt;/td>&lt;/tr>';\r
 text += '&lt;tr>&lt;td align=center>&lt;input id=yes type="button" '\r
 text += 'value="   OK   " onClick="fnClose(1)">&amp;nbsp;&amp;nbsp;&amp;nbsp;'\r
 text += '&lt;input type="button" value="Cancel" onClick="fnClose(0)">&lt;/td>&lt;/tr>'\r
 text += '&lt;/table>&lt;/form>';\r
 text += '&lt;/body>'\r
 text += "')"\r
 return window.showModalDialog( text , vArgs, sFeatures );\r
}\r
\r
var result = MPInstall();\r
\r
var action = "fallthrough";\r
if (result == 1 || result == 3) {\r
 window.open("http://www.dessci.com/webmath/mathplayer");\r
 var wait = WaitDialog();\r
 if ( wait == 1) {\r
  action =  "install";\r
  document.location.reload();\r
\r
 }\r
}\r
if (action == "fallthrough") {\r
var xsl = new ActiveXObject("Microsoft.FreeThreadedXMLDOM");\r
xsl.async = false;\r
xsl.validateOnParse = false;\r
xsl.load("pmathmlcss.xsl");\r
var xslTemplate = new ActiveXObject("MSXML2.XSLTemplate.3.0");\r
xslTemplate.stylesheet=xsl.documentElement;\r
var xslProc = xslTemplate.createProcessor();\r
xslProc.input = document.XMLDocument;\r
\r
xslProc.transform();\r
var str = xslProc.output;\r
<!-- work around bug in IE6 under Win XP, RM 6/5/2002 -->\r
var repl = "replace";\r
if (window.navigator.appVersion.match(/Windows NT 5.1/)) { repl = ""; }\r
var newDoc = document.open("text/html", repl);\r
newDoc.write(str);\r
document.close();\r
}\r
</xsl:variable>\r
\r
<fns:x name="mathplayer-dl" >mathplayer-dl</fns:x>\r
\r
<fns:x name="techexplorer-plugin" >techexplorer-plugin</fns:x>\r
\r
<xsl:variable name="root" select="/"/>\r
\r
\r
\r
<xsl:param name="activex">\r
   <xsl:choose>\r
     <xsl:when test="/*/@fns:renderer='techexplorer-plugin'">techexplorer-plugin</xsl:when>\r
     <xsl:when test="system-property('xsl:vendor')!='Microsoft'"/>\r
     <xsl:otherwise>\r
<xsl:variable name="docpref" select="document('')/*/fns:x[@name=$root/*/@fns:renderer][1]"/>\r
     <xsl:choose>\r
     <xsl:when test="$docpref='mathplayer-dl'">mathplayer-dl</xsl:when>\r
     <xsl:when test="$docpref and fns:isinstalled(string($docpref/@o))='true'">\r
	   <xsl:copy-of select="$docpref/node()"/>\r
     </xsl:when>\r
     <xsl:otherwise>\r
       <xsl:copy-of select="(document('')/*/fns:x[fns:isinstalled(string(@o))='true'])[1]/node()"/>\r
     </xsl:otherwise>\r
  </xsl:choose>\r
     </xsl:otherwise>\r
  </xsl:choose>\r
</xsl:param>\r
\r
<h:div doc:ref="iehack">\r
<h:h3>IE5 hacks</h:h3>\r
<h:p>This code will be ignored by an XSLT engine as a top level\r
element in a foreign namespace. It will be executed by an IE5XSL\r
engine and insert &lt;!-- into the output stream, ie the start of a\r
comment. This will comment out all the XSLT code which will be copied\r
to the output. A similar clause below will close this comment, it is\r
then followed by the IE5XSL templates to be executed.</h:p>\r
<h:p>This trick is due to Jonathan Marsh of Microsoft, and used in\r
<h:a href="http://www.w3.org/TR/2001/WD-query-datamodel-20010607/xmlspec-ie-dm.xsl">the stylesheet for\r
the XPath 2 data model draft</h:a>.</h:p>\r
</h:div>\r
\r
<h:h2>XSLT stylesheet</h:h2>\r
<h:h3>MSXSL script block</h:h3>\r
\r
<h:p>The following script block implements an extension function that\r
tests whether a specified ActiveX component is known to the client.\r
This is used below to test for the existence of MathML rendering\r
components.</h:p>\r
<msxsl:script language="JScript" implements-prefix="fns">\r
    function isinstalled(ax)\r
    {\r
    try {\r
	var ActiveX = new ActiveXObject(ax);\r
	return "true";\r
    } catch (e) {\r
	return "false";\r
    }\r
}\r
</msxsl:script>\r
\r
<h:p>The main bulk of this stylesheet is an identity transformation so...</h:p>\r
<xsl:template match="*|comment()">\r
<xsl:copy>\r
<xsl:copy-of select="@*"/>\r
<xsl:apply-templates/>\r
</xsl:copy>\r
</xsl:template>\r
\r
\r
\r
<h:p>XHTML elements are copied sans prefix (XHTML is default namespace\r
here, so these elements will still be in XHTML namespace</h:p>\r
<xsl:template match="h:*">\r
<xsl:element name="{local-name(.)}">\r
 <xsl:copy-of select="@*"/>\r
<xsl:apply-templates/>\r
</xsl:element>\r
</xsl:template>\r
\r
<h:p>IE's treatment of XHTML as HTML needs a little help here...</h:p>\r
<xsl:template match="h:br|h:hr">\r
<xsl:choose>\r
<xsl:when test="system-property('xsl:vendor')='Microsoft'">\r
  <xsl:value-of disable-output-escaping="yes" select="concat('&lt;',local-name(.))"/>\r
  <xsl:apply-templates mode="verb" select="@*"/>\r
  <xsl:text disable-output-escaping="yes">&gt;</xsl:text>\r
</xsl:when>\r
<xsl:otherwise>\r
<xsl:element name="{local-name(.)}">\r
 <xsl:copy-of select="@*"/>\r
<xsl:apply-templates/>\r
</xsl:element>\r
</xsl:otherwise>\r
</xsl:choose>\r
</xsl:template>\r
\r
<h:p>This just ensures the mathml prefix declaration isn't copied from\r
the source at this stage, so that the system will use the mml prefix\r
coming from this stylesheet</h:p>\r
<xsl:template match="h:html|html">\r
<html>\r
<xsl:copy-of select="@*[not(namespace-uri(.)='http://www.w3.org/2002/Math/preference')]"/>\r
<xsl:apply-templates/>\r
</html>\r
</xsl:template>\r
\r
<h:p>We modify the head element to add code to specify a Microsoft\r
"Behaviour" if the behaviour component is known to the system.</h:p>\r
<h:span doc:ref="mp">Test for MathPlayer (Design Science)</h:span>\r
<h:span doc:ref="te">Test for Techexplorer (IBM)</h:span>\r
<h:span doc:ref="ms"><h:div>Test for Microsoft. In this case we just\r
output a small HTML file that executes a script that will re-process\r
the source docuument with a different stylesheet. Doing things this\r
way avoids the need to xsl:import the second stylesheet, which would\r
very much increase the processing overhead of running this\r
stylesheet.</h:div></h:span>\r
<h:span doc:ref="other">Further tests (eg for netscape/mozilla) could\r
be added here if necessary</h:span>\r
<xsl:template match="h:head|head">\r
<head>\r
\r
<!-- new if for IE frames bug -->\r
<xsl:if test="system-property('xsl:vendor')='Microsoft'">\r
<xsl:if test="name(msxsl:node-set($activex)/*)=''">\r
<object id="mmlFactory"\r
	classid="clsid:32F66A20-7614-11D4-BD11-00104BD3F987">\r
</object>\r
<xsl:processing-instruction name="import">\r
 namespace="mml" implementation="#mmlFactory"\r
</xsl:processing-instruction>\r
</xsl:if>\r
</xsl:if>\r
\r
<xsl:choose>\r
<xsl:when doc:id="mp" test="$activex='mathplayer-dl'">\r
    <xsl:if test="fns:isinstalled('MathPlayer.Factory.1')='false'">\r
     <SCRIPT for="window" event="onload">\r
       <xsl:value-of select="$mpdialog" disable-output-escaping="yes"/>\r
     </SCRIPT>\r
    </xsl:if>\r
   <xsl:copy-of select="document('')/*/fns:x[@name='mathplayer']"/>\r
</xsl:when>\r
<xsl:when doc:id="mp" test="not($activex='techexplorer-plugin') and system-property('xsl:vendor')='Microsoft'">\r
  <xsl:copy-of select="$activex"/>\r
</xsl:when>\r
<xsl:otherwise doc:id="other">\r
</xsl:otherwise>\r
</xsl:choose>\r
  <xsl:apply-templates/>\r
</head>\r
</xsl:template>\r
\r
\r
<xsl:template match="mml:math" priority="22">\r
<xsl:choose>\r
<xsl:when test="$activex='techexplorer-plugin'">\r
<embed	type="text/mathml" height="75" width="300">\r
<xsl:attribute name="mmldata">\r
<xsl:apply-templates mode="verb" select="."/>\r
</xsl:attribute>\r
</embed>\r
</xsl:when>\r
<xsl:otherwise>\r
<xsl:element name="mml:{local-name(.)}">\r
 <xsl:copy-of select="@*"/>\r
<xsl:apply-templates/>\r
</xsl:element>\r
</xsl:otherwise>\r
</xsl:choose>\r
</xsl:template>\r
\r
\r
<!-- squash annotation elements -->\r
\r
\r
\r
<h:p>Somewhat bizarrely in an otherwise namespace aware system,\r
Microsoft behaviours are defined to trigger off the\r
<h:em>prefix</h:em> not the <h:em>Namespace</h:em>. In the code above\r
we associated a MathML rendering behaviour (if one was found) with the\r
prefix <h:code>mml:</h:code> so here we ensure that this is the prefix\r
that actually gets used in the output.</h:p>\r
<xsl:template match="mml:*">\r
<xsl:element name="mml:{local-name(.)}">\r
 <xsl:copy-of select="@*"/>\r
<xsl:apply-templates/>\r
</xsl:element>\r
</xsl:template>\r
\r
<h:p>Copy semantics element through in IE (so mathplayer gets to see\r
mathplayer annotations, otherwise use first child or a presentation annotation.</h:p>\r
<xsl:template match="mml:semantics">\r
<xsl:choose>\r
 <xsl:when test="system-property('xsl:vendor')='Microsoft'">\r
   <xsl:element name="mml:{local-name(.)}">\r
    <xsl:copy-of select="@*"/>\r
    <xsl:apply-templates/>\r
   </xsl:element>\r
 </xsl:when>\r
 <xsl:when test="mml:annotation-xml[@encoding='MathML-Presentation']">\r
   <xsl:apply-templates select="mml:annotation-xml[@encoding='MathML-Presentation']/node()"/>\r
 </xsl:when>\r
 <xsl:otherwise>\r
   <xsl:apply-templates select="*[1]"/>\r
 </xsl:otherwise>\r
</xsl:choose>\r
</xsl:template>\r
\r
<!-- a version of my old verb.xsl -->\r
\r
<!-- non empty elements and other nodes. -->\r
<xsl:template mode="verb" match="*[*]|*[text()]|*[comment()]|*[processing-instruction()]">\r
  <xsl:value-of select="concat('&lt;',local-name(.))"/>\r
  <xsl:apply-templates mode="verb" select="@*"/>\r
  <xsl:text>&gt;</xsl:text>\r
  <xsl:apply-templates mode="verb"/>\r
  <xsl:value-of select="concat('&lt;/',local-name(.),'&gt;')"/>\r
</xsl:template>\r
\r
<!-- empty elements -->\r
<xsl:template mode="verb" match="*">\r
  <xsl:value-of select="concat('&lt;',local-name(.))"/>\r
  <xsl:apply-templates mode="verb" select="@*"/>\r
  <xsl:text>/&gt;</xsl:text>\r
</xsl:template>\r
\r
<!-- attributes\r
     Output always surrounds attribute value by "\r
     so we need to make sure no literal " appear in the value  -->\r
<xsl:template mode="verb" match="@*">\r
  <xsl:value-of select="concat(' ',local-name(.),'=')"/>\r
  <xsl:text>"</xsl:text>\r
  <xsl:call-template name="string-replace">\r
    <xsl:with-param name="from" select="'&quot;'"/>\r
    <xsl:with-param name="to" select="'&amp;quot;'"/>\r
    <xsl:with-param name="string" select="."/>\r
  </xsl:call-template>\r
  <xsl:text>"</xsl:text>\r
</xsl:template>\r
\r
<!-- pis -->\r
<xsl:template mode="verb" match="processing-instruction()"/>\r
\r
<!-- only works if parser passes on comment nodes -->\r
<xsl:template mode="verb" match="comment()"/>\r
\r
\r
<!-- text elements\r
     need to replace & and < by entity references-->\r
<xsl:template mode="verb" match="text()">\r
  <a name="{generate-id(.)}"/>\r
  <xsl:call-template name="string-replace">\r
    <xsl:with-param name="to" select="'&amp;gt;'"/>\r
    <xsl:with-param name="from" select="'&gt;'"/>\r
    <xsl:with-param name="string">\r
      <xsl:call-template name="string-replace">\r
	<xsl:with-param name="to" select="'&amp;lt;'"/>\r
	<xsl:with-param name="from" select="'&lt;'"/>\r
	<xsl:with-param name="string">\r
	  <xsl:call-template name="string-replace">\r
	    <xsl:with-param name="to" select="'&amp;amp;'"/>\r
	    <xsl:with-param name="from" select="'&amp;'"/>\r
	    <xsl:with-param name="string" select="."/>\r
	  </xsl:call-template>\r
	</xsl:with-param>\r
      </xsl:call-template>\r
    </xsl:with-param>\r
  </xsl:call-template>\r
</xsl:template>\r
\r
\r
<!-- end  verb mode -->\r
\r
<!-- replace all occurences of the character(s) `from'\r
     by the string `to' in the string `string'.-->\r
<xsl:template name="string-replace" >\r
  <xsl:param name="string"/>\r
  <xsl:param name="from"/>\r
  <xsl:param name="to"/>\r
  <xsl:choose>\r
    <xsl:when test="contains($string,$from)">\r
      <xsl:value-of select="substring-before($string,$from)"/>\r
      <xsl:value-of select="$to"/>\r
      <xsl:call-template name="string-replace">\r
      <xsl:with-param name="string" select="substring-after($string,$from)"/>\r
      <xsl:with-param name="from" select="$from"/>\r
      <xsl:with-param name="to" select="$to"/>\r
      </xsl:call-template>\r
    </xsl:when>\r
    <xsl:otherwise>\r
      <xsl:value-of select="$string"/>\r
    </xsl:otherwise>\r
  </xsl:choose>\r
</xsl:template>\r
\r
\r
<!-- end of verb.xsl -->\r
\r
\r
\r
<h:h2>IE5XSL stylesheet</h:h2>\r
<h:p>In a rare fit of sympathy for users of\r
<h:em>the-language-known-as-XSL-in-IE5</h:em> this file incorporates a\r
version of the above code designed to work in the Microsoft dialect.\r
This is needed otherwise users of a MathML rendering behaviour would\r
have to make a choice whether they wanted to use this stylesheet\r
(keeping their source documents conforming XHTML+MathML) or to use\r
the explicit Microsoft Object code, which is less portable, but would\r
work in at least IE5.5.</h:p>\r
\r
<h:p>This entire section of code, down to the end of the stylesheet is\r
contained within this ie5:if. Thus XSLT sees it as a top level element\r
from a foreign namespace and silently ignores it. IE5XSL sees it as\r
"if true" and so executes the code.</h:p>\r
\r
\r
<h:p doc:ref="closecomment">First close the comment started at the beginning. This ensures\r
that the bulk of the XSLT code, while being copied to the result tree\r
by the IE5XSL engine, will not be rendered in the browser.</h:p>\r
\r
<h:span doc:ref="eval">Lacking attribute value templates in\r
xsl:element, and the local-name() function, we resort to constructing\r
the start and end tags in strings in javascript, then using\r
no-entities attribute which is the IE5XSL equivalent of disable-output-encoding</h:span>\r
<ie5:if test=".">\r
\r
<ie5:eval doc:id="closecomment" no-entities="t">'--&gt;'</ie5:eval>\r
\r
<ie5:apply-templates select=".">\r
\r
\r
<ie5:script>\r
    function mpisinstalled()\r
    {\r
    try {\r
	var ActiveX = new ActiveXObject("MathPlayer.Factory.1");\r
	return "true";\r
    } catch (e) {\r
	return "false";\r
    }\r
}\r
</ie5:script>\r
\r
<ie5:template match="/">\r
<ie5:apply-templates/>\r
</ie5:template>\r
\r
<ie5:template match="head|h:head"/>\r
\r
<ie5:template match="text()">\r
<ie5:value-of select="."/>\r
</ie5:template>\r
\r
<ie5:template match="*|@*">\r
<ie5:copy>\r
<ie5:apply-templates select="*|text()|@*"/>\r
</ie5:copy>\r
</ie5:template>\r
\r
\r
<ie5:template match="mml:*">\r
<ie5:eval  no-entities="t" doc:id="eval">'&lt;mml:' + this.nodeName.substring(this.nodeName.indexOf(":")+1)</ie5:eval>\r
<ie5:for-each select="@*">\r
<ie5:eval no-entities="t">' ' + this.nodeName</ie5:eval>="<ie5:value-of select="."/>"\r
</ie5:for-each>\r
<ie5:eval no-entities="t">'&gt;'</ie5:eval>\r
<ie5:apply-templates select="*|text()"/>\r
<ie5:eval no-entities="t">'&lt;/mml:' +  this.nodeName.substring(this.nodeName.indexOf(":")+1) + '&gt;'</ie5:eval>\r
</ie5:template>\r
\r
\r
<ie5:template match="mml:math">\r
<ie5:if expr="mpisinstalled()=='false'">\r
<embed	type="text/mathml" height="75" width="300">\r
<ie5:attribute name="mmldata">\r
<ie5:eval  doc:id="eval"  no-entities="t">'&lt;math&gt;'</ie5:eval>\r
<ie5:apply-templates/>\r
<ie5:eval  doc:id="eval"  no-entities="t">'&lt;/math&gt;'</ie5:eval>\r
</ie5:attribute>\r
</embed>\r
</ie5:if>\r
<ie5:if expr="mpisinstalled()=='true'">\r
<ie5:eval  doc:id="eval"  no-entities="t">'&lt;mml:' + this.nodeName.substring(this.nodeName.indexOf(":")+1)</ie5:eval>\r
<ie5:for-each select="@*">\r
<ie5:eval no-entities="t">' ' + this.nodeName</ie5:eval>="<ie5:value-of select="."/>"\r
</ie5:for-each>\r
<ie5:eval no-entities="t">'&gt;'</ie5:eval>\r
<ie5:apply-templates select="*|text()"/>\r
<ie5:eval no-entities="t">'&lt;/mml:' +  this.nodeName.substring(this.nodeName.indexOf(":")+1) + '&gt;'</ie5:eval>\r
</ie5:if>\r
</ie5:template>\r
\r
<ie5:template match="html|h:html">\r
<html	xmlns:mml="http://www.w3.org/1998/Math/MathML">\r
<head>\r
<ie5:if expr="mpisinstalled()=='true'">\r
<object id="mmlFactory"\r
	classid="clsid:32F66A20-7614-11D4-BD11-00104BD3F987">\r
</object>\r
<ie5:pi name="IMPORT">\r
 namespace="mml" implementation="#mmlFactory"\r
</ie5:pi>\r
</ie5:if>\r
<ie5:apply-templates select="h:head/*|head/*"/>\r
</head>\r
<body>\r
<ie5:apply-templates select="body|h:body"/>\r
</body>\r
</html>\r
</ie5:template>\r
\r
</ie5:apply-templates>\r
\r
\r
</ie5:if>\r
\r
\r
</xsl:stylesheet>\r