module/statprof.scm

   1 ;;;; (statprof) -- a statistical profiler for Guile
   2 ;;;; -*-scheme-*-
   3 ;;;;
   4 ;;;;    Copyright (C) 2009, 2010, 2011, 2013, 2014  Free Software Foundation, Inc.
   5 ;;;;    Copyright (C) 2004, 2009 Andy Wingo <wingo at pobox dot com>
   6 ;;;;    Copyright (C) 2001 Rob Browning <rlb at defaultvalue dot org>
   7 ;;;;
   8 ;;;; This library is free software; you can redistribute it and/or
   9 ;;;; modify it under the terms of the GNU Lesser General Public
  10 ;;;; License as published by the Free Software Foundation; either
  11 ;;;; version 3 of the License, or (at your option) any later version.
  12 ;;;;
  13 ;;;; This library is distributed in the hope that it will be useful,
  14 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;;;; Lesser General Public License for more details.
  17 ;;;;
  18 ;;;; You should have received a copy of the GNU Lesser General Public
  19 ;;;; License along with this library; if not, write to the Free Software
  20 ;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  21 ;;;;
  22 \f
  23
  24 ;;; Commentary:
  25 ;;;
  26 ;;; @code{(statprof)} is a statistical profiler for Guile.
  27 ;;;
  28 ;;; A simple use of statprof would look like this:
  29 ;;;
  30 ;;; @example
  31 ;;;   (statprof-reset 0 50000 #t)
  32 ;;;   (statprof-start)
  33 ;;;   (do-something)
  34 ;;;   (statprof-stop)
  35 ;;;   (statprof-display)
  36 ;;; @end example
  37 ;;;
  38 ;;; This would reset statprof, clearing all accumulated statistics, then
  39 ;;; start profiling, run some code, stop profiling, and finally display a
  40 ;;; gprof flat-style table of statistics which will look something like
  41 ;;; this:
  42 ;;;
  43 ;;; @example
  44 ;;;   %   cumulative      self              self    total
  45 ;;;  time    seconds   seconds    calls  ms/call  ms/call  name
  46 ;;;  35.29      0.23      0.23     2002     0.11     0.11  -
  47 ;;;  23.53      0.15      0.15     2001     0.08     0.08  positive?
  48 ;;;  23.53      0.15      0.15     2000     0.08     0.08  +
  49 ;;;  11.76      0.23      0.08     2000     0.04     0.11  do-nothing
  50 ;;;   5.88      0.64      0.04     2001     0.02     0.32  loop
  51 ;;;   0.00      0.15      0.00        1     0.00   150.59  do-something
  52 ;;;  ...
  53 ;;; @end example
  54 ;;;
  55 ;;; All of the numerical data with the exception of the calls column is
  56 ;;; statistically approximate. In the following column descriptions, and
  57 ;;; in all of statprof, "time" refers to execution time (both user and
  58 ;;; system), not wall clock time.
  59 ;;;
  60 ;;; @table @asis
  61 ;;; @item % time
  62 ;;; The percent of the time spent inside the procedure itself
  63 ;;; (not counting children).
  64 ;;; @item cumulative seconds
  65 ;;; The total number of seconds spent in the procedure, including
  66 ;;; children.
  67 ;;; @item self seconds
  68 ;;; The total number of seconds spent in the procedure itself (not counting
  69 ;;; children).
  70 ;;; @item calls
  71 ;;; The total number of times the procedure was called.
  72 ;;; @item self ms/call
  73 ;;; The average time taken by the procedure itself on each call, in ms.
  74 ;;; @item total ms/call
  75 ;;; The average time taken by each call to the procedure, including time
  76 ;;; spent in child functions.
  77 ;;; @item name
  78 ;;; The name of the procedure.
  79 ;;; @end table
  80 ;;;
  81 ;;; The profiler uses @code{eq?} and the procedure object itself to
  82 ;;; identify the procedures, so it won't confuse different procedures with
  83 ;;; the same name. They will show up as two different rows in the output.
  84 ;;;
  85 ;;; Right now the profiler is quite simplistic.  I cannot provide
  86 ;;; call-graphs or other higher level information.  What you see in the
  87 ;;; table is pretty much all there is. Patches are welcome :-)
  88 ;;;
  89 ;;; @section Implementation notes
  90 ;;;
  91 ;;; The profiler works by setting the unix profiling signal
  92 ;;; @code{ITIMER_PROF} to go off after the interval you define in the call
  93 ;;; to @code{statprof-reset}. When the signal fires, a sampling routine is
  94 ;;; run which looks at the current procedure that's executing, and then
  95 ;;; crawls up the stack, and for each procedure encountered, increments
  96 ;;; that procedure's sample count. Note that if a procedure is encountered
  97 ;;; multiple times on a given stack, it is only counted once. After the
  98 ;;; sampling is complete, the profiler resets profiling timer to fire
  99 ;;; again after the appropriate interval.
 100 ;;;
 101 ;;; Meanwhile, the profiler keeps track, via @code{get-internal-run-time},
 102 ;;; how much CPU time (system and user -- which is also what
 103 ;;; @code{ITIMER_PROF} tracks), has elapsed while code has been executing
 104 ;;; within a statprof-start/stop block.
 105 ;;;
 106 ;;; The profiler also tries to avoid counting or timing its own code as
 107 ;;; much as possible.
 108 ;;;
 109 ;;; Code:
 110
 111 (define-module (statprof)
 112   #:use-module (srfi srfi-1)
 113   #:use-module (srfi srfi-9)
 114   #:use-module (srfi srfi-9 gnu)
 115   #:autoload   (ice-9 format) (format)
 116   #:use-module (system vm vm)
 117   #:use-module (system vm frame)
 118   #:use-module (system vm program)
 119   #:export (statprof-active?
 120             statprof-start
 121             statprof-stop
 122             statprof-reset
 123
 124             statprof-accumulated-time
 125             statprof-sample-count
 126             statprof-fold-call-data
 127             statprof-proc-call-data
 128             statprof-call-data-name
 129             statprof-call-data-calls
 130             statprof-call-data-cum-samples
 131             statprof-call-data-self-samples
 132             statprof-call-data->stats
 133
 134             statprof-stats-proc-name
 135             statprof-stats-%-time-in-proc
 136             statprof-stats-cum-secs-in-proc
 137             statprof-stats-self-secs-in-proc
 138             statprof-stats-calls
 139             statprof-stats-self-secs-per-call
 140             statprof-stats-cum-secs-per-call
 141
 142             statprof-display
 143             statprof-display-anomolies
 144
 145             statprof-fetch-stacks
 146             statprof-fetch-call-tree
 147
 148             statprof
 149             with-statprof
 150
 151             gcprof))
 152
 153
 154 ;; This profiler tracks two numbers for every function called while
 155 ;; it's active.  It tracks the total number of calls, and the number
 156 ;; of times the function was active when the sampler fired.
 157 ;;
 158 ;; Globally the profiler tracks the total time elapsed and the number
 159 ;; of times the sampler was fired.
 160 ;;
 161 ;; Right now, this profiler is not per-thread and is not thread safe.
 162
 163 (define-record-type <state>
 164   (make-state accumulated-time last-start-time sample-count
 165               sampling-period remaining-prof-time profile-level
 166               count-calls? gc-time-taken record-full-stacks?
 167               stacks procedure-data inside-profiler?)
 168   state?
 169   ;; Total time so far.
 170   (accumulated-time accumulated-time set-accumulated-time!)
 171   ;; Start-time when timer is active.
 172   (last-start-time last-start-time set-last-start-time!)
 173   ;; Total count of sampler calls.
 174   (sample-count sample-count set-sample-count!)
 175   ;; Microseconds.
 176   (sampling-period sampling-period set-sampling-period!)
 177   ;; Time remaining when prof suspended.
 178   (remaining-prof-time remaining-prof-time set-remaining-prof-time!)
 179   ;; For user start/stop nesting.
 180   (profile-level profile-level set-profile-level!)
 181   ;; Whether to catch apply-frame.
 182   (count-calls? count-calls? set-count-calls?!)
 183   ;; GC time between statprof-start and statprof-stop.
 184   (gc-time-taken gc-time-taken set-gc-time-taken!)
 185   ;; If #t, stash away the stacks for future analysis.
 186   (record-full-stacks? record-full-stacks? set-record-full-stacks?!)
 187   ;; If record-full-stacks?, the stashed full stacks.
 188   (stacks stacks set-stacks!)
 189   ;; A hash where the key is the function object itself and the value is
 190   ;; the data. The data will be a vector like this:
 191   ;;   #(name call-count cum-sample-count self-sample-count)
 192   (procedure-data procedure-data set-procedure-data!)
 193   ;; True if we are inside the profiler.
 194   (inside-profiler? inside-profiler? set-inside-profiler?!))
 195
 196 (define profiler-state (make-parameter #f))
 197
 198 (define* (fresh-profiler-state #:key (count-calls? #f)
 199                                (sampling-period 10000)
 200                                (full-stacks? #f))
 201   (make-state 0 #f 0 sampling-period 0 0 count-calls? 0 #f '()
 202               (make-hash-table) #f))
 203
 204 (define (ensure-profiler-state)
 205   (or (profiler-state)
 206       (let ((state (fresh-profiler-state)))
 207         (profiler-state state)
 208         state)))
 209
 210 (define (existing-profiler-state)
 211   (or (profiler-state)
 212       (error "expected there to be a profiler state")))
 213
 214 (define-record-type call-data
 215   (make-call-data proc call-count cum-sample-count self-sample-count)
 216   call-data?
 217   (proc call-data-proc)
 218   (call-count call-data-call-count set-call-data-call-count!)
 219   (cum-sample-count call-data-cum-sample-count set-call-data-cum-sample-count!)
 220   (self-sample-count call-data-self-sample-count set-call-data-self-sample-count!))
 221
 222 (define (call-data-name cd) (procedure-name (call-data-proc cd)))
 223 (define (call-data-printable cd)
 224   (or (call-data-name cd)
 225       (with-output-to-string (lambda () (write (call-data-proc cd))))))
 226
 227 (define (inc-call-data-call-count! cd)
 228   (set-call-data-call-count! cd (1+ (call-data-call-count cd))))
 229 (define (inc-call-data-cum-sample-count! cd)
 230   (set-call-data-cum-sample-count! cd (1+ (call-data-cum-sample-count cd))))
 231 (define (inc-call-data-self-sample-count! cd)
 232   (set-call-data-self-sample-count! cd (1+ (call-data-self-sample-count cd))))
 233
 234 (define (accumulate-time state stop-time)
 235   (set-accumulated-time! state
 236                          (+ (accumulated-time state)
 237                             (- stop-time (last-start-time state)))))
 238
 239 (define (get-call-data state proc)
 240   (let ((k (cond
 241             ((program? proc) (program-code proc))
 242             (else proc))))
 243     (or (hashv-ref (procedure-data state) k)
 244         (let ((call-data (make-call-data proc 0 0 0)))
 245           (hashv-set! (procedure-data state) k call-data)
 246           call-data))))
 247
 248 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 249 ;; SIGPROF handler
 250
 251 ;; FIXME: Instead of this messing about with hash tables and
 252 ;; frame-procedure, just record the stack of return addresses into a
 253 ;; growable vector, and resolve them to procedures when analyzing
 254 ;; instead of at collection time.
 255 ;;
 256 (define (sample-stack-procs state stack)
 257   (let ((stacklen (stack-length stack))
 258         (hit-count-call? #f))
 259
 260     (when (record-full-stacks? state)
 261       (set-stacks! state (cons stack (stacks state))))
 262
 263     (set-sample-count! state (+ (sample-count state) 1))
 264     ;; Now accumulate stats for the whole stack.
 265     (let loop ((frame (stack-ref stack 0))
 266                (procs-seen (make-hash-table 13))
 267                (self #f))
 268       (cond
 269        ((not frame)
 270         (hash-fold
 271          (lambda (proc val accum)
 272            (inc-call-data-cum-sample-count!
 273             (get-call-data state proc)))
 274          #f
 275          procs-seen)
 276         (and=> (and=> self (lambda (proc)
 277                              (get-call-data state proc)))
 278                inc-call-data-self-sample-count!))
 279        ((frame-procedure frame)
 280         => (lambda (proc)
 281              (cond
 282               ((eq? proc count-call)
 283                ;; We're not supposed to be sampling count-call and
 284                ;; its sub-functions, so loop again with a clean
 285                ;; slate.
 286                (set! hit-count-call? #t)
 287                (loop (frame-previous frame) (make-hash-table 13) #f))
 288               (else
 289                (hashq-set! procs-seen proc #t)
 290                (loop (frame-previous frame)
 291                      procs-seen
 292                      (or self proc))))))
 293        (else
 294         (loop (frame-previous frame) procs-seen self))))
 295     hit-count-call?))
 296
 297 (define (reset-sigprof-timer usecs)
 298   (let ((secs (quotient usecs #e1e6))
 299         (usecs (remainder usecs #e1e6)))
 300     ;; Guile's setitimer binding is terrible.
 301     (let ((prev (setitimer ITIMER_PROF 0 0 secs usecs)))
 302       (+ (* (caadr prev) #e1e6) (cdadr prev)))))
 303
 304 (define (profile-signal-handler sig)
 305   (define state (existing-profiler-state))
 306
 307   (set-inside-profiler?! state #t)
 308
 309   ;; FIXME: with-statprof should be able to set an outer frame for the
 310   ;; stack cut
 311   (when (positive? (profile-level state))
 312     (let* ((stop-time (get-internal-run-time))
 313            ;; cut down to the signal handler. note that this will only
 314            ;; work if statprof.scm is compiled; otherwise we get
 315            ;; `eval' on the stack instead, because if it's not
 316            ;; compiled, profile-signal-handler is a thunk that
 317            ;; tail-calls eval. perhaps we should always compile the
 318            ;; signal handler instead...
 319            (stack (or (make-stack #t profile-signal-handler)
 320                       (pk 'what! (make-stack #t)))))
 321
 322       (sample-stack-procs state stack)
 323       (accumulate-time state stop-time)
 324       (set-last-start-time! state (get-internal-run-time))
 325
 326       (reset-sigprof-timer (sampling-period state))))
 327
 328   (set-inside-profiler?! state #f))
 329
 330 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 331 ;; Count total calls.
 332
 333 (define (count-call frame)
 334   (define state (existing-profiler-state))
 335
 336   (unless (inside-profiler? state)
 337     (accumulate-time state (get-internal-run-time))
 338
 339     (and=> (frame-procedure frame)
 340            (lambda (proc)
 341              (inc-call-data-call-count!
 342               (get-call-data state proc))))
 343
 344     (set-last-start-time! state (get-internal-run-time))))
 345
 346 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 347
 348 (define (statprof-active?)
 349   "Returns @code{#t} if @code{statprof-start} has been called more times
 350 than @code{statprof-stop}, @code{#f} otherwise."
 351   (define state (profiler-state))
 352   (and state (positive? (profile-level state))))
 353
 354 ;; Do not call this from statprof internal functions -- user only.
 355 (define (statprof-start)
 356   "Start the profiler.@code{}"
 357   ;; After some head-scratching, I don't *think* I need to mask/unmask
 358   ;; signals here, but if I'm wrong, please let me know.
 359   (define state (ensure-profiler-state))
 360   (set-profile-level! state (+ (profile-level state) 1))
 361   (when (= (profile-level state) 1)
 362     (let ((rpt (remaining-prof-time state)))
 363       (set-remaining-prof-time! state 0)
 364       ;; FIXME: Use per-thread run time.
 365       (set-last-start-time! state (get-internal-run-time))
 366       (set-gc-time-taken! state (assq-ref (gc-stats) 'gc-time-taken))
 367       (reset-sigprof-timer (if (zero? rpt) (sampling-period state) rpt))
 368       (when (count-calls? state)
 369         (add-hook! (vm-apply-hook) count-call))
 370       (set-vm-trace-level! (1+ (vm-trace-level)))
 371       #t)))
 372
 373 ;; Do not call this from statprof internal functions -- user only.
 374 (define (statprof-stop)
 375   "Stop the profiler.@code{}"
 376   ;; After some head-scratching, I don't *think* I need to mask/unmask
 377   ;; signals here, but if I'm wrong, please let me know.
 378   (define state (ensure-profiler-state))
 379   (set-profile-level! state (- (profile-level state) 1))
 380   (when (zero? (profile-level state))
 381     (set-gc-time-taken! state
 382                         (- (assq-ref (gc-stats) 'gc-time-taken)
 383                            (gc-time-taken state)))
 384     (set-vm-trace-level! (1- (vm-trace-level)))
 385     (when (count-calls? state)
 386       (remove-hook! (vm-apply-hook) count-call))
 387     ;; I believe that we need to do this before getting the time
 388     ;; (unless we want to make things even more complicated).
 389     (set-remaining-prof-time! state (reset-sigprof-timer 0))
 390     (accumulate-time state (get-internal-run-time))
 391     (set-last-start-time! state #f)))
 392
 393 (define* (statprof-reset sample-seconds sample-microseconds count-calls?
 394                          #:optional full-stacks?)
 395   "Reset the statprof sampler interval to @var{sample-seconds} and
 396 @var{sample-microseconds}. If @var{count-calls?} is true, arrange to
 397 instrument procedure calls as well as collecting statistical profiling
 398 data. If @var{full-stacks?} is true, collect all sampled stacks into a
 399 list for later analysis.
 400
 401 Enables traps and debugging as necessary."
 402   (when (statprof-active?)
 403     (error "Can't reset profiler while profiler is running."))
 404   (let ((state (fresh-profiler-state #:count-calls? count-calls?
 405                                      #:sampling-period
 406                                      (+ (* sample-seconds #e1e6)
 407                                         sample-microseconds)
 408                                      #:full-stacks? full-stacks?)))
 409     (profiler-state state)
 410     (sigaction SIGPROF profile-signal-handler)
 411     #t))
 412
 413 (define (statprof-fold-call-data proc init)
 414   "Fold @var{proc} over the call-data accumulated by statprof. Cannot be
 415 called while statprof is active. @var{proc} should take two arguments,
 416 @code{(@var{call-data} @var{prior-result})}.
 417
 418 Note that a given proc-name may appear multiple times, but if it does,
 419 it represents different functions with the same name."
 420   (when (statprof-active?)
 421     (error "Can't call statprof-fold-call-data while profiler is running."))
 422   (hash-fold
 423    (lambda (key value prior-result)
 424      (proc value prior-result))
 425    init
 426    (procedure-data (existing-profiler-state))))
 427
 428 (define (statprof-proc-call-data proc)
 429   "Returns the call-data associated with @var{proc}, or @code{#f} if
 430 none is available."
 431   (when (statprof-active?)
 432     (error "Can't call statprof-proc-call-data while profiler is running."))
 433   (get-call-data (existing-profiler-state) proc))
 434
 435 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 436 ;; Stats
 437
 438 (define (statprof-call-data->stats call-data)
 439   "Returns an object of type @code{statprof-stats}."
 440   ;; returns (vector proc-name
 441   ;;                 %-time-in-proc
 442   ;;                 cum-seconds-in-proc
 443   ;;                 self-seconds-in-proc
 444   ;;                 num-calls
 445   ;;                 self-secs-per-call
 446   ;;                 total-secs-per-call)
 447
 448   (define state (existing-profiler-state))
 449
 450   (let* ((proc-name (call-data-printable call-data))
 451          (self-samples (call-data-self-sample-count call-data))
 452          (cum-samples (call-data-cum-sample-count call-data))
 453          (all-samples (statprof-sample-count))
 454          (secs-per-sample (/ (statprof-accumulated-time)
 455                              (statprof-sample-count)))
 456          (num-calls (and (count-calls? state) (statprof-call-data-calls call-data))))
 457
 458     (vector proc-name
 459             (* (/ self-samples all-samples) 100.0)
 460             (* cum-samples secs-per-sample 1.0)
 461             (* self-samples secs-per-sample 1.0)
 462             num-calls
 463             (and num-calls ;; maybe we only sampled in children
 464                  (if (zero? self-samples) 0.0
 465                      (/ (* self-samples secs-per-sample) 1.0 num-calls)))
 466             (and num-calls ;; cum-samples must be positive
 467                  (/ (* cum-samples secs-per-sample)
 468                     1.0
 469                     ;; num-calls might be 0 if we entered statprof during the
 470                     ;; dynamic extent of the call
 471                     (max num-calls 1))))))
 472
 473 (define (statprof-stats-proc-name stats) (vector-ref stats 0))
 474 (define (statprof-stats-%-time-in-proc stats) (vector-ref stats 1))
 475 (define (statprof-stats-cum-secs-in-proc stats) (vector-ref stats 2))
 476 (define (statprof-stats-self-secs-in-proc stats) (vector-ref stats 3))
 477 (define (statprof-stats-calls stats) (vector-ref stats 4))
 478 (define (statprof-stats-self-secs-per-call stats) (vector-ref stats 5))
 479 (define (statprof-stats-cum-secs-per-call stats) (vector-ref stats 6))
 480
 481 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 482
 483 (define (stats-sorter x y)
 484   (let ((diff (- (statprof-stats-self-secs-in-proc x)
 485                  (statprof-stats-self-secs-in-proc y))))
 486     (positive?
 487      (if (= diff 0)
 488          (- (statprof-stats-cum-secs-in-proc x)
 489             (statprof-stats-cum-secs-in-proc y))
 490          diff))))
 491
 492 (define* (statprof-display #:optional (port (current-output-port)))
 493   "Displays a gprof-like summary of the statistics collected. Unless an
 494 optional @var{port} argument is passed, uses the current output port."
 495   (define state (existing-profiler-state))
 496
 497   (cond
 498    ((zero? (statprof-sample-count))
 499     (format port "No samples recorded.\n"))
 500    (else
 501     (let* ((stats-list (statprof-fold-call-data
 502                         (lambda (data prior-value)
 503                           (cons (statprof-call-data->stats data)
 504                                 prior-value))
 505                         '()))
 506            (sorted-stats (sort stats-list stats-sorter)))
 507
 508       (define (display-stats-line stats)
 509         (if (count-calls? state)
 510             (format  port "~6,2f ~9,2f ~9,2f ~7d ~8,2f ~8,2f  "
 511                      (statprof-stats-%-time-in-proc stats)
 512                      (statprof-stats-cum-secs-in-proc stats)
 513                      (statprof-stats-self-secs-in-proc stats)
 514                      (statprof-stats-calls stats)
 515                      (* 1000 (statprof-stats-self-secs-per-call stats))
 516                      (* 1000 (statprof-stats-cum-secs-per-call stats)))
 517             (format  port "~6,2f ~9,2f ~9,2f  "
 518                      (statprof-stats-%-time-in-proc stats)
 519                      (statprof-stats-cum-secs-in-proc stats)
 520                      (statprof-stats-self-secs-in-proc stats)))
 521         (display (statprof-stats-proc-name stats) port)
 522         (newline port))
 523
 524       (if (count-calls? state)
 525           (begin
 526             (format  port "~5a ~10a   ~7a ~8a ~8a ~8a  ~8@a\n"
 527                      "%  " "cumulative" "self" "" "self" "total" "")
 528             (format  port "~5a  ~9a  ~8a ~8a ~8a ~8a  ~8@a\n"
 529                      "time" "seconds" "seconds" "calls" "ms/call" "ms/call" "name"))
 530           (begin
 531             (format  port "~5a ~10a   ~7a  ~8@a\n"
 532                      "%" "cumulative" "self" "")
 533             (format  port "~5a  ~10a  ~7a  ~8@a\n"
 534                      "time" "seconds" "seconds" "name")))
 535
 536       (for-each display-stats-line sorted-stats)
 537
 538       (display "---\n" port)
 539       (simple-format #t "Sample count: ~A\n" (statprof-sample-count))
 540       (simple-format #t "Total time: ~A seconds (~A seconds in GC)\n"
 541                      (statprof-accumulated-time)
 542                      (/ (gc-time-taken state)
 543                         1.0 internal-time-units-per-second))))))
 544
 545 (define (statprof-display-anomolies)
 546   "A sanity check that attempts to detect anomolies in statprof's
 547 statistics.@code{}"
 548   (define state (existing-profiler-state))
 549
 550   (statprof-fold-call-data
 551    (lambda (data prior-value)
 552      (when (and (count-calls? state)
 553                 (zero? (call-data-call-count data))
 554                 (positive? (call-data-cum-sample-count data)))
 555        (simple-format #t
 556                       "==[~A ~A ~A]\n"
 557                       (call-data-name data)
 558                       (call-data-call-count data)
 559                       (call-data-cum-sample-count data))))
 560    #f)
 561   (simple-format #t "Total time: ~A\n" (statprof-accumulated-time))
 562   (simple-format #t "Sample count: ~A\n" (statprof-sample-count)))
 563
 564 (define (statprof-accumulated-time)
 565   "Returns the time accumulated during the last statprof run.@code{}"
 566   (when (statprof-active?)
 567     (error "Can't get accumulated time while profiler is running."))
 568   (/ (accumulated-time (existing-profiler-state)) 1.0 internal-time-units-per-second))
 569
 570 (define (statprof-sample-count)
 571   "Returns the number of samples taken during the last statprof run.@code{}"
 572   (when (statprof-active?)
 573     (error "Can't get sample count while profiler is running."))
 574   (sample-count (existing-profiler-state)))
 575
 576 (define statprof-call-data-name call-data-name)
 577 (define statprof-call-data-calls call-data-call-count)
 578 (define statprof-call-data-cum-samples call-data-cum-sample-count)
 579 (define statprof-call-data-self-samples call-data-self-sample-count)
 580
 581 (define (statprof-fetch-stacks)
 582   "Returns a list of stacks, as they were captured since the last call
 583 to @code{statprof-reset}.
 584
 585 Note that stacks are only collected if the @var{full-stacks?} argument
 586 to @code{statprof-reset} is true."
 587   (define state (existing-profiler-state))
 588   (stacks state))
 589
 590 (define procedure=?
 591   (lambda (a b)
 592     (cond
 593      ((eq? a b))
 594      ((and (program? a) (program? b))
 595       (eq? (program-code a) (program-code b)))
 596      (else
 597       #f))))
 598
 599 ;; tree ::= (car n . tree*)
 600
 601 (define (lists->trees lists equal?)
 602   (let lp ((in lists) (n-terminal 0) (tails '()))
 603     (cond
 604      ((null? in)
 605       (let ((trees (map (lambda (tail)
 606                           (cons (car tail)
 607                                 (lists->trees (cdr tail) equal?)))
 608                         tails)))
 609         (cons (apply + n-terminal (map cadr trees))
 610               (sort trees
 611                     (lambda (a b) (> (cadr a) (cadr b)))))))
 612      ((null? (car in))
 613       (lp (cdr in) (1+ n-terminal) tails))
 614      ((find (lambda (x) (equal? (car x) (caar in)))
 615             tails)
 616       => (lambda (tail)
 617            (lp (cdr in)
 618                n-terminal
 619                (assq-set! tails
 620                           (car tail)
 621                           (cons (cdar in) (cdr tail))))))
 622      (else
 623       (lp (cdr in)
 624           n-terminal
 625           (acons (caar in) (list (cdar in)) tails))))))
 626
 627 (define (stack->procedures stack)
 628   (filter identity
 629           (unfold-right (lambda (x) (not x))
 630                         frame-procedure
 631                         frame-previous
 632                         (stack-ref stack 0))))
 633
 634 (define (statprof-fetch-call-tree)
 635   "Return a call tree for the previous statprof run.
 636
 637 The return value is a list of nodes, each of which is of the type:
 638 @code
 639  node ::= (@var{proc} @var{count} . @var{nodes})
 640 @end code"
 641   (define state (existing-profiler-state))
 642   (cons #t (lists->trees (map stack->procedures (stacks state)) procedure=?)))
 643
 644 (define* (statprof thunk #:key (loop 1) (hz 100) (count-calls? #f)
 645                    (full-stacks? #f))
 646   "Profiles the execution of @var{thunk}.
 647
 648 The stack will be sampled @var{hz} times per second, and the thunk itself will
 649 be called @var{loop} times.
 650
 651 If @var{count-calls?} is true, all procedure calls will be recorded. This
 652 operation is somewhat expensive.
 653
 654 If @var{full-stacks?} is true, at each sample, statprof will store away the
 655 whole call tree, for later analysis. Use @code{statprof-fetch-stacks} or
 656 @code{statprof-fetch-call-tree} to retrieve the last-stored stacks."
 657
 658   (let ((state (fresh-profiler-state)))
 659     (parameterize ((profiler-state state))
 660       (dynamic-wind
 661         (lambda ()
 662           (statprof-reset (inexact->exact (floor (/ 1 hz)))
 663                           (inexact->exact (* 1e6 (- (/ 1 hz)
 664                                                     (floor (/ 1 hz)))))
 665                           count-calls?
 666                           full-stacks?)
 667           (statprof-start))
 668         (lambda ()
 669           (let lp ((i loop))
 670             (unless (zero? i)
 671               (thunk)
 672               (lp (1- i)))))
 673         (lambda ()
 674           (statprof-stop)
 675           (statprof-display))))))
 676
 677 (define-macro (with-statprof . args)
 678   "Profiles the expressions in its body.
 679
 680 Keyword arguments:
 681
 682 @table @code
 683 @item #:loop
 684 Execute the body @var{loop} number of times, or @code{#f} for no looping
 685
 686 default: @code{#f}
 687 @item #:hz
 688 Sampling rate
 689
 690 default: @code{20}
 691 @item #:count-calls?
 692 Whether to instrument each function call (expensive)
 693
 694 default: @code{#f}
 695 @item #:full-stacks?
 696 Whether to collect away all sampled stacks into a list
 697
 698 default: @code{#f}
 699 @end table"
 700   (define (kw-arg-ref kw args def)
 701     (cond
 702      ((null? args) (error "Invalid macro body"))
 703      ((keyword? (car args))
 704       (if (eq? (car args) kw)
 705           (cadr args)
 706           (kw-arg-ref kw (cddr args) def)))
 707      ((eq? kw #f def) ;; asking for the body
 708       args)
 709      (else def))) ;; kw not found
 710   `((@ (statprof) statprof)
 711     (lambda () ,@(kw-arg-ref #f args #f))
 712     #:loop ,(kw-arg-ref #:loop args 1)
 713     #:hz ,(kw-arg-ref #:hz args 100)
 714     #:count-calls? ,(kw-arg-ref #:count-calls? args #f)
 715     #:full-stacks? ,(kw-arg-ref #:full-stacks? args #f)))
 716
 717 (define* (gcprof thunk #:key (loop 1) (full-stacks? #f))
 718   "Do an allocation profile of the execution of @var{thunk}.
 719
 720 The stack will be sampled soon after every garbage collection, yielding
 721 an approximate idea of what is causing allocation in your program.
 722
 723 Since GC does not occur very frequently, you may need to use the
 724 @var{loop} parameter, to cause @var{thunk} to be called @var{loop}
 725 times.
 726
 727 If @var{full-stacks?} is true, at each sample, statprof will store away the
 728 whole call tree, for later analysis. Use @code{statprof-fetch-stacks} or
 729 @code{statprof-fetch-call-tree} to retrieve the last-stored stacks."
 730
 731   (let ((state (fresh-profiler-state #:full-stacks? full-stacks?)))
 732     (parameterize ((profiler-state state))
 733       (define (gc-callback)
 734         (cond
 735          ((inside-profiler? state))
 736          (else
 737           (set-inside-profiler?! state #t)
 738
 739           ;; FIXME: should be able to set an outer frame for the stack cut
 740           (let ((stop-time (get-internal-run-time))
 741                 ;; Cut down to gc-callback, and then one before (the
 742                 ;; after-gc async).  See the note in profile-signal-handler
 743                 ;; also.
 744                 (stack (or (make-stack #t gc-callback 0 1)
 745                            (pk 'what! (make-stack #t)))))
 746             (sample-stack-procs state stack)
 747             (accumulate-time state stop-time)
 748             (set-last-start-time! state (get-internal-run-time)))
 749
 750           (set-inside-profiler?! state #f))))
 751
 752       (define (start)
 753         (set-profile-level! state (+ (profile-level state) 1))
 754         (when (= (profile-level state) 1)
 755           (set-remaining-prof-time! state 0)
 756           (set-last-start-time! state (get-internal-run-time))
 757           (set-gc-time-taken! state (assq-ref (gc-stats) 'gc-time-taken))
 758           (add-hook! after-gc-hook gc-callback)
 759           #t))
 760
 761       (define (stop)
 762         (set-profile-level! state (- (profile-level state) 1))
 763         (when (zero? (profile-level state))
 764           (set-gc-time-taken! state
 765                               (- (assq-ref (gc-stats) 'gc-time-taken)
 766                                  (gc-time-taken state)))
 767           (remove-hook! after-gc-hook gc-callback)
 768           (accumulate-time state (get-internal-run-time))
 769           (set-last-start-time! state #f)))
 770
 771       (dynamic-wind
 772         (lambda ()
 773           (start))
 774         (lambda ()
 775           (let lp ((i loop))
 776             (unless (zero? i)
 777               (thunk)
 778               (lp (1- i)))))
 779         (lambda ()
 780           (stop)
 781           (statprof-display))))))