m4/readlink.m4

   1 # readlink.m4 serial 7
   2 dnl Copyright (C) 2003, 2007, 2009 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_READLINK],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_CHECK_FUNCS_ONCE([readlink])
  11   if test $ac_cv_func_readlink = no; then
  12     HAVE_READLINK=0
  13     AC_LIBOBJ([readlink])
  14     gl_PREREQ_READLINK
  15   else
  16     AC_CACHE_CHECK([whether readlink signature is correct],
  17       [gl_cv_decl_readlink_works],
  18       [AC_COMPILE_IFELSE(
  19          [AC_LANG_PROGRAM(
  20            [[#include <unistd.h>
  21       /* Cause compilation failure if original declaration has wrong type.  */
  22       ssize_t readlink (const char *, char *, size_t);]])],
  23          [gl_cv_decl_readlink_works=yes], [gl_cv_decl_readlink_works=no])])
  24     AC_CACHE_CHECK([whether readlink handles trailing slash correctly],
  25       [gl_cv_func_readlink_works],
  26       [# We have readlink, so assume ln -s works.
  27        ln -s conftest.no-such conftest.link
  28        AC_RUN_IFELSE(
  29          [AC_LANG_PROGRAM(
  30            [[#include <unistd.h>
  31 ]], [[char buf[20];
  32       return readlink ("conftest.link/", buf, sizeof buf) != -1;]])],
  33          [gl_cv_func_readlink_works=yes], [gl_cv_func_readlink_works=no],
  34          [gl_cv_func_readlink_works="guessing no"])
  35       rm -f conftest.link])
  36     if test "$gl_cv_func_readlink_works" != yes; then
  37       AC_DEFINE([READLINK_TRAILING_SLASH_BUG], [1], [Define to 1 if readlink
  38         fails to recognize a trailing slash.])
  39       REPLACE_READLINK=1
  40       AC_LIBOBJ([readlink])
  41     elif test "$gl_cv_decl_readlink_works" != yes; then
  42       REPLACE_READLINK=1
  43       AC_LIBOBJ([readlink])
  44     fi
  45   fi
  46 ])
  47
  48 # Like gl_FUNC_READLINK, except prepare for separate compilation (no AC_LIBOBJ).
  49 AC_DEFUN([gl_FUNC_READLINK_SEPARATE],
  50 [
  51   AC_CHECK_FUNCS_ONCE([readlink])
  52   gl_PREREQ_READLINK
  53 ])
  54
  55 # Prerequisites of lib/readlink.c.
  56 AC_DEFUN([gl_PREREQ_READLINK],
  57 [
  58   :
  59 ])