configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_INIT(Makefile.in)
  24 . $srcdir/GUILE-VERSION
  25 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  26 AM_MAINTAINER_MODE
  27 AM_CONFIG_HEADER(libguile/scmconfig.h)
  28
  29 #--------------------------------------------------------------------
  30 #
  31 # Independent Subdirectories
  32 #
  33 #--------------------------------------------------------------------
  34
  35 AC_CONFIG_SUBDIRS(guile-readline)
  36
  37 #--------------------------------------------------------------------
  38 #
  39 # User options
  40 #
  41 #--------------------------------------------------------------------
  42
  43 AC_ARG_ENABLE(debug-freelist,
  44   [  --enable-debug-freelist include garbage collector freelist debugging code],
  45   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  46     AC_DEFINE(GUILE_DEBUG_FREELIST)
  47   fi)
  48
  49 AC_ARG_ENABLE(debug-malloc,
  50   [  --enable-debug-malloc   include malloc debugging code],
  51   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
  52     AC_DEFINE(GUILE_DEBUG_MALLOC)
  53   fi)
  54
  55 AC_ARG_ENABLE(guile-debug,
  56   [  --enable-guile-debug    include internal debugging functions],
  57   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  58     AC_DEFINE(GUILE_DEBUG)
  59   fi)
  60
  61 AC_ARG_ENABLE(arrays,
  62   [  --disable-arrays        omit array and uniform array support],,
  63   enable_arrays=yes)
  64
  65 AC_ARG_ENABLE(posix,
  66   [  --disable-posix         omit posix interfaces],,
  67   enable_posix=yes)
  68
  69 AC_ARG_ENABLE(networking,
  70   [  --disable-networking    omit networking interfaces],,
  71   enable_networking=yes)
  72
  73 AC_ARG_ENABLE(regex,
  74   [  --disable-regex         omit regular expression interfaces],,
  75   enable_regex=yes)
  76
  77 AC_ARG_ENABLE(htmldoc,
  78   [  --enable-htmldoc        build HTML documentation as well as Info],
  79   [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
  80      htmldoc_enabled=yes
  81      AC_PATH_PROG(TEXI2HTML, texi2html, not found)
  82      if test "$TEXI2HTML" = "not found"; then
  83        echo
  84        echo Building HTML documentation requires the \`texi2html\' program,
  85        echo which appears not to be present on your machine.
  86        echo
  87        echo \`texi2html\' is available from
  88        echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
  89        echo
  90        echo In the meantime, to build the guile-doc distribution
  91        echo without HTML enabled, please rerun \`./configure\' without
  92        echo the \`--enable-htmldoc\' option.
  93        exit -1
  94      fi
  95    fi])
  96
  97 AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)
  98
  99 AC_ARG_ENABLE(deprecated,
 100   [  --disable-deprecated    omit deprecated features [no]])
 101
 102 if test "$enable_deprecated" = no; then
 103   AC_DEFINE(SCM_DEBUG_DEPRECATED, 1)
 104 else
 105   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 106     warn_default=summary
 107   elif test "$enable_deprecated" = shutup; then
 108     warn_default=no
 109   else
 110     warn_default=$enable_deprecated
 111   fi
 112   AC_DEFINE(SCM_DEBUG_DEPRECATED, 0)
 113   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default")
 114 fi
 115
 116 dnl The --disable-debug used to control these two.  But now they are
 117 dnl a required part of the distribution.
 118 AC_DEFINE(DEBUG_EXTENSIONS)
 119 AC_DEFINE(READER_EXTENSIONS)
 120
 121 dnl files which are destined for separate modules.
 122
 123 if test "$enable_arrays" = yes; then
 124    LIBOBJS="$LIBOBJS ramap.o unif.o"
 125    AC_DEFINE(HAVE_ARRAYS)
 126 fi
 127
 128 if test "$enable_posix" = yes; then
 129    LIBOBJS="$LIBOBJS filesys.o posix.o"
 130    AC_DEFINE(HAVE_POSIX)
 131 fi
 132
 133 if test "$enable_networking" = yes; then
 134    LIBOBJS="$LIBOBJS net_db.o socket.o"
 135    AC_DEFINE(HAVE_NETWORKING)
 136 fi
 137
 138 if test "$enable_debug_malloc" = yes; then
 139    LIBOBJS="$LIBOBJS debug-malloc.o"
 140 fi
 141
 142 #--------------------------------------------------------------------
 143
 144 AC_LIBLTDL_CONVENIENCE
 145 AC_CONFIG_SUBDIRS(libltdl)
 146
 147 AC_PROG_CC
 148 AC_PROG_CPP
 149 AC_LIBTOOL_DLOPEN
 150
 151 AC_AIX
 152 AC_ISC_POSIX
 153 AC_MINIX
 154
 155 AM_PROG_CC_STDC
 156 AM_PROG_LIBTOOL
 157
 158 AC_C_CONST
 159 AC_C_INLINE
 160 AC_C_BIGENDIAN
 161
 162 AC_CHECK_SIZEOF(int)
 163 AC_CHECK_SIZEOF(long)
 164
 165 dnl by the pre C9X ANSI C standards, size_t & ptrdiff_t have to be
 166 dnl representable by a standard integral type.  since the largest
 167 dnl integer type in the pre-C9X ANSI C standards is long...
 168 AC_CHECK_TYPE(ptrdiff_t, long)
 169
 170 AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
 171                AC_TRY_COMPILE(,
 172                               [long long a],
 173                               scm_cv_long_longs=yes,
 174                               scm_cv_long_longs=no))
 175 if test "$scm_cv_long_longs" = yes; then
 176   AC_DEFINE(HAVE_LONG_LONGS)
 177   AC_CHECK_SIZEOF(long long)
 178 fi
 179
 180 AC_CHECK_SIZEOF(void *)
 181
 182 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 183   AC_MSG_ERROR(sizes of long and void* are not identical)
 184 fi
 185
 186 AC_HEADER_STDC
 187 AC_HEADER_DIRENT
 188 AC_HEADER_TIME
 189 AC_HEADER_SYS_WAIT
 190 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h sys/utime.h time.h unistd.h utime.h)
 191 GUILE_HEADER_LIBC_WITH_UNISTD
 192
 193 AC_TYPE_GETGROUPS
 194 AC_TYPE_SIGNAL
 195 AC_TYPE_MODE_T
 196
 197 AC_CHECK_LIB(m, main)
 198 AC_CHECK_FUNCS(gethostbyname)
 199 if test $ac_cv_func_gethostbyname = no; then
 200     AC_CHECK_LIB(nsl, gethostbyname)
 201 fi
 202 AC_CHECK_FUNCS(connect)
 203 if test $ac_cv_func_connect = no; then
 204     AC_CHECK_LIB(socket, connect)
 205 fi
 206
 207 # Check for dynamic linking
 208
 209 use_modules=yes
 210 AC_ARG_WITH(modules,
 211 [  --with-modules[=FILES]  Add support for dynamic modules],
 212 use_modules="$withval")
 213 test -z "$use_modules" && use_modules=yes
 214 DLPREOPEN=
 215 if test "$use_modules" != no; then
 216   AC_DEFINE(DYNAMIC_LINKING)
 217   if test "$use_modules" = yes; then
 218     DLPREOPEN="-dlpreopen force"
 219   else
 220     DLPREOPEN="-export-dynamic"
 221     for module in $use_modules; do
 222       DLPREOPEN="$DLPREOPEN -dlopen $module"
 223     done
 224   fi
 225 fi
 226 AC_SUBST(INCLTDL)
 227 AC_SUBST(LIBLTDL)
 228 AC_SUBST(DLPREOPEN)
 229
 230 AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit)
 231
 232 AC_CHECK_HEADERS(crypt.h sys/resource.h sys/file.h)
 233 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 234 AC_CHECK_LIB(crypt, crypt)
 235
 236 ### Some systems don't declare some functions.  On such systems, we
 237 ### need to at least provide our own K&R-style declarations.
 238
 239 ### GUILE_FUNC_DECLARED(function, headerfile)
 240
 241 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 242 ### not there, #define MISSING_FUNCTION_DECL.
 243 AC_DEFUN(GUILE_FUNC_DECLARED, [
 244   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 245     AC_EGREP_HEADER($1, $2,
 246                     guile_cv_func_$1_declared=yes,
 247                     guile_cv_func_$1_declared=no))
 248   if test [x$guile_cv_func_]$1[_declared] = xno; then
 249     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 250   fi
 251 ])
 252
 253 GUILE_FUNC_DECLARED(strptime, time.h)
 254 GUILE_FUNC_DECLARED(sleep, unistd.h)
 255 GUILE_FUNC_DECLARED(usleep, unistd.h)
 256
 257 ### On some systems usleep has no return value.  If it does have one,
 258 ### we'd like to return it; otherwise, we'll fake it.
 259 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 260   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 261                    /usr/include/unistd.h,
 262                    [guile_cv_func_usleep_return_type=void],
 263                    [guile_cv_func_usleep_return_type=int])])
 264 case "$guile_cv_func_usleep_return_type" in
 265   "void" )
 266     AC_DEFINE(USLEEP_RETURNS_VOID)
 267   ;;
 268 esac
 269
 270 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 271 if test -n "$have_sys_un_h" ; then
 272 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 273 fi
 274
 275 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 276
 277 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 278                setnetent    getnetent    endnetent    dnl
 279                setprotoent  getprotoent  endprotoent  dnl
 280                setservent   getservent   endservent   dnl
 281                getnetbyaddr getnetbyname dnl
 282                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 283                inet_pton inet_ntop)
 284
 285 dnl Some systems do not declare this.  Some systems do declare it, as a
 286 dnl macro.  With cygwin it may be in a DLL.
 287
 288 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 289 AC_CACHE_VAL(guile_cv_have_h_errno,
 290 [AC_TRY_COMPILE([#include <netdb.h>],
 291 [int a = h_errno;],
 292 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 293 AC_MSG_RESULT($guile_cv_have_h_errno)
 294 if test $guile_cv_have_h_errno = yes; then
 295   AC_DEFINE(HAVE_H_ERRNO)
 296 fi
 297
 298 AC_MSG_CHECKING(whether netdb.h defines uint32_t)
 299 AC_CACHE_VAL(guile_cv_have_uint32_t,
 300 [AC_TRY_COMPILE([#include <netdb.h>],
 301 [uint32_t a;],
 302 guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 303 AC_MSG_RESULT($guile_cv_have_uint32_t)
 304 if test $guile_cv_have_uint32_t = yes; then
 305   AC_DEFINE(HAVE_UINT32_T)
 306 fi
 307
 308 AC_MSG_CHECKING(for working IPv6 support)
 309 AC_CACHE_VAL(guile_cv_have_ipv6,
 310 [AC_TRY_COMPILE([#include <netinet/in.h>
 311 #include <sys/socket.h>],
 312 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 313 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 314 AC_MSG_RESULT($guile_cv_have_ipv6)
 315 if test $guile_cv_have_ipv6 = yes; then
 316   AC_DEFINE(HAVE_IPV6)
 317 fi
 318
 319 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 320 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 321 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 322 [AC_TRY_COMPILE([#include <netinet/in.h>],
 323 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 324 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 325 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 326 if test $guile_cv_have_sin6_scope_id = yes; then
 327   AC_DEFINE(HAVE_SIN6_SCOPE_ID)
 328 fi
 329
 330 AC_MSG_CHECKING(whether localtime caches TZ)
 331 AC_CACHE_VAL(guile_cv_localtime_cache,
 332 [if test x$ac_cv_func_tzset = xyes; then
 333 AC_TRY_RUN([#include <time.h>
 334 #if STDC_HEADERS
 335 # include <stdlib.h>
 336 #endif
 337 extern char **environ;
 338 unset_TZ ()
 339 {
 340   char **from, **to;
 341   for (to = from = environ; (*to = *from); from++)
 342     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 343       to++;
 344 }
 345 char TZ_GMT0[] = "TZ=GMT0";
 346 char TZ_PST8[] = "TZ=PST8";
 347 main()
 348 {
 349   time_t now = time ((time_t *) 0);
 350   int hour_GMT0, hour_unset;
 351   if (putenv (TZ_GMT0) != 0)
 352     exit (1);
 353   hour_GMT0 = localtime (&now)->tm_hour;
 354   unset_TZ ();
 355   hour_unset = localtime (&now)->tm_hour;
 356   if (putenv (TZ_PST8) != 0)
 357     exit (1);
 358   if (localtime (&now)->tm_hour == hour_GMT0)
 359     exit (1);
 360   unset_TZ ();
 361   if (localtime (&now)->tm_hour != hour_unset)
 362     exit (1);
 363   exit (0);
 364 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 365 [# If we have tzset, assume the worst when cross-compiling.
 366 guile_cv_localtime_cache=yes])
 367 else
 368         # If we lack tzset, report that localtime does not cache TZ,
 369         # since we can't invalidate the cache if we don't have tzset.
 370         guile_cv_localtime_cache=no
 371 fi])dnl
 372 AC_MSG_RESULT($guile_cv_localtime_cache)
 373 if test $guile_cv_localtime_cache = yes; then
 374   AC_DEFINE(LOCALTIME_CACHE)
 375 fi
 376
 377 dnl Test whether system calls are restartable by default on the
 378 dnl current system.  If they are not, we put a loop around every system
 379 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 380 dnl change from the default behaviour.  On the other hand, if signals
 381 dnl are restartable then the loop is not installed and when libguile
 382 dnl initialises it also resets the behaviour of each signal to cause a
 383 dnl restart (in case a different runtime had a different default
 384 dnl behaviour for some reason: e.g., different versions of linux seem
 385 dnl to behave differently.)
 386
 387 AC_SYS_RESTARTABLE_SYSCALLS
 388
 389 if test "$enable_regex" = yes; then
 390    if test "$ac_cv_header_regex_h" = yes ||
 391       test "$ac_cv_header_rxposix_h" = yes ||
 392       test "$ac_cv_header_rx_rxposix_h" = yes; then
 393      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 394      [AC_CHECK_LIB(rx, main)
 395       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 396      )
 397      dnl The following should not be necessary, but for some reason
 398      dnl autoheader misses it if we don't include it!
 399      if test "$ac_cv_func_regcomp_norx" = yes ||
 400         test "$ac_cv_func_regcomp_rx" = yes; then
 401        AC_DEFINE(HAVE_REGCOMP)
 402      fi
 403    fi
 404 fi
 405
 406 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove)
 407
 408 # When testing for the presence of alloca, we need to add alloca.o
 409 # explicitly to LIBOBJS to make sure that it is translated to
 410 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 411 AC_FUNC_ALLOCA
 412 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 413
 414 AC_STRUCT_ST_RDEV
 415 AC_STRUCT_ST_BLKSIZE
 416
 417 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 418 # LIBOBJS, which we don't need.  This seems more direct.
 419 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 420 [AC_TRY_COMPILE([#include <sys/types.h>
 421 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 422 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 423 if test $ac_cv_struct_st_blocks = yes; then
 424   AC_DEFINE(HAVE_ST_BLOCKS)
 425 fi
 426
 427 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 428   [AC_TRY_CPP([#include <sys/stat.h>
 429                #ifndef S_ISLNK
 430                #error no S_ISLNK
 431                #endif],
 432                ac_cv_macro_S_ISLNK=yes,
 433                ac_cv_macro_S_ISLNK=no)])
 434 if test $ac_cv_macro_S_ISLNK = yes; then
 435   AC_DEFINE(HAVE_S_ISLNK)
 436 fi
 437
 438 AC_STRUCT_TIMEZONE
 439 GUILE_STRUCT_UTIMBUF
 440
 441 #--------------------------------------------------------------------
 442 #
 443 # Which way does the stack grow?
 444 #
 445 #--------------------------------------------------------------------
 446
 447 AC_TRY_RUN(aux (l) unsigned long l;
 448              { int x; exit (l >= ((unsigned long)&x)); }
 449            main () { int q; aux((unsigned long)&q); },
 450            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 451
 452 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 453     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 454                 [guile_cv_type_float_fits_long=yes],
 455                 [guile_cv_type_float_fits_long=no],
 456                 [guile_cv_type_float_fits_long=guess-yes])])
 457 case $guile_cv_type_float_fits_long in
 458   "yes" )
 459     AC_DEFINE(SCM_SINGLES)
 460   ;;
 461   "guess-yes" )
 462     AC_DEFINE(SCM_SINGLES)
 463     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 464     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 465   ;;
 466 esac
 467
 468
 469 AC_MSG_CHECKING(for struct linger)
 470 AC_CACHE_VAL(scm_cv_struct_linger,
 471         AC_TRY_COMPILE([
 472 #include <sys/types.h>
 473 #include <sys/socket.h>],
 474                         [struct linger lgr;  lgr.l_linger = 100],
 475                         scm_cv_struct_linger="yes",
 476                         scm_cv_struct_linger="no"))
 477 AC_MSG_RESULT($scm_cv_struct_linger)
 478 if test $scm_cv_struct_linger = yes; then
 479         AC_DEFINE(HAVE_STRUCT_LINGER)
 480 fi
 481
 482
 483 AC_MSG_CHECKING(for struct timespec)
 484 AC_CACHE_VAL(scm_cv_struct_timespec,
 485         AC_TRY_COMPILE([
 486 #include <time.h>],
 487                         [struct timespec t;  t.tv_nsec = 100],
 488                         scm_cv_struct_timespec="yes",
 489                         scm_cv_struct_timespec="no"))
 490 AC_MSG_RESULT($scm_cv_struct_timespec)
 491 if test $scm_cv_struct_timespec = yes; then
 492         AC_DEFINE(HAVE_STRUCT_TIMESPEC)
 493 fi
 494
 495 #--------------------------------------------------------------------
 496 #
 497 # Flags for thread support
 498 #
 499 #--------------------------------------------------------------------
 500
 501 ### What thread package has the user asked for?
 502 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 503             , with_threads=no)
 504
 505 ### Turn $with_threads into either the name of a threads package, like
 506 ### `qt', or `no', meaning that threads should not be supported.
 507 AC_MSG_CHECKING(whether to support threads)
 508 case "$with_threads" in
 509   "yes" | "qt" | "coop" | "")
 510     with_threads=qt
 511   ;;
 512   "no" )
 513   ;;
 514   * )
 515     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 516   ;;
 517 esac
 518 AC_MSG_RESULT($with_threads)
 519
 520 ## Make sure the threads package we've chosen is actually supported on
 521 ## the present platform.
 522 case "${with_threads}" in
 523   "qt" )
 524     ## This configures the QuickThreads package, and sets or clears
 525     ## the THREAD_PACKAGE variable if qthreads don't configure
 526     ## correctly.
 527     QTHREADS_CONFIGURE
 528    ;;
 529 esac
 530
 531 ## If we're using threads, bring in some other parts of Guile which
 532 ## work with them.
 533 if test "${THREAD_PACKAGE}" != "" ; then
 534   AC_DEFINE(USE_THREADS, 1)
 535
 536   ## Include the Guile thread interface in the library...
 537   LIBOBJS="$LIBOBJS threads.o"
 538
 539   ## ... and tell it which package to talk to.
 540   case "${THREAD_PACKAGE}" in
 541     "QT" )
 542       AC_DEFINE(USE_COOP_THREADS, 1)
 543     ;;
 544     * )
 545       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 546     ;;
 547   esac
 548
 549   ## Bring in scm_internal_select, if appropriate.
 550   if test $ac_cv_func_gettimeofday = yes &&
 551      test $ac_cv_func_select = yes; then
 552     AC_DEFINE(GUILE_ISELECT, 1)
 553   fi
 554
 555   ## Workaround for linuxthreads (currently disabled)
 556   if test $host_os = linux-gnu; then
 557     AC_DEFINE(GUILE_PTHREAD_COMPAT, 1)
 558     AC_CHECK_LIB(pthread, main)
 559   fi
 560 fi
 561 AC_SUBST(LIBGUILEQTHREADS_MAJOR_VERSION)
 562 AC_SUBST(LIBGUILEQTHREADS_MINOR_VERSION)
 563 AC_SUBST(LIBGUILEQTHREADS_REVISION_VERSION)
 564 AC_SUBST(LIBGUILEQTHREADS_VERSION)
 565
 566 ## If we're using GCC, ask for aggressive warnings.
 567 case "$GCC" in
 568   yes )
 569     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 570     ## much stuff with generic function pointers for that to really be
 571     ## less than exasperating.
 572     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 573     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 574     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 575 esac
 576
 577 AC_PROG_AWK
 578
 579 ## If we're creating a shared library (using libtool!), then we'll
 580 ## need to generate a list of .lo files corresponding to the .o files
 581 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 582 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 583
 584 ## We also need to create corresponding .doc and .x files
 585 EXTRA_DOT_DOC_FILES="`echo ${LIBOBJS} | sed 's/\.o/.doc/g'`"
 586 EXTRA_DOT_X_FILES="`echo ${LIBOBJS} | sed 's/\.o/.x/g'`"
 587
 588 AC_SUBST(GUILE_MAJOR_VERSION)
 589 AC_SUBST(GUILE_MINOR_VERSION)
 590 AC_SUBST(GUILE_MICRO_VERSION)
 591 AC_SUBST(GUILE_VERSION)
 592 AC_SUBST(LIBGUILE_MAJOR_VERSION)
 593 AC_SUBST(LIBGUILE_MINOR_VERSION)
 594 AC_SUBST(LIBGUILE_REVISION_VERSION)
 595 AC_SUBST(LIBGUILE_VERSION)
 596
 597 dnl Tell guile-config what flags guile users should link against.
 598 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 599 AC_SUBST(GUILE_LIBS)
 600
 601 AC_SUBST(AWK)
 602 AC_SUBST(LIBLOBJS)
 603 AC_SUBST(EXTRA_DOT_DOC_FILES)
 604 AC_SUBST(EXTRA_DOT_X_FILES)
 605
 606 AC_OUTPUT([Makefile
 607            libguile/Makefile
 608            libguile/guile-snarf
 609            libguile/guile-doc-snarf
 610            libguile/guile-func-name-check
 611            libguile/guile-snarf.awk
 612            libguile/versiondat.h
 613            ice-9/Makefile
 614            oop/Makefile
 615            oop/goops/Makefile
 616            scripts/Makefile
 617            srfi/Makefile
 618            qt/Makefile
 619            qt/qt.h
 620            qt/md/Makefile
 621            qt/time/Makefile
 622            guile-config/Makefile
 623            doc/Makefile
 624            check-guile
 625            guile-tools],
 626           [chmod +x libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check check-guile guile-tools])
 627
 628 dnl Local Variables:
 629 dnl comment-start: "dnl "
 630 dnl comment-end: ""
 631 dnl comment-start-skip: "\\bdnl\\b\\s *"
 632 dnl End: