module/ice-9/i18n.scm

   1 ;;;; i18n.scm --- internationalization support
   2
   3 ;;;;    Copyright (C) 2006, 2007 Free Software Foundation, Inc.
   4 ;;;;
   5 ;;;; This library is free software; you can redistribute it and/or
   6 ;;;; modify it under the terms of the GNU Lesser General Public
   7 ;;;; License as published by the Free Software Foundation; either
   8 ;;;; version 2.1 of the License, or (at your option) any later version.
   9 ;;;;
  10 ;;;; This library is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 ;;;; Lesser General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU Lesser General Public
  16 ;;;; License along with this library; if not, write to the Free Software
  17 ;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  18
  19 ;;; Author: Ludovic Courtès <ludovic.courtes@laas.fr>
  20
  21 ;;; Commentary:
  22 ;;;
  23 ;;; This module provides a number of routines that support
  24 ;;; internationalization (e.g., locale-dependent text collation, character
  25 ;;; mapping, etc.).  It also defines `locale' objects, representing locale
  26 ;;; settings, that may be passed around to most of these procedures.
  27 ;;;
  28
  29 ;;; Code:
  30
  31 (define-module (ice-9 i18n)
  32   :use-module (ice-9 optargs)
  33   :export (;; `locale' type
  34            make-locale locale?
  35            %global-locale
  36
  37            ;; text collation
  38            string-locale<? string-locale>?
  39            string-locale-ci<? string-locale-ci>? string-locale-ci=?
  40
  41            char-locale<? char-locale>?
  42            char-locale-ci<? char-locale-ci>? char-locale-ci=?
  43
  44            ;; character mapping
  45            char-locale-downcase char-locale-upcase
  46            string-locale-downcase string-locale-upcase
  47
  48            ;; reading numbers
  49            locale-string->integer locale-string->inexact
  50
  51            ;; charset/encoding
  52            locale-encoding
  53
  54            ;; days and months
  55            locale-day-short locale-day locale-month-short locale-month
  56
  57            ;; date and time
  58            locale-am-string locale-pm-string
  59            locale-date+time-format locale-date-format locale-time-format
  60            locale-time+am/pm-format
  61            locale-era locale-era-year
  62            locale-era-date-format locale-era-date+time-format
  63            locale-era-time-format
  64
  65            ;; monetary
  66            locale-currency-symbol
  67            locale-monetary-decimal-point locale-monetary-thousands-separator
  68            locale-monetary-grouping locale-monetary-fractional-digits
  69            locale-currency-symbol-precedes-positive?
  70            locale-currency-symbol-precedes-negative?
  71            locale-positive-separated-by-space?
  72            locale-negative-separated-by-space?
  73            locale-monetary-positive-sign locale-monetary-negative-sign
  74            locale-positive-sign-position locale-negative-sign-position
  75            monetary-amount->locale-string
  76
  77            ;; number formatting
  78            locale-digit-grouping locale-decimal-point
  79            locale-thousands-separator
  80            number->locale-string
  81
  82            ;; miscellaneous
  83            locale-yes-regexp locale-no-regexp))
  84
  85
  86 (eval-when (eval load compile)
  87   (load-extension "libguile-i18n-v-0" "scm_init_i18n"))
  88
  89 \f
  90 ;;;
  91 ;;; Charset/encoding.
  92 ;;;
  93
  94 (define (locale-encoding . locale)
  95   (apply nl-langinfo CODESET locale))
  96
  97 \f
  98 ;;;
  99 ;;; Months and days.
 100 ;;;
 101
 102 ;; Helper macro: Define a procedure named NAME that maps its argument to
 103 ;; NL-ITEMS (when `nl-langinfo' is provided) or DEFAULTS (when `nl-langinfo'
 104 ;; is not provided).
 105 (define-macro (define-vector-langinfo-mapping name nl-items defaults)
 106   (let* ((item-count (length nl-items))
 107          (defines    (if (provided? 'nl-langinfo)
 108                          `(define %nl-items (vector #f ,@nl-items))
 109                          `(define %defaults (vector #f ,@defaults))))
 110          (make-body (lambda (result)
 111                       `(if (and (integer? item) (exact? item))
 112                            (if (and (>= item 1) (<= item ,item-count))
 113                                ,result
 114                                (throw 'out-of-range "out of range" item))
 115                            (throw 'wrong-type-arg "wrong argument type" item)))))
 116     `(define (,name item . locale)
 117        ,defines
 118        ,(make-body (if (provided? 'nl-langinfo)
 119                        '(apply nl-langinfo (vector-ref %nl-items item) locale)
 120                        '(vector-ref %defaults item))))))
 121
 122
 123 (define-vector-langinfo-mapping locale-day-short
 124   (ABDAY_1 ABDAY_2 ABDAY_3 ABDAY_4 ABDAY_5 ABDAY_6 ABDAY_7)
 125   ("Sun" "Mon" "Tue" "Wed" "Thu" "Fri" "Sat"))
 126
 127 (define-vector-langinfo-mapping locale-day
 128   (DAY_1 DAY_2 DAY_3 DAY_4 DAY_5 DAY_6 DAY_7)
 129   ("Sunday" "Monday" "Tuesday" "Wednesday" "Thursday" "Friday" "Saturday"))
 130
 131 (define-vector-langinfo-mapping locale-month-short
 132   (ABMON_1 ABMON_2 ABMON_3 ABMON_4 ABMON_5 ABMON_6
 133    ABMON_7 ABMON_8 ABMON_9 ABMON_10 ABMON_11 ABMON_12)
 134   ("Jan" "Feb" "Mar" "Apr" "May" "Jun" "Jul" "Aug" "Sep" "Oct" "Nov" "Dec"))
 135
 136 (define-vector-langinfo-mapping locale-month
 137   (MON_1 MON_2 MON_3 MON_4 MON_5 MON_6 MON_7 MON_8 MON_9 MON_10 MON_11 MON_12)
 138   ("January" "February" "March" "April" "May" "June" "July" "August"
 139    "September" "October" "November" "December"))
 140
 141
 142 \f
 143 ;;;
 144 ;;; Date and time.
 145 ;;;
 146
 147 ;; Helper macro: Define a procedure NAME that gets langinfo item ITEM.
 148 (define-macro (define-simple-langinfo-mapping name item default)
 149   (let ((body (if (and (provided? 'nl-langinfo) (defined? item))
 150                   `(apply nl-langinfo ,item locale)
 151                   default)))
 152     `(define (,name . locale)
 153        ,body)))
 154
 155 (define-simple-langinfo-mapping locale-am-string
 156   AM_STR "AM")
 157 (define-simple-langinfo-mapping locale-pm-string
 158   PM_STR "PM")
 159 (define-simple-langinfo-mapping locale-date+time-format
 160   D_T_FMT "%a %b %e %H:%M:%S %Y")
 161 (define-simple-langinfo-mapping locale-date-format
 162   D_FMT   "%m/%d/%y")
 163 (define-simple-langinfo-mapping locale-time-format
 164   T_FMT   "%H:%M:%S")
 165 (define-simple-langinfo-mapping locale-time+am/pm-format
 166   T_FMT_AMPM "%I:%M:%S %p")
 167 (define-simple-langinfo-mapping locale-era
 168   ERA        "")
 169 (define-simple-langinfo-mapping locale-era-year
 170   ERA_YEAR   "")
 171 (define-simple-langinfo-mapping locale-era-date+time-format
 172   ERA_D_T_FMT "")
 173 (define-simple-langinfo-mapping locale-era-date-format
 174   ERA_D_FMT   "")
 175 (define-simple-langinfo-mapping locale-era-time-format
 176   ERA_T_FMT   "")
 177
 178
 179 \f
 180 ;;;
 181 ;;; Monetary information.
 182 ;;;
 183
 184 (define-macro (define-monetary-langinfo-mapping name local-item intl-item
 185                                                 default/local default/intl)
 186   (let ((body
 187          (let ((intl  (if (and (provided? 'nl-langinfo) (defined? intl-item))
 188                           `(apply nl-langinfo ,intl-item locale)
 189                           default/intl))
 190                (local (if (and (provided? 'nl-langinfo) (defined? local-item))
 191                           `(apply nl-langinfo ,local-item locale)
 192                           default/local)))
 193            `(if intl? ,intl ,local))))
 194
 195     `(define (,name intl? . locale)
 196        ,body)))
 197
 198 ;; FIXME: How can we use ALT_DIGITS?
 199 (define-monetary-langinfo-mapping locale-currency-symbol
 200   CRNCYSTR           INT_CURR_SYMBOL
 201   "-"                "")
 202 (define-monetary-langinfo-mapping locale-monetary-fractional-digits
 203   FRAC_DIGITS        INT_FRAC_DIGITS
 204   2                  2)
 205
 206 (define-simple-langinfo-mapping locale-monetary-positive-sign
 207   POSITIVE_SIGN        "+")
 208 (define-simple-langinfo-mapping locale-monetary-negative-sign
 209   NEGATIVE_SIGN        "-")
 210 (define-simple-langinfo-mapping locale-monetary-decimal-point
 211   MON_DECIMAL_POINT    "")
 212 (define-simple-langinfo-mapping locale-monetary-thousands-separator
 213   MON_THOUSANDS_SEP    "")
 214 (define-simple-langinfo-mapping locale-monetary-digit-grouping
 215   MON_GROUPING         '())
 216
 217 (define-monetary-langinfo-mapping locale-currency-symbol-precedes-positive?
 218   P_CS_PRECEDES       INT_P_CS_PRECEDES
 219   #t                  #t)
 220 (define-monetary-langinfo-mapping locale-currency-symbol-precedes-negative?
 221   N_CS_PRECEDES       INT_N_CS_PRECEDES
 222   #t                  #t)
 223
 224
 225 (define-monetary-langinfo-mapping locale-positive-separated-by-space?
 226   ;; Whether a space should be inserted between a positive amount and the
 227   ;; currency symbol.
 228   P_SEP_BY_SPACE      INT_P_SEP_BY_SPACE
 229   #t                  #t)
 230 (define-monetary-langinfo-mapping locale-negative-separated-by-space?
 231   ;; Whether a space should be inserted between a negative amount and the
 232   ;; currency symbol.
 233   N_SEP_BY_SPACE      INT_N_SEP_BY_SPACE
 234   #t                  #t)
 235
 236 (define-monetary-langinfo-mapping locale-positive-sign-position
 237   ;; Position of the positive sign wrt. currency symbol and quantity in a
 238   ;; monetary amount.
 239   P_SIGN_POSN         INT_P_SIGN_POSN
 240   'unspecified        'unspecified)
 241 (define-monetary-langinfo-mapping locale-negative-sign-position
 242   ;; Position of the negative sign wrt. currency symbol and quantity in a
 243   ;; monetary amount.
 244   N_SIGN_POSN         INT_N_SIGN_POSN
 245   'unspecified        'unspecified)
 246
 247
 248 (define (%number-integer-part int grouping separator)
 249   ;; Process INT (a string denoting a number's integer part) and return a new
 250   ;; string with digit grouping and separators according to GROUPING (a list,
 251   ;; potentially circular) and SEPARATOR (a string).
 252
 253   ;; Process INT from right to left.
 254   (let loop ((int      int)
 255              (grouping grouping)
 256              (result   '()))
 257     (cond ((string=? int "") (apply string-append result))
 258           ((null? grouping)  (apply string-append int result))
 259           (else
 260            (let* ((len (string-length int))
 261                   (cut (min (car grouping) len)))
 262              (loop (substring int 0 (- len cut))
 263                    (cdr grouping)
 264                    (let ((sub (substring int (- len cut) len)))
 265                      (if (> len cut)
 266                          (cons* separator sub result)
 267                          (cons sub result)))))))))
 268
 269 (define (add-monetary-sign+currency amount figure intl? locale)
 270   ;; Add a sign and currency symbol around FIGURE.  FIGURE should be a
 271   ;; formatted unsigned amount (a string) representing AMOUNT.
 272   (let* ((positive? (> amount 0))
 273          (sign
 274           (cond ((> amount 0) (locale-monetary-positive-sign locale))
 275                 ((< amount 0) (locale-monetary-negative-sign locale))
 276                 (else         "")))
 277          (currency (locale-currency-symbol intl? locale))
 278          (currency-precedes?
 279           (if positive?
 280               locale-currency-symbol-precedes-positive?
 281               locale-currency-symbol-precedes-negative?))
 282          (separated?
 283           (if positive?
 284               locale-positive-separated-by-space?
 285               locale-negative-separated-by-space?))
 286          (sign-position
 287           (if positive?
 288               locale-positive-sign-position
 289               locale-negative-sign-position))
 290          (currency-space
 291           (if (separated? intl? locale) " " ""))
 292          (append-currency
 293           (lambda (amt)
 294             (if (currency-precedes? intl? locale)
 295                 (string-append currency currency-space amt)
 296                 (string-append amt currency-space currency)))))
 297
 298     (case (sign-position intl? locale)
 299       ((parenthesize)
 300        (string-append "(" (append-currency figure) ")"))
 301       ((sign-before)
 302        (string-append sign (append-currency figure)))
 303       ((sign-after unspecified)
 304        ;; following glibc's recommendation for `unspecified'.
 305        (if (currency-precedes? intl? locale)
 306            (string-append currency currency-space sign figure)
 307            (string-append figure currency-space currency sign)))
 308       ((sign-before-currency-symbol)
 309        (if (currency-precedes? intl? locale)
 310            (string-append sign currency currency-space figure)
 311            (string-append figure currency-space sign currency))) ;; unlikely
 312       ((sign-after-currency-symbol)
 313        (if (currency-precedes? intl? locale)
 314            (string-append currency sign currency-space figure)
 315            (string-append figure currency-space currency sign)))
 316       (else
 317        (error "unsupported sign position" (sign-position intl? locale))))))
 318
 319
 320 (define* (monetary-amount->locale-string amount intl?
 321                                          #:optional (locale %global-locale))
 322   "Convert @var{amount} (an inexact) into a string according to the cultural
 323 conventions of either @var{locale} (a locale object) or the current locale.
 324 If @var{intl?} is true, then the international monetary format for the given
 325 locale is used."
 326
 327   (let* ((fraction-digits
 328           (or (locale-monetary-fractional-digits intl? locale) 2))
 329          (decimal-part
 330           (lambda (dec)
 331             (if (or (string=? dec "") (eq? 0 fraction-digits))
 332                 ""
 333                 (string-append (locale-monetary-decimal-point locale)
 334                                (if (< fraction-digits (string-length dec))
 335                                    (substring dec 0 fraction-digits)
 336                                    dec)))))
 337
 338          (external-repr (number->string (if (> amount 0) amount (- amount))))
 339          (int+dec   (string-split external-repr #\.))
 340          (int       (car int+dec))
 341          (dec       (decimal-part (if (null? (cdr int+dec))
 342                                       ""
 343                                       (cadr int+dec))))
 344          (grouping  (locale-monetary-digit-grouping locale))
 345          (separator (locale-monetary-thousands-separator locale)))
 346
 347       (add-monetary-sign+currency amount
 348                                   (string-append
 349                                    (%number-integer-part int grouping
 350                                                          separator)
 351                                    dec)
 352                                   intl? locale)))
 353
 354
 355 \f
 356 ;;;
 357 ;;; Number formatting.
 358 ;;;
 359
 360 (define-simple-langinfo-mapping locale-digit-grouping
 361   GROUPING             '())
 362 (define-simple-langinfo-mapping locale-decimal-point
 363   RADIXCHAR            ".")
 364 (define-simple-langinfo-mapping locale-thousands-separator
 365   THOUSEP              "")
 366
 367 (define* (number->locale-string number
 368                                 #:optional (fraction-digits #t)
 369                                            (locale %global-locale))
 370   "Convert @var{number} (an inexact) into a string according to the cultural
 371 conventions of either @var{locale} (a locale object) or the current locale.
 372 Optionally, @var{fraction-digits} may be bound to an integer specifying the
 373 number of fractional digits to be displayed."
 374
 375   (let* ((sign
 376           (cond ((> number 0) "")
 377                 ((< number 0) "-")
 378                 (else         "")))
 379          (decimal-part
 380           (lambda (dec)
 381             (if (or (string=? dec "") (eq? 0 fraction-digits))
 382                 ""
 383                 (string-append (locale-decimal-point locale)
 384                                (if (and (integer? fraction-digits)
 385                                         (< fraction-digits
 386                                            (string-length dec)))
 387                                    (substring dec 0 fraction-digits)
 388                                    dec))))))
 389
 390     (let* ((external-repr (number->string (if (> number 0)
 391                                               number
 392                                               (- number))))
 393            (int+dec   (string-split external-repr #\.))
 394            (int       (car int+dec))
 395            (dec       (decimal-part (if (null? (cdr int+dec))
 396                                         ""
 397                                         (cadr int+dec))))
 398            (grouping  (locale-digit-grouping locale))
 399            (separator (locale-thousands-separator locale)))
 400
 401       (string-append sign
 402                      (%number-integer-part int grouping separator)
 403                      dec))))
 404
 405 \f
 406 ;;;
 407 ;;; Miscellaneous.
 408 ;;;
 409
 410 (define-simple-langinfo-mapping locale-yes-regexp
 411   YESEXPR              "^[yY]")
 412 (define-simple-langinfo-mapping locale-no-regexp
 413   NOEXPR               "^[nN]")
 414
 415 ;; `YESSTR' and `NOSTR' are considered deprecated so we don't provide them.
 416
 417
 418 ;;; Local Variables:
 419 ;;; coding: latin-1
 420 ;;; End:
 421
 422 ;;; i18n.scm ends here