m4/inet_pton.m4

   1 # inet_pton.m4 serial 9
   2 dnl Copyright (C) 2006, 2008, 2009 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_INET_PTON],
   8 [
   9   dnl Persuade Solaris <arpa/inet.h> to declare inet_pton.
  10   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  11
  12   gl_REPLACE_ARPA_INET_H
  13
  14   dnl Most platforms that provide inet_pton define it in libc.
  15   dnl Solaris 8..10 provide inet_pton in libnsl instead.
  16   gl_save_LIBS=$LIBS
  17   AC_SEARCH_LIBS([inet_pton], [nsl], [],
  18     [AC_REPLACE_FUNCS([inet_pton])])
  19   LIBS=$gl_save_LIBS
  20   INET_PTON_LIB=
  21   if test "$ac_cv_search_inet_pton" != "no" &&
  22      test "$ac_cv_search_inet_pton" != "none required"; then
  23     INET_PTON_LIB="$ac_cv_search_inet_pton"
  24   fi
  25   AC_SUBST([INET_PTON_LIB])
  26
  27   gl_PREREQ_INET_PTON
  28 ])
  29
  30 # Prerequisites of lib/inet_pton.c.
  31 AC_DEFUN([gl_PREREQ_INET_PTON], [
  32   AC_CHECK_DECLS([inet_pton],,,[#include <arpa/inet.h>])
  33   if test $ac_cv_have_decl_inet_pton = no; then
  34     HAVE_DECL_INET_PTON=0
  35   fi
  36   AC_REQUIRE([gl_SOCKET_FAMILIES])
  37   AC_REQUIRE([AC_C_RESTRICT])
  38 ])