configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   8   2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   9
  10 This file is part of GUILE
  11
  12 GUILE is free software; you can redistribute it and/or modify it under
  13 the terms of the GNU Lesser General Public License as published by the
  14 Free Software Foundation; either version 3, or (at your option) any
  15 later version.
  16
  17 GUILE is distributed in the hope that it will be useful, but WITHOUT
  18 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  19 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  20 License for more details.
  21
  22 You should have received a copy of the GNU Lesser General Public
  23 License along with GUILE; see the file COPYING.LESSER.  If not, write
  24 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  25 Floor, Boston, MA 02110-1301, USA.
  26
  27 ]])
  28
  29 AC_PREREQ(2.61)
  30
  31 AC_INIT([GNU Guile],
  32         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  33         [bug-guile@gnu.org])
  34 AC_CONFIG_AUX_DIR([build-aux])
  35 AC_CONFIG_MACRO_DIR([m4])
  36 AC_CONFIG_SRCDIR(GUILE-VERSION)
  37
  38 dnl `AM_SUBST_NOTMAKE' was introduced in Automake 1.11.
  39 AM_INIT_AUTOMAKE([1.11 gnu no-define -Wall -Wno-override dist-xz])
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AC_SUBST([AM_DEFAULT_VERBOSITY],1)])
  41
  42 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  43 AC_CONFIG_SRCDIR([GUILE-VERSION])
  44
  45 . $srcdir/GUILE-VERSION
  46 GUILE_VERSION="$PACKAGE_VERSION"
  47
  48 AC_CONFIG_HEADERS([config.h])
  49 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  50
  51 #--------------------------------------------------------------------
  52
  53 AC_LANG([C])
  54
  55 dnl Some more checks for Win32
  56 AC_CANONICAL_HOST
  57
  58 AC_LIBTOOL_WIN32_DLL
  59
  60 AC_PROG_INSTALL
  61 AC_PROG_CC
  62 gl_EARLY
  63 AC_PROG_CPP
  64 AC_PROG_SED
  65 AC_PROG_AWK
  66 AC_PROG_LN_S
  67
  68 dnl Gnulib.
  69 gl_INIT
  70 dnl FIXME: remove me and the acinclude.m4 code when clock-gettime is
  71 dnl fixed for clock_getcpuclockid and can be imported normally from
  72 dnl gnulib.  See
  73 dnl <http://lists.gnu.org/archive/html/bug-gnulib/2011-06/msg00227.html>
  74 dnl for details.
  75 gl_CLOCK_TIME
  76
  77 AC_PROG_CC_C89
  78
  79 # for per-target cflags in the libguile subdir
  80 AM_PROG_CC_C_O
  81
  82 AC_LIBTOOL_DLOPEN
  83 AC_PROG_LIBTOOL
  84
  85 AM_CONDITIONAL([HAVE_SHARED_LIBRARIES], [test "x$enable_shared" = "xyes"])
  86
  87 AC_DEFINE_UNQUOTED([SHARED_LIBRARY_PATH_VARIABLE], ["$shlibpath_var"],
  88   [Name of the environment variable that tells the dynamic linker where
  89 to find shared libraries.])
  90
  91 dnl Check for libltdl.
  92 AC_LIB_HAVE_LINKFLAGS([ltdl], [], [#include <ltdl.h>],
  93   [lt_dlopenext ("foo");])
  94 if test "x$HAVE_LIBLTDL" != "xyes"; then
  95   AC_MSG_ERROR([GNU libltdl (Libtool) not found, see README.])
  96 fi
  97
  98 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  99 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
 100
 101 AM_PATH_LISPDIR
 102
 103 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
 104   [Define to the host's GNU triplet.])
 105
 106 #--------------------------------------------------------------------
 107 #
 108 # User options (after above tests that may set default CFLAGS etc.)
 109 #
 110 #--------------------------------------------------------------------
 111
 112 GUILE_ERROR_ON_WARNING="no"
 113
 114 AC_ARG_ENABLE(error-on-warning,
 115   [  --enable-error-on-warning    treat compile warnings as errors],
 116   [case "${enableval}" in
 117      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 118      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 119      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 120    esac])
 121
 122 AC_ARG_ENABLE(debug-malloc,
 123   [  --enable-debug-malloc   include malloc debugging code],
 124   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 125     AC_DEFINE([GUILE_DEBUG_MALLOC], 1,
 126       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 127   fi)
 128
 129 SCM_I_GSC_GUILE_DEBUG=0
 130 AC_ARG_ENABLE(guile-debug,
 131   [AS_HELP_STRING([--enable-guile-debug],
 132                   [include internal debugging functions])],
 133   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 134     SCM_I_GSC_GUILE_DEBUG=1
 135   fi)
 136
 137 AC_ARG_ENABLE(posix,
 138   [  --disable-posix         omit non-essential POSIX interfaces],,
 139   enable_posix=yes)
 140
 141 AC_ARG_ENABLE(networking,
 142   [  --disable-networking    omit networking interfaces],,
 143   enable_networking=yes)
 144
 145 AC_ARG_ENABLE(regex,
 146   [  --disable-regex         omit regular expression interfaces],,
 147   enable_regex=yes)
 148
 149 AC_ARG_ENABLE([deprecated],
 150   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 151
 152 if test "$enable_deprecated" = no; then
 153   SCM_I_GSC_ENABLE_DEPRECATED=0
 154   warn_default=no
 155 else
 156   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 157     warn_default=summary
 158   elif test "$enable_deprecated" = shutup; then
 159     warn_default=no
 160   else
 161     warn_default=$enable_deprecated
 162   fi
 163   SCM_I_GSC_ENABLE_DEPRECATED=1
 164 fi
 165 AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default",
 166 [Define this to control the default warning level for deprecated features.])
 167
 168 dnl  Added the following configure option in January 2008 following
 169 dnl  investigation of problems with "64" system and library calls on
 170 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 171 dnl  system has stat64, it will have all the other 64 APIs too; but on
 172 dnl  Darwin, stat64 is there but other APIs are missing.
 173 dnl
 174 dnl  It also appears, from the Darwin docs, that most system call APIs
 175 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 176 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 177 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 178 dnl
 179 dnl  A similar problem has been reported for HP-UX:
 180 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 181 dnl
 182 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 183 dnl  better than no Guile at all, we provide this option to suppress
 184 dnl  trying to use "64" calls.
 185 dnl
 186 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 187 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 188 dnl  missing out on that.  If so, someone can work on that in the future.
 189 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 190 dnl  wasn't building before.
 191 AC_MSG_CHECKING([whether to use system and library "64" calls])
 192 AC_ARG_WITH([64-calls],
 193   AS_HELP_STRING([--without-64-calls],
 194                  [don't attempt to use system and library calls with "64" in their names]),
 195   [use_64_calls=$withval],
 196   [use_64_calls=yes
 197    case $host in
 198      *-apple-darwin* )
 199        use_64_calls=no
 200        ;;
 201      powerpc-ibm-aix* )
 202        use_64_calls=no
 203        ;;
 204    esac])
 205 AC_MSG_RESULT($use_64_calls)
 206 case "$use_64_calls" in
 207   y* )
 208     AC_DEFINE([GUILE_USE_64_CALLS], 1,
 209       [Define to 1 in order to try to use "64" versions of system and library calls.])
 210     ;;
 211 esac
 212
 213 #--------------------------------------------------------------------
 214
 215 dnl Check for dynamic linking
 216
 217 use_modules=yes
 218 AC_ARG_WITH(modules,
 219 [  --with-modules[=FILES]  Add support for dynamic modules],
 220 use_modules="$withval")
 221 test -z "$use_modules" && use_modules=yes
 222 DLPREOPEN=
 223 if test "$use_modules" != no; then
 224   if test "$use_modules" = yes; then
 225     DLPREOPEN="-dlpreopen force"
 226   else
 227     DLPREOPEN="-export-dynamic"
 228     for module in $use_modules; do
 229       DLPREOPEN="$DLPREOPEN -dlopen $module"
 230     done
 231   fi
 232 fi
 233
 234 dnl files which are destined for separate modules.
 235
 236 if test "$use_modules" != no; then
 237    AC_LIBOBJ([dynl])
 238    AC_DEFINE([HAVE_MODULES], 1,
 239      [Define this if you want support for dynamically loaded modules in Guile.])
 240 fi
 241
 242 if test "$enable_posix" = yes; then
 243    AC_LIBOBJ([posix])
 244    AC_DEFINE([HAVE_POSIX], 1,
 245      [Define this if you want support for non-essential POSIX system calls in Guile.])
 246 fi
 247
 248 if test "$enable_networking" = yes; then
 249    AC_LIBOBJ([net_db])
 250    AC_LIBOBJ([socket])
 251    AC_DEFINE([HAVE_NETWORKING], 1,
 252      [Define this if you want support for networking in Guile.])
 253 fi
 254
 255 if test "$enable_debug_malloc" = yes; then
 256    AC_LIBOBJ([debug-malloc])
 257 fi
 258
 259 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 260
 261 AC_C_CONST
 262
 263 # "volatile" is used in a couple of tests below.
 264 AC_C_VOLATILE
 265
 266 AC_C_INLINE
 267 if test "$ac_cv_c_inline" != no; then
 268   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 269 else
 270   SCM_I_GSC_C_INLINE=NULL
 271 fi
 272 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 273
 274 AC_C_BIGENDIAN
 275
 276 AC_C_LABELS_AS_VALUES
 277
 278 AC_CHECK_SIZEOF(char)
 279 AC_CHECK_SIZEOF(unsigned char)
 280 AC_CHECK_SIZEOF(short)
 281 AC_CHECK_SIZEOF(unsigned short)
 282 AC_CHECK_SIZEOF(int)
 283 AC_CHECK_SIZEOF(unsigned int)
 284 AC_CHECK_SIZEOF(long)
 285 AC_CHECK_SIZEOF(unsigned long)
 286 AC_CHECK_SIZEOF(size_t)
 287 AC_CHECK_SIZEOF(long long)
 288 AC_CHECK_SIZEOF(unsigned long long)
 289 AC_CHECK_SIZEOF(__int64)
 290 AC_CHECK_SIZEOF(unsigned __int64)
 291 AC_CHECK_SIZEOF(void *)
 292 AC_CHECK_SIZEOF(intptr_t)
 293 AC_CHECK_SIZEOF(uintptr_t)
 294 AC_CHECK_SIZEOF(ptrdiff_t)
 295 AC_CHECK_SIZEOF(size_t)
 296 AC_CHECK_SIZEOF(off_t)
 297
 298 if test "$ac_cv_sizeof_long" -gt "$ac_cv_sizeof_void_p"; then
 299   AC_MSG_ERROR(long does not fit into a void*)
 300 fi
 301
 302 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 303   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 304 else
 305   SCM_I_GSC_T_PTRDIFF='"long"'
 306 fi
 307 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 308
 309 AC_CHECK_HEADERS([stdint.h])
 310 AC_CHECK_HEADERS([inttypes.h])
 311
 312 AC_CHECK_SIZEOF(intmax_t)
 313
 314 SCM_I_GSC_NEEDS_STDINT_H=0
 315 SCM_I_GSC_NEEDS_INTTYPES_H=0
 316
 317 ### intptr and uintptr (try not to use inttypes if we don't have to)
 318 if test "$ac_cv_header_inttypes_h" = yes; then
 319   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 320     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 321 #include <stdio.h>])
 322     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 323       SCM_I_GSC_NEEDS_INTTYPES_H=1
 324     fi
 325   fi
 326   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 327     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 328 #include <stdio.h>])
 329     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 330       SCM_I_GSC_NEEDS_INTTYPES_H=1
 331     fi
 332   fi
 333 fi
 334
 335 ### See what's provided by stdint.h
 336 if test "$ac_cv_header_stdint_h" = yes; then
 337    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 338    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 339    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 340    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 341    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 342    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 343    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 344    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 345    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 346    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 347    AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>])
 348    AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>])
 349 fi
 350
 351 # so we don't get confused by the cache (wish there was a better way
 352 # to check particular headers for the same type...)
 353
 354 unset ac_cv_type_int8_t
 355 unset ac_cv_type_uint8_t
 356 unset ac_cv_type_int16_t
 357 unset ac_cv_type_uint16_t
 358 unset ac_cv_type_int32_t
 359 unset ac_cv_type_uint32_t
 360 unset ac_cv_type_int64_t
 361 unset ac_cv_type_uint64_t
 362 unset ac_cv_type_intmax_t
 363 unset ac_cv_type_uintmax_t
 364
 365 ### See what's provided by inttypes.h
 366 if test "$ac_cv_header_inttypes_h" = yes; then
 367   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 368   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 369   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 370   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 371   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 372   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 373   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 374   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 375   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 376   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 377   AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>])
 378   AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>])
 379 fi
 380
 381 # Try hard to find definitions for some required scm_t_*int* types.
 382
 383 ### Required type scm_t_int8
 384 if test "$scm_stdint_has_int8"; then
 385   SCM_I_GSC_T_INT8='"int8_t"'
 386   SCM_I_GSC_NEEDS_STDINT_H=1
 387 elif test "$scm_inttypes_has_int8"; then
 388   SCM_I_GSC_T_INT8='"int8_t"'
 389   SCM_I_GSC_NEEDS_INTTYPES_H=1
 390 elif test "$ac_cv_sizeof_char" -eq 1; then
 391   SCM_I_GSC_T_INT8='"signed char"'
 392 else
 393   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 394 fi
 395 AC_SUBST([SCM_I_GSC_T_INT8])
 396
 397 ### Required type scm_t_uint8
 398 if test "$scm_stdint_has_uint8"; then
 399   SCM_I_GSC_T_UINT8='"uint8_t"'
 400   SCM_I_GSC_NEEDS_STDINT_H=1
 401 elif test "$scm_inttypes_has_uint8"; then
 402   SCM_I_GSC_T_UINT8='"uint8_t"'
 403   SCM_I_GSC_NEEDS_INTTYPES_H=1
 404 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 405   SCM_I_GSC_T_UINT8='"unsigned char"'
 406 else
 407   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 408 fi
 409 AC_SUBST([SCM_I_GSC_T_UINT8])
 410
 411 ### Required type scm_t_int16 (ANSI C says int or short might work)
 412 if test "$scm_stdint_has_int16"; then
 413   SCM_I_GSC_T_INT16='"int16_t"'
 414   SCM_I_GSC_NEEDS_STDINT_H=1
 415 elif test "$scm_inttypes_has_int16"; then
 416   SCM_I_GSC_T_INT16='"int16_t"'
 417   SCM_I_GSC_NEEDS_INTTYPES_H=1
 418 elif test "$ac_cv_sizeof_int" -eq 2; then
 419   SCM_I_GSC_T_INT16='"int"'
 420 elif test "$ac_cv_sizeof_short" -eq 2; then
 421   SCM_I_GSC_T_INT16='"short"'
 422 else
 423   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 424 fi
 425 AC_SUBST([SCM_I_GSC_T_INT16])
 426
 427 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 428 if test "$scm_stdint_has_uint16"; then
 429   SCM_I_GSC_T_UINT16='"uint16_t"'
 430   SCM_I_GSC_NEEDS_STDINT_H=1
 431 elif test "$scm_inttypes_has_uint16"; then
 432   SCM_I_GSC_T_UINT16='"uint16_t"'
 433   SCM_I_GSC_NEEDS_INTTYPES_H=1
 434 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 435   SCM_I_GSC_T_UINT16='"unsigned int"'
 436 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 437   SCM_I_GSC_T_UINT16='"unsigned short"'
 438 else
 439   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 440 fi
 441 AC_SUBST([SCM_I_GSC_T_UINT16])
 442
 443
 444 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 445 if test "$scm_stdint_has_int32"; then
 446   SCM_I_GSC_T_INT32='"int32_t"'
 447   SCM_I_GSC_NEEDS_STDINT_H=1
 448 elif test "$scm_inttypes_has_int32"; then
 449   SCM_I_GSC_T_INT32='"int32_t"'
 450   SCM_I_GSC_NEEDS_INTTYPES_H=1
 451 elif test "$ac_cv_sizeof_int" -eq 4; then
 452   SCM_I_GSC_T_INT32='"int"'
 453 elif test "$ac_cv_sizeof_long" -eq 4; then
 454   SCM_I_GSC_T_INT32='"long"'
 455 elif test "$ac_cv_sizeof_short" -eq 4; then
 456   SCM_I_GSC_T_INT32='"short"'
 457 else
 458   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 459 fi
 460 AC_SUBST([SCM_I_GSC_T_INT32])
 461
 462 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 463 if test "$scm_stdint_has_uint32"; then
 464   SCM_I_GSC_T_UINT32='"uint32_t"'
 465   SCM_I_GSC_NEEDS_STDINT_H=1
 466 elif test "$scm_inttypes_has_uint32"; then
 467   SCM_I_GSC_T_UINT32='"uint32_t"'
 468   SCM_I_GSC_NEEDS_INTTYPES_H=1
 469 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 470   SCM_I_GSC_T_UINT32='"unsigned int"'
 471 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 472   SCM_I_GSC_T_UINT32='"unsigned long"'
 473 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 474   SCM_I_GSC_T_UINT32='"unsigned short"'
 475 else
 476   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 477 fi
 478 AC_SUBST([SCM_I_GSC_T_UINT32])
 479
 480 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 481 ### Also try 'long long' and '__int64' if we have it.
 482 SCM_I_GSC_T_INT64=0
 483 if test "$scm_stdint_has_int64"; then
 484   SCM_I_GSC_T_INT64='"int64_t"'
 485   SCM_I_GSC_NEEDS_STDINT_H=1
 486 elif test "$scm_inttypes_has_int64"; then
 487   SCM_I_GSC_T_INT64='"int64_t"'
 488   SCM_I_GSC_NEEDS_INTTYPES_H=1
 489 elif test "$ac_cv_sizeof_int" -eq 8; then
 490   SCM_I_GSC_T_INT64='"int"'
 491 elif test "$ac_cv_sizeof_long" -eq 8; then
 492   SCM_I_GSC_T_INT64='"long"'
 493 elif test "$ac_cv_sizeof_short" -eq 8; then
 494   SCM_I_GSC_T_INT64='"short"'
 495 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 496   SCM_I_GSC_T_INT64='"long long"'
 497 elif test "$ac_cv_sizeof___int64" -eq 8; then
 498   SCM_I_GSC_T_INT64='"__int64"'
 499 else
 500   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 501 fi
 502 AC_SUBST([SCM_I_GSC_T_INT64])
 503
 504
 505 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 506 ### Also try 'long long' and '__int64' if we have it.
 507 SCM_I_GSC_T_UINT64=0
 508 if test "$scm_stdint_has_uint64"; then
 509   SCM_I_GSC_T_UINT64='"uint64_t"'
 510   SCM_I_GSC_NEEDS_STDINT_H=1
 511 elif test "$scm_inttypes_has_uint64"; then
 512   SCM_I_GSC_T_UINT64='"uint64_t"'
 513   SCM_I_GSC_NEEDS_INTTYPES_H=1
 514 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 515   SCM_I_GSC_T_UINT64='"unsigned int"'
 516 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 517   SCM_I_GSC_T_UINT64='"unsigned long"'
 518 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 519   SCM_I_GSC_T_UINT64='"unsigned short"'
 520 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 521   SCM_I_GSC_T_UINT64='"unsigned long long"'
 522 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 523   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 524 else
 525   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 526 fi
 527 AC_SUBST([SCM_I_GSC_T_UINT64])
 528
 529 ### Required type scm_t_intmax
 530 ###
 531 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 532 ### none of them is available, we use 'long'.
 533 ###
 534 SCM_I_GSC_T_INTMAX=0
 535 if test "$scm_stdint_has_intmax"; then
 536   SCM_I_GSC_T_INTMAX='"intmax_t"'
 537   SCM_I_GSC_NEEDS_STDINT_H=1
 538 elif test "$scm_inttypes_has_intmax"; then
 539   SCM_I_GSC_T_INTMAX='"intmax_t"'
 540   SCM_I_GSC_NEEDS_INTTYPES_H=1
 541 elif test "$ac_cv_sizeof___int64" -ne 0; then
 542   SCM_I_GSC_T_INTMAX='"__int64"'
 543 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 544   SCM_I_GSC_T_INTMAX='"long long"'
 545 else
 546   SCM_I_GSC_T_INTMAX='"long"'
 547 fi
 548 AC_SUBST([SCM_I_GSC_T_INTMAX])
 549
 550 ### Required type scm_t_uintmax
 551 ###
 552 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 553 ### this order.  When none of them is available, we use 'unsigned long'.
 554 ###
 555 SCM_I_GSC_T_UINTMAX=0
 556 if test "$scm_stdint_has_uintmax"; then
 557   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 558   SCM_I_GSC_NEEDS_STDINT_H=1
 559 elif test "$scm_inttypes_has_uintmax"; then
 560   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 561   SCM_I_GSC_NEEDS_INTTYPES_H=1
 562 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 563   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 564 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 565   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 566 else
 567   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 568 fi
 569 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 570
 571 ### Required type scm_t_intptr
 572 ###
 573 SCM_I_GSC_T_INTPTR=0
 574 if test "$scm_stdint_has_intptr"; then
 575   SCM_I_GSC_T_INTPTR='"intptr_t"'
 576   SCM_I_GSC_NEEDS_STDINT_H=1
 577 elif test "$scm_inttypes_has_intptr"; then
 578   SCM_I_GSC_T_INTPTR='"intptr_t"'
 579   SCM_I_GSC_NEEDS_INTTYPES_H=1
 580 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 581   SCM_I_GSC_T_INTPTR='"int"'
 582 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 583   SCM_I_GSC_T_INTPTR='"long"'
 584 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 585   SCM_I_GSC_T_INTPTR='"long long"'
 586 else
 587   AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.])
 588 fi
 589 AC_SUBST([SCM_I_GSC_T_INTPTR])
 590
 591 ### Required type scm_t_uintptr
 592 ###
 593 SCM_I_GSC_T_UINTPTR=0
 594 if test "$scm_stdint_has_uintptr"; then
 595   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 596   SCM_I_GSC_NEEDS_STDINT_H=1
 597 elif test "$scm_inttypes_has_uintptr"; then
 598   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 599   SCM_I_GSC_NEEDS_INTTYPES_H=1
 600 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 601   SCM_I_GSC_T_UINTPTR='"unsigned int"'
 602 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 603   SCM_I_GSC_T_UINTPTR='"unsigned long"'
 604 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 605   SCM_I_GSC_T_UINTPTR='"unsigned long long"'
 606 else
 607   AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.])
 608 fi
 609 AC_SUBST([SCM_I_GSC_T_UINTPTR])
 610
 611
 612 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 613 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 614
 615 AC_HEADER_STDC
 616 AC_HEADER_TIME
 617 AC_HEADER_SYS_WAIT
 618 AC_HEADER_DIRENT
 619
 620 # Reason for checking:
 621 #
 622 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 623 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 624 #
 625 AC_CHECK_MEMBER([struct dirent64.d_name],
 626   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 627   [ #ifndef _LARGEFILE64_SOURCE
 628     # define _LARGEFILE64_SOURCE
 629     #endif
 630
 631     /* Per Autoconf manual.  */
 632     #include <sys/types.h>
 633     #ifdef HAVE_DIRENT_H
 634     # include <dirent.h>
 635     #else
 636     # define dirent direct
 637     # ifdef HAVE_SYS_NDIR_H
 638     #  include <sys/ndir.h>
 639     # endif
 640     # ifdef HAVE_SYS_DIR_H
 641     #  include <sys/dir.h>
 642     # endif
 643     # ifdef HAVE_NDIR_H
 644     #  include <ndir.h>
 645     # endif
 646     #endif ])
 647 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 648
 649 # Reasons for testing:
 650 #   complex.h - new in C99
 651 #   fenv.h - available in C99, but not older systems
 652 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 653 #     this file instead of <fenv.h>
 654 #   process.h - mingw specific
 655 #   langinfo.h, nl_types.h - SuS v2
 656 #   sched.h - missing on MinGW
 657 #
 658 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h memory.h process.h string.h \
 659 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 660 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 661 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 662 direct.h langinfo.h nl_types.h machine/fpu.h poll.h sched.h])
 663
 664 # Reasons for testing:
 665 #   nl_item - lacking on Cygwin
 666 AC_CHECK_TYPES([nl_item], [], [],
 667   [[#ifdef HAVE_LANGINFO_H
 668     # include <langinfo.h>
 669     #endif
 670     #ifdef HAVE_NL_TYPES_H
 671     # include <nl_types.h>
 672     #endif]])
 673
 674 # "complex double" is new in C99, and "complex" is only a keyword if
 675 # <complex.h> is included
 676 AC_CHECK_TYPES(complex double,,,
 677 [#if HAVE_COMPLEX_H
 678 #include <complex.h>
 679 #endif])
 680
 681 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 682 # when testing.
 683 AC_CHECK_TYPE(socklen_t, ,
 684   [AC_DEFINE_UNQUOTED([socklen_t], int,
 685                       [Define to `int' if <sys/socket.h> does not define.])],
 686   [#if HAVE_SYS_TYPES_H
 687 #include <sys/types.h>
 688 #endif
 689 #include <sys/socket.h>
 690 ])
 691
 692 AC_CHECK_TYPES([struct ip_mreq], , , [#include <netinet/in.h>])
 693
 694 GUILE_HEADER_LIBC_WITH_UNISTD
 695
 696 AC_TYPE_GETGROUPS
 697 AC_TYPE_SIGNAL
 698 AC_TYPE_MODE_T
 699
 700 # On mingw -lm is empty, so this test is unnecessary, but it's
 701 # harmless so we don't hard-code to suppress it.
 702 #
 703 AC_CHECK_LIB(m, cos)
 704
 705 AC_CHECK_FUNCS(gethostbyname)
 706 if test $ac_cv_func_gethostbyname = no; then
 707     AC_CHECK_LIB(nsl, gethostbyname)
 708 fi
 709
 710 AC_CHECK_FUNCS(connect)
 711 if test $ac_cv_func_connect = no; then
 712     AC_CHECK_LIB(socket, connect)
 713 fi
 714
 715 dnl
 716 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 717 dnl
 718 EXTRA_DEFS=""
 719 case $host in
 720   *-*-mingw*)
 721     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 722       [Define if you have the <winsock2.h> header file.])])
 723     AC_CHECK_LIB(ws2_32, main)
 724     AC_LIBOBJ([win32-uname])
 725     if test "$enable_networking" = yes ; then
 726       AC_LIBOBJ([win32-socket])
 727     fi
 728     if test "$enable_shared" = yes ; then
 729       EXTRA_DEFS="-DSCM_IMPORT"
 730       AC_DEFINE([USE_DLL_IMPORT], 1,
 731         [Define if you need additional CPP macros on Win32 platforms.])
 732     fi
 733     ;;
 734 esac
 735 AC_SUBST(EXTRA_DEFS)
 736
 737 # Reasons for testing:
 738 #   crt_externs.h - Darwin specific
 739 #
 740 AC_CHECK_HEADERS([assert.h crt_externs.h])
 741
 742 # Reasons for testing:
 743 #   DINFINITY - OSF specific
 744 #   DQNAN - OSF specific
 745 #       (DINFINITY and DQNAN are actually global variables, not functions)
 746 #   chsize - an MS-DOS-ism, found in mingw
 747 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 748 #       for gcc to provide the "complex double" type but the system to not
 749 #       have functions like cexp and clog
 750 #   clog10 - not in mingw (though others like clog and csqrt are)
 751 #   fesetround - available in C99, but not older systems
 752 #   ftruncate - posix, but probably not older systems (current mingw
 753 #               has it as an inline for chsize)
 754 #   ioctl - not in mingw.
 755 #   gmtime_r - recent posix, not on old systems
 756 #   pipe - not in mingw
 757 #   _pipe - specific to mingw, taking 3 args
 758 #   poll - since posix 2001
 759 #   readdir_r - recent posix, not on old systems
 760 #   readdir64_r - not available on HP-UX 11.11
 761 #   stat64 - SuS largefile stuff, not on old systems
 762 #   sysconf - not on old systems
 763 #   truncate - not in mingw
 764 #   isblank - available as a GNU extension or in C99
 765 #   _NSGetEnviron - Darwin specific
 766 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 767 #   nl_langinfo - X/Open, not available on Windows.
 768 #   utimensat: posix.1-2008
 769 #   sched_getaffinity, sched_setaffinity: GNU extensions (glibc)
 770 #
 771 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid getsid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe poll readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo utimensat sched_getaffinity sched_setaffinity])
 772
 773 # Reasons for testing:
 774 #   netdb.h - not in mingw
 775 #   sys/param.h - not in mingw
 776 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 777 #       check this specifically, we need it for the timespec test below.
 778 #   pthread_np.h - available on FreeBSD
 779 #   sethostname - the function itself check because it's not in mingw,
 780 #       the DECL is checked because Solaris 10 doens't have in any header
 781 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 782 #       declaration isn't anywhere.
 783 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 784 #       only with `_XOPEN_SOURCE' or some such.
 785 #
 786 AC_CHECK_HEADERS([crypt.h netdb.h pthread.h pthread_np.h sys/param.h sys/resource.h sys/file.h sys/mman.h])
 787 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 788 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 789
 790 # crypt() may or may not be available, for instance in some countries there
 791 # are restrictions on cryptography.
 792 #
 793 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 794 # -lcrypt library (eg. Debian GNU/Linux).
 795 #
 796 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 797 # be careful to avoid -lcrypt in this case, since libtool will see there's
 798 # only a static libcrypt and decide to build only a static libguile.
 799 #
 800 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 801 # libraries already in that list.
 802 #
 803 AC_SEARCH_LIBS(crypt, crypt,
 804   [AC_DEFINE([HAVE_CRYPT],1,
 805              [Define to 1 if you have the `crypt' function.])])
 806
 807 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 808 # work; in the reported cases so far, 1.0fi works well instead.  According
 809 # to the C99 spec, the complex.h header must provide a working definition
 810 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 811 # is a workaround for the failure of some systems to conform to C99.
 812 if test "$ac_cv_type_complex_double" = yes; then
 813   AC_MSG_CHECKING([for i])
 814   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 815 #if HAVE_COMPLEX_H
 816 #include <complex.h>
 817 #endif
 818 complex double z;
 819 ]], [[
 820 z = _Complex_I;
 821 ]])],
 822     [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).])
 823      AC_MSG_RESULT([_Complex_I])],
 824     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 825 #if HAVE_COMPLEX_H
 826 #include <complex.h>
 827 #endif
 828 complex double z;
 829 ]],[[
 830 z = 1.0fi;
 831 ]])],
 832   [AC_DEFINE([GUILE_I],1.0fi)
 833    AC_MSG_RESULT([1.0fi])],
 834   [ac_cv_type_complex_double=no
 835    AC_MSG_RESULT([not available])])])
 836 fi
 837
 838 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 839 # csqrt(-i) returned a negative real part, when it should be positive
 840 # for the principal root.
 841 #
 842 if test "$ac_cv_type_complex_double" = yes; then
 843
 844   AC_CACHE_CHECK([whether csqrt is usable],
 845     guile_cv_use_csqrt,
 846     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 847 #include <complex.h>
 848 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 849    constant, we want to test libc. */
 850 volatile complex double z = - _Complex_I;
 851 int
 852 main (void)
 853 {
 854   z = csqrt (z);
 855   if (creal (z) > 0.0)
 856     return 0;  /* good */
 857   else
 858     return 1;  /* bad */
 859 }]])],
 860     [guile_cv_use_csqrt=yes],
 861     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 862     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 863   case $guile_cv_use_csqrt in
 864     yes*)
 865       AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free])
 866       ;;
 867   esac
 868 fi
 869
 870 AC_CACHE_SAVE
 871
 872 dnl GMP tests
 873 AC_LIB_HAVE_LINKFLAGS([gmp],
 874   [],
 875   [#include <gmp.h>],
 876   [mpz_import (0, 0, 0, 0, 0, 0, 0);])
 877
 878 if test "x$HAVE_LIBGMP" != "xyes"; then
 879   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README])
 880 fi
 881
 882 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 883 if test "x$LTLIBUNISTRING" = "x"; then
 884   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 885 fi
 886
 887 GUILE_LIBUNISTRING_WITH_ICONV_SUPPORT
 888 if test "x$ac_cv_libunistring_with_iconv_support" != "xyes"; then
 889   AC_MSG_ERROR([No iconv support.  Please recompile libunistring with iconv enabled.])
 890 fi
 891
 892 dnl Libffi is needed to compile Guile's foreign function interface, but its
 893 dnl interface isn't exposed in Guile's API.
 894 PKG_CHECK_MODULES(LIBFFI, libffi)
 895 AC_SUBST(LIBFFI_CFLAGS)
 896 AC_SUBST(LIBFFI_LIBS)
 897
 898 dnl figure out approriate ffi type for size_t
 899 AC_CHECK_SIZEOF(size_t)
 900 AC_CHECK_SIZEOF(ssize_t)
 901 ffi_size_type=uint$(($ac_cv_sizeof_size_t*8))
 902 ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8))
 903 AC_DEFINE_UNQUOTED([ffi_type_size_t], ffi_type_${ffi_size_type},
 904                    [ffi type for size_t])
 905 AC_DEFINE_UNQUOTED([ffi_type_ssize_t], ffi_type_${ffi_ssize_type},
 906                    [ffi type for ssize_t])
 907
 908 dnl i18n tests
 909 #AC_CHECK_HEADERS([libintl.h])
 910 #AC_CHECK_FUNCS(gettext)
 911 #if test $ac_cv_func_gettext = no; then
 912 #   AC_CHECK_LIB(intl, gettext)
 913 #fi
 914 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 915 AM_GNU_GETTEXT([external], [need-ngettext])
 916
 917 ### Some systems don't declare some functions.  On such systems, we
 918 ### need to at least provide our own K&R-style declarations.
 919
 920 ### GUILE_FUNC_DECLARED(function, headerfile)
 921
 922 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 923 ### not there, #define MISSING_FUNCTION_DECL.
 924 AC_DEFUN([GUILE_FUNC_DECLARED], [
 925   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 926     AC_EGREP_HEADER($1, $2,
 927                     guile_cv_func_$1_declared=yes,
 928                     guile_cv_func_$1_declared=no))
 929   if test [x$guile_cv_func_]$1[_declared] = xno; then
 930     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 931       [Define if the operating system supplies $1 without declaring it.])
 932   fi
 933 ])
 934
 935 GUILE_FUNC_DECLARED(sleep, unistd.h)
 936 GUILE_FUNC_DECLARED(usleep, unistd.h)
 937
 938 AC_CHECK_DECLS([strptime],,,
 939 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 940 #include <time.h>])
 941
 942 ### On some systems usleep has no return value.  If it does have one,
 943 ### we'd like to return it; otherwise, we'll fake it.
 944 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 945   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 946                    unistd.h,
 947                    [guile_cv_func_usleep_return_type=void],
 948                    [guile_cv_func_usleep_return_type=int])])
 949 case "$guile_cv_func_usleep_return_type" in
 950   "void" )
 951     AC_DEFINE([USLEEP_RETURNS_VOID], 1,
 952       [Define if the system headers declare usleep to return void.])
 953   ;;
 954 esac
 955
 956 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 957 if test -n "$have_sys_un_h" ; then
 958   AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1,
 959     [Define if the system supports Unix-domain (file-domain) sockets.])
 960 fi
 961
 962 AC_CHECK_FUNCS(getrlimit setrlimit)
 963
 964 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 965
 966 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 967                setnetent    getnetent    endnetent    dnl
 968                setprotoent  getprotoent  endprotoent  dnl
 969                setservent   getservent   endservent   dnl
 970                getnetbyaddr getnetbyname dnl
 971                inet_lnaof inet_makeaddr inet_netof hstrerror)
 972
 973 AC_CHECK_MEMBERS([struct sockaddr_in.sin_len],,,
 974 [#ifdef HAVE_SYS_TYPES_H
 975 #include <sys/types.h>
 976 #endif
 977 #include <netinet/in.h>])
 978
 979 AC_MSG_CHECKING(for __libc_stack_end)
 980 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 981 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 982 extern char *__libc_stack_end;]],
 983    [[printf("%p", (char*) __libc_stack_end);]])],
 984    [guile_cv_have_libc_stack_end=yes],
 985    [guile_cv_have_libc_stack_end=no])])
 986 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 987
 988 if test $guile_cv_have_libc_stack_end = yes; then
 989   AC_DEFINE([HAVE_LIBC_STACK_END], 1,
 990            [Define if you have the __libc_stack_end variable.])
 991 fi
 992
 993 dnl Some systems do not declare this.  Some systems do declare it, as a
 994 dnl macro.  With cygwin it may be in a DLL.
 995
 996 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 997 AC_CACHE_VAL(guile_cv_have_h_errno,
 998   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 999                                       [[int a = h_errno;]])],
1000   [guile_cv_have_h_errno=yes],
1001   [guile_cv_have_h_errno=no])])
1002 AC_MSG_RESULT($guile_cv_have_h_errno)
1003 if test $guile_cv_have_h_errno = yes; then
1004   AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.])
1005 fi
1006
1007 AC_MSG_CHECKING(whether uint32_t is defined)
1008 AC_CACHE_VAL(guile_cv_have_uint32_t,
1009   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1010                    #if HAVE_STDINT_H
1011                    #include <stdint.h>
1012                    #endif
1013                    #ifndef HAVE_NETDB_H
1014                    #include <netdb.h>
1015                    #endif]],
1016                    [[uint32_t a;]])],
1017                    [guile_cv_have_uint32_t=yes],
1018                    [guile_cv_have_uint32_t=no])])
1019 AC_MSG_RESULT($guile_cv_have_uint32_t)
1020 if test $guile_cv_have_uint32_t = yes; then
1021   AC_DEFINE([HAVE_UINT32_T], 1,
1022     [Define if uint32_t typedef is defined when netdb.h is include.])
1023 fi
1024
1025 AC_MSG_CHECKING(for working IPv6 support)
1026 AC_CACHE_VAL(guile_cv_have_ipv6,
1027 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1028 #ifdef HAVE_SYS_TYPES_H
1029 #include <sys/types.h>
1030 #endif
1031 #include <netinet/in.h>
1032 #include <sys/socket.h>]],
1033 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
1034 [guile_cv_have_ipv6=yes],
1035 [guile_cv_have_ipv6=no])])
1036 AC_MSG_RESULT($guile_cv_have_ipv6)
1037 if test $guile_cv_have_ipv6 = yes; then
1038   AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.])
1039 fi
1040
1041 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
1042 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
1043 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
1044 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1045 #ifdef HAVE_SYS_TYPES_H
1046 #include <sys/types.h>
1047 #endif
1048 #include <netinet/in.h>]],
1049 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
1050 [guile_cv_have_sin6_scope_id=yes],
1051 [guile_cv_have_sin6_scope_id=no])])
1052 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
1053 if test $guile_cv_have_sin6_scope_id = yes; then
1054   AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1,
1055     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
1056 fi
1057
1058 # struct sockaddr_in6 field sin_len is only present on BSD systems
1059 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1060 [#ifdef HAVE_SYS_TYPES_H
1061 #include <sys/types.h>
1062 #endif
1063 #include <netinet/in.h>])
1064
1065 AC_MSG_CHECKING(whether localtime caches TZ)
1066 AC_CACHE_VAL(guile_cv_localtime_cache,
1067 [if test x$ac_cv_func_tzset = xyes; then
1068 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1069 #if STDC_HEADERS
1070 # include <stdlib.h>
1071 #endif
1072 extern char **environ;
1073 unset_TZ ()
1074 {
1075   char **from, **to;
1076   for (to = from = environ; (*to = *from); from++)
1077     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1078       to++;
1079 }
1080 char TZ_GMT0[] = "TZ=GMT0";
1081 char TZ_PST8[] = "TZ=PST8";
1082 main()
1083 {
1084   time_t now = time ((time_t *) 0);
1085   int hour_GMT0, hour_unset;
1086   if (putenv (TZ_GMT0) != 0)
1087     exit (1);
1088   hour_GMT0 = localtime (&now)->tm_hour;
1089   unset_TZ ();
1090   hour_unset = localtime (&now)->tm_hour;
1091   if (putenv (TZ_PST8) != 0)
1092     exit (1);
1093   if (localtime (&now)->tm_hour == hour_GMT0)
1094     exit (1);
1095   unset_TZ ();
1096   if (localtime (&now)->tm_hour != hour_unset)
1097     exit (1);
1098   exit (0);
1099 }]])],
1100 [guile_cv_localtime_cache=no],
1101 [guile_cv_localtime_cache=yes],
1102 [# If we have tzset, assume the worst when cross-compiling.
1103 guile_cv_localtime_cache=yes])
1104 else
1105         # If we lack tzset, report that localtime does not cache TZ,
1106         # since we can't invalidate the cache if we don't have tzset.
1107         guile_cv_localtime_cache=no
1108 fi])dnl
1109 AC_MSG_RESULT($guile_cv_localtime_cache)
1110 if test $guile_cv_localtime_cache = yes; then
1111   AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.])
1112 fi
1113
1114 if test "$enable_regex" = yes; then
1115    if test "$ac_cv_header_regex_h" = yes ||
1116       test "$ac_cv_header_rxposix_h" = yes ||
1117       test "$ac_cv_header_rx_rxposix_h" = yes; then
1118      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1119      [AC_CHECK_LIB(rx, main)
1120       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1121      [AC_CHECK_LIB(regex, main)
1122       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1123      )
1124      dnl The following should not be necessary, but for some reason
1125      dnl autoheader misses it if we don't include it!
1126      if test "$ac_cv_func_regcomp_norx" = yes ||
1127         test "$ac_cv_func_regcomp_regex" = yes ||
1128         test "$ac_cv_func_regcomp_rx" = yes; then
1129        AC_DEFINE([HAVE_REGCOMP], 1,
1130          [This is included as part of a workaround for a autoheader bug.])
1131      fi
1132    fi
1133 fi
1134
1135 AC_REPLACE_FUNCS([strerror memmove mkstemp])
1136
1137 # Reasons for testing:
1138 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1139 #                                older systems
1140 #   sincos - GLIBC extension
1141 #
1142 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1143
1144 # C99 specifies isinf and isnan as macros.
1145 # HP-UX provides only macros, no functions.
1146 # glibc 2.3.2 provides both macros and functions.
1147 # IRIX 6.5 and Solaris 8 only provide functions.
1148 #
1149 # The following tests detect isinf and isnan either as functions or as
1150 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1151 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1152 #
1153 AC_MSG_CHECKING([for isinf])
1154 AC_LINK_IFELSE([AC_LANG_SOURCE(
1155 [[#include <math.h>
1156 volatile double x = 0.0;
1157 int main () { return (isinf(x) != 0); }]])],
1158   [AC_MSG_RESULT([yes])
1159    AC_DEFINE([HAVE_ISINF], 1,
1160              [Define to 1 if you have the `isinf' macro or function.])],
1161   [AC_MSG_RESULT([no])])
1162 AC_MSG_CHECKING([for isnan])
1163 AC_LINK_IFELSE([AC_LANG_SOURCE([[
1164 #include <math.h>
1165 volatile double x = 0.0;
1166 int main () { return (isnan(x) != 0); }]])],
1167   [AC_MSG_RESULT([yes])
1168    AC_DEFINE([HAVE_ISNAN], 1,
1169              [Define to 1 if you have the `isnan' macro or function.])],
1170   [AC_MSG_RESULT([no])])
1171
1172 # Reasons for checking:
1173 #
1174 #     st_rdev
1175 #     st_blksize
1176 #     st_blocks   not in mingw
1177 #     tm_gmtoff   BSD+GNU, not in C99
1178 #
1179 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1180 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1181 #
1182 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,,
1183                  [#define _GNU_SOURCE
1184 AC_INCLUDES_DEFAULT
1185 ])
1186
1187 AC_STRUCT_TIMEZONE
1188 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1189 [#include <time.h>
1190 #ifdef TIME_WITH_SYS_TIME
1191 # include <sys/time.h>
1192 # include <time.h>
1193 #else
1194 # if HAVE_SYS_TIME_H
1195 #  include <sys/time.h>
1196 # else
1197 #  include <time.h>
1198 # endif
1199 #endif
1200 ])
1201 GUILE_STRUCT_UTIMBUF
1202
1203
1204 #--------------------------------------------------------------------
1205 #
1206 # What values do the iconv error handlers have?
1207 #
1208 # The only place that we need iconv in our public interfaces is for
1209 # the error handlers, which are just ints.  So we weaken our
1210 # dependency by looking up those values at configure-time.
1211 #--------------------------------------------------------------------
1212 GUILE_UNISTRING_ICONVEH_VALUES
1213
1214 #--------------------------------------------------------------------
1215 #
1216 # Which way does the stack grow?
1217 #
1218 # Following code comes from Autoconf 2.69's internal _AC_LIBOBJ_ALLOCA
1219 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1220 # very similar code, so in future we could look at using that.
1221 #
1222 # An important detail is that the code involves find_stack_direction
1223 # calling _itself_ - which means that find_stack_direction (or at
1224 # least the second find_stack_direction() call) cannot be inlined.
1225 # If the code could be inlined, that might cause the test to give
1226 # an incorrect answer.
1227 #--------------------------------------------------------------------
1228
1229 SCM_I_GSC_STACK_GROWS_UP=0
1230 AC_RUN_IFELSE([AC_LANG_SOURCE(
1231 [AC_INCLUDES_DEFAULT
1232 int
1233 find_stack_direction (int *addr, int depth)
1234 {
1235   int dir, dummy = 0;
1236   if (! addr)
1237     addr = &dummy;
1238   *addr = addr < &dummy ? 1 : addr == &dummy ? 0 : -1;
1239   dir = depth ? find_stack_direction (addr, depth - 1) : 0;
1240   return dir + dummy;
1241 }
1242
1243 int
1244 main (int argc, char **argv)
1245 {
1246   return find_stack_direction (0, argc + !argv + 20) < 0;
1247 }])],
1248                [SCM_I_GSC_STACK_GROWS_UP=1],
1249                [],
1250                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1251
1252 #--------------------------------------------------------------------
1253 #
1254 # Boehm's GC library
1255 #
1256 #--------------------------------------------------------------------
1257 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1258
1259 save_LIBS="$LIBS"
1260 LIBS="$BDW_GC_LIBS $LIBS"
1261 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1262
1263 AC_CHECK_FUNCS([GC_do_blocking GC_call_with_gc_active GC_pthread_exit GC_pthread_cancel GC_allow_register_threads GC_pthread_sigmask GC_set_start_callback GC_get_suspend_signal GC_move_disappearing_link GC_get_heap_usage_safe GC_get_free_space_divisor GC_gcollect_and_unmap GC_get_unmapped_bytes])
1264
1265 # Though the `GC_do_blocking ()' symbol is present in GC 7.1, it is not
1266 # declared, and has a different type (returning void instead of
1267 # void*).
1268 AC_CHECK_DECL([GC_do_blocking],
1269   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1270     [Define this if the `GC_do_blocking ()' function is declared])],
1271   [],
1272   [#include <gc/gc.h>])
1273
1274 # `GC_fn_type' is not available in GC 7.1 and earlier.
1275 AC_CHECK_TYPE([GC_fn_type],
1276   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1277     [Define this if the `GC_fn_type' type is available.])],
1278   [],
1279   [#include <gc/gc.h>])
1280
1281 # `GC_stack_base' is not available in GC 7.1 and earlier.
1282 AC_CHECK_TYPE([struct GC_stack_base],
1283   [AC_DEFINE([HAVE_GC_STACK_BASE], [1],
1284     [Define this if the `GC_stack_base' type is available.])],
1285   [],
1286   [#include <gc/gc.h>])
1287
1288 LIBS="$save_LIBS"
1289
1290
1291 AC_CHECK_SIZEOF(float)
1292 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1293     AC_DEFINE([SCM_SINGLES], 1,
1294               [Define this if floats are the same size as longs.])
1295 fi
1296
1297 AC_MSG_CHECKING(for struct linger)
1298 AC_CACHE_VAL(scm_cv_struct_linger,
1299         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1300 #include <sys/types.h>
1301 #include <sys/socket.h>]],
1302                           [[struct linger lgr;  lgr.l_linger = 100]])],
1303                           [scm_cv_struct_linger="yes"],
1304                           [scm_cv_struct_linger="no"]))
1305 AC_MSG_RESULT($scm_cv_struct_linger)
1306 if test $scm_cv_struct_linger = yes; then
1307         AC_DEFINE([HAVE_STRUCT_LINGER], 1,
1308           [Define this if your system defines struct linger, for use with the
1309            getsockopt and setsockopt system calls.])
1310 fi
1311
1312
1313 # On mingw, struct timespec is in <pthread.h>.
1314 #
1315 AC_MSG_CHECKING(for struct timespec)
1316 AC_CACHE_VAL(scm_cv_struct_timespec,
1317         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1318 #include <time.h>
1319 #if HAVE_PTHREAD_H
1320 #include <pthread.h>
1321 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1322           [scm_cv_struct_timespec="yes"],
1323           [scm_cv_struct_timespec="no"]))
1324 AC_MSG_RESULT($scm_cv_struct_timespec)
1325 if test $scm_cv_struct_timespec = yes; then
1326   AC_DEFINE([HAVE_STRUCT_TIMESPEC], 1,
1327     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1328 fi
1329
1330 #--------------------------------------------------------------------
1331 #
1332 # Flags for thread support
1333 #
1334 #--------------------------------------------------------------------
1335
1336 SCM_I_GSC_USE_PTHREAD_THREADS=0
1337 SCM_I_GSC_USE_NULL_THREADS=0
1338 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1339 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1340
1341 ### What thread package has the user asked for?
1342 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1343             , with_threads=yes)
1344
1345 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1346 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1347
1348 case "$with_threads" in
1349   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1350
1351     build_pthread_support="yes"
1352
1353     ACX_PTHREAD([CC="$PTHREAD_CC"
1354        LIBS="$PTHREAD_LIBS $LIBS"
1355        SCM_I_GSC_USE_PTHREAD_THREADS=1
1356        with_threads="pthreads"],
1357       [with_threads="null"
1358        build_pthread_support="no"])
1359
1360     old_CFLAGS="$CFLAGS"
1361     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1362
1363     # Reasons for testing:
1364     #     pthread_getattr_np - "np" meaning "non portable" says it
1365     #         all; not present on MacOS X or Solaris 10
1366     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1367     #         all; specific to MacOS X
1368     #     pthread_attr_get_np - "np" meaning "non portable" says it
1369     #         all; specific to FreeBSD
1370     #     pthread_sigmask - not available on mingw
1371     #
1372     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_attr_get_np pthread_sigmask)
1373
1374     # On past versions of Solaris, believe 8 through 10 at least, you
1375     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1376     # This is contrary to POSIX:
1377     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1378     # Check here if this style is required.
1379     #
1380     # glibc (2.3.6 at least) works both with or without braces, so the
1381     # test checks whether it works without.
1382     #
1383
1384     if test "$GCC" = "yes"; then
1385       # Since GCC only issues a warning for missing braces, so we need
1386       # `-Werror' to catch it.
1387       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1388     fi
1389
1390     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1391       guile_cv_need_braces_on_pthread_once_init,
1392       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>
1393          pthread_once_t foo = PTHREAD_ONCE_INIT;]])],
1394         [guile_cv_need_braces_on_pthread_once_init=no],
1395         [guile_cv_need_braces_on_pthread_once_init=yes])])
1396     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1397       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1398     fi
1399
1400     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1401     # 6.5.30m with GCC 3.3.
1402     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1403       guile_cv_need_braces_on_pthread_mutex_initializer,
1404       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>
1405          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;]])],
1406         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1407         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1408     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1409       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1410     fi
1411
1412     CFLAGS="$old_CFLAGS"
1413
1414     # On Solaris, sched_yield lives in -lrt.
1415     AC_SEARCH_LIBS(sched_yield, rt)
1416
1417   ;;
1418 esac
1419
1420 case "$with_threads" in
1421   "pthreads")
1422   ;;
1423   "no" | "null")
1424     SCM_I_GSC_USE_NULL_THREADS=1
1425     SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
1426     with_threads="null-threads"
1427   ;;
1428   * )
1429     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1430   ;;
1431 esac
1432
1433 AC_MSG_CHECKING(what kind of threads to support)
1434 AC_MSG_RESULT($with_threads)
1435
1436 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1437   [test "x$build_pthread_support" = "xyes"])
1438
1439
1440 ## Check whether pthread_attr_getstack works for the main thread
1441
1442 if test "$with_threads" = pthreads; then
1443
1444 AC_MSG_CHECKING([whether pthread_attr_getstack works for the main thread])
1445 old_CFLAGS="$CFLAGS"
1446 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1447 if test "$cross_compiling" = "no"; then
1448   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1449   #if HAVE_PTHREAD_ATTR_GETSTACK
1450   #include <pthread.h>
1451
1452   int main ()
1453   {
1454     pthread_attr_t attr;
1455     void *start, *end;
1456     size_t size;
1457
1458     pthread_getattr_np (pthread_self (), &attr);
1459     pthread_attr_getstack (&attr, &start, &size);
1460     end = (char *)start + size;
1461
1462     if ((void *)&attr < start || (void *)&attr >= end)
1463       return 1;
1464     else
1465       return 0;
1466   }
1467   #else
1468   int main ()
1469   {
1470     return 1;
1471   }
1472   #endif
1473   ]])],
1474   [works=yes
1475    AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])],
1476   [works=no],
1477   [])
1478 else
1479   works="assuming it doesn't"
1480 fi
1481 CFLAGS="$old_CFLAGS"
1482 AC_MSG_RESULT($works)
1483
1484 GUILE_THREAD_LOCAL_STORAGE
1485
1486 fi # with_threads=pthreads
1487
1488
1489 ## Cross building
1490 if test "$cross_compiling" = "yes"; then
1491   AC_MSG_CHECKING(cc for build)
1492   ## /usr/bin/cc still uses wrong assembler
1493   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1494   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1495 else
1496   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1497 fi
1498
1499 ## AC_MSG_CHECKING("if we are cross compiling")
1500 ## AC_MSG_RESULT($cross_compiling)
1501 if test "$cross_compiling" = "yes"; then
1502    AC_MSG_RESULT($CC_FOR_BUILD)
1503 fi
1504
1505 ## No need as yet to be more elaborate
1506 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1507
1508 AC_SUBST(cross_compiling)
1509 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1510 AC_SUBST(CCLD_FOR_BUILD)
1511
1512 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1513 ## --HOST is the platform that PACKAGE is compiled for.
1514 HOST_CC="$CC_FOR_BUILD"
1515 AC_SUBST(HOST_CC)
1516
1517 GUILE_CHECK_GUILE_FOR_BUILD
1518
1519 ## If we're using GCC, ask for aggressive warnings.
1520 GCC_CFLAGS=""
1521 case "$GCC" in
1522   yes )
1523     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1524     ## much stuff with generic function pointers for that to really be
1525     ## less than exasperating.
1526     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1527     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1528     ## -Wundef was removed because Gnulib prevented it (see
1529     ## <http://thread.gmane.org/gmane.lisp.guile.bugs/5329>.)
1530
1531     ## Build with `-fno-strict-aliasing' to prevent miscompilation on
1532     ## some platforms.  See
1533     ## <http://lists.gnu.org/archive/html/guile-devel/2012-01/msg00487.html>.
1534
1535     POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \
1536       -Wdeclaration-after-statement \
1537       -Wswitch-enum -fno-strict-aliasing"
1538     # Do this here so we don't screw up any of the tests above that might
1539     # not be "warning free"
1540     if test "${GUILE_ERROR_ON_WARNING}" = yes
1541     then
1542         POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror"
1543         enable_compile_warnings=no
1544     fi
1545
1546     for flag in $POTENTIAL_GCC_CFLAGS
1547     do
1548         gl_WARN_ADD([$flag], [GCC_CFLAGS])
1549     done
1550     ;;
1551 esac
1552
1553 AC_SUBST(GCC_CFLAGS)
1554
1555 # Check for GNU ld's "-z relro".
1556 GUILE_GNU_LD_RELRO
1557
1558
1559 ## If we're creating a shared library (using libtool!), then we'll
1560 ## need to generate a list of .lo files corresponding to the .o files
1561 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1562 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1563
1564 ## We also need to create corresponding .doc and .x files
1565 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1566 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1567
1568 # GNU Readline bindings.
1569 GUILE_READLINE
1570
1571 AC_SUBST(GUILE_MAJOR_VERSION)
1572 AC_SUBST(GUILE_MINOR_VERSION)
1573 AC_SUBST(GUILE_MICRO_VERSION)
1574 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1575 AC_SUBST(GUILE_VERSION)
1576
1577 #######################################################################
1578 # library versioning
1579
1580 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1581 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1582 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1583 AC_SUBST(LIBGUILE_INTERFACE)
1584
1585 AC_SUBST(LIBGUILE_I18N_MAJOR)
1586 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1587 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1588 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1589 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1590
1591
1592 #######################################################################
1593
1594 dnl Tell guile-config what flags guile users should compile and link
1595 dnl with, keeping only `-I' flags from $CPPFLAGS.
1596 GUILE_CFLAGS=""
1597 next_is_includedir=false
1598 for flag in $CPPFLAGS
1599 do
1600   if $next_is_includedir; then
1601     GUILE_CFLAGS="$GUILE_CFLAGS -I $flag"
1602     next_is_includedir=false
1603   else
1604     case "$flag" in
1605       -I)  next_is_includedir=true;;
1606       -I*) GUILE_CFLAGS="$GUILE_CFLAGS $flag";;
1607       *)   ;;
1608     esac
1609   fi
1610 done
1611
1612 GUILE_CFLAGS="$GUILE_CFLAGS $PTHREAD_CFLAGS"
1613 GUILE_LIBS="$LDFLAGS $LIBS"
1614
1615 AC_SUBST(GUILE_LIBS)
1616 AC_SUBST(GUILE_CFLAGS)
1617
1618 AC_SUBST(AWK)
1619 AC_SUBST(LIBLOBJS)
1620 AC_SUBST(EXTRA_DOT_DOC_FILES)
1621 AC_SUBST(EXTRA_DOT_X_FILES)
1622
1623 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1624 top_builddir_absolute=`pwd`
1625 AC_SUBST(top_builddir_absolute)
1626 top_srcdir_absolute=`(cd $srcdir && pwd)`
1627 AC_SUBST(top_srcdir_absolute)
1628
1629 dnl `sitedir' goes into libpath.h and the pkg-config file.
1630 pkgdatadir="$datadir/$PACKAGE_TARNAME"
1631 sitedir="$pkgdatadir/site/$GUILE_EFFECTIVE_VERSION"
1632 AC_SUBST([sitedir])
1633
1634 dnl Name of the `guile' program.
1635 guile_program_name="`echo guile | "$SED" "$program_transform_name"`"
1636 AC_SUBST([guile_program_name])
1637
1638 # Additional SCM_I_GSC definitions are above.
1639 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1640 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1641 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1642 AC_SUBST([SCM_I_GSC_C_INLINE])
1643 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1644
1645 AC_CONFIG_FILES([
1646   Makefile
1647   am/Makefile
1648   lib/Makefile
1649   benchmark-suite/Makefile
1650   gc-benchmarks/Makefile
1651   doc/Makefile
1652   doc/r5rs/Makefile
1653   doc/ref/Makefile
1654   emacs/Makefile
1655   examples/Makefile
1656   libguile/Makefile
1657   libguile/version.h
1658   guile-readline/Makefile
1659   test-suite/Makefile
1660   test-suite/standalone/Makefile
1661   test-suite/vm/Makefile
1662   meta/Makefile
1663   module/Makefile
1664 ])
1665
1666 AC_CONFIG_FILES([meta/guile-2.2.pc])
1667 AC_CONFIG_FILES([meta/guile-2.2-uninstalled.pc])
1668 AC_CONFIG_FILES([doc/ref/effective-version.texi])
1669
1670 GUILE_CONFIG_SCRIPT([check-guile])
1671 GUILE_CONFIG_SCRIPT([benchmark-guile])
1672 GUILE_CONFIG_SCRIPT([meta/guile])
1673 GUILE_CONFIG_SCRIPT([meta/uninstalled-env])
1674 GUILE_CONFIG_SCRIPT([meta/gdb-uninstalled-guile])
1675 GUILE_CONFIG_SCRIPT([meta/guild])
1676 GUILE_CONFIG_SCRIPT([libguile/guile-snarf])
1677 GUILE_CONFIG_SCRIPT([libguile/guile-snarf-docs])
1678 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-use-srfi])
1679 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-fast-slot-ref])
1680
1681 AC_OUTPUT
1682
1683 dnl Local Variables:
1684 dnl comment-start: "dnl "
1685 dnl comment-end: ""
1686 dnl comment-start-skip: "\\bdnl\\b\\s *"
1687 dnl End: