configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it under
  12 the terms of the GNU Lesser General Public License as published by the
  13 Free Software Foundation; either version 3, or (at your option) any
  14 later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but WITHOUT
  17 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  19 License for more details.
  20
  21 You should have received a copy of the GNU Lesser General Public
  22 License along with GUILE; see the file COPYING.LESSER.  If not, write
  23 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  24 Floor, Boston, MA 02110-1301, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.61)
  29
  30 dnl  `patsubst' here deletes the newline which "echo" prints.  We can't use
  31 dnl  "echo -n" since -n is not portable (see autoconf manual "Limitations of
  32 dnl  Builtins"), in particular on solaris it results in a literal "-n" in
  33 dnl  the output.
  34 dnl
  35 AC_INIT(patsubst(m4_esyscmd(. ./GUILE-VERSION && echo ${PACKAGE}),[
  36 ]),
  37         patsubst(m4_esyscmd(. ./GUILE-VERSION && echo ${GUILE_VERSION}),[
  38 ]),
  39         [bug-guile@gnu.org])
  40 AC_CONFIG_AUX_DIR([build-aux])
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR(GUILE-VERSION)
  43
  44 AM_INIT_AUTOMAKE([gnu no-define check-news -Wall -Wno-override])
  45
  46 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  47 AC_CONFIG_SRCDIR([GUILE-VERSION])
  48
  49 . $srcdir/GUILE-VERSION
  50
  51 AC_CONFIG_HEADERS([config.h])
  52 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  53
  54 #--------------------------------------------------------------------
  55
  56 AC_LANG([C])
  57
  58 dnl Some more checks for Win32
  59 AC_CANONICAL_HOST
  60
  61 AC_LIBTOOL_WIN32_DLL
  62
  63 AC_PROG_INSTALL
  64 AC_PROG_CC
  65 gl_EARLY
  66 AC_PROG_CPP
  67 AC_PROG_AWK
  68
  69 dnl Gnulib.
  70 gl_INIT
  71
  72 AC_PROG_CC_C89
  73
  74 # for per-target cflags in the libguile subdir
  75 AM_PROG_CC_C_O
  76
  77 AC_LIBTOOL_DLOPEN
  78 AC_PROG_LIBTOOL
  79 AC_CHECK_LIB([ltdl], [lt_dlinit], ,
  80   [AC_MSG_ERROR([libltdl not found.  See README.])])
  81 AC_CHECK_HEADER([ltdl.h], [],
  82   [AC_MSG_ERROR([<ltdl.h> not found.  See README.])])
  83
  84 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  85 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  86
  87 AM_PATH_LISPDIR
  88
  89 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
  90   [Define to the host's GNU triplet.])
  91
  92 #--------------------------------------------------------------------
  93 #
  94 # User options (after above tests that may set default CFLAGS etc.)
  95 #
  96 #--------------------------------------------------------------------
  97
  98 GUILE_ERROR_ON_WARNING="yes"
  99
 100 AC_ARG_ENABLE(error-on-warning,
 101   [  --enable-error-on-warning    treat compile warnings as errors],
 102   [case "${enableval}" in
 103      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 104      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 105      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 106    esac])
 107
 108 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
 109 AC_ARG_ENABLE(debug-freelist,
 110   [  --enable-debug-freelist include garbage collector freelist debugging code],
 111   if test "$enable_debug_freelist" = y \
 112      || test "$enable_debug_freelist" = yes; then
 113     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
 114   fi)
 115
 116 AC_ARG_ENABLE(debug-malloc,
 117   [  --enable-debug-malloc   include malloc debugging code],
 118   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 119     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 120       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 121   fi)
 122
 123 SCM_I_GSC_GUILE_DEBUG=0
 124 AC_ARG_ENABLE(guile-debug,
 125   [AS_HELP_STRING([--enable-guile-debug],
 126                   [include internal debugging functions])],
 127   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 128     SCM_I_GSC_GUILE_DEBUG=1
 129   fi)
 130
 131 AC_ARG_ENABLE(posix,
 132   [  --disable-posix         omit posix interfaces],,
 133   enable_posix=yes)
 134
 135 AC_ARG_ENABLE(networking,
 136   [  --disable-networking    omit networking interfaces],,
 137   enable_networking=yes)
 138
 139 AC_ARG_ENABLE(regex,
 140   [  --disable-regex         omit regular expression interfaces],,
 141   enable_regex=yes)
 142
 143 AC_ARG_ENABLE([discouraged],
 144   AS_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 145
 146 if test "$enable_discouraged" = no; then
 147   SCM_I_GSC_ENABLE_DISCOURAGED=0
 148 else
 149   SCM_I_GSC_ENABLE_DISCOURAGED=1
 150 fi
 151
 152 AC_ARG_ENABLE([deprecated],
 153   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 154
 155 if test "$enable_deprecated" = no; then
 156   SCM_I_GSC_ENABLE_DEPRECATED=0
 157   warn_default=no
 158 else
 159   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 160     warn_default=summary
 161   elif test "$enable_deprecated" = shutup; then
 162     warn_default=no
 163   else
 164     warn_default=$enable_deprecated
 165   fi
 166   SCM_I_GSC_ENABLE_DEPRECATED=1
 167 fi
 168 AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 169 [Define this to control the default warning level for deprecated features.])
 170
 171 AC_ARG_ENABLE(elisp,
 172   [  --disable-elisp         omit Emacs Lisp support],,
 173   enable_elisp=yes)
 174
 175 dnl  Added the following configure option in January 2008 following
 176 dnl  investigation of problems with "64" system and library calls on
 177 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 178 dnl  system has stat64, it will have all the other 64 APIs too; but on
 179 dnl  Darwin, stat64 is there but other APIs are missing.
 180 dnl
 181 dnl  It also appears, from the Darwin docs, that most system call APIs
 182 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 183 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 184 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 185 dnl
 186 dnl  A similar problem has been reported for HP-UX:
 187 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 188 dnl
 189 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 190 dnl  better than no Guile at all, we provide this option to suppress
 191 dnl  trying to use "64" calls.
 192 dnl
 193 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 194 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 195 dnl  missing out on that.  If so, someone can work on that in the future.
 196 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 197 dnl  wasn't building before.
 198 AC_MSG_CHECKING([whether to use system and library "64" calls])
 199 AC_ARG_WITH([64-calls],
 200   AS_HELP_STRING([--without-64-calls],
 201                  [don't attempt to use system and library calls with "64" in their names]),
 202   [use_64_calls=$withval],
 203   [use_64_calls=yes
 204    case $host in
 205      *-apple-darwin* )
 206        use_64_calls=no
 207        ;;
 208      powerpc-ibm-aix* )
 209        use_64_calls=no
 210        ;;
 211    esac])
 212 AC_MSG_RESULT($use_64_calls)
 213 case "$use_64_calls" in
 214   y* )
 215     AC_DEFINE(GUILE_USE_64_CALLS, 1,
 216       [Define to 1 in order to try to use "64" versions of system and library calls.])
 217     ;;
 218 esac
 219
 220 #--------------------------------------------------------------------
 221
 222 dnl Check for dynamic linking
 223
 224 use_modules=yes
 225 AC_ARG_WITH(modules,
 226 [  --with-modules[=FILES]  Add support for dynamic modules],
 227 use_modules="$withval")
 228 test -z "$use_modules" && use_modules=yes
 229 DLPREOPEN=
 230 if test "$use_modules" != no; then
 231   if test "$use_modules" = yes; then
 232     DLPREOPEN="-dlpreopen force"
 233   else
 234     DLPREOPEN="-export-dynamic"
 235     for module in $use_modules; do
 236       DLPREOPEN="$DLPREOPEN -dlopen $module"
 237     done
 238   fi
 239 fi
 240
 241 dnl files which are destined for separate modules.
 242
 243 if test "$use_modules" != no; then
 244    AC_LIBOBJ([dynl])
 245 fi
 246
 247 if test "$enable_posix" = yes; then
 248    AC_LIBOBJ([filesys])
 249    AC_LIBOBJ([posix])
 250    AC_DEFINE(HAVE_POSIX, 1,
 251      [Define this if you want support for POSIX system calls in Guile.])
 252 fi
 253
 254 if test "$enable_networking" = yes; then
 255    AC_LIBOBJ([net_db])
 256    AC_LIBOBJ([socket])
 257    AC_DEFINE(HAVE_NETWORKING, 1,
 258      [Define this if you want support for networking in Guile.])
 259 fi
 260
 261 if test "$enable_debug_malloc" = yes; then
 262    AC_LIBOBJ([debug-malloc])
 263 fi
 264
 265 if test "$enable_elisp" = yes; then
 266   SCM_I_GSC_ENABLE_ELISP=1
 267 else
 268   SCM_I_GSC_ENABLE_ELISP=0
 269 fi
 270 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 271
 272 AC_C_CONST
 273
 274 # "volatile" is used in a couple of tests below.
 275 AC_C_VOLATILE
 276
 277 AC_C_INLINE
 278 if test "$ac_cv_c_inline" != no; then
 279   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 280 else
 281   SCM_I_GSC_C_INLINE=NULL
 282 fi
 283 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 284
 285 AC_C_BIGENDIAN
 286
 287 AC_C_LABELS_AS_VALUES
 288
 289 AC_CHECK_SIZEOF(char)
 290 AC_CHECK_SIZEOF(unsigned char)
 291 AC_CHECK_SIZEOF(short)
 292 AC_CHECK_SIZEOF(unsigned short)
 293 AC_CHECK_SIZEOF(int)
 294 AC_CHECK_SIZEOF(unsigned int)
 295 AC_CHECK_SIZEOF(long)
 296 AC_CHECK_SIZEOF(unsigned long)
 297 AC_CHECK_SIZEOF(size_t)
 298 AC_CHECK_SIZEOF(long long)
 299 AC_CHECK_SIZEOF(unsigned long long)
 300 AC_CHECK_SIZEOF(__int64)
 301 AC_CHECK_SIZEOF(unsigned __int64)
 302 AC_CHECK_SIZEOF(void *)
 303 AC_CHECK_SIZEOF(intptr_t)
 304 AC_CHECK_SIZEOF(uintptr_t)
 305 AC_CHECK_SIZEOF(ptrdiff_t)
 306 AC_CHECK_SIZEOF(size_t)
 307 AC_CHECK_SIZEOF(off_t)
 308
 309 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 310   AC_MSG_ERROR(sizes of long and void* are not identical)
 311 fi
 312
 313 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 314   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 315 else
 316   SCM_I_GSC_T_PTRDIFF='"long"'
 317 fi
 318 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 319
 320 AC_CHECK_HEADERS([stdint.h])
 321 AC_CHECK_HEADERS([inttypes.h])
 322
 323 AC_CHECK_SIZEOF(intmax_t)
 324
 325 SCM_I_GSC_NEEDS_STDINT_H=0
 326 SCM_I_GSC_NEEDS_INTTYPES_H=0
 327
 328 ### intptr and uintptr (try not to use inttypes if we don't have to)
 329 if test "$ac_cv_header_inttypes_h" = yes; then
 330   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 331     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 332 #include <stdio.h>])
 333     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 334       SCM_I_GSC_NEEDS_INTTYPES_H=1
 335     fi
 336   fi
 337   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 338     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 339 #include <stdio.h>])
 340     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 341       SCM_I_GSC_NEEDS_INTTYPES_H=1
 342     fi
 343   fi
 344 fi
 345
 346 ### See what's provided by stdint.h
 347 if test "$ac_cv_header_stdint_h" = yes; then
 348    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 349    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 350    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 351    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 352    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 353    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 354    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 355    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 356    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 357    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 358 fi
 359
 360 # so we don't get confused by the cache (wish there was a better way
 361 # to check particular headers for the same type...)
 362
 363 unset ac_cv_type_int8_t
 364 unset ac_cv_type_uint8_t
 365 unset ac_cv_type_int16_t
 366 unset ac_cv_type_uint16_t
 367 unset ac_cv_type_int32_t
 368 unset ac_cv_type_uint32_t
 369 unset ac_cv_type_int64_t
 370 unset ac_cv_type_uint64_t
 371 unset ac_cv_type_intmax_t
 372 unset ac_cv_type_uintmax_t
 373
 374 ### See what's provided by inttypes.h
 375 if test "$ac_cv_header_inttypes_h" = yes; then
 376   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 377   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 378   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 379   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 380   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 381   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 382   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 383   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 384   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 385   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 386 fi
 387
 388 # Try hard to find definitions for some required scm_t_*int* types.
 389
 390 ### Required type scm_t_int8
 391 if test "$scm_stdint_has_int8"; then
 392   SCM_I_GSC_T_INT8='"int8_t"'
 393   SCM_I_GSC_NEEDS_STDINT_H=1
 394 elif test "$scm_inttypes_has_int8"; then
 395   SCM_I_GSC_T_INT8='"int8_t"'
 396   SCM_I_GSC_NEEDS_INTTYPES_H=1
 397 elif test "$ac_cv_sizeof_char" -eq 1; then
 398   SCM_I_GSC_T_INT8='"signed char"'
 399 else
 400   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 401 fi
 402 AC_SUBST([SCM_I_GSC_T_INT8])
 403
 404 ### Required type scm_t_uint8
 405 if test "$scm_stdint_has_uint8"; then
 406   SCM_I_GSC_T_UINT8='"uint8_t"'
 407   SCM_I_GSC_NEEDS_STDINT_H=1
 408 elif test "$scm_inttypes_has_uint8"; then
 409   SCM_I_GSC_T_UINT8='"uint8_t"'
 410   SCM_I_GSC_NEEDS_INTTYPES_H=1
 411 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 412   SCM_I_GSC_T_UINT8='"unsigned char"'
 413 else
 414   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 415 fi
 416 AC_SUBST([SCM_I_GSC_T_UINT8])
 417
 418 ### Required type scm_t_int16 (ANSI C says int or short might work)
 419 if test "$scm_stdint_has_int16"; then
 420   SCM_I_GSC_T_INT16='"int16_t"'
 421   SCM_I_GSC_NEEDS_STDINT_H=1
 422 elif test "$scm_inttypes_has_int16"; then
 423   SCM_I_GSC_T_INT16='"int16_t"'
 424   SCM_I_GSC_NEEDS_INTTYPES_H=1
 425 elif test "$ac_cv_sizeof_int" -eq 2; then
 426   SCM_I_GSC_T_INT16='"int"'
 427 elif test "$ac_cv_sizeof_short" -eq 2; then
 428   SCM_I_GSC_T_INT16='"short"'
 429 else
 430   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 431 fi
 432 AC_SUBST([SCM_I_GSC_T_INT16])
 433
 434 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 435 if test "$scm_stdint_has_uint16"; then
 436   SCM_I_GSC_T_UINT16='"uint16_t"'
 437   SCM_I_GSC_NEEDS_STDINT_H=1
 438 elif test "$scm_inttypes_has_uint16"; then
 439   SCM_I_GSC_T_UINT16='"uint16_t"'
 440   SCM_I_GSC_NEEDS_INTTYPES_H=1
 441 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 442   SCM_I_GSC_T_UINT16='"unsigned int"'
 443 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 444   SCM_I_GSC_T_UINT16='"unsigned short"'
 445 else
 446   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 447 fi
 448 AC_SUBST([SCM_I_GSC_T_UINT16])
 449
 450
 451 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 452 if test "$scm_stdint_has_int32"; then
 453   SCM_I_GSC_T_INT32='"int32_t"'
 454   SCM_I_GSC_NEEDS_STDINT_H=1
 455 elif test "$scm_inttypes_has_int32"; then
 456   SCM_I_GSC_T_INT32='"int32_t"'
 457   SCM_I_GSC_NEEDS_INTTYPES_H=1
 458 elif test "$ac_cv_sizeof_int" -eq 4; then
 459   SCM_I_GSC_T_INT32='"int"'
 460 elif test "$ac_cv_sizeof_long" -eq 4; then
 461   SCM_I_GSC_T_INT32='"long"'
 462 elif test "$ac_cv_sizeof_short" -eq 4; then
 463   SCM_I_GSC_T_INT32='"short"'
 464 else
 465   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 466 fi
 467 AC_SUBST([SCM_I_GSC_T_INT32])
 468
 469 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 470 if test "$scm_stdint_has_uint32"; then
 471   SCM_I_GSC_T_UINT32='"uint32_t"'
 472   SCM_I_GSC_NEEDS_STDINT_H=1
 473 elif test "$scm_inttypes_has_uint32"; then
 474   SCM_I_GSC_T_UINT32='"uint32_t"'
 475   SCM_I_GSC_NEEDS_INTTYPES_H=1
 476 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 477   SCM_I_GSC_T_UINT32='"unsigned int"'
 478 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 479   SCM_I_GSC_T_UINT32='"unsigned long"'
 480 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 481   SCM_I_GSC_T_UINT32='"unsigned short"'
 482 else
 483   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 484 fi
 485 AC_SUBST([SCM_I_GSC_T_UINT32])
 486
 487 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 488 ### Also try 'long long' and '__int64' if we have it.
 489 SCM_I_GSC_T_INT64=0
 490 if test "$scm_stdint_has_int64"; then
 491   SCM_I_GSC_T_INT64='"int64_t"'
 492   SCM_I_GSC_NEEDS_STDINT_H=1
 493 elif test "$scm_inttypes_has_int64"; then
 494   SCM_I_GSC_T_INT64='"int64_t"'
 495   SCM_I_GSC_NEEDS_INTTYPES_H=1
 496 elif test "$ac_cv_sizeof_int" -eq 8; then
 497   SCM_I_GSC_T_INT64='"int"'
 498 elif test "$ac_cv_sizeof_long" -eq 8; then
 499   SCM_I_GSC_T_INT64='"long"'
 500 elif test "$ac_cv_sizeof_short" -eq 8; then
 501   SCM_I_GSC_T_INT64='"short"'
 502 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 503   SCM_I_GSC_T_INT64='"long long"'
 504 elif test "$ac_cv_sizeof___int64" -eq 8; then
 505   SCM_I_GSC_T_INT64='"__int64"'
 506 else
 507   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 508 fi
 509 AC_SUBST([SCM_I_GSC_T_INT64])
 510
 511
 512 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 513 ### Also try 'long long' and '__int64' if we have it.
 514 SCM_I_GSC_T_UINT64=0
 515 if test "$scm_stdint_has_uint64"; then
 516   SCM_I_GSC_T_UINT64='"uint64_t"'
 517   SCM_I_GSC_NEEDS_STDINT_H=1
 518 elif test "$scm_inttypes_has_uint64"; then
 519   SCM_I_GSC_T_UINT64='"uint64_t"'
 520   SCM_I_GSC_NEEDS_INTTYPES_H=1
 521 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 522   SCM_I_GSC_T_UINT64='"unsigned int"'
 523 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 524   SCM_I_GSC_T_UINT64='"unsigned long"'
 525 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 526   SCM_I_GSC_T_UINT64='"unsigned short"'
 527 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 528   SCM_I_GSC_T_UINT64='"unsigned long long"'
 529 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 530   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 531 else
 532   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 533 fi
 534 AC_SUBST([SCM_I_GSC_T_UINT64])
 535
 536 ### Required type scm_t_intmax
 537 ###
 538 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 539 ### none of them is available, we use 'long'.
 540 ###
 541 SCM_I_GSC_T_INTMAX=0
 542 if test "$scm_stdint_has_intmax"; then
 543   SCM_I_GSC_T_INTMAX='"intmax_t"'
 544   SCM_I_GSC_NEEDS_STDINT_H=1
 545 elif test "$scm_inttypes_has_intmax"; then
 546   SCM_I_GSC_T_INTMAX='"intmax_t"'
 547   SCM_I_GSC_NEEDS_INTTYPES_H=1
 548 elif test "$ac_cv_sizeof___int64" -ne 0; then
 549   SCM_I_GSC_T_INTMAX='"__int64"'
 550 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 551   SCM_I_GSC_T_INTMAX='"long long"'
 552 else
 553   SCM_I_GSC_T_INTMAX='"long"'
 554 fi
 555 AC_SUBST([SCM_I_GSC_T_INTMAX])
 556
 557 ### Required type scm_t_uintmax
 558 ###
 559 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 560 ### this order.  When none of them is available, we use 'unsigned long'.
 561 ###
 562 SCM_I_GSC_T_UINTMAX=0
 563 if test "$scm_stdint_has_uintmax"; then
 564   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 565   SCM_I_GSC_NEEDS_STDINT_H=1
 566 elif test "$scm_inttypes_has_uintmax"; then
 567   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 568   SCM_I_GSC_NEEDS_INTTYPES_H=1
 569 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 570   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 571 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 572   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 573 else
 574   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 575 fi
 576 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 577
 578
 579 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 580 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 581
 582 AC_HEADER_STDC
 583 AC_HEADER_TIME
 584 AC_HEADER_SYS_WAIT
 585 AC_HEADER_DIRENT
 586
 587 # Reason for checking:
 588 #
 589 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 590 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 591 #
 592 AC_CHECK_MEMBER([struct dirent64.d_name],
 593   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 594   [ #ifndef _LARGEFILE64_SOURCE
 595     # define _LARGEFILE64_SOURCE
 596     #endif
 597
 598     /* Per Autoconf manual.  */
 599     #include <sys/types.h>
 600     #ifdef HAVE_DIRENT_H
 601     # include <dirent.h>
 602     #else
 603     # define dirent direct
 604     # ifdef HAVE_SYS_NDIR_H
 605     #  include <sys/ndir.h>
 606     # endif
 607     # ifdef HAVE_SYS_DIR_H
 608     #  include <sys/dir.h>
 609     # endif
 610     # ifdef HAVE_NDIR_H
 611     #  include <ndir.h>
 612     # endif
 613     #endif ])
 614 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 615
 616 # Reasons for testing:
 617 #   complex.h - new in C99
 618 #   fenv.h - available in C99, but not older systems
 619 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 620 #     this file instead of <fenv.h>
 621 #   process.h - mingw specific
 622 #   langinfo.h, nl_types.h - SuS v2
 623 #
 624 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 625 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 626 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 627 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 628 direct.h langinfo.h nl_types.h machine/fpu.h])
 629
 630 # "complex double" is new in C99, and "complex" is only a keyword if
 631 # <complex.h> is included
 632 AC_CHECK_TYPES(complex double,,,
 633 [#if HAVE_COMPLEX_H
 634 #include <complex.h>
 635 #endif])
 636
 637 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 638 # when testing.
 639 AC_CHECK_TYPE(socklen_t, ,
 640   [AC_DEFINE_UNQUOTED(socklen_t, int,
 641                       [Define to `int' if <sys/socket.h> does not define.])],
 642   [#if HAVE_SYS_TYPES_H
 643 #include <sys/types.h>
 644 #endif
 645 #include <sys/socket.h>
 646 ])
 647 AC_CHECK_TYPE(struct ip_mreq)
 648
 649 GUILE_HEADER_LIBC_WITH_UNISTD
 650
 651 AC_TYPE_GETGROUPS
 652 AC_TYPE_SIGNAL
 653 AC_TYPE_MODE_T
 654
 655 # On mingw -lm is empty, so this test is unnecessary, but it's
 656 # harmless so we don't hard-code to suppress it.
 657 #
 658 AC_CHECK_LIB(m, cos)
 659
 660 AC_CHECK_FUNCS(gethostbyname)
 661 if test $ac_cv_func_gethostbyname = no; then
 662     AC_CHECK_LIB(nsl, gethostbyname)
 663 fi
 664
 665 AC_CHECK_FUNCS(connect)
 666 if test $ac_cv_func_connect = no; then
 667     AC_CHECK_LIB(socket, connect)
 668 fi
 669
 670 dnl
 671 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 672 dnl
 673 EXTRA_DEFS=""
 674 case $host in
 675   *-*-mingw*)
 676     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 677       [Define if you have the <winsock2.h> header file.])])
 678     AC_CHECK_LIB(ws2_32, main)
 679     AC_LIBOBJ([win32-uname])
 680     AC_LIBOBJ([win32-dirent])
 681     if test "$enable_networking" = yes ; then
 682       AC_LIBOBJ([win32-socket])
 683     fi
 684     if test "$enable_shared" = yes ; then
 685       EXTRA_DEFS="-DSCM_IMPORT"
 686       AC_DEFINE(USE_DLL_IMPORT, 1,
 687         [Define if you need additional CPP macros on Win32 platforms.])
 688     fi
 689     ;;
 690 esac
 691 AC_SUBST(EXTRA_DEFS)
 692
 693 # Reasons for testing:
 694 #   crt_externs.h - Darwin specific
 695 #
 696 AC_CHECK_HEADERS([assert.h crt_externs.h])
 697
 698 # Reasons for testing:
 699 #   DINFINITY - OSF specific
 700 #   DQNAN - OSF specific
 701 #       (DINFINITY and DQNAN are actually global variables, not functions)
 702 #   chsize - an MS-DOS-ism, found in mingw
 703 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 704 #       for gcc to provide the "complex double" type but the system to not
 705 #       have functions like cexp and clog
 706 #   clog10 - not in mingw (though others like clog and csqrt are)
 707 #   fesetround - available in C99, but not older systems
 708 #   ftruncate - posix, but probably not older systems (current mingw
 709 #               has it as an inline for chsize)
 710 #   ioctl - not in mingw.
 711 #   gmtime_r - recent posix, not on old systems
 712 #   pipe - not in mingw
 713 #   _pipe - specific to mingw, taking 3 args
 714 #   readdir_r - recent posix, not on old systems
 715 #   readdir64_r - not available on HP-UX 11.11
 716 #   stat64 - SuS largefile stuff, not on old systems
 717 #   sysconf - not on old systems
 718 #   truncate - not in mingw
 719 #   isblank - available as a GNU extension or in C99
 720 #   _NSGetEnviron - Darwin specific
 721 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 722 #   nl_langinfo - X/Open, not available on Windows.
 723 #
 724 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo])
 725
 726 # Reasons for testing:
 727 #   netdb.h - not in mingw
 728 #   sys/param.h - not in mingw
 729 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 730 #       check this specifically, we need it for the timespec test below.
 731 #   sethostname - the function itself check because it's not in mingw,
 732 #       the DECL is checked because Solaris 10 doens't have in any header
 733 #   xlocale.h - needed on Darwin for the `locale_t' API
 734 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 735 #       declaration isn't anywhere.
 736 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 737 #       only with `_XOPEN_SOURCE' or some such.
 738 #
 739 AC_CHECK_HEADERS(crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h xlocale.h)
 740 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 741 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 742
 743 # crypt() may or may not be available, for instance in some countries there
 744 # are restrictions on cryptography.
 745 #
 746 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 747 # -lcrypt library (eg. Debian GNU/Linux).
 748 #
 749 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 750 # be careful to avoid -lcrypt in this case, since libtool will see there's
 751 # only a static libcrypt and decide to build only a static libguile.
 752 #
 753 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 754 # libraries already in that list.
 755 #
 756 AC_SEARCH_LIBS(crypt, crypt,
 757   [AC_DEFINE(HAVE_CRYPT,1,
 758              [Define to 1 if you have the `crypt' function.])])
 759
 760 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 761 # work; in the reported cases so far, 1.0fi works well instead.  According
 762 # to the C99 spec, the complex.h header must provide a working definition
 763 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 764 # is a workaround for the failure of some systems to conform to C99.
 765 if test "$ac_cv_type_complex_double" = yes; then
 766   AC_MSG_CHECKING([for i])
 767   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 768 #if HAVE_COMPLEX_H
 769 #include <complex.h>
 770 #endif
 771 complex double z;
 772 ]], [[
 773 z = _Complex_I;
 774 ]])],
 775     [AC_DEFINE(GUILE_I,_Complex_I,[The imaginary unit (positive square root of -1).])
 776      AC_MSG_RESULT([_Complex_I])],
 777     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 778 #if HAVE_COMPLEX_H
 779 #include <complex.h>
 780 #endif
 781 complex double z;
 782 ]],[[
 783 z = 1.0fi;
 784 ]])],
 785   [AC_DEFINE(GUILE_I,1.0fi)
 786    AC_MSG_RESULT([1.0fi])],
 787   [ac_cv_type_complex_double=no
 788    AC_MSG_RESULT([not available])])])
 789 fi
 790
 791 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 792 # csqrt(-i) returned a negative real part, when it should be positive
 793 # for the principal root.
 794 #
 795 if test "$ac_cv_type_complex_double" = yes; then
 796
 797   AC_CACHE_CHECK([whether csqrt is usable],
 798     guile_cv_use_csqrt,
 799     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 800 #include <complex.h>
 801 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 802    constant, we want to test libc. */
 803 volatile complex double z = - _Complex_I;
 804 int
 805 main (void)
 806 {
 807   z = csqrt (z);
 808   if (creal (z) > 0.0)
 809     return 0;  /* good */
 810   else
 811     return 1;  /* bad */
 812 }]])],
 813     [guile_cv_use_csqrt=yes],
 814     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 815     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 816   case $guile_cv_use_csqrt in
 817     yes*)
 818       AC_DEFINE(HAVE_USABLE_CSQRT, 1, [Define to 1 if csqrt is bug-free])
 819       ;;
 820   esac
 821 fi
 822
 823
 824 dnl GMP tests
 825 AC_LIB_HAVE_LINKFLAGS(gmp,
 826   [],
 827   [#include <gmp.h>],
 828   [mpz_import (0, 0, 0, 0, 0, 0, 0);],
 829   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README]))
 830
 831 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 832 if test "x$LTLIBUNISTRING" != "x"; then
 833   LIBS="$LTLIBUNISTRING $LIBS"
 834 else
 835   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 836 fi
 837
 838 dnl i18n tests
 839 #AC_CHECK_HEADERS([libintl.h])
 840 #AC_CHECK_FUNCS(gettext)
 841 #if test $ac_cv_func_gettext = no; then
 842 #   AC_CHECK_LIB(intl, gettext)
 843 #fi
 844 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 845 AM_GNU_GETTEXT([external], [need-ngettext])
 846
 847 ### Some systems don't declare some functions.  On such systems, we
 848 ### need to at least provide our own K&R-style declarations.
 849
 850 ### GUILE_FUNC_DECLARED(function, headerfile)
 851
 852 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 853 ### not there, #define MISSING_FUNCTION_DECL.
 854 AC_DEFUN([GUILE_FUNC_DECLARED], [
 855   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 856     AC_EGREP_HEADER($1, $2,
 857                     guile_cv_func_$1_declared=yes,
 858                     guile_cv_func_$1_declared=no))
 859   if test [x$guile_cv_func_]$1[_declared] = xno; then
 860     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 861       [Define if the operating system supplies $1 without declaring it.])
 862   fi
 863 ])
 864
 865 GUILE_FUNC_DECLARED(sleep, unistd.h)
 866 GUILE_FUNC_DECLARED(usleep, unistd.h)
 867
 868 AC_CHECK_DECLS([strptime],,,
 869 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 870 #include <time.h>])
 871
 872 ### On some systems usleep has no return value.  If it does have one,
 873 ### we'd like to return it; otherwise, we'll fake it.
 874 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 875   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 876                    unistd.h,
 877                    [guile_cv_func_usleep_return_type=void],
 878                    [guile_cv_func_usleep_return_type=int])])
 879 case "$guile_cv_func_usleep_return_type" in
 880   "void" )
 881     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 882       [Define if the system headers declare usleep to return void.])
 883   ;;
 884 esac
 885
 886 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 887 if test -n "$have_sys_un_h" ; then
 888   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 889     [Define if the system supports Unix-domain (file-domain) sockets.])
 890 fi
 891
 892 AC_CHECK_FUNCS(getrlimit setrlimit)
 893
 894 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 895
 896 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 897                setnetent    getnetent    endnetent    dnl
 898                setprotoent  getprotoent  endprotoent  dnl
 899                setservent   getservent   endservent   dnl
 900                getnetbyaddr getnetbyname dnl
 901                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 902                inet_pton inet_ntop)
 903
 904 # struct sockaddr field sin_len is only present on BSD systems.
 905 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 906 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 907 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 908 [#ifdef HAVE_SYS_TYPES_H
 909 #include <sys/types.h>
 910 #endif
 911 #include <netinet/in.h>])
 912
 913 AC_MSG_CHECKING(for __libc_stack_end)
 914 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 915 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 916 extern char *__libc_stack_end;]],
 917    [[printf("%p", (char*) __libc_stack_end);]])],
 918    [guile_cv_have_libc_stack_end=yes],
 919    [guile_cv_have_libc_stack_end=no])])
 920 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 921
 922 if test $guile_cv_have_libc_stack_end = yes; then
 923   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 924            [Define if you have the __libc_stack_end variable.])
 925 fi
 926
 927 dnl Some systems do not declare this.  Some systems do declare it, as a
 928 dnl macro.  With cygwin it may be in a DLL.
 929
 930 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 931 AC_CACHE_VAL(guile_cv_have_h_errno,
 932   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 933                                       [[int a = h_errno;]])],
 934   [guile_cv_have_h_errno=yes],
 935   [guile_cv_have_h_errno=no])])
 936 AC_MSG_RESULT($guile_cv_have_h_errno)
 937 if test $guile_cv_have_h_errno = yes; then
 938   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 939 fi
 940
 941 AC_MSG_CHECKING(whether uint32_t is defined)
 942 AC_CACHE_VAL(guile_cv_have_uint32_t,
 943   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 944                    #if HAVE_STDINT_H
 945                    #include <stdint.h>
 946                    #endif
 947                    #ifndef HAVE_NETDB_H
 948                    #include <netdb.h>
 949                    #endif]],
 950                    [[uint32_t a;]])],
 951                    [guile_cv_have_uint32_t=yes],
 952                    [guile_cv_have_uint32_t=no])])
 953 AC_MSG_RESULT($guile_cv_have_uint32_t)
 954 if test $guile_cv_have_uint32_t = yes; then
 955   AC_DEFINE(HAVE_UINT32_T, 1,
 956     [Define if uint32_t typedef is defined when netdb.h is include.])
 957 fi
 958
 959 AC_MSG_CHECKING(for working IPv6 support)
 960 AC_CACHE_VAL(guile_cv_have_ipv6,
 961 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 962 #ifdef HAVE_SYS_TYPES_H
 963 #include <sys/types.h>
 964 #endif
 965 #include <netinet/in.h>
 966 #include <sys/socket.h>]],
 967 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
 968 [guile_cv_have_ipv6=yes],
 969 [guile_cv_have_ipv6=no])])
 970 AC_MSG_RESULT($guile_cv_have_ipv6)
 971 if test $guile_cv_have_ipv6 = yes; then
 972   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 973 fi
 974
 975 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 976 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 977 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 978 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 979 #ifdef HAVE_SYS_TYPES_H
 980 #include <sys/types.h>
 981 #endif
 982 #include <netinet/in.h>]],
 983 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
 984 [guile_cv_have_sin6_scope_id=yes],
 985 [guile_cv_have_sin6_scope_id=no])])
 986 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 987 if test $guile_cv_have_sin6_scope_id = yes; then
 988   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 989     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 990 fi
 991
 992 # struct sockaddr_in6 field sin_len is only present on BSD systems
 993 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
 994 [#ifdef HAVE_SYS_TYPES_H
 995 #include <sys/types.h>
 996 #endif
 997 #include <netinet/in.h>])
 998
 999 AC_MSG_CHECKING(whether localtime caches TZ)
1000 AC_CACHE_VAL(guile_cv_localtime_cache,
1001 [if test x$ac_cv_func_tzset = xyes; then
1002 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1003 #if STDC_HEADERS
1004 # include <stdlib.h>
1005 #endif
1006 extern char **environ;
1007 unset_TZ ()
1008 {
1009   char **from, **to;
1010   for (to = from = environ; (*to = *from); from++)
1011     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1012       to++;
1013 }
1014 char TZ_GMT0[] = "TZ=GMT0";
1015 char TZ_PST8[] = "TZ=PST8";
1016 main()
1017 {
1018   time_t now = time ((time_t *) 0);
1019   int hour_GMT0, hour_unset;
1020   if (putenv (TZ_GMT0) != 0)
1021     exit (1);
1022   hour_GMT0 = localtime (&now)->tm_hour;
1023   unset_TZ ();
1024   hour_unset = localtime (&now)->tm_hour;
1025   if (putenv (TZ_PST8) != 0)
1026     exit (1);
1027   if (localtime (&now)->tm_hour == hour_GMT0)
1028     exit (1);
1029   unset_TZ ();
1030   if (localtime (&now)->tm_hour != hour_unset)
1031     exit (1);
1032   exit (0);
1033 }]])],
1034 [guile_cv_localtime_cache=no],
1035 [guile_cv_localtime_cache=yes],
1036 [# If we have tzset, assume the worst when cross-compiling.
1037 guile_cv_localtime_cache=yes])
1038 else
1039         # If we lack tzset, report that localtime does not cache TZ,
1040         # since we can't invalidate the cache if we don't have tzset.
1041         guile_cv_localtime_cache=no
1042 fi])dnl
1043 AC_MSG_RESULT($guile_cv_localtime_cache)
1044 if test $guile_cv_localtime_cache = yes; then
1045   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
1046 fi
1047
1048 if test "$enable_regex" = yes; then
1049    if test "$ac_cv_header_regex_h" = yes ||
1050       test "$ac_cv_header_rxposix_h" = yes ||
1051       test "$ac_cv_header_rx_rxposix_h" = yes; then
1052      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1053      [AC_CHECK_LIB(rx, main)
1054       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1055      [AC_CHECK_LIB(regex, main)
1056       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1057      )
1058      dnl The following should not be necessary, but for some reason
1059      dnl autoheader misses it if we don't include it!
1060      if test "$ac_cv_func_regcomp_norx" = yes ||
1061         test "$ac_cv_func_regcomp_regex" = yes ||
1062         test "$ac_cv_func_regcomp_rx" = yes; then
1063        AC_DEFINE(HAVE_REGCOMP, 1,
1064          [This is included as part of a workaround for a autoheader bug.])
1065      fi
1066    fi
1067 fi
1068
1069 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
1070
1071 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
1072
1073 # Reasons for testing:
1074 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1075 #                                older systems
1076 #   sincos - GLIBC extension
1077 #
1078 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1079
1080 # C99 specifies isinf and isnan as macros.
1081 # HP-UX provides only macros, no functions.
1082 # glibc 2.3.2 provides both macros and functions.
1083 # IRIX 6.5 and Solaris 8 only provide functions.
1084 #
1085 # The following tests detect isinf and isnan either as functions or as
1086 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1087 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1088 #
1089 AC_MSG_CHECKING([for isinf])
1090 AC_LINK_IFELSE(AC_LANG_SOURCE(
1091 [[#include <math.h>
1092 volatile double x = 0.0;
1093 int main () { return (isinf(x) != 0); }]]),
1094   [AC_MSG_RESULT([yes])
1095    AC_DEFINE(HAVE_ISINF, 1,
1096              [Define to 1 if you have the `isinf' macro or function.])],
1097   [AC_MSG_RESULT([no])])
1098 AC_MSG_CHECKING([for isnan])
1099 AC_LINK_IFELSE(AC_LANG_SOURCE(
1100 [[#include <math.h>
1101 volatile double x = 0.0;
1102 int main () { return (isnan(x) != 0); }]]),
1103   [AC_MSG_RESULT([yes])
1104    AC_DEFINE(HAVE_ISNAN, 1,
1105              [Define to 1 if you have the `isnan' macro or function.])],
1106   [AC_MSG_RESULT([no])])
1107
1108 # Reasons for checking:
1109 #
1110 #     st_rdev
1111 #     st_blksize
1112 #     st_blocks   not in mingw
1113 #     tm_gmtoff   BSD+GNU, not in C99
1114 #
1115 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1116 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1117 #
1118 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks])
1119
1120 AC_STRUCT_TIMEZONE
1121 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1122 [#include <time.h>
1123 #ifdef TIME_WITH_SYS_TIME
1124 # include <sys/time.h>
1125 # include <time.h>
1126 #else
1127 # if HAVE_SYS_TIME_H
1128 #  include <sys/time.h>
1129 # else
1130 #  include <time.h>
1131 # endif
1132 #endif
1133 ])
1134 GUILE_STRUCT_UTIMBUF
1135
1136
1137 #--------------------------------------------------------------------
1138 #
1139 # Which way does the stack grow?
1140 #
1141 # Following code comes from Autoconf 2.61's internal _AC_LIBOBJ_ALLOCA
1142 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1143 # very similar code, so in future we could look at using that.
1144 #
1145 # An important detail is that the code involves find_stack_direction
1146 # calling _itself_ - which means that find_stack_direction (or at
1147 # least the second find_stack_direction() call) cannot be inlined.
1148 # If the code could be inlined, that might cause the test to give
1149 # an incorrect answer.
1150 #--------------------------------------------------------------------
1151
1152 SCM_I_GSC_STACK_GROWS_UP=0
1153 AC_RUN_IFELSE([AC_LANG_SOURCE(
1154 [AC_INCLUDES_DEFAULT
1155 int
1156 find_stack_direction ()
1157 {
1158   static char *addr = 0;
1159   auto char dummy;
1160   if (addr == 0)
1161     {
1162       addr = &dummy;
1163       return find_stack_direction ();
1164     }
1165   else
1166     return (&dummy > addr) ? 1 : -1;
1167 }
1168
1169 int
1170 main ()
1171 {
1172   return find_stack_direction () < 0;
1173 }])],
1174                [SCM_I_GSC_STACK_GROWS_UP=1],
1175                [],
1176                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1177
1178 #--------------------------------------------------------------------
1179 #
1180 # Boehm's GC library
1181 #
1182 #--------------------------------------------------------------------
1183 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1184
1185 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1186 LIBS="$BDW_GC_LIBS $LIBS"
1187
1188 # `GC_do_blocking ()' is available in GC 7.1 but not declared.
1189 AC_CHECK_FUNCS([GC_do_blocking])
1190 AC_CHECK_DECL([GC_do_blocking],
1191   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1192     [Define this if the `GC_do_blocking ()' function is declared])],
1193   [],
1194   [#include <gc/gc.h>])
1195
1196
1197 AC_CHECK_SIZEOF(float)
1198 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1199     AC_DEFINE(SCM_SINGLES, 1,
1200               [Define this if floats are the same size as longs.])
1201 fi
1202
1203 AC_MSG_CHECKING(for struct linger)
1204 AC_CACHE_VAL(scm_cv_struct_linger,
1205         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1206 #include <sys/types.h>
1207 #include <sys/socket.h>]],
1208                           [[struct linger lgr;  lgr.l_linger = 100]])],
1209                           [scm_cv_struct_linger="yes"],
1210                           [scm_cv_struct_linger="no"]))
1211 AC_MSG_RESULT($scm_cv_struct_linger)
1212 if test $scm_cv_struct_linger = yes; then
1213         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
1214           [Define this if your system defines struct linger, for use with the
1215            getsockopt and setsockopt system calls.])
1216 fi
1217
1218
1219 # On mingw, struct timespec is in <pthread.h>.
1220 #
1221 AC_MSG_CHECKING(for struct timespec)
1222 AC_CACHE_VAL(scm_cv_struct_timespec,
1223         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1224 #include <time.h>
1225 #if HAVE_PTHREAD_H
1226 #include <pthread.h>
1227 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1228           [scm_cv_struct_timespec="yes"],
1229           [scm_cv_struct_timespec="no"]))
1230 AC_MSG_RESULT($scm_cv_struct_timespec)
1231 if test $scm_cv_struct_timespec = yes; then
1232   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
1233     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1234 fi
1235
1236 #--------------------------------------------------------------------
1237 #
1238 # Flags for thread support
1239 #
1240 #--------------------------------------------------------------------
1241
1242 SCM_I_GSC_USE_PTHREAD_THREADS=0
1243 SCM_I_GSC_USE_NULL_THREADS=0
1244 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1245 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1246
1247 ### What thread package has the user asked for?
1248 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1249             , with_threads=yes)
1250
1251 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1252 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1253
1254 case "$with_threads" in
1255   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1256
1257     build_pthread_support="yes"
1258
1259     ACX_PTHREAD([CC="$PTHREAD_CC"
1260        LIBS="$PTHREAD_LIBS $LIBS"
1261        SCM_I_GSC_USE_PTHREAD_THREADS=1
1262        with_threads="pthreads"],
1263       [with_threads="null"
1264        build_pthread_support="no"])
1265
1266     old_CFLAGS="$CFLAGS"
1267     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1268
1269     # Reasons for testing:
1270     #     pthread_getattr_np - "np" meaning "non portable" says it
1271     #         all; not present on MacOS X or Solaris 10
1272     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1273     #         all; specific to MacOS X
1274     #     pthread_sigmask - not available on mingw
1275     #
1276     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1277
1278     # On past versions of Solaris, believe 8 through 10 at least, you
1279     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1280     # This is contrary to POSIX:
1281     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1282     # Check here if this style is required.
1283     #
1284     # glibc (2.3.6 at least) works both with or without braces, so the
1285     # test checks whether it works without.
1286     #
1287
1288     if test "$GCC" = "yes"; then
1289       # Since GCC only issues a warning for missing braces, so we need
1290       # `-Werror' to catch it.
1291       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1292     fi
1293
1294     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1295       guile_cv_need_braces_on_pthread_once_init,
1296       [AC_COMPILE_IFELSE([#include <pthread.h>
1297          pthread_once_t foo = PTHREAD_ONCE_INIT;],
1298         [guile_cv_need_braces_on_pthread_once_init=no],
1299         [guile_cv_need_braces_on_pthread_once_init=yes])])
1300     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1301       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1302     fi
1303
1304     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1305     # 6.5.30m with GCC 3.3.
1306     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1307       guile_cv_need_braces_on_pthread_mutex_initializer,
1308       [AC_COMPILE_IFELSE([#include <pthread.h>
1309          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;],
1310         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1311         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1312     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1313       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1314     fi
1315
1316     CFLAGS="$old_CFLAGS"
1317
1318     # On Solaris, sched_yield lives in -lrt.
1319     AC_SEARCH_LIBS(sched_yield, rt)
1320
1321   ;;
1322 esac
1323
1324 case "$with_threads" in
1325   "pthreads")
1326   ;;
1327   "no" | "null")
1328     SCM_I_GSC_USE_NULL_THREADS=1
1329     with_threads="null-threads"
1330   ;;
1331   * )
1332     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1333   ;;
1334 esac
1335
1336 AC_MSG_CHECKING(what kind of threads to support)
1337 AC_MSG_RESULT($with_threads)
1338
1339 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1340   [test "x$build_pthread_support" = "xyes"])
1341
1342
1343 ## Check whether pthread_attr_getstack works for the main thread
1344
1345 if test "$with_threads" = pthreads; then
1346
1347 AC_MSG_CHECKING(whether pthread_attr_getstack works for the main thread)
1348 old_CFLAGS="$CFLAGS"
1349 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1350 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1351 #if HAVE_PTHREAD_ATTR_GETSTACK
1352 #include <pthread.h>
1353
1354 int main ()
1355 {
1356   pthread_attr_t attr;
1357   void *start, *end;
1358   size_t size;
1359
1360   pthread_getattr_np (pthread_self (), &attr);
1361   pthread_attr_getstack (&attr, &start, &size);
1362   end = (char *)start + size;
1363
1364   if ((void *)&attr < start || (void *)&attr >= end)
1365     return 1;
1366   else
1367     return 0;
1368 }
1369 #else
1370 int main ()
1371 {
1372   return 1;
1373 }
1374 #endif
1375 ]])],
1376 [works=yes
1377 AC_DEFINE(PTHREAD_ATTR_GETSTACK_WORKS, [1], [Define when pthread_att_get_stack works for the main thread])],
1378 [works=no],
1379 [])
1380 CFLAGS="$old_CFLAGS"
1381 AC_MSG_RESULT($works)
1382
1383 fi # with_threads=pthreads
1384
1385
1386 ## Cross building
1387 if test "$cross_compiling" = "yes"; then
1388   AC_MSG_CHECKING(cc for build)
1389   ## /usr/bin/cc still uses wrong assembler
1390   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1391   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1392 else
1393   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1394 fi
1395
1396 ## AC_MSG_CHECKING("if we are cross compiling")
1397 ## AC_MSG_RESULT($cross_compiling)
1398 if test "$cross_compiling" = "yes"; then
1399    AC_MSG_RESULT($CC_FOR_BUILD)
1400 fi
1401
1402 ## No need as yet to be more elaborate
1403 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1404
1405 AC_SUBST(cross_compiling)
1406 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1407 AC_SUBST(CCLD_FOR_BUILD)
1408
1409 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1410 ## --HOST is the platform that PACKAGE is compiled for.
1411 HOST_CC="$CC_FOR_BUILD"
1412 AC_SUBST(HOST_CC)
1413
1414 if test "$cross_compiling" = "yes"; then
1415   AC_MSG_CHECKING(guile for build)
1416   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1417 else
1418   GUILE_FOR_BUILD='$(preinstguile)'
1419 fi
1420
1421 ## AC_MSG_CHECKING("if we are cross compiling")
1422 ## AC_MSG_RESULT($cross_compiling)
1423 if test "$cross_compiling" = "yes"; then
1424    AC_MSG_RESULT($GUILE_FOR_BUILD)
1425 fi
1426 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1427 AC_SUBST(GUILE_FOR_BUILD)
1428
1429 ## If we're using GCC, ask for aggressive warnings.
1430 case "$GCC" in
1431   yes )
1432     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1433     ## much stuff with generic function pointers for that to really be
1434     ## less than exasperating.
1435     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1436     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1437     GCC_CFLAGS="-Wall -Wmissing-prototypes"
1438     # Do this here so we don't screw up any of the tests above that might
1439     # not be "warning free"
1440     if test "${GUILE_ERROR_ON_WARNING}" = yes
1441     then
1442         GCC_CFLAGS="${GCC_CFLAGS} -Werror"
1443         enable_compile_warnings=no
1444     fi
1445     ;;
1446 esac
1447
1448 AC_SUBST(GCC_CFLAGS)
1449
1450 # Check for GNU ld's "-z relro".
1451 GUILE_GNU_LD_RELRO
1452
1453
1454 ## If we're creating a shared library (using libtool!), then we'll
1455 ## need to generate a list of .lo files corresponding to the .o files
1456 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1457 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1458
1459 ## We also need to create corresponding .doc and .x files
1460 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1461 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1462
1463 # GNU Readline bindings.
1464 GUILE_READLINE
1465
1466 AC_SUBST(GUILE_MAJOR_VERSION)
1467 AC_SUBST(GUILE_MINOR_VERSION)
1468 AC_SUBST(GUILE_MICRO_VERSION)
1469 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1470 AC_SUBST(GUILE_VERSION)
1471
1472 #######################################################################
1473 # library versioning
1474
1475 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1476 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1477 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1478 AC_SUBST(LIBGUILE_INTERFACE)
1479
1480 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1481 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1482 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1483 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1484 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1485
1486 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1487 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1488 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1489 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1490 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1491
1492 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1493 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1494 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1495 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1496 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1497
1498 AC_SUBST(LIBGUILE_SRFI_SRFI_60_MAJOR)
1499 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_CURRENT)
1500 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_REVISION)
1501 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_AGE)
1502 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE)
1503
1504 AC_SUBST(LIBGUILE_I18N_MAJOR)
1505 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1506 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1507 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1508 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1509
1510
1511 #######################################################################
1512
1513 dnl Tell guile-config what flags guile users should compile and link with.
1514 GUILE_LIBS="$LDFLAGS $LIBS"
1515 GUILE_CFLAGS="$CPPFLAGS $PTHREAD_CFLAGS"
1516 AC_SUBST(GUILE_LIBS)
1517 AC_SUBST(GUILE_CFLAGS)
1518
1519 AC_SUBST(AWK)
1520 AC_SUBST(LIBLOBJS)
1521 AC_SUBST(EXTRA_DOT_DOC_FILES)
1522 AC_SUBST(EXTRA_DOT_X_FILES)
1523
1524 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1525 top_builddir_absolute=`pwd`
1526 AC_SUBST(top_builddir_absolute)
1527 top_srcdir_absolute=`(cd $srcdir && pwd)`
1528 AC_SUBST(top_srcdir_absolute)
1529
1530 dnl We need `sitedir' in `guile-1.8.pc'.
1531 dnl Note: `sitedir' must be kept in sync with `GUILE_SITE_DIR' in `guile.m4'.
1532 pkgdatadir="$datadir/guile"
1533 sitedir="$pkgdatadir/site"
1534 AC_SUBST([sitedir])
1535
1536 # Additional SCM_I_GSC definitions are above.
1537 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1538 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1539 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1540 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1541 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1542 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1543 AC_SUBST([SCM_I_GSC_C_INLINE])
1544 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1545
1546 AC_CONFIG_FILES([
1547   Makefile
1548   am/Makefile
1549   lib/Makefile
1550   benchmark-suite/Makefile
1551   doc/Makefile
1552   doc/r5rs/Makefile
1553   doc/ref/Makefile
1554   doc/tutorial/Makefile
1555   emacs/Makefile
1556   examples/Makefile
1557   lang/Makefile
1558   libguile/Makefile
1559   srfi/Makefile
1560   guile-readline/Makefile
1561   test-suite/Makefile
1562   test-suite/standalone/Makefile
1563   meta/Makefile
1564   module/Makefile
1565   testsuite/Makefile
1566 ])
1567
1568 AC_CONFIG_FILES([meta/guile-2.0.pc])
1569 AC_CONFIG_FILES([meta/guile-2.0-uninstalled.pc])
1570 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1571 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1572 AC_CONFIG_FILES([meta/guile], [chmod +x meta/guile])
1573 AC_CONFIG_FILES([meta/uninstalled-env], [chmod +x meta/uninstalled-env])
1574 AC_CONFIG_FILES([meta/gdb-uninstalled-guile], [chmod +x meta/gdb-uninstalled-guile])
1575 AC_CONFIG_FILES([meta/guile-tools], [chmod +x meta/guile-tools])
1576 AC_CONFIG_FILES([libguile/guile-snarf],
1577                 [chmod +x libguile/guile-snarf])
1578 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1579                 [chmod +x libguile/guile-doc-snarf])
1580 AC_CONFIG_FILES([libguile/guile-func-name-check],
1581                 [chmod +x libguile/guile-func-name-check])
1582 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1583                 [chmod +x libguile/guile-snarf-docs])
1584 AC_CONFIG_FILES([test-suite/standalone/test-use-srfi],
1585                 [chmod +x test-suite/standalone/test-use-srfi])
1586 AC_CONFIG_FILES([test-suite/standalone/test-fast-slot-ref],
1587                 [chmod +x test-suite/standalone/test-fast-slot-ref])
1588 AC_CONFIG_FILES([doc/ref/effective-version.texi])
1589
1590 AC_OUTPUT
1591
1592 dnl Local Variables:
1593 dnl comment-start: "dnl "
1594 dnl comment-end: ""
1595 dnl comment-start-skip: "\\bdnl\\b\\s *"
1596 dnl End: