configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   8   2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   9
  10 This file is part of GUILE
  11
  12 GUILE is free software; you can redistribute it and/or modify it under
  13 the terms of the GNU Lesser General Public License as published by the
  14 Free Software Foundation; either version 3, or (at your option) any
  15 later version.
  16
  17 GUILE is distributed in the hope that it will be useful, but WITHOUT
  18 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  19 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  20 License for more details.
  21
  22 You should have received a copy of the GNU Lesser General Public
  23 License along with GUILE; see the file COPYING.LESSER.  If not, write
  24 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  25 Floor, Boston, MA 02110-1301, USA.
  26
  27 ]])
  28
  29 AC_PREREQ(2.61)
  30
  31 AC_INIT([GNU Guile],
  32         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  33         [bug-guile@gnu.org])
  34 AC_CONFIG_AUX_DIR([build-aux])
  35 AC_CONFIG_MACRO_DIR([m4])
  36 AC_CONFIG_SRCDIR(GUILE-VERSION)
  37
  38 AM_INIT_AUTOMAKE([gnu no-define -Wall -Wno-override])
  39 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AC_SUBST([AM_DEFAULT_VERBOSITY],1)])
  40
  41 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  42 AC_CONFIG_SRCDIR([GUILE-VERSION])
  43
  44 . $srcdir/GUILE-VERSION
  45 GUILE_VERSION="$PACKAGE_VERSION"
  46
  47 AC_CONFIG_HEADERS([config.h])
  48 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  49
  50 #--------------------------------------------------------------------
  51
  52 AC_LANG([C])
  53
  54 dnl Some more checks for Win32
  55 AC_CANONICAL_HOST
  56
  57 AC_LIBTOOL_WIN32_DLL
  58
  59 AC_PROG_INSTALL
  60 AC_PROG_CC
  61 gl_EARLY
  62 AC_PROG_CPP
  63 AC_PROG_SED
  64 AC_PROG_AWK
  65 AC_PROG_LN_S
  66
  67 dnl Gnulib.
  68 gl_INIT
  69 dnl FIXME: remove me and the acinclude.m4 code when clock-gettime is
  70 dnl fixed for clock_getcpuclockid and can be imported normally from
  71 dnl gnulib.  See
  72 dnl <http://lists.gnu.org/archive/html/bug-gnulib/2011-06/msg00227.html>
  73 dnl for details.
  74 gl_CLOCK_TIME
  75
  76 AC_PROG_CC_C89
  77
  78 # for per-target cflags in the libguile subdir
  79 AM_PROG_CC_C_O
  80
  81 AC_LIBTOOL_DLOPEN
  82 AC_PROG_LIBTOOL
  83
  84 AM_CONDITIONAL([HAVE_SHARED_LIBRARIES], [test "x$enable_shared" = "xyes"])
  85
  86 AC_DEFINE_UNQUOTED([SHARED_LIBRARY_PATH_VARIABLE], ["$shlibpath_var"],
  87   [Name of the environment variable that tells the dynamic linker where
  88 to find shared libraries.])
  89
  90 dnl Check for libltdl.
  91 AC_LIB_HAVE_LINKFLAGS([ltdl], [], [#include <ltdl.h>],
  92   [lt_dlopenext ("foo");])
  93 if test "x$HAVE_LIBLTDL" != "xyes"; then
  94   AC_MSG_ERROR([GNU libltdl (Libtool) not found, see README.])
  95 fi
  96
  97 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  98 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  99
 100 AM_PATH_LISPDIR
 101
 102 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
 103   [Define to the host's GNU triplet.])
 104
 105 #--------------------------------------------------------------------
 106 #
 107 # User options (after above tests that may set default CFLAGS etc.)
 108 #
 109 #--------------------------------------------------------------------
 110
 111 GUILE_ERROR_ON_WARNING="no"
 112
 113 AC_ARG_ENABLE(error-on-warning,
 114   [  --enable-error-on-warning    treat compile warnings as errors],
 115   [case "${enableval}" in
 116      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 117      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 118      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 119    esac])
 120
 121 AC_ARG_ENABLE(debug-malloc,
 122   [  --enable-debug-malloc   include malloc debugging code],
 123   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 124     AC_DEFINE([GUILE_DEBUG_MALLOC], 1,
 125       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 126   fi)
 127
 128 SCM_I_GSC_GUILE_DEBUG=0
 129 AC_ARG_ENABLE(guile-debug,
 130   [AS_HELP_STRING([--enable-guile-debug],
 131                   [include internal debugging functions])],
 132   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 133     SCM_I_GSC_GUILE_DEBUG=1
 134   fi)
 135
 136 AC_ARG_ENABLE(posix,
 137   [  --disable-posix         omit non-essential POSIX interfaces],,
 138   enable_posix=yes)
 139
 140 AC_ARG_ENABLE(networking,
 141   [  --disable-networking    omit networking interfaces],,
 142   enable_networking=yes)
 143
 144 AC_ARG_ENABLE(regex,
 145   [  --disable-regex         omit regular expression interfaces],,
 146   enable_regex=yes)
 147
 148 AC_ARG_ENABLE([deprecated],
 149   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 150
 151 if test "$enable_deprecated" = no; then
 152   SCM_I_GSC_ENABLE_DEPRECATED=0
 153   warn_default=no
 154 else
 155   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 156     warn_default=summary
 157   elif test "$enable_deprecated" = shutup; then
 158     warn_default=no
 159   else
 160     warn_default=$enable_deprecated
 161   fi
 162   SCM_I_GSC_ENABLE_DEPRECATED=1
 163 fi
 164 AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default",
 165 [Define this to control the default warning level for deprecated features.])
 166
 167 dnl  Added the following configure option in January 2008 following
 168 dnl  investigation of problems with "64" system and library calls on
 169 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 170 dnl  system has stat64, it will have all the other 64 APIs too; but on
 171 dnl  Darwin, stat64 is there but other APIs are missing.
 172 dnl
 173 dnl  It also appears, from the Darwin docs, that most system call APIs
 174 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 175 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 176 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 177 dnl
 178 dnl  A similar problem has been reported for HP-UX:
 179 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 180 dnl
 181 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 182 dnl  better than no Guile at all, we provide this option to suppress
 183 dnl  trying to use "64" calls.
 184 dnl
 185 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 186 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 187 dnl  missing out on that.  If so, someone can work on that in the future.
 188 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 189 dnl  wasn't building before.
 190 AC_MSG_CHECKING([whether to use system and library "64" calls])
 191 AC_ARG_WITH([64-calls],
 192   AS_HELP_STRING([--without-64-calls],
 193                  [don't attempt to use system and library calls with "64" in their names]),
 194   [use_64_calls=$withval],
 195   [use_64_calls=yes
 196    case $host in
 197      *-apple-darwin* )
 198        use_64_calls=no
 199        ;;
 200      powerpc-ibm-aix* )
 201        use_64_calls=no
 202        ;;
 203    esac])
 204 AC_MSG_RESULT($use_64_calls)
 205 case "$use_64_calls" in
 206   y* )
 207     AC_DEFINE([GUILE_USE_64_CALLS], 1,
 208       [Define to 1 in order to try to use "64" versions of system and library calls.])
 209     ;;
 210 esac
 211
 212 #--------------------------------------------------------------------
 213
 214 dnl Check for dynamic linking
 215
 216 use_modules=yes
 217 AC_ARG_WITH(modules,
 218 [  --with-modules[=FILES]  Add support for dynamic modules],
 219 use_modules="$withval")
 220 test -z "$use_modules" && use_modules=yes
 221 DLPREOPEN=
 222 if test "$use_modules" != no; then
 223   if test "$use_modules" = yes; then
 224     DLPREOPEN="-dlpreopen force"
 225   else
 226     DLPREOPEN="-export-dynamic"
 227     for module in $use_modules; do
 228       DLPREOPEN="$DLPREOPEN -dlopen $module"
 229     done
 230   fi
 231 fi
 232
 233 dnl files which are destined for separate modules.
 234
 235 if test "$use_modules" != no; then
 236    AC_LIBOBJ([dynl])
 237 fi
 238
 239 if test "$enable_posix" = yes; then
 240    AC_LIBOBJ([posix])
 241    AC_DEFINE([HAVE_POSIX], 1,
 242      [Define this if you want support for non-essential POSIX system calls in Guile.])
 243 fi
 244
 245 if test "$enable_networking" = yes; then
 246    AC_LIBOBJ([net_db])
 247    AC_LIBOBJ([socket])
 248    AC_DEFINE([HAVE_NETWORKING], 1,
 249      [Define this if you want support for networking in Guile.])
 250 fi
 251
 252 if test "$enable_debug_malloc" = yes; then
 253    AC_LIBOBJ([debug-malloc])
 254 fi
 255
 256 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 257
 258 AC_C_CONST
 259
 260 # "volatile" is used in a couple of tests below.
 261 AC_C_VOLATILE
 262
 263 AC_C_INLINE
 264 if test "$ac_cv_c_inline" != no; then
 265   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 266 else
 267   SCM_I_GSC_C_INLINE=NULL
 268 fi
 269 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 270
 271 AC_C_BIGENDIAN
 272
 273 AC_C_LABELS_AS_VALUES
 274
 275 AC_CHECK_SIZEOF(char)
 276 AC_CHECK_SIZEOF(unsigned char)
 277 AC_CHECK_SIZEOF(short)
 278 AC_CHECK_SIZEOF(unsigned short)
 279 AC_CHECK_SIZEOF(int)
 280 AC_CHECK_SIZEOF(unsigned int)
 281 AC_CHECK_SIZEOF(long)
 282 AC_CHECK_SIZEOF(unsigned long)
 283 AC_CHECK_SIZEOF(size_t)
 284 AC_CHECK_SIZEOF(long long)
 285 AC_CHECK_SIZEOF(unsigned long long)
 286 AC_CHECK_SIZEOF(__int64)
 287 AC_CHECK_SIZEOF(unsigned __int64)
 288 AC_CHECK_SIZEOF(void *)
 289 AC_CHECK_SIZEOF(intptr_t)
 290 AC_CHECK_SIZEOF(uintptr_t)
 291 AC_CHECK_SIZEOF(ptrdiff_t)
 292 AC_CHECK_SIZEOF(size_t)
 293 AC_CHECK_SIZEOF(off_t)
 294
 295 if test "$ac_cv_sizeof_long" -gt "$ac_cv_sizeof_void_p"; then
 296   AC_MSG_ERROR(long does not fit into a void*)
 297 fi
 298
 299 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 300   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 301 else
 302   SCM_I_GSC_T_PTRDIFF='"long"'
 303 fi
 304 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 305
 306 AC_CHECK_HEADERS([stdint.h])
 307 AC_CHECK_HEADERS([inttypes.h])
 308
 309 AC_CHECK_SIZEOF(intmax_t)
 310
 311 SCM_I_GSC_NEEDS_STDINT_H=0
 312 SCM_I_GSC_NEEDS_INTTYPES_H=0
 313
 314 ### intptr and uintptr (try not to use inttypes if we don't have to)
 315 if test "$ac_cv_header_inttypes_h" = yes; then
 316   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 317     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 318 #include <stdio.h>])
 319     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 320       SCM_I_GSC_NEEDS_INTTYPES_H=1
 321     fi
 322   fi
 323   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 324     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 325 #include <stdio.h>])
 326     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 327       SCM_I_GSC_NEEDS_INTTYPES_H=1
 328     fi
 329   fi
 330 fi
 331
 332 ### See what's provided by stdint.h
 333 if test "$ac_cv_header_stdint_h" = yes; then
 334    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 335    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 336    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 337    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 338    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 339    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 340    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 341    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 342    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 343    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 344    AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>])
 345    AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>])
 346 fi
 347
 348 # so we don't get confused by the cache (wish there was a better way
 349 # to check particular headers for the same type...)
 350
 351 unset ac_cv_type_int8_t
 352 unset ac_cv_type_uint8_t
 353 unset ac_cv_type_int16_t
 354 unset ac_cv_type_uint16_t
 355 unset ac_cv_type_int32_t
 356 unset ac_cv_type_uint32_t
 357 unset ac_cv_type_int64_t
 358 unset ac_cv_type_uint64_t
 359 unset ac_cv_type_intmax_t
 360 unset ac_cv_type_uintmax_t
 361
 362 ### See what's provided by inttypes.h
 363 if test "$ac_cv_header_inttypes_h" = yes; then
 364   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 365   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 366   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 367   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 368   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 369   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 370   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 371   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 372   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 373   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 374   AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>])
 375   AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>])
 376 fi
 377
 378 # Try hard to find definitions for some required scm_t_*int* types.
 379
 380 ### Required type scm_t_int8
 381 if test "$scm_stdint_has_int8"; then
 382   SCM_I_GSC_T_INT8='"int8_t"'
 383   SCM_I_GSC_NEEDS_STDINT_H=1
 384 elif test "$scm_inttypes_has_int8"; then
 385   SCM_I_GSC_T_INT8='"int8_t"'
 386   SCM_I_GSC_NEEDS_INTTYPES_H=1
 387 elif test "$ac_cv_sizeof_char" -eq 1; then
 388   SCM_I_GSC_T_INT8='"signed char"'
 389 else
 390   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 391 fi
 392 AC_SUBST([SCM_I_GSC_T_INT8])
 393
 394 ### Required type scm_t_uint8
 395 if test "$scm_stdint_has_uint8"; then
 396   SCM_I_GSC_T_UINT8='"uint8_t"'
 397   SCM_I_GSC_NEEDS_STDINT_H=1
 398 elif test "$scm_inttypes_has_uint8"; then
 399   SCM_I_GSC_T_UINT8='"uint8_t"'
 400   SCM_I_GSC_NEEDS_INTTYPES_H=1
 401 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 402   SCM_I_GSC_T_UINT8='"unsigned char"'
 403 else
 404   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 405 fi
 406 AC_SUBST([SCM_I_GSC_T_UINT8])
 407
 408 ### Required type scm_t_int16 (ANSI C says int or short might work)
 409 if test "$scm_stdint_has_int16"; then
 410   SCM_I_GSC_T_INT16='"int16_t"'
 411   SCM_I_GSC_NEEDS_STDINT_H=1
 412 elif test "$scm_inttypes_has_int16"; then
 413   SCM_I_GSC_T_INT16='"int16_t"'
 414   SCM_I_GSC_NEEDS_INTTYPES_H=1
 415 elif test "$ac_cv_sizeof_int" -eq 2; then
 416   SCM_I_GSC_T_INT16='"int"'
 417 elif test "$ac_cv_sizeof_short" -eq 2; then
 418   SCM_I_GSC_T_INT16='"short"'
 419 else
 420   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 421 fi
 422 AC_SUBST([SCM_I_GSC_T_INT16])
 423
 424 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 425 if test "$scm_stdint_has_uint16"; then
 426   SCM_I_GSC_T_UINT16='"uint16_t"'
 427   SCM_I_GSC_NEEDS_STDINT_H=1
 428 elif test "$scm_inttypes_has_uint16"; then
 429   SCM_I_GSC_T_UINT16='"uint16_t"'
 430   SCM_I_GSC_NEEDS_INTTYPES_H=1
 431 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 432   SCM_I_GSC_T_UINT16='"unsigned int"'
 433 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 434   SCM_I_GSC_T_UINT16='"unsigned short"'
 435 else
 436   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 437 fi
 438 AC_SUBST([SCM_I_GSC_T_UINT16])
 439
 440
 441 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 442 if test "$scm_stdint_has_int32"; then
 443   SCM_I_GSC_T_INT32='"int32_t"'
 444   SCM_I_GSC_NEEDS_STDINT_H=1
 445 elif test "$scm_inttypes_has_int32"; then
 446   SCM_I_GSC_T_INT32='"int32_t"'
 447   SCM_I_GSC_NEEDS_INTTYPES_H=1
 448 elif test "$ac_cv_sizeof_int" -eq 4; then
 449   SCM_I_GSC_T_INT32='"int"'
 450 elif test "$ac_cv_sizeof_long" -eq 4; then
 451   SCM_I_GSC_T_INT32='"long"'
 452 elif test "$ac_cv_sizeof_short" -eq 4; then
 453   SCM_I_GSC_T_INT32='"short"'
 454 else
 455   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 456 fi
 457 AC_SUBST([SCM_I_GSC_T_INT32])
 458
 459 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 460 if test "$scm_stdint_has_uint32"; then
 461   SCM_I_GSC_T_UINT32='"uint32_t"'
 462   SCM_I_GSC_NEEDS_STDINT_H=1
 463 elif test "$scm_inttypes_has_uint32"; then
 464   SCM_I_GSC_T_UINT32='"uint32_t"'
 465   SCM_I_GSC_NEEDS_INTTYPES_H=1
 466 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 467   SCM_I_GSC_T_UINT32='"unsigned int"'
 468 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 469   SCM_I_GSC_T_UINT32='"unsigned long"'
 470 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 471   SCM_I_GSC_T_UINT32='"unsigned short"'
 472 else
 473   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 474 fi
 475 AC_SUBST([SCM_I_GSC_T_UINT32])
 476
 477 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 478 ### Also try 'long long' and '__int64' if we have it.
 479 SCM_I_GSC_T_INT64=0
 480 if test "$scm_stdint_has_int64"; then
 481   SCM_I_GSC_T_INT64='"int64_t"'
 482   SCM_I_GSC_NEEDS_STDINT_H=1
 483 elif test "$scm_inttypes_has_int64"; then
 484   SCM_I_GSC_T_INT64='"int64_t"'
 485   SCM_I_GSC_NEEDS_INTTYPES_H=1
 486 elif test "$ac_cv_sizeof_int" -eq 8; then
 487   SCM_I_GSC_T_INT64='"int"'
 488 elif test "$ac_cv_sizeof_long" -eq 8; then
 489   SCM_I_GSC_T_INT64='"long"'
 490 elif test "$ac_cv_sizeof_short" -eq 8; then
 491   SCM_I_GSC_T_INT64='"short"'
 492 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 493   SCM_I_GSC_T_INT64='"long long"'
 494 elif test "$ac_cv_sizeof___int64" -eq 8; then
 495   SCM_I_GSC_T_INT64='"__int64"'
 496 else
 497   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 498 fi
 499 AC_SUBST([SCM_I_GSC_T_INT64])
 500
 501
 502 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 503 ### Also try 'long long' and '__int64' if we have it.
 504 SCM_I_GSC_T_UINT64=0
 505 if test "$scm_stdint_has_uint64"; then
 506   SCM_I_GSC_T_UINT64='"uint64_t"'
 507   SCM_I_GSC_NEEDS_STDINT_H=1
 508 elif test "$scm_inttypes_has_uint64"; then
 509   SCM_I_GSC_T_UINT64='"uint64_t"'
 510   SCM_I_GSC_NEEDS_INTTYPES_H=1
 511 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 512   SCM_I_GSC_T_UINT64='"unsigned int"'
 513 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 514   SCM_I_GSC_T_UINT64='"unsigned long"'
 515 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 516   SCM_I_GSC_T_UINT64='"unsigned short"'
 517 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 518   SCM_I_GSC_T_UINT64='"unsigned long long"'
 519 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 520   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 521 else
 522   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 523 fi
 524 AC_SUBST([SCM_I_GSC_T_UINT64])
 525
 526 ### Required type scm_t_intmax
 527 ###
 528 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 529 ### none of them is available, we use 'long'.
 530 ###
 531 SCM_I_GSC_T_INTMAX=0
 532 if test "$scm_stdint_has_intmax"; then
 533   SCM_I_GSC_T_INTMAX='"intmax_t"'
 534   SCM_I_GSC_NEEDS_STDINT_H=1
 535 elif test "$scm_inttypes_has_intmax"; then
 536   SCM_I_GSC_T_INTMAX='"intmax_t"'
 537   SCM_I_GSC_NEEDS_INTTYPES_H=1
 538 elif test "$ac_cv_sizeof___int64" -ne 0; then
 539   SCM_I_GSC_T_INTMAX='"__int64"'
 540 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 541   SCM_I_GSC_T_INTMAX='"long long"'
 542 else
 543   SCM_I_GSC_T_INTMAX='"long"'
 544 fi
 545 AC_SUBST([SCM_I_GSC_T_INTMAX])
 546
 547 ### Required type scm_t_uintmax
 548 ###
 549 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 550 ### this order.  When none of them is available, we use 'unsigned long'.
 551 ###
 552 SCM_I_GSC_T_UINTMAX=0
 553 if test "$scm_stdint_has_uintmax"; then
 554   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 555   SCM_I_GSC_NEEDS_STDINT_H=1
 556 elif test "$scm_inttypes_has_uintmax"; then
 557   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 558   SCM_I_GSC_NEEDS_INTTYPES_H=1
 559 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 560   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 561 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 562   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 563 else
 564   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 565 fi
 566 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 567
 568 ### Required type scm_t_intptr
 569 ###
 570 SCM_I_GSC_T_INTPTR=0
 571 if test "$scm_stdint_has_intptr"; then
 572   SCM_I_GSC_T_INTPTR='"intptr_t"'
 573   SCM_I_GSC_NEEDS_STDINT_H=1
 574 elif test "$scm_inttypes_has_intptr"; then
 575   SCM_I_GSC_T_INTPTR='"intptr_t"'
 576   SCM_I_GSC_NEEDS_INTTYPES_H=1
 577 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 578   SCM_I_GSC_T_INTPTR='"int"'
 579 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 580   SCM_I_GSC_T_INTPTR='"long"'
 581 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 582   SCM_I_GSC_T_INTPTR='"long long"'
 583 else
 584   AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.])
 585 fi
 586 AC_SUBST([SCM_I_GSC_T_INTPTR])
 587
 588 ### Required type scm_t_uintptr
 589 ###
 590 SCM_I_GSC_T_UINTPTR=0
 591 if test "$scm_stdint_has_uintptr"; then
 592   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 593   SCM_I_GSC_NEEDS_STDINT_H=1
 594 elif test "$scm_inttypes_has_uintptr"; then
 595   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 596   SCM_I_GSC_NEEDS_INTTYPES_H=1
 597 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 598   SCM_I_GSC_T_UINTPTR='"unsigned int"'
 599 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 600   SCM_I_GSC_T_UINTPTR='"unsigned long"'
 601 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 602   SCM_I_GSC_T_UINTPTR='"unsigned long long"'
 603 else
 604   AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.])
 605 fi
 606 AC_SUBST([SCM_I_GSC_T_UINTPTR])
 607
 608
 609 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 610 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 611
 612 AC_HEADER_STDC
 613 AC_HEADER_TIME
 614 AC_HEADER_SYS_WAIT
 615 AC_HEADER_DIRENT
 616
 617 # Reason for checking:
 618 #
 619 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 620 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 621 #
 622 AC_CHECK_MEMBER([struct dirent64.d_name],
 623   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 624   [ #ifndef _LARGEFILE64_SOURCE
 625     # define _LARGEFILE64_SOURCE
 626     #endif
 627
 628     /* Per Autoconf manual.  */
 629     #include <sys/types.h>
 630     #ifdef HAVE_DIRENT_H
 631     # include <dirent.h>
 632     #else
 633     # define dirent direct
 634     # ifdef HAVE_SYS_NDIR_H
 635     #  include <sys/ndir.h>
 636     # endif
 637     # ifdef HAVE_SYS_DIR_H
 638     #  include <sys/dir.h>
 639     # endif
 640     # ifdef HAVE_NDIR_H
 641     #  include <ndir.h>
 642     # endif
 643     #endif ])
 644 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 645
 646 # Reasons for testing:
 647 #   complex.h - new in C99
 648 #   fenv.h - available in C99, but not older systems
 649 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 650 #     this file instead of <fenv.h>
 651 #   process.h - mingw specific
 652 #   langinfo.h, nl_types.h - SuS v2
 653 #   sched.h - missing on MinGW
 654 #
 655 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 656 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 657 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 658 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 659 direct.h langinfo.h nl_types.h machine/fpu.h poll.h sched.h])
 660
 661 # Reasons for testing:
 662 #   nl_item - lacking on Cygwin
 663 AC_CHECK_TYPES([nl_item], [], [],
 664   [[#ifdef HAVE_LANGINFO_H
 665     # include <langinfo.h>
 666     #endif
 667     #ifdef HAVE_NL_TYPES_H
 668     # include <nl_types.h>
 669     #endif]])
 670
 671 # "complex double" is new in C99, and "complex" is only a keyword if
 672 # <complex.h> is included
 673 AC_CHECK_TYPES(complex double,,,
 674 [#if HAVE_COMPLEX_H
 675 #include <complex.h>
 676 #endif])
 677
 678 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 679 # when testing.
 680 AC_CHECK_TYPE(socklen_t, ,
 681   [AC_DEFINE_UNQUOTED([socklen_t], int,
 682                       [Define to `int' if <sys/socket.h> does not define.])],
 683   [#if HAVE_SYS_TYPES_H
 684 #include <sys/types.h>
 685 #endif
 686 #include <sys/socket.h>
 687 ])
 688
 689 AC_CHECK_TYPES([struct ip_mreq], , , [#include <netinet/in.h>])
 690
 691 GUILE_HEADER_LIBC_WITH_UNISTD
 692
 693 AC_TYPE_GETGROUPS
 694 AC_TYPE_SIGNAL
 695 AC_TYPE_MODE_T
 696
 697 # On mingw -lm is empty, so this test is unnecessary, but it's
 698 # harmless so we don't hard-code to suppress it.
 699 #
 700 AC_CHECK_LIB(m, cos)
 701
 702 AC_CHECK_FUNCS(gethostbyname)
 703 if test $ac_cv_func_gethostbyname = no; then
 704     AC_CHECK_LIB(nsl, gethostbyname)
 705 fi
 706
 707 AC_CHECK_FUNCS(connect)
 708 if test $ac_cv_func_connect = no; then
 709     AC_CHECK_LIB(socket, connect)
 710 fi
 711
 712 dnl
 713 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 714 dnl
 715 EXTRA_DEFS=""
 716 case $host in
 717   *-*-mingw*)
 718     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 719       [Define if you have the <winsock2.h> header file.])])
 720     AC_CHECK_LIB(ws2_32, main)
 721     AC_LIBOBJ([win32-uname])
 722     if test "$enable_networking" = yes ; then
 723       AC_LIBOBJ([win32-socket])
 724     fi
 725     if test "$enable_shared" = yes ; then
 726       EXTRA_DEFS="-DSCM_IMPORT"
 727       AC_DEFINE([USE_DLL_IMPORT], 1,
 728         [Define if you need additional CPP macros on Win32 platforms.])
 729     fi
 730     ;;
 731 esac
 732 AC_SUBST(EXTRA_DEFS)
 733
 734 # Reasons for testing:
 735 #   crt_externs.h - Darwin specific
 736 #
 737 AC_CHECK_HEADERS([assert.h crt_externs.h])
 738
 739 # Reasons for testing:
 740 #   DINFINITY - OSF specific
 741 #   DQNAN - OSF specific
 742 #       (DINFINITY and DQNAN are actually global variables, not functions)
 743 #   chsize - an MS-DOS-ism, found in mingw
 744 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 745 #       for gcc to provide the "complex double" type but the system to not
 746 #       have functions like cexp and clog
 747 #   clog10 - not in mingw (though others like clog and csqrt are)
 748 #   fesetround - available in C99, but not older systems
 749 #   ftruncate - posix, but probably not older systems (current mingw
 750 #               has it as an inline for chsize)
 751 #   ioctl - not in mingw.
 752 #   gmtime_r - recent posix, not on old systems
 753 #   pipe - not in mingw
 754 #   _pipe - specific to mingw, taking 3 args
 755 #   poll - since posix 2001
 756 #   readdir_r - recent posix, not on old systems
 757 #   readdir64_r - not available on HP-UX 11.11
 758 #   stat64 - SuS largefile stuff, not on old systems
 759 #   sysconf - not on old systems
 760 #   truncate - not in mingw
 761 #   isblank - available as a GNU extension or in C99
 762 #   _NSGetEnviron - Darwin specific
 763 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 764 #   nl_langinfo - X/Open, not available on Windows.
 765 #   utimensat: posix.1-2008
 766 #   sched_getaffinity, sched_setaffinity: GNU extensions (glibc)
 767 #
 768 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid getsid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe poll readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo utimensat sched_getaffinity sched_setaffinity])
 769
 770 # Reasons for testing:
 771 #   netdb.h - not in mingw
 772 #   sys/param.h - not in mingw
 773 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 774 #       check this specifically, we need it for the timespec test below.
 775 #   sethostname - the function itself check because it's not in mingw,
 776 #       the DECL is checked because Solaris 10 doens't have in any header
 777 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 778 #       declaration isn't anywhere.
 779 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 780 #       only with `_XOPEN_SOURCE' or some such.
 781 #
 782 AC_CHECK_HEADERS([crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h sys/mman.h])
 783 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 784 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 785
 786 # crypt() may or may not be available, for instance in some countries there
 787 # are restrictions on cryptography.
 788 #
 789 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 790 # -lcrypt library (eg. Debian GNU/Linux).
 791 #
 792 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 793 # be careful to avoid -lcrypt in this case, since libtool will see there's
 794 # only a static libcrypt and decide to build only a static libguile.
 795 #
 796 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 797 # libraries already in that list.
 798 #
 799 AC_SEARCH_LIBS(crypt, crypt,
 800   [AC_DEFINE([HAVE_CRYPT],1,
 801              [Define to 1 if you have the `crypt' function.])])
 802
 803 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 804 # work; in the reported cases so far, 1.0fi works well instead.  According
 805 # to the C99 spec, the complex.h header must provide a working definition
 806 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 807 # is a workaround for the failure of some systems to conform to C99.
 808 if test "$ac_cv_type_complex_double" = yes; then
 809   AC_MSG_CHECKING([for i])
 810   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 811 #if HAVE_COMPLEX_H
 812 #include <complex.h>
 813 #endif
 814 complex double z;
 815 ]], [[
 816 z = _Complex_I;
 817 ]])],
 818     [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).])
 819      AC_MSG_RESULT([_Complex_I])],
 820     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 821 #if HAVE_COMPLEX_H
 822 #include <complex.h>
 823 #endif
 824 complex double z;
 825 ]],[[
 826 z = 1.0fi;
 827 ]])],
 828   [AC_DEFINE([GUILE_I],1.0fi)
 829    AC_MSG_RESULT([1.0fi])],
 830   [ac_cv_type_complex_double=no
 831    AC_MSG_RESULT([not available])])])
 832 fi
 833
 834 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 835 # csqrt(-i) returned a negative real part, when it should be positive
 836 # for the principal root.
 837 #
 838 if test "$ac_cv_type_complex_double" = yes; then
 839
 840   AC_CACHE_CHECK([whether csqrt is usable],
 841     guile_cv_use_csqrt,
 842     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 843 #include <complex.h>
 844 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 845    constant, we want to test libc. */
 846 volatile complex double z = - _Complex_I;
 847 int
 848 main (void)
 849 {
 850   z = csqrt (z);
 851   if (creal (z) > 0.0)
 852     return 0;  /* good */
 853   else
 854     return 1;  /* bad */
 855 }]])],
 856     [guile_cv_use_csqrt=yes],
 857     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 858     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 859   case $guile_cv_use_csqrt in
 860     yes*)
 861       AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free])
 862       ;;
 863   esac
 864 fi
 865
 866 AC_CACHE_SAVE
 867
 868 dnl GMP tests
 869 AC_LIB_HAVE_LINKFLAGS([gmp],
 870   [],
 871   [#include <gmp.h>],
 872   [mpz_import (0, 0, 0, 0, 0, 0, 0);])
 873
 874 if test "x$HAVE_LIBGMP" != "xyes"; then
 875   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README])
 876 fi
 877
 878 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 879 if test "x$LTLIBUNISTRING" = "x"; then
 880   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 881 fi
 882
 883 GUILE_LIBUNISTRING_WITH_ICONV_SUPPORT
 884 if test "x$ac_cv_libunistring_with_iconv_support" != "xyes"; then
 885   AC_MSG_ERROR([No iconv support.  Please recompile libunistring with iconv enabled.])
 886 fi
 887
 888 dnl Libffi is needed to compile Guile's foreign function interface, but its
 889 dnl interface isn't exposed in Guile's API.
 890 PKG_CHECK_MODULES(LIBFFI, libffi)
 891 AC_SUBST(LIBFFI_CFLAGS)
 892 AC_SUBST(LIBFFI_LIBS)
 893
 894 dnl figure out approriate ffi type for size_t
 895 AC_CHECK_SIZEOF(size_t)
 896 AC_CHECK_SIZEOF(ssize_t)
 897 ffi_size_type=uint$(($ac_cv_sizeof_size_t*8))
 898 ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8))
 899 AC_DEFINE_UNQUOTED([ffi_type_size_t], ffi_type_${ffi_size_type},
 900                    [ffi type for size_t])
 901 AC_DEFINE_UNQUOTED([ffi_type_ssize_t], ffi_type_${ffi_ssize_type},
 902                    [ffi type for ssize_t])
 903
 904 dnl i18n tests
 905 #AC_CHECK_HEADERS([libintl.h])
 906 #AC_CHECK_FUNCS(gettext)
 907 #if test $ac_cv_func_gettext = no; then
 908 #   AC_CHECK_LIB(intl, gettext)
 909 #fi
 910 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 911 AM_GNU_GETTEXT([external], [need-ngettext])
 912
 913 ### Some systems don't declare some functions.  On such systems, we
 914 ### need to at least provide our own K&R-style declarations.
 915
 916 ### GUILE_FUNC_DECLARED(function, headerfile)
 917
 918 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 919 ### not there, #define MISSING_FUNCTION_DECL.
 920 AC_DEFUN([GUILE_FUNC_DECLARED], [
 921   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 922     AC_EGREP_HEADER($1, $2,
 923                     guile_cv_func_$1_declared=yes,
 924                     guile_cv_func_$1_declared=no))
 925   if test [x$guile_cv_func_]$1[_declared] = xno; then
 926     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 927       [Define if the operating system supplies $1 without declaring it.])
 928   fi
 929 ])
 930
 931 GUILE_FUNC_DECLARED(sleep, unistd.h)
 932 GUILE_FUNC_DECLARED(usleep, unistd.h)
 933
 934 AC_CHECK_DECLS([strptime],,,
 935 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 936 #include <time.h>])
 937
 938 ### On some systems usleep has no return value.  If it does have one,
 939 ### we'd like to return it; otherwise, we'll fake it.
 940 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 941   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 942                    unistd.h,
 943                    [guile_cv_func_usleep_return_type=void],
 944                    [guile_cv_func_usleep_return_type=int])])
 945 case "$guile_cv_func_usleep_return_type" in
 946   "void" )
 947     AC_DEFINE([USLEEP_RETURNS_VOID], 1,
 948       [Define if the system headers declare usleep to return void.])
 949   ;;
 950 esac
 951
 952 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 953 if test -n "$have_sys_un_h" ; then
 954   AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1,
 955     [Define if the system supports Unix-domain (file-domain) sockets.])
 956 fi
 957
 958 AC_CHECK_FUNCS(getrlimit setrlimit)
 959
 960 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 961
 962 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 963                setnetent    getnetent    endnetent    dnl
 964                setprotoent  getprotoent  endprotoent  dnl
 965                setservent   getservent   endservent   dnl
 966                getnetbyaddr getnetbyname dnl
 967                inet_lnaof inet_makeaddr inet_netof hstrerror)
 968
 969 AC_CHECK_MEMBERS([struct sockaddr_in.sin_len],,,
 970 [#ifdef HAVE_SYS_TYPES_H
 971 #include <sys/types.h>
 972 #endif
 973 #include <netinet/in.h>])
 974
 975 AC_MSG_CHECKING(for __libc_stack_end)
 976 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 977 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 978 extern char *__libc_stack_end;]],
 979    [[printf("%p", (char*) __libc_stack_end);]])],
 980    [guile_cv_have_libc_stack_end=yes],
 981    [guile_cv_have_libc_stack_end=no])])
 982 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 983
 984 if test $guile_cv_have_libc_stack_end = yes; then
 985   AC_DEFINE([HAVE_LIBC_STACK_END], 1,
 986            [Define if you have the __libc_stack_end variable.])
 987 fi
 988
 989 dnl Some systems do not declare this.  Some systems do declare it, as a
 990 dnl macro.  With cygwin it may be in a DLL.
 991
 992 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 993 AC_CACHE_VAL(guile_cv_have_h_errno,
 994   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 995                                       [[int a = h_errno;]])],
 996   [guile_cv_have_h_errno=yes],
 997   [guile_cv_have_h_errno=no])])
 998 AC_MSG_RESULT($guile_cv_have_h_errno)
 999 if test $guile_cv_have_h_errno = yes; then
1000   AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.])
1001 fi
1002
1003 AC_MSG_CHECKING(whether uint32_t is defined)
1004 AC_CACHE_VAL(guile_cv_have_uint32_t,
1005   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1006                    #if HAVE_STDINT_H
1007                    #include <stdint.h>
1008                    #endif
1009                    #ifndef HAVE_NETDB_H
1010                    #include <netdb.h>
1011                    #endif]],
1012                    [[uint32_t a;]])],
1013                    [guile_cv_have_uint32_t=yes],
1014                    [guile_cv_have_uint32_t=no])])
1015 AC_MSG_RESULT($guile_cv_have_uint32_t)
1016 if test $guile_cv_have_uint32_t = yes; then
1017   AC_DEFINE([HAVE_UINT32_T], 1,
1018     [Define if uint32_t typedef is defined when netdb.h is include.])
1019 fi
1020
1021 AC_MSG_CHECKING(for working IPv6 support)
1022 AC_CACHE_VAL(guile_cv_have_ipv6,
1023 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1024 #ifdef HAVE_SYS_TYPES_H
1025 #include <sys/types.h>
1026 #endif
1027 #include <netinet/in.h>
1028 #include <sys/socket.h>]],
1029 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
1030 [guile_cv_have_ipv6=yes],
1031 [guile_cv_have_ipv6=no])])
1032 AC_MSG_RESULT($guile_cv_have_ipv6)
1033 if test $guile_cv_have_ipv6 = yes; then
1034   AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.])
1035 fi
1036
1037 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
1038 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
1039 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
1040 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1041 #ifdef HAVE_SYS_TYPES_H
1042 #include <sys/types.h>
1043 #endif
1044 #include <netinet/in.h>]],
1045 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
1046 [guile_cv_have_sin6_scope_id=yes],
1047 [guile_cv_have_sin6_scope_id=no])])
1048 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
1049 if test $guile_cv_have_sin6_scope_id = yes; then
1050   AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1,
1051     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
1052 fi
1053
1054 # struct sockaddr_in6 field sin_len is only present on BSD systems
1055 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1056 [#ifdef HAVE_SYS_TYPES_H
1057 #include <sys/types.h>
1058 #endif
1059 #include <netinet/in.h>])
1060
1061 AC_MSG_CHECKING(whether localtime caches TZ)
1062 AC_CACHE_VAL(guile_cv_localtime_cache,
1063 [if test x$ac_cv_func_tzset = xyes; then
1064 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1065 #if STDC_HEADERS
1066 # include <stdlib.h>
1067 #endif
1068 extern char **environ;
1069 unset_TZ ()
1070 {
1071   char **from, **to;
1072   for (to = from = environ; (*to = *from); from++)
1073     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1074       to++;
1075 }
1076 char TZ_GMT0[] = "TZ=GMT0";
1077 char TZ_PST8[] = "TZ=PST8";
1078 main()
1079 {
1080   time_t now = time ((time_t *) 0);
1081   int hour_GMT0, hour_unset;
1082   if (putenv (TZ_GMT0) != 0)
1083     exit (1);
1084   hour_GMT0 = localtime (&now)->tm_hour;
1085   unset_TZ ();
1086   hour_unset = localtime (&now)->tm_hour;
1087   if (putenv (TZ_PST8) != 0)
1088     exit (1);
1089   if (localtime (&now)->tm_hour == hour_GMT0)
1090     exit (1);
1091   unset_TZ ();
1092   if (localtime (&now)->tm_hour != hour_unset)
1093     exit (1);
1094   exit (0);
1095 }]])],
1096 [guile_cv_localtime_cache=no],
1097 [guile_cv_localtime_cache=yes],
1098 [# If we have tzset, assume the worst when cross-compiling.
1099 guile_cv_localtime_cache=yes])
1100 else
1101         # If we lack tzset, report that localtime does not cache TZ,
1102         # since we can't invalidate the cache if we don't have tzset.
1103         guile_cv_localtime_cache=no
1104 fi])dnl
1105 AC_MSG_RESULT($guile_cv_localtime_cache)
1106 if test $guile_cv_localtime_cache = yes; then
1107   AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.])
1108 fi
1109
1110 if test "$enable_regex" = yes; then
1111    if test "$ac_cv_header_regex_h" = yes ||
1112       test "$ac_cv_header_rxposix_h" = yes ||
1113       test "$ac_cv_header_rx_rxposix_h" = yes; then
1114      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1115      [AC_CHECK_LIB(rx, main)
1116       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1117      [AC_CHECK_LIB(regex, main)
1118       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1119      )
1120      dnl The following should not be necessary, but for some reason
1121      dnl autoheader misses it if we don't include it!
1122      if test "$ac_cv_func_regcomp_norx" = yes ||
1123         test "$ac_cv_func_regcomp_regex" = yes ||
1124         test "$ac_cv_func_regcomp_rx" = yes; then
1125        AC_DEFINE([HAVE_REGCOMP], 1,
1126          [This is included as part of a workaround for a autoheader bug.])
1127      fi
1128    fi
1129 fi
1130
1131 AC_REPLACE_FUNCS([strerror memmove mkstemp])
1132
1133 # Reasons for testing:
1134 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1135 #                                older systems
1136 #   sincos - GLIBC extension
1137 #
1138 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1139
1140 # C99 specifies isinf and isnan as macros.
1141 # HP-UX provides only macros, no functions.
1142 # glibc 2.3.2 provides both macros and functions.
1143 # IRIX 6.5 and Solaris 8 only provide functions.
1144 #
1145 # The following tests detect isinf and isnan either as functions or as
1146 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1147 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1148 #
1149 AC_MSG_CHECKING([for isinf])
1150 AC_LINK_IFELSE([AC_LANG_SOURCE(
1151 [[#include <math.h>
1152 volatile double x = 0.0;
1153 int main () { return (isinf(x) != 0); }]])],
1154   [AC_MSG_RESULT([yes])
1155    AC_DEFINE([HAVE_ISINF], 1,
1156              [Define to 1 if you have the `isinf' macro or function.])],
1157   [AC_MSG_RESULT([no])])
1158 AC_MSG_CHECKING([for isnan])
1159 AC_LINK_IFELSE([AC_LANG_SOURCE([[
1160 #include <math.h>
1161 volatile double x = 0.0;
1162 int main () { return (isnan(x) != 0); }]])],
1163   [AC_MSG_RESULT([yes])
1164    AC_DEFINE([HAVE_ISNAN], 1,
1165              [Define to 1 if you have the `isnan' macro or function.])],
1166   [AC_MSG_RESULT([no])])
1167
1168 # Reasons for checking:
1169 #
1170 #     st_rdev
1171 #     st_blksize
1172 #     st_blocks   not in mingw
1173 #     tm_gmtoff   BSD+GNU, not in C99
1174 #
1175 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1176 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1177 #
1178 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,,
1179                  [#define _GNU_SOURCE
1180 AC_INCLUDES_DEFAULT
1181 ])
1182
1183 AC_STRUCT_TIMEZONE
1184 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1185 [#include <time.h>
1186 #ifdef TIME_WITH_SYS_TIME
1187 # include <sys/time.h>
1188 # include <time.h>
1189 #else
1190 # if HAVE_SYS_TIME_H
1191 #  include <sys/time.h>
1192 # else
1193 #  include <time.h>
1194 # endif
1195 #endif
1196 ])
1197 GUILE_STRUCT_UTIMBUF
1198
1199
1200 #--------------------------------------------------------------------
1201 #
1202 # What values do the iconv error handlers have?
1203 #
1204 # The only place that we need iconv in our public interfaces is for
1205 # the error handlers, which are just ints.  So we weaken our
1206 # dependency by looking up those values at configure-time.
1207 #--------------------------------------------------------------------
1208 GUILE_UNISTRING_ICONVEH_VALUES
1209
1210 #--------------------------------------------------------------------
1211 #
1212 # Which way does the stack grow?
1213 #
1214 # Following code comes from Autoconf 2.61's internal _AC_LIBOBJ_ALLOCA
1215 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1216 # very similar code, so in future we could look at using that.
1217 #
1218 # An important detail is that the code involves find_stack_direction
1219 # calling _itself_ - which means that find_stack_direction (or at
1220 # least the second find_stack_direction() call) cannot be inlined.
1221 # If the code could be inlined, that might cause the test to give
1222 # an incorrect answer.
1223 #--------------------------------------------------------------------
1224
1225 SCM_I_GSC_STACK_GROWS_UP=0
1226 AC_RUN_IFELSE([AC_LANG_SOURCE(
1227 [AC_INCLUDES_DEFAULT
1228 int
1229 find_stack_direction ()
1230 {
1231   static char *addr = 0;
1232   auto char dummy;
1233   if (addr == 0)
1234     {
1235       addr = &dummy;
1236       return find_stack_direction ();
1237     }
1238   else
1239     return (&dummy > addr) ? 1 : -1;
1240 }
1241
1242 int
1243 main ()
1244 {
1245   return find_stack_direction () < 0;
1246 }])],
1247                [SCM_I_GSC_STACK_GROWS_UP=1],
1248                [],
1249                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1250
1251 #--------------------------------------------------------------------
1252 #
1253 # Boehm's GC library
1254 #
1255 #--------------------------------------------------------------------
1256 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1257
1258 save_LIBS="$LIBS"
1259 LIBS="$BDW_GC_LIBS $LIBS"
1260 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1261
1262 AC_CHECK_FUNCS([GC_do_blocking GC_call_with_gc_active GC_pthread_exit GC_pthread_cancel GC_allow_register_threads GC_pthread_sigmask GC_set_start_callback])
1263
1264 # Though the `GC_do_blocking ()' symbol is present in GC 7.1, it is not
1265 # declared, and has a different type (returning void instead of
1266 # void*).
1267 AC_CHECK_DECL([GC_do_blocking],
1268   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1269     [Define this if the `GC_do_blocking ()' function is declared])],
1270   [],
1271   [#include <gc/gc.h>])
1272
1273 # `GC_fn_type' is not available in GC 7.1 and earlier.
1274 AC_CHECK_TYPE([GC_fn_type],
1275   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1276     [Define this if the `GC_fn_type' type is available.])],
1277   [],
1278   [#include <gc/gc.h>])
1279
1280 # `GC_stack_base' is not available in GC 7.1 and earlier.
1281 AC_CHECK_TYPE([struct GC_stack_base],
1282   [AC_DEFINE([HAVE_GC_STACK_BASE], [1],
1283     [Define this if the `GC_stack_base' type is available.])],
1284   [],
1285   [#include <gc/gc.h>])
1286
1287 LIBS="$save_LIBS"
1288
1289
1290 AC_CHECK_SIZEOF(float)
1291 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1292     AC_DEFINE([SCM_SINGLES], 1,
1293               [Define this if floats are the same size as longs.])
1294 fi
1295
1296 AC_MSG_CHECKING(for struct linger)
1297 AC_CACHE_VAL(scm_cv_struct_linger,
1298         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1299 #include <sys/types.h>
1300 #include <sys/socket.h>]],
1301                           [[struct linger lgr;  lgr.l_linger = 100]])],
1302                           [scm_cv_struct_linger="yes"],
1303                           [scm_cv_struct_linger="no"]))
1304 AC_MSG_RESULT($scm_cv_struct_linger)
1305 if test $scm_cv_struct_linger = yes; then
1306         AC_DEFINE([HAVE_STRUCT_LINGER], 1,
1307           [Define this if your system defines struct linger, for use with the
1308            getsockopt and setsockopt system calls.])
1309 fi
1310
1311
1312 # On mingw, struct timespec is in <pthread.h>.
1313 #
1314 AC_MSG_CHECKING(for struct timespec)
1315 AC_CACHE_VAL(scm_cv_struct_timespec,
1316         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1317 #include <time.h>
1318 #if HAVE_PTHREAD_H
1319 #include <pthread.h>
1320 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1321           [scm_cv_struct_timespec="yes"],
1322           [scm_cv_struct_timespec="no"]))
1323 AC_MSG_RESULT($scm_cv_struct_timespec)
1324 if test $scm_cv_struct_timespec = yes; then
1325   AC_DEFINE([HAVE_STRUCT_TIMESPEC], 1,
1326     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1327 fi
1328
1329 #--------------------------------------------------------------------
1330 #
1331 # Flags for thread support
1332 #
1333 #--------------------------------------------------------------------
1334
1335 SCM_I_GSC_USE_PTHREAD_THREADS=0
1336 SCM_I_GSC_USE_NULL_THREADS=0
1337 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1338 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1339
1340 ### What thread package has the user asked for?
1341 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1342             , with_threads=yes)
1343
1344 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1345 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1346
1347 case "$with_threads" in
1348   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1349
1350     build_pthread_support="yes"
1351
1352     ACX_PTHREAD([CC="$PTHREAD_CC"
1353        LIBS="$PTHREAD_LIBS $LIBS"
1354        SCM_I_GSC_USE_PTHREAD_THREADS=1
1355        with_threads="pthreads"],
1356       [with_threads="null"
1357        build_pthread_support="no"])
1358
1359     old_CFLAGS="$CFLAGS"
1360     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1361
1362     # Reasons for testing:
1363     #     pthread_getattr_np - "np" meaning "non portable" says it
1364     #         all; not present on MacOS X or Solaris 10
1365     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1366     #         all; specific to MacOS X
1367     #     pthread_sigmask - not available on mingw
1368     #
1369     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1370
1371     # On past versions of Solaris, believe 8 through 10 at least, you
1372     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1373     # This is contrary to POSIX:
1374     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1375     # Check here if this style is required.
1376     #
1377     # glibc (2.3.6 at least) works both with or without braces, so the
1378     # test checks whether it works without.
1379     #
1380
1381     if test "$GCC" = "yes"; then
1382       # Since GCC only issues a warning for missing braces, so we need
1383       # `-Werror' to catch it.
1384       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1385     fi
1386
1387     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1388       guile_cv_need_braces_on_pthread_once_init,
1389       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>
1390          pthread_once_t foo = PTHREAD_ONCE_INIT;]])],
1391         [guile_cv_need_braces_on_pthread_once_init=no],
1392         [guile_cv_need_braces_on_pthread_once_init=yes])])
1393     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1394       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1395     fi
1396
1397     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1398     # 6.5.30m with GCC 3.3.
1399     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1400       guile_cv_need_braces_on_pthread_mutex_initializer,
1401       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>
1402          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;]])],
1403         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1404         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1405     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1406       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1407     fi
1408
1409     CFLAGS="$old_CFLAGS"
1410
1411     # On Solaris, sched_yield lives in -lrt.
1412     AC_SEARCH_LIBS(sched_yield, rt)
1413
1414   ;;
1415 esac
1416
1417 case "$with_threads" in
1418   "pthreads")
1419   ;;
1420   "no" | "null")
1421     SCM_I_GSC_USE_NULL_THREADS=1
1422     SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
1423     with_threads="null-threads"
1424   ;;
1425   * )
1426     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1427   ;;
1428 esac
1429
1430 AC_MSG_CHECKING(what kind of threads to support)
1431 AC_MSG_RESULT($with_threads)
1432
1433 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1434   [test "x$build_pthread_support" = "xyes"])
1435
1436
1437 ## Check whether pthread_attr_getstack works for the main thread
1438
1439 if test "$with_threads" = pthreads; then
1440
1441 AC_MSG_CHECKING([whether pthread_attr_getstack works for the main thread])
1442 old_CFLAGS="$CFLAGS"
1443 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1444 if test "$cross_compiling" = "no"; then
1445   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1446   #if HAVE_PTHREAD_ATTR_GETSTACK
1447   #include <pthread.h>
1448
1449   int main ()
1450   {
1451     pthread_attr_t attr;
1452     void *start, *end;
1453     size_t size;
1454
1455     pthread_getattr_np (pthread_self (), &attr);
1456     pthread_attr_getstack (&attr, &start, &size);
1457     end = (char *)start + size;
1458
1459     if ((void *)&attr < start || (void *)&attr >= end)
1460       return 1;
1461     else
1462       return 0;
1463   }
1464   #else
1465   int main ()
1466   {
1467     return 1;
1468   }
1469   #endif
1470   ]])],
1471   [works=yes
1472    AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])],
1473   [works=no],
1474   [])
1475 else
1476   works="assuming it doesn't"
1477 fi
1478 CFLAGS="$old_CFLAGS"
1479 AC_MSG_RESULT($works)
1480
1481 GUILE_THREAD_LOCAL_STORAGE
1482
1483 fi # with_threads=pthreads
1484
1485
1486 ## Cross building
1487 if test "$cross_compiling" = "yes"; then
1488   AC_MSG_CHECKING(cc for build)
1489   ## /usr/bin/cc still uses wrong assembler
1490   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1491   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1492 else
1493   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1494 fi
1495
1496 ## AC_MSG_CHECKING("if we are cross compiling")
1497 ## AC_MSG_RESULT($cross_compiling)
1498 if test "$cross_compiling" = "yes"; then
1499    AC_MSG_RESULT($CC_FOR_BUILD)
1500 fi
1501
1502 ## No need as yet to be more elaborate
1503 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1504
1505 AC_SUBST(cross_compiling)
1506 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1507 AC_SUBST(CCLD_FOR_BUILD)
1508
1509 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1510 ## --HOST is the platform that PACKAGE is compiled for.
1511 HOST_CC="$CC_FOR_BUILD"
1512 AC_SUBST(HOST_CC)
1513
1514 if test "$cross_compiling" = "yes"; then
1515   AC_MSG_CHECKING(guile for build)
1516   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1517 else
1518   GUILE_FOR_BUILD='this-value-will-never-be-used'
1519 fi
1520
1521 ## AC_MSG_CHECKING("if we are cross compiling")
1522 ## AC_MSG_RESULT($cross_compiling)
1523 if test "$cross_compiling" = "yes"; then
1524    AC_MSG_RESULT($GUILE_FOR_BUILD)
1525 fi
1526 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1527 AM_SUBST_NOTMAKE(GUILE_FOR_BUILD)
1528
1529 ## If we're using GCC, ask for aggressive warnings.
1530 GCC_CFLAGS=""
1531 case "$GCC" in
1532   yes )
1533     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1534     ## much stuff with generic function pointers for that to really be
1535     ## less than exasperating.
1536     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1537     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1538     ## -Wundef was removed because Gnulib prevented it (see
1539     ## <http://thread.gmane.org/gmane.lisp.guile.bugs/5329>.)
1540     POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \
1541       -Wdeclaration-after-statement \
1542       -Wswitch-enum"
1543     # Do this here so we don't screw up any of the tests above that might
1544     # not be "warning free"
1545     if test "${GUILE_ERROR_ON_WARNING}" = yes
1546     then
1547         POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror"
1548         enable_compile_warnings=no
1549     fi
1550
1551     for flag in $POTENTIAL_GCC_CFLAGS
1552     do
1553         gl_WARN_ADD([$flag], [GCC_CFLAGS])
1554     done
1555     ;;
1556 esac
1557
1558 AC_SUBST(GCC_CFLAGS)
1559
1560 # Check for GNU ld's "-z relro".
1561 GUILE_GNU_LD_RELRO
1562
1563
1564 ## If we're creating a shared library (using libtool!), then we'll
1565 ## need to generate a list of .lo files corresponding to the .o files
1566 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1567 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1568
1569 ## We also need to create corresponding .doc and .x files
1570 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1571 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1572
1573 # GNU Readline bindings.
1574 GUILE_READLINE
1575
1576 AC_SUBST(GUILE_MAJOR_VERSION)
1577 AC_SUBST(GUILE_MINOR_VERSION)
1578 AC_SUBST(GUILE_MICRO_VERSION)
1579 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1580 AC_SUBST(GUILE_VERSION)
1581
1582 #######################################################################
1583 # library versioning
1584
1585 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1586 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1587 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1588 AC_SUBST(LIBGUILE_INTERFACE)
1589
1590 AC_SUBST(LIBGUILE_I18N_MAJOR)
1591 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1592 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1593 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1594 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1595
1596
1597 #######################################################################
1598
1599 dnl Tell guile-config what flags guile users should compile and link
1600 dnl with, keeping only `-I' flags from $CPPFLAGS.
1601 GUILE_CFLAGS=""
1602 next_is_includedir=false
1603 for flag in $CPPFLAGS
1604 do
1605   if $next_is_includedir; then
1606     GUILE_CFLAGS="$GUILE_CFLAGS -I $flag"
1607     next_is_includedir=false
1608   else
1609     case "$flag" in
1610       -I)  next_is_includedir=true;;
1611       -I*) GUILE_CFLAGS="$GUILE_CFLAGS $flag";;
1612       *)   ;;
1613     esac
1614   fi
1615 done
1616
1617 GUILE_CFLAGS="$GUILE_CFLAGS $PTHREAD_CFLAGS"
1618 GUILE_LIBS="$LDFLAGS $LIBS"
1619
1620 AC_SUBST(GUILE_LIBS)
1621 AC_SUBST(GUILE_CFLAGS)
1622
1623 AC_SUBST(AWK)
1624 AC_SUBST(LIBLOBJS)
1625 AC_SUBST(EXTRA_DOT_DOC_FILES)
1626 AC_SUBST(EXTRA_DOT_X_FILES)
1627
1628 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1629 top_builddir_absolute=`pwd`
1630 AC_SUBST(top_builddir_absolute)
1631 top_srcdir_absolute=`(cd $srcdir && pwd)`
1632 AC_SUBST(top_srcdir_absolute)
1633
1634 dnl `sitedir' goes into libpath.h and the pkg-config file.
1635 pkgdatadir="$datadir/$PACKAGE_TARNAME"
1636 sitedir="$pkgdatadir/site/$GUILE_EFFECTIVE_VERSION"
1637 AC_SUBST([sitedir])
1638
1639 # Additional SCM_I_GSC definitions are above.
1640 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1641 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1642 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1643 AC_SUBST([SCM_I_GSC_C_INLINE])
1644 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1645
1646 AC_CONFIG_FILES([
1647   Makefile
1648   am/Makefile
1649   lib/Makefile
1650   benchmark-suite/Makefile
1651   gc-benchmarks/Makefile
1652   doc/Makefile
1653   doc/r5rs/Makefile
1654   doc/ref/Makefile
1655   emacs/Makefile
1656   examples/Makefile
1657   libguile/Makefile
1658   libguile/version.h
1659   guile-readline/Makefile
1660   test-suite/Makefile
1661   test-suite/standalone/Makefile
1662   test-suite/vm/Makefile
1663   meta/Makefile
1664   module/Makefile
1665 ])
1666
1667 AC_CONFIG_FILES([meta/guile-2.0.pc])
1668 AC_CONFIG_FILES([meta/guile-2.0-uninstalled.pc])
1669 AC_CONFIG_FILES([doc/ref/effective-version.texi])
1670
1671 GUILE_CONFIG_SCRIPT([check-guile])
1672 GUILE_CONFIG_SCRIPT([benchmark-guile])
1673 GUILE_CONFIG_SCRIPT([meta/guile])
1674 GUILE_CONFIG_SCRIPT([meta/uninstalled-env])
1675 GUILE_CONFIG_SCRIPT([meta/gdb-uninstalled-guile])
1676 GUILE_CONFIG_SCRIPT([meta/guild])
1677 GUILE_CONFIG_SCRIPT([libguile/guile-snarf])
1678 GUILE_CONFIG_SCRIPT([libguile/guile-snarf-docs])
1679 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-use-srfi])
1680 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-fast-slot-ref])
1681
1682 AC_OUTPUT
1683
1684 dnl Local Variables:
1685 dnl comment-start: "dnl "
1686 dnl comment-end: ""
1687 dnl comment-start-skip: "\\bdnl\\b\\s *"
1688 dnl End: