test-suite/tests/ports.test

   1 ;;;; ports.test --- test suite for Guile I/O ports     -*- scheme -*-
   2 ;;;; Jim Blandy <jimb@red-bean.com> --- October 1998
   3 ;;;;
   4 ;;;;    Copyright (C) 1998, 1999 Free Software Foundation, Inc.
   5 ;;;;
   6 ;;;; This program is free software; you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation; either version 2, or (at your option)
   9 ;;;; any later version.
  10 ;;;;
  11 ;;;; This program is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with this software; see the file COPYING.  If not, write to
  18 ;;;; the Free Software Foundation, Inc., 59 Temple Place, Suite 330,
  19 ;;;; Boston, MA 02111-1307 USA
  20
  21 (use-modules (test-suite lib)
  22              (ice-9 popen))
  23
  24 (define (display-line . args)
  25   (for-each display args)
  26   (newline))
  27
  28 (define (test-file)
  29   (tmpnam))
  30
  31 \f
  32 ;;;; Some general utilities for testing ports.
  33
  34 ;;; Read from PORT until EOF, and return the result as a string.
  35 (define (read-all port)
  36   (let loop ((chars '()))
  37     (let ((char (read-char port)))
  38       (if (eof-object? char)
  39           (list->string (reverse! chars))
  40           (loop (cons char chars))))))
  41
  42 (define (read-file filename)
  43   (let* ((port (open-input-file filename))
  44          (string (read-all port)))
  45     (close-port port)
  46     string))
  47
  48 \f
  49 ;;;; Normal file ports.
  50
  51 ;;; Write out an s-expression, and read it back.
  52 (catch-test-errors
  53  (let ((string '("From fairest creatures we desire increase,"
  54                  "That thereby beauty's rose might never die,"))
  55        (filename (test-file)))
  56    (let ((port (open-output-file filename)))
  57      (write string port)
  58      (close-port port))
  59    (let ((port (open-input-file filename)))
  60      (let ((in-string (read port)))
  61        (pass-if "file: write and read back list of strings"
  62                 (equal? string in-string)))
  63      (close-port port))
  64    (delete-file filename)))
  65
  66 ;;; Write out a string, and read it back a character at a time.
  67 (catch-test-errors
  68  (let ((string "This is a test string\nwith no newline at the end")
  69        (filename (test-file)))
  70    (let ((port (open-output-file filename)))
  71      (display string port)
  72      (close-port port))
  73    (let ((in-string (read-file filename)))
  74      (pass-if "file: write and read back characters"
  75               (equal? string in-string)))
  76    (delete-file filename)))
  77
  78 ;;; Buffered input/output port with seeking.
  79 (catch-test-errors
  80  (let* ((filename (test-file))
  81         (port (open-file filename "w+")))
  82    (display "J'Accuse" port)
  83    (seek port -1 SEEK_CUR)
  84    (pass-if "file: r/w 1"
  85             (char=? (read-char port) #\e))
  86    (pass-if "file: r/w 2"
  87             (eof-object? (read-char port)))
  88    (seek port -1 SEEK_CUR)
  89    (write-char #\x port)
  90    (seek port 7 SEEK_SET)
  91    (pass-if "file: r/w 3"
  92             (char=? (read-char port) #\x))
  93    (seek port -2 SEEK_END)
  94    (pass-if "file: r/w 4"
  95             (char=? (read-char port) #\s))
  96    (delete-file filename)))
  97
  98 ;;; Unbuffered input/output port with seeking.
  99 (catch-test-errors
 100  (let* ((filename (test-file))
 101         (port (open-file filename "w+0")))
 102    (display "J'Accuse" port)
 103    (seek port -1 SEEK_CUR)
 104    (pass-if "file: ub r/w 1"
 105             (char=? (read-char port) #\e))
 106    (pass-if "file: ub r/w 2"
 107             (eof-object? (read-char port)))
 108    (seek port -1 SEEK_CUR)
 109    (write-char #\x port)
 110    (seek port 7 SEEK_SET)
 111    (pass-if "file: ub r/w 3"
 112             (char=? (read-char port) #\x))
 113    (seek port -2 SEEK_END)
 114    (pass-if "file: ub r/w 4"
 115             (char=? (read-char port) #\s))
 116    (delete-file filename)))
 117
 118 ;;; unusual characters.
 119 (catch-test-errors
 120  (let* ((filename (test-file))
 121         (port (open-output-file filename)))
 122    (display (string #\nul (integer->char 255) (integer->char 128)
 123                     #\nul) port)
 124    (close-port port)
 125    (let* ((port (open-input-file filename))
 126           (line (read-line port)))
 127      (pass-if "file: read back NUL 1"
 128               (char=? (string-ref line 0) #\nul))
 129      (pass-if "file: read back 255"
 130               (char=? (string-ref line 1) (integer->char 255)))
 131      (pass-if "file: read back 128"
 132               (char=? (string-ref line 2) (integer->char 128)))
 133      (pass-if "file: read back NUL 2"
 134               (char=? (string-ref line 3) #\nul))
 135      (pass-if "file: EOF"
 136               (eof-object? (read-char port))))
 137    (delete-file filename)))
 138
 139 ;;; line buffering mode.
 140 (catch-test-errors
 141  (let* ((filename (test-file))
 142         (port (open-file filename "wl"))
 143         (test-string "one line more or less"))
 144    (write-line test-string port)
 145    (let* ((in-port (open-input-file filename))
 146           (line (read-line in-port)))
 147      (close-port in-port)
 148      (close-port port)
 149      (pass-if "file: line buffering"
 150               (string=? line test-string)))
 151    (delete-file filename)))
 152
 153 ;;; ungetting characters and strings.
 154 (catch-test-errors
 155  (with-input-from-string "walk on the moon\nmoon"
 156                          (lambda ()
 157                            (read-char)
 158                            (unread-char #\a (current-input-port))
 159                            (pass-if "unread-char"
 160                                     (char=? (read-char) #\a))
 161                            (read-line)
 162                            (let ((replacenoid "chicken enchilada"))
 163                              (unread-char #\newline (current-input-port))
 164                              (unread-string replacenoid (current-input-port))
 165                              (pass-if "unread-string"
 166                                       (string=? (read-line) replacenoid)))
 167                            (pass-if "unread residue"
 168                                     (string=? (read-line) "moon")))))
 169
 170 \f
 171 ;;;; Pipe ports.
 172
 173 ;;; Run a command, and read its output.
 174 (catch-test-errors
 175  (let* ((pipe (open-pipe "echo 'Howdy there, partner!'" "r"))
 176         (in-string (read-all pipe)))
 177    (close-pipe pipe)
 178    (pass-if "pipe: read"
 179             (equal? in-string "Howdy there, partner!\n"))))
 180
 181 ;;; Run a command, send some output to it, and see if it worked.
 182 (catch-test-errors
 183  (let* ((filename (test-file))
 184         (pipe (open-pipe (string-append "grep Mommy > " filename) "w")))
 185    (display "Now Jimmy lives on a mushroom cloud\n" pipe)
 186    (display "Mommy, why does everybody have a bomb?\n" pipe)
 187    (close-pipe pipe)
 188    (let ((in-string (read-file filename)))
 189      (pass-if "pipe: write"
 190               (equal? in-string "Mommy, why does everybody have a bomb?\n")))
 191    (delete-file filename)))
 192
 193 \f
 194 ;;;; Void ports.  These are so trivial we don't test them.
 195
 196 \f
 197 ;;;; String ports.
 198
 199 (with-test-prefix "string ports"
 200
 201   ;; Write text to a string port.
 202   (catch-test-errors
 203    (let* ((string "Howdy there, partner!")
 204           (in-string (call-with-output-string
 205                       (lambda (port)
 206                         (display string port)
 207                         (newline port)))))
 208      (pass-if "display text"
 209               (equal? in-string (string-append string "\n")))))
 210
 211   ;; Write an s-expression to a string port.
 212   (catch-test-errors
 213    (let* ((sexpr '("more utterly random text" 1729 #(a vector) 3.1415926))
 214           (in-sexpr
 215            (call-with-input-string (call-with-output-string
 216                                     (lambda (port)
 217                                       (write sexpr port)))
 218                                    read)))
 219      (pass-if "write/read sexpr"
 220               (equal? in-sexpr sexpr)))))
 221
 222 \f
 223 ;;;; Soft ports.  No tests implemented yet.
 224
 225 \f
 226 ;;;; Generic operations across all port types.
 227
 228 (let ((port-loop-temp (test-file)))
 229
 230   ;; Return a list of input ports that all return the same text.
 231   ;; We map tests over this list.
 232   (define (input-port-list text)
 233
 234     ;; Create a text file some of the ports will use.
 235     (let ((out-port (open-output-file port-loop-temp)))
 236       (display text out-port)
 237       (close-port out-port))
 238
 239     (list (open-input-file port-loop-temp)
 240           (open-input-pipe (string-append "cat " port-loop-temp))
 241           (call-with-input-string text (lambda (x) x))
 242           ;; We don't test soft ports at the moment.
 243           ))
 244
 245   (define port-list-names '("file" "pipe" "string"))
 246
 247   ;; Test the line counter.
 248   (define (test-line-counter text second-line final-column)
 249     (with-test-prefix "line counter"
 250       (let ((ports (input-port-list text)))
 251         (for-each
 252          (lambda (port port-name)
 253            (with-test-prefix port-name
 254              (pass-if "at beginning of input"
 255                       (= (port-line port) 0))
 256              (pass-if "read first character"
 257                       (eqv? (read-char port) #\x))
 258              (pass-if "after reading one character"
 259                       (= (port-line port) 0))
 260              (pass-if "read first newline"
 261                       (eqv? (read-char port) #\newline))
 262              (pass-if "after reading first newline char"
 263                       (= (port-line port) 1))
 264              (pass-if "second line read correctly"
 265                       (equal? (read-line port) second-line))
 266              (pass-if "read-line increments line number"
 267                       (= (port-line port) 2))
 268              (pass-if "read-line returns EOF"
 269                       (let loop ((i 0))
 270                         (cond
 271                          ((eof-object? (read-line port)) #t)
 272                          ((> i 20) #f)
 273                          (else (loop (+ i 1))))))
 274              (pass-if "line count is 5 at EOF"
 275                       (= (port-line port) 5))
 276              (pass-if "column is correct at EOF"
 277                       (= (port-column port) final-column))))
 278          ports port-list-names)
 279         (for-each close-port ports)
 280         (delete-file port-loop-temp))))
 281
 282   (catch-test-errors
 283    (with-test-prefix "newline"
 284      (test-line-counter
 285       (string-append "x\n"
 286                      "He who receives an idea from me, receives instruction\n"
 287                      "himself without lessening mine; as he who lights his\n"
 288                      "taper at mine, receives light without darkening me.\n"
 289                      "  --- Thomas Jefferson\n")
 290       "He who receives an idea from me, receives instruction"
 291       0)))
 292
 293   (catch-test-errors
 294    (with-test-prefix "no newline"
 295      (test-line-counter
 296       (string-append "x\n"
 297                      "He who receives an idea from me, receives instruction\n"
 298                      "himself without lessening mine; as he who lights his\n"
 299                      "taper at mine, receives light without darkening me.\n"
 300                      "  --- Thomas Jefferson\n"
 301                      "no newline here")
 302       "He who receives an idea from me, receives instruction"
 303       15))))
 304
 305 \f
 306 ;;;; testing read-delimited and friends
 307
 308 (with-test-prefix "read-delimited!"
 309   (let ((c (make-string 20 #\!)))
 310     (call-with-input-string
 311      "defdef\nghighi\n"
 312      (lambda (port)
 313
 314        (read-delimited! "\n" c port 'concat)
 315        (pass-if "read-delimited! reads a first line"
 316                 (string=? c "defdef\n!!!!!!!!!!!!!"))
 317
 318        (read-delimited! "\n" c port 'concat 3)
 319        (pass-if "read-delimited! reads a first line"
 320                 (string=? c "defghighi\n!!!!!!!!!!"))))))
 321
 322 \f
 323 ;;;; char-ready?
 324
 325 (call-with-input-string
 326  "howdy"
 327  (lambda (port)
 328    (pass-if "char-ready? returns true on string port"
 329             (char-ready? port))))
 330
 331 ;;; This segfaults on some versions of Guile.  We really should run
 332 ;;; the tests in a subprocess...
 333
 334 (call-with-input-string
 335  "howdy"
 336  (lambda (port)
 337    (with-input-from-port
 338        port
 339      (lambda ()
 340        (pass-if "char-ready? returns true on string port as default port"
 341                 (char-ready?))))))