module/language/cps.scm

   1 ;;; Continuation-passing style (CPS) intermediate language (IL)
   2
   3 ;; Copyright (C) 2013, 2014 Free Software Foundation, Inc.
   4
   5 ;;;; This library is free software; you can redistribute it and/or
   6 ;;;; modify it under the terms of the GNU Lesser General Public
   7 ;;;; License as published by the Free Software Foundation; either
   8 ;;;; version 3 of the License, or (at your option) any later version.
   9 ;;;;
  10 ;;;; This library is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 ;;;; Lesser General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU Lesser General Public
  16 ;;;; License along with this library; if not, write to the Free Software
  17 ;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  18
  19 ;;; Commentary:
  20 ;;;
  21 ;;; This is the continuation-passing style (CPS) intermediate language
  22 ;;; (IL) for Guile.
  23 ;;;
  24 ;;; There are two kinds of terms in CPS: terms that bind continuations,
  25 ;;; and terms that call continuations.
  26 ;;;
  27 ;;; $letk binds a set of mutually recursive continuations, each one an
  28 ;;; instance of $cont.  A $cont declares the name of a continuation, and
  29 ;;; then contains as a subterm the particular continuation instance:
  30 ;;; $kif for test continuations, $kargs for continuations that bind
  31 ;;; values, etc.
  32 ;;;
  33 ;;; $continue nodes call continuations.  The expression contained in the
  34 ;;; $continue node determines the value or values that are passed to the
  35 ;;; target continuation: $const to pass a constant value, $values to
  36 ;;; pass multiple named values, etc.  $continue nodes also record the source at which
  37 ;;;
  38 ;;; Additionally there is $letrec, a term that binds mutually recursive
  39 ;;; functions.  The contification pass will turn $letrec into $letk if
  40 ;;; it can do so.  Otherwise, the closure conversion pass will desugar
  41 ;;; $letrec into an equivalent sequence of make-closure primcalls and
  42 ;;; subsequent initializations of the captured variables of the
  43 ;;; closures.  You can think of $letrec as pertaining to "high CPS",
  44 ;;; whereas later passes will only see "low CPS", which does not have
  45 ;;; $letrec.
  46 ;;;
  47 ;;; This particular formulation of CPS was inspired by Andrew Kennedy's
  48 ;;; 2007 paper, "Compiling with Continuations, Continued".  All Guile
  49 ;;; hackers should read that excellent paper!  As in Kennedy's paper,
  50 ;;; continuations are second-class, and may be thought of as basic block
  51 ;;; labels.  All values are bound to variables using continuation calls:
  52 ;;; even constants!
  53 ;;;
  54 ;;; There are some Guile-specific quirks as well:
  55 ;;;
  56 ;;;   - $kreceive represents a continuation that receives multiple values,
  57 ;;;     but which truncates them to some number of required values,
  58 ;;;     possibly with a rest list.
  59 ;;;
  60 ;;;   - $kfun labels an entry point for a $fun (a function), and
  61 ;;;     contains a $ktail representing the formal argument which is the
  62 ;;;     function's continuation.
  63 ;;;
  64 ;;;   - $kfun also contain a $kclause continuation, corresponding to
  65 ;;;     the first case-lambda clause of the function.  $kclause actually
  66 ;;;     contains the clause body, and the subsequent clause (if any).
  67 ;;;     This is because the $kclause logically matches or doesn't match
  68 ;;;     a given set of actual arguments against a formal arity, then
  69 ;;;     proceeds to a "body" continuation (which is a $kargs).
  70 ;;;
  71 ;;;     That's to say that a $fun can be matched like this:
  72 ;;;
  73 ;;;     (match f
  74 ;;;       (($ $fun free
  75 ;;;           ($ $cont kfun
  76 ;;;              ($ $kfun src meta self ($ $cont ktail ($ $ktail))
  77 ;;;                 ($ $kclause arity
  78 ;;;                    ($ $cont kbody ($ $kargs names syms body))
  79 ;;;                    alternate))))
  80 ;;;         #t))
  81 ;;;
  82 ;;;     A $continue to ktail is in tail position.  $kfun, $kclause,
  83 ;;;     and $ktail will never be seen elsewhere in a CPS term.
  84 ;;;
  85 ;;;   - $prompt continues to the body of the prompt, having pushed on a
  86 ;;;     prompt whose handler will continue at its "handler"
  87 ;;;     continuation.  The continuation of the prompt is responsible for
  88 ;;;     popping the prompt.
  89 ;;;
  90 ;;; In summary:
  91 ;;;
  92 ;;;   - $letk, $letrec, and $continue are terms.
  93 ;;;
  94 ;;;   - $cont is a continuation, containing a continuation body ($kargs,
  95 ;;;     $kif, etc).
  96 ;;;
  97 ;;;   - $continue terms contain an expression ($call, $const, $fun,
  98 ;;;     etc).
  99 ;;;
 100 ;;; See (language tree-il compile-cps) for details on how Tree-IL
 101 ;;; converts to CPS.
 102 ;;;
 103 ;;; Code:
 104
 105 (define-module (language cps)
 106   #:use-module (ice-9 match)
 107   #:use-module ((srfi srfi-1) #:select (fold))
 108   #:use-module (srfi srfi-9)
 109   #:use-module (srfi srfi-9 gnu)
 110   #:use-module (srfi srfi-11)
 111   #:export (;; Helper.
 112             $arity
 113             make-$arity
 114
 115             ;; Terms.
 116             $letk $continue $letrec
 117
 118             ;; Continuations.
 119             $cont
 120
 121             ;; Continuation bodies.
 122             $kif $kreceive $kargs $kfun $ktail $kclause
 123
 124             ;; Expressions.
 125             $void $const $prim $fun $closure
 126             $call $callk $primcall $values $prompt
 127
 128             ;; First-order CPS root.
 129             $program
 130
 131             ;; Fresh names.
 132             label-counter var-counter
 133             fresh-label fresh-var
 134             with-fresh-name-state compute-max-label-and-var
 135             let-fresh
 136
 137             ;; Building macros.
 138             build-cps-term build-cps-cont build-cps-exp
 139             rewrite-cps-term rewrite-cps-cont rewrite-cps-exp
 140
 141             ;; Misc.
 142             parse-cps unparse-cps
 143             make-global-cont-folder make-local-cont-folder
 144             fold-conts fold-local-conts
 145             visit-cont-successors))
 146
 147 ;; FIXME: Use SRFI-99, when Guile adds it.
 148 (define-syntax define-record-type*
 149   (lambda (x)
 150     (define (id-append ctx . syms)
 151       (datum->syntax ctx (apply symbol-append (map syntax->datum syms))))
 152     (syntax-case x ()
 153       ((_ name field ...)
 154        (and (identifier? #'name) (and-map identifier? #'(field ...)))
 155        (with-syntax ((cons (id-append #'name #'make- #'name))
 156                      (pred (id-append #'name #'name #'?))
 157                      ((getter ...) (map (lambda (f)
 158                                           (id-append f #'name #'- f))
 159                                         #'(field ...))))
 160          #'(define-record-type name
 161              (cons field ...)
 162              pred
 163              (field getter)
 164              ...))))))
 165
 166 (define-syntax-rule (define-cps-type name field ...)
 167   (begin
 168     (define-record-type* name field ...)
 169     (set-record-type-printer! name print-cps)))
 170
 171 (define (print-cps exp port)
 172   (format port "#<cps ~S>" (unparse-cps exp)))
 173
 174 ;; Helper.
 175 (define-record-type* $arity req opt rest kw allow-other-keys?)
 176
 177 ;; Terms.
 178 (define-cps-type $letk conts body)
 179 (define-cps-type $continue k src exp)
 180 (define-cps-type $letrec names syms funs body) ; Higher-order.
 181
 182 ;; Continuations
 183 (define-cps-type $cont k cont)
 184 (define-cps-type $kif kt kf)
 185 (define-cps-type $kreceive arity k)
 186 (define-cps-type $kargs names syms body)
 187 (define-cps-type $kfun src meta self tail clause)
 188 (define-cps-type $ktail)
 189 (define-cps-type $kclause arity cont alternate)
 190
 191 ;; Expressions.
 192 (define-cps-type $void)
 193 (define-cps-type $const val)
 194 (define-cps-type $prim name)
 195 (define-cps-type $fun free body) ; Higher-order.
 196 (define-cps-type $closure label nfree) ; First-order.
 197 (define-cps-type $call proc args)
 198 (define-cps-type $callk k proc args) ; First-order.
 199 (define-cps-type $primcall name args)
 200 (define-cps-type $values args)
 201 (define-cps-type $prompt escape? tag handler)
 202
 203 ;; The root of a higher-order CPS term is $cont containing a $kfun.  The
 204 ;; root of a first-order CPS term is a $program.
 205 (define-cps-type $program funs)
 206
 207 (define label-counter (make-parameter #f))
 208 (define var-counter (make-parameter #f))
 209
 210 (define (fresh-label)
 211   (let ((count (or (label-counter)
 212                    (error "fresh-label outside with-fresh-name-state"))))
 213     (label-counter (1+ count))
 214     count))
 215
 216 (define (fresh-var)
 217   (let ((count (or (var-counter)
 218                    (error "fresh-var outside with-fresh-name-state"))))
 219     (var-counter (1+ count))
 220     count))
 221
 222 (define-syntax-rule (let-fresh (label ...) (var ...) body ...)
 223   (let ((label (fresh-label)) ...
 224         (var (fresh-var)) ...)
 225     body ...))
 226
 227 (define-syntax-rule (with-fresh-name-state fun body ...)
 228   (call-with-values (lambda () (compute-max-label-and-var fun))
 229     (lambda (max-label max-var)
 230       (parameterize ((label-counter (1+ max-label))
 231                      (var-counter (1+ max-var)))
 232         body ...))))
 233
 234 (define-syntax build-arity
 235   (syntax-rules (unquote)
 236     ((_ (unquote exp)) exp)
 237     ((_ (req opt rest kw allow-other-keys?))
 238      (make-$arity req opt rest kw allow-other-keys?))))
 239
 240 (define-syntax build-cont-body
 241   (syntax-rules (unquote $kif $kreceive $kargs $kfun $ktail $kclause)
 242     ((_ (unquote exp))
 243      exp)
 244     ((_ ($kif kt kf))
 245      (make-$kif kt kf))
 246     ((_ ($kreceive req rest kargs))
 247      (make-$kreceive (make-$arity req '() rest '() #f) kargs))
 248     ((_ ($kargs (name ...) (unquote syms) body))
 249      (make-$kargs (list name ...) syms (build-cps-term body)))
 250     ((_ ($kargs (name ...) (sym ...) body))
 251      (make-$kargs (list name ...) (list sym ...) (build-cps-term body)))
 252     ((_ ($kargs names syms body))
 253      (make-$kargs names syms (build-cps-term body)))
 254     ((_ ($kfun src meta self tail clause))
 255      (make-$kfun src meta self (build-cps-cont tail) (build-cps-cont clause)))
 256     ((_ ($ktail))
 257      (make-$ktail))
 258     ((_ ($kclause arity cont alternate))
 259      (make-$kclause (build-arity arity) (build-cps-cont cont)
 260                     (build-cps-cont alternate)))))
 261
 262 (define-syntax build-cps-cont
 263   (syntax-rules (unquote)
 264     ((_ (unquote exp)) exp)
 265     ((_ (k cont)) (make-$cont k (build-cont-body cont)))))
 266
 267 (define-syntax build-cps-exp
 268   (syntax-rules (unquote
 269                  $void $const $prim $fun $closure
 270                  $call $callk $primcall $values $prompt)
 271     ((_ (unquote exp)) exp)
 272     ((_ ($void)) (make-$void))
 273     ((_ ($const val)) (make-$const val))
 274     ((_ ($prim name)) (make-$prim name))
 275     ((_ ($fun free body)) (make-$fun free (build-cps-cont body)))
 276     ((_ ($closure k nfree)) (make-$closure k nfree))
 277     ((_ ($call proc (unquote args))) (make-$call proc args))
 278     ((_ ($call proc (arg ...))) (make-$call proc (list arg ...)))
 279     ((_ ($call proc args)) (make-$call proc args))
 280     ((_ ($callk k proc (unquote args))) (make-$callk k proc args))
 281     ((_ ($callk k proc (arg ...))) (make-$callk k proc (list arg ...)))
 282     ((_ ($callk k proc args)) (make-$callk k proc args))
 283     ((_ ($primcall name (unquote args))) (make-$primcall name args))
 284     ((_ ($primcall name (arg ...))) (make-$primcall name (list arg ...)))
 285     ((_ ($primcall name args)) (make-$primcall name args))
 286     ((_ ($values (unquote args))) (make-$values args))
 287     ((_ ($values (arg ...))) (make-$values (list arg ...)))
 288     ((_ ($values args)) (make-$values args))
 289     ((_ ($prompt escape? tag handler))
 290      (make-$prompt escape? tag handler))))
 291
 292 (define-syntax build-cps-term
 293   (syntax-rules (unquote $letk $letk* $letconst $letrec $program $continue)
 294     ((_ (unquote exp))
 295      exp)
 296     ((_ ($letk (unquote conts) body))
 297      (make-$letk conts (build-cps-term body)))
 298     ((_ ($letk (cont ...) body))
 299      (make-$letk (list (build-cps-cont cont) ...)
 300                  (build-cps-term body)))
 301     ((_ ($letk* () body))
 302      (build-cps-term body))
 303     ((_ ($letk* (cont conts ...) body))
 304      (build-cps-term ($letk (cont) ($letk* (conts ...) body))))
 305     ((_ ($letconst () body))
 306      (build-cps-term body))
 307     ((_ ($letconst ((name sym val) tail ...) body))
 308      (let-fresh (kconst) ()
 309        (build-cps-term
 310          ($letk ((kconst ($kargs (name) (sym) ($letconst (tail ...) body))))
 311            ($continue kconst (let ((props (source-properties val)))
 312                                (and (pair? props) props))
 313              ($const val))))))
 314     ((_ ($letrec names gensyms funs body))
 315      (make-$letrec names gensyms funs (build-cps-term body)))
 316     ((_ ($program (unquote conts)))
 317      (make-$program conts))
 318     ((_ ($program (cont ...)))
 319      (make-$program (list (build-cps-cont cont) ...)))
 320     ((_ ($program conts))
 321      (make-$program conts))
 322     ((_ ($continue k src exp))
 323      (make-$continue k src (build-cps-exp exp)))))
 324
 325 (define-syntax-rule (rewrite-cps-term x (pat body) ...)
 326   (match x
 327     (pat (build-cps-term body)) ...))
 328 (define-syntax-rule (rewrite-cps-cont x (pat body) ...)
 329   (match x
 330     (pat (build-cps-cont body)) ...))
 331 (define-syntax-rule (rewrite-cps-exp x (pat body) ...)
 332   (match x
 333     (pat (build-cps-exp body)) ...))
 334
 335 (define (parse-cps exp)
 336   (define (src exp)
 337     (let ((props (source-properties exp)))
 338       (and (pair? props) props)))
 339   (match exp
 340     ;; Continuations.
 341     (('letconst k (name sym c) body)
 342      (build-cps-term
 343        ($letk ((k ($kargs (name) (sym)
 344                     ,(parse-cps body))))
 345          ($continue k (src exp) ($const c)))))
 346     (('let k (name sym val) body)
 347      (build-cps-term
 348       ($letk ((k ($kargs (name) (sym)
 349                    ,(parse-cps body))))
 350         ,(parse-cps val))))
 351     (('letk (cont ...) body)
 352      (build-cps-term
 353        ($letk ,(map parse-cps cont) ,(parse-cps body))))
 354     (('k sym body)
 355      (build-cps-cont
 356        (sym ,(parse-cps body))))
 357     (('kif kt kf)
 358      (build-cont-body ($kif kt kf)))
 359     (('kreceive req rest k)
 360      (build-cont-body ($kreceive req rest k)))
 361     (('kargs names syms body)
 362      (build-cont-body ($kargs names syms ,(parse-cps body))))
 363     (('kfun src meta self tail clause)
 364      (build-cont-body
 365       ($kfun (src exp) meta self ,(parse-cps tail)
 366         ,(and=> clause parse-cps))))
 367     (('ktail)
 368      (build-cont-body
 369       ($ktail)))
 370     (('kclause (req opt rest kw allow-other-keys?) body)
 371      (build-cont-body
 372       ($kclause (req opt rest kw allow-other-keys?)
 373         ,(parse-cps body)
 374         ,#f)))
 375     (('kclause (req opt rest kw allow-other-keys?) body alternate)
 376      (build-cont-body
 377       ($kclause (req opt rest kw allow-other-keys?)
 378         ,(parse-cps body)
 379         ,(parse-cps alternate))))
 380     (('kseq body)
 381      (build-cont-body ($kargs () () ,(parse-cps body))))
 382
 383     ;; Calls.
 384     (('continue k exp)
 385      (build-cps-term ($continue k (src exp) ,(parse-cps exp))))
 386     (('void)
 387      (build-cps-exp ($void)))
 388     (('const exp)
 389      (build-cps-exp ($const exp)))
 390     (('prim name)
 391      (build-cps-exp ($prim name)))
 392     (('fun free body)
 393      (build-cps-exp ($fun free ,(parse-cps body))))
 394     (('closure k nfree)
 395      (build-cps-exp ($closure k nfree)))
 396     (('letrec ((name sym fun) ...) body)
 397      (build-cps-term
 398        ($letrec name sym (map parse-cps fun) ,(parse-cps body))))
 399     (('program (cont ...))
 400      (build-cps-term ($program ,(map parse-cps cont))))
 401     (('call proc arg ...)
 402      (build-cps-exp ($call proc arg)))
 403     (('callk k proc arg ...)
 404      (build-cps-exp ($callk k proc arg)))
 405     (('primcall name arg ...)
 406      (build-cps-exp ($primcall name arg)))
 407     (('values arg ...)
 408      (build-cps-exp ($values arg)))
 409     (('prompt escape? tag handler)
 410      (build-cps-exp ($prompt escape? tag handler)))
 411     (_
 412      (error "unexpected cps" exp))))
 413
 414 (define (unparse-cps exp)
 415   (match exp
 416     ;; Continuations.
 417     (($ $letk (($ $cont k ($ $kargs (name) (sym) body)))
 418         ($ $continue k src ($ $const c)))
 419      `(letconst ,k (,name ,sym ,c)
 420                 ,(unparse-cps body)))
 421     (($ $letk (($ $cont k ($ $kargs (name) (sym) body))) val)
 422      `(let ,k (,name ,sym ,(unparse-cps val))
 423            ,(unparse-cps body)))
 424     (($ $letk conts body)
 425      `(letk ,(map unparse-cps conts) ,(unparse-cps body)))
 426     (($ $cont sym body)
 427      `(k ,sym ,(unparse-cps body)))
 428     (($ $kif kt kf)
 429      `(kif ,kt ,kf))
 430     (($ $kreceive ($ $arity req () rest '() #f) k)
 431      `(kreceive ,req ,rest ,k))
 432     (($ $kargs () () body)
 433      `(kseq ,(unparse-cps body)))
 434     (($ $kargs names syms body)
 435      `(kargs ,names ,syms ,(unparse-cps body)))
 436     (($ $kfun src meta self tail clause)
 437      `(kfun ,meta ,self ,(unparse-cps tail) ,(unparse-cps clause)))
 438     (($ $ktail)
 439      `(ktail))
 440     (($ $kclause ($ $arity req opt rest kw allow-other-keys?) body alternate)
 441      `(kclause (,req ,opt ,rest ,kw ,allow-other-keys?) ,(unparse-cps body)
 442                . ,(if alternate (list (unparse-cps alternate)) '())))
 443
 444     ;; Calls.
 445     (($ $continue k src exp)
 446      `(continue ,k ,(unparse-cps exp)))
 447     (($ $void)
 448      `(void))
 449     (($ $const val)
 450      `(const ,val))
 451     (($ $prim name)
 452      `(prim ,name))
 453     (($ $fun free body)
 454      `(fun ,free ,(unparse-cps body)))
 455     (($ $closure k nfree)
 456      `(closure ,k ,nfree))
 457     (($ $letrec names syms funs body)
 458      `(letrec ,(map (lambda (name sym fun)
 459                       (list name sym (unparse-cps fun)))
 460                     names syms funs)
 461         ,(unparse-cps body)))
 462     (($ $program conts)
 463      `(program ,(map unparse-cps conts)))
 464     (($ $call proc args)
 465      `(call ,proc ,@args))
 466     (($ $callk k proc args)
 467      `(callk ,k ,proc ,@args))
 468     (($ $primcall name args)
 469      `(primcall ,name ,@args))
 470     (($ $values args)
 471      `(values ,@args))
 472     (($ $prompt escape? tag handler)
 473      `(prompt ,escape? ,tag ,handler))
 474     (_
 475      (error "unexpected cps" exp))))
 476
 477 (define-syntax-rule (make-global-cont-folder seed ...)
 478   (lambda (proc cont seed ...)
 479     (define (fold-values proc in seed ...)
 480       (if (null? in)
 481           (values seed ...)
 482           (let-values (((seed ...) (proc (car in) seed ...)))
 483             (fold-values proc (cdr in) seed ...))))
 484
 485     (define (cont-folder cont seed ...)
 486       (match cont
 487         (($ $cont k cont)
 488          (let-values (((seed ...) (proc k cont seed ...)))
 489            (match cont
 490              (($ $kargs names syms body)
 491               (term-folder body seed ...))
 492
 493              (($ $kfun src meta self tail clause)
 494               (let-values (((seed ...) (cont-folder tail seed ...)))
 495                 (if clause
 496                     (cont-folder clause seed ...)
 497                     (values seed ...))))
 498
 499              (($ $kclause arity body alternate)
 500               (let-values (((seed ...) (cont-folder body seed ...)))
 501                 (if alternate
 502                     (cont-folder alternate seed ...)
 503                     (values seed ...))))
 504
 505              (_ (values seed ...)))))))
 506
 507     (define (fun-folder fun seed ...)
 508       (match fun
 509         (($ $fun free body)
 510          (cont-folder body seed ...))))
 511
 512     (define (term-folder term seed ...)
 513       (match term
 514         (($ $letk conts body)
 515          (let-values (((seed ...) (term-folder body seed ...)))
 516            (fold-values cont-folder conts seed ...)))
 517
 518         (($ $continue k src exp)
 519          (match exp
 520            (($ $fun) (fun-folder exp seed ...))
 521            (_ (values seed ...))))
 522
 523         (($ $letrec names syms funs body)
 524          (let-values (((seed ...) (term-folder body seed ...)))
 525            (fold-values fun-folder funs seed ...)))))
 526
 527     (cont-folder cont seed ...)))
 528
 529 (define-syntax-rule (make-local-cont-folder seed ...)
 530   (lambda (proc cont seed ...)
 531     (define (cont-folder cont seed ...)
 532       (match cont
 533         (($ $cont k (and cont ($ $kargs names syms body)))
 534          (let-values (((seed ...) (proc k cont seed ...)))
 535            (term-folder body seed ...)))
 536         (($ $cont k cont)
 537          (proc k cont seed ...))))
 538     (define (term-folder term seed ...)
 539       (match term
 540         (($ $letk conts body)
 541          (let-values (((seed ...) (term-folder body seed ...)))
 542            (let lp ((conts conts) (seed seed) ...)
 543              (match conts
 544                (() (values seed ...))
 545                ((cont) (cont-folder cont seed ...))
 546                ((cont . conts)
 547                 (let-values (((seed ...) (cont-folder cont seed ...)))
 548                   (lp conts seed ...)))))))
 549         (($ $letrec names syms funs body) (term-folder body seed ...))
 550         (_ (values seed ...))))
 551     (define (clause-folder clause seed ...)
 552       (match clause
 553         (($ $cont k (and cont ($ $kclause arity body alternate)))
 554          (let-values (((seed ...) (proc k cont seed ...)))
 555            (if alternate
 556                (let-values (((seed ...) (cont-folder body seed ...)))
 557                  (clause-folder alternate seed ...))
 558                (cont-folder body seed ...))))))
 559     (match cont
 560       (($ $cont k (and cont ($ $kfun src meta self tail clause)))
 561        (let*-values (((seed ...) (proc k cont seed ...))
 562                      ((seed ...) (if clause
 563                                      (clause-folder clause seed ...)
 564                                      (values seed ...))))
 565          (cont-folder tail seed ...))))))
 566
 567 (define (compute-max-label-and-var fun)
 568   (match fun
 569     (($ $cont)
 570      ((make-global-cont-folder max-label max-var)
 571       (lambda (label cont max-label max-var)
 572         (values (max label max-label)
 573                 (match cont
 574                   (($ $kargs names vars body)
 575                    (let lp ((body body) (max-var (fold max max-var vars)))
 576                      (match body
 577                        (($ $letk conts body) (lp body max-var))
 578                        (($ $letrec names vars funs body)
 579                         (lp body (fold max max-var vars)))
 580                        (_ max-var))))
 581                   (($ $kfun src meta self)
 582                    (max self max-var))
 583                   (_ max-var))))
 584       fun -1 -1))
 585     (($ $program conts)
 586      (define (fold/2 proc in s0 s1)
 587       (if (null? in)
 588           (values s0 s1)
 589           (let-values (((s0 s1) (proc (car in) s0 s1)))
 590             (fold/2 proc (cdr in) s0 s1))))
 591      (let lp ((conts conts) (max-label -1) (max-var -1))
 592        (if (null? conts)
 593            (values max-label max-var)
 594            (call-with-values (lambda ()
 595                                ((make-local-cont-folder max-label max-var)
 596                                 (lambda (label cont max-label max-var)
 597                                   (values (max label max-label)
 598                                           (match cont
 599                                             (($ $kargs names vars body)
 600                                              (fold max max-var vars))
 601                                             (($ $kfun src meta self)
 602                                              (max self max-var))
 603                                             (_ max-var))))
 604                                 (car conts) max-label max-var))
 605              (lambda (max-label max-var)
 606                (lp (cdr conts) max-label max-var))))))))
 607
 608 (define (fold-conts proc seed fun)
 609   ((make-global-cont-folder seed) proc fun seed))
 610
 611 (define (fold-local-conts proc seed fun)
 612   ((make-local-cont-folder seed) proc fun seed))
 613
 614 (define (visit-cont-successors proc cont)
 615   (match cont
 616     (($ $kargs names syms body)
 617      (let lp ((body body))
 618        (match body
 619          (($ $letk conts body) (lp body))
 620          (($ $letrec names vars funs body) (lp body))
 621          (($ $continue k src exp)
 622           (match exp
 623             (($ $prompt escape? tag handler) (proc k handler))
 624             (_ (proc k)))))))
 625
 626     (($ $kif kt kf) (proc kt kf))
 627
 628     (($ $kreceive arity k) (proc k))
 629
 630     (($ $kclause arity ($ $cont kbody) #f) (proc kbody))
 631
 632     (($ $kclause arity ($ $cont kbody) ($ $cont kalt)) (proc kbody kalt))
 633
 634     (($ $kfun src meta self tail ($ $cont clause)) (proc clause))
 635
 636     (($ $kfun src meta self tail #f) (proc))
 637
 638     (($ $ktail) (proc))))