* configure.in: Check for a missing `sleep' declaration.
[bpt/guile.git] / configure.in
1 dnl configuration script for Guile
2 dnl Process this file with autoconf to produce configure.
3 AC_INIT(Makefile.in)
4 . $srcdir/GUILE-VERSION
5 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
6 AM_MAINTAINER_MODE
7 AM_CONFIG_HEADER(libguile/scmconfig.h)
8
9 #--------------------------------------------------------------------
10 #
11 # User options
12 #
13 #--------------------------------------------------------------------
14
15 AC_ARG_ENABLE(dynamic-linking,
16 [ --enable-dynamic-linking Include support for dynamic linking],,
17 enable_dynamic_linking=yes)
18
19 AC_ARG_ENABLE(guile-debug,
20 [ --enable-guile-debug Include internal debugging functions])
21 if test "$enableval" = y || test "$enableval" = yes; then
22 AC_DEFINE(GUILE_DEBUG)
23 fi
24
25 dnl The --disable-debug used to control these two. But now they are
26 dnl a required part of the distribution.
27 AC_DEFINE(DEBUG_EXTENSIONS)
28 AC_DEFINE(READER_EXTENSIONS)
29
30 #--------------------------------------------------------------------
31
32 AC_PROG_CC
33 AC_PROG_CPP
34 AM_PROG_LIBTOOL
35
36 AC_AIX
37 AC_ISC_POSIX
38 AC_MINIX
39
40 AC_C_CONST
41
42 AC_HEADER_STDC
43 AC_HEADER_DIRENT
44 AC_HEADER_TIME
45 AC_HEADER_SYS_WAIT
46 AC_CHECK_HEADERS(libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
47 GUILE_HEADER_LIBC_WITH_UNISTD
48
49 AC_TYPE_GETGROUPS
50 AC_TYPE_SIGNAL
51 AC_TYPE_MODE_T
52
53 AC_CHECK_LIB(m, main)
54 AC_CHECK_FUNCS(gethostbyname)
55 if test $ac_cv_func_gethostbyname = no; then
56 AC_CHECK_LIB(nsl, gethostbyname)
57 fi
58 AC_CHECK_FUNCS(connect)
59 if test $ac_cv_func_connect = no; then
60 AC_CHECK_LIB(socket, connect)
61 fi
62 AC_CHECK_LIB(termcap, tgoto)
63 AC_CHECK_LIB(readline, readline)
64 AC_CHECK_FUNCS(rl_getc_function rl_clear_signals rl_cleanup_after_signal)
65 if test $ac_cv_lib_readline_readline = yes -a $ac_cv_func_rl_getc_function = no; then
66 echo 'Warning: libreadline is too old on your system. Need >= 2.1.'
67 fi
68
69 # Checks for dynamic linking
70
71 if test "$enable_dynamic_linking" = "yes"; then
72
73 AC_CHECK_LIB(dl,dlopen)
74 if test "$ac_cv_lib_dl_dlopen" = "yes"; then
75 AC_CHECK_FUNCS(dlopen)
76 AC_DEFINE(DYNAMIC_LINKING)
77 else
78 AC_CHECK_LIB(dld,dld_link)
79 if test "$ac_cv_lib_dld_dld_link" = "yes"; then
80 AC_DEFINE(DYNAMIC_LINKING)
81 else
82 AC_CHECK_FUNCS(shl_load)
83 if test "$ac_cv_func_shl_load" = "yes"; then
84 AC_DEFINE(DYNAMIC_LINKING)
85 else
86 AC_CHECK_FUNCS(dlopen)
87 if test "$ac_cv_func_dlopen" = "yes"; then
88 AC_DEFINE(DYNAMIC_LINKING)
89 fi
90 fi
91 fi
92 fi
93
94 fi
95
96 GUILE_DLSYM_USCORE
97
98 AC_CHECK_FUNCS(ctermid ftime getcwd geteuid gethostent gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid bzero strdup system usleep)
99
100 ### Some systems don't declare some functions. On such systems, we
101 ### need to at least provide our own K&R-style declarations.
102
103 ### GUILE_FUNC_DECLARED(function, headerfile)
104
105 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
106 ### not there, #define MISSING_FUNCTION_DECL.
107 AC_DEFUN(GUILE_FUNC_DECLARED, [
108 AC_CACHE_CHECK(for $1 declaration, ac_cv_func_$1_declared,
109 AC_EGREP_HEADER($1, $2,
110 ac_cv_func_$1_declared=yes,
111 ac_cv_func_$1_declared=no))
112 if test [x$ac_cv_func_]$1[_declared] = xno; then
113 AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
114 fi
115 ])
116
117 GUILE_FUNC_DECLARED(strptime, time.h)
118 GUILE_FUNC_DECLARED(bzero, string.h)
119 GUILE_FUNC_DECLARED(sleep, unistd.h)
120 GUILE_FUNC_DECLARED(usleep, unistd.h)
121
122 # On some systems usleep has no return value
123 AC_EGREP_HEADER(changequote(<, >)<void[ ][ ]*usleep>changequote([, ]),
124 /usr/include/unistd.h,
125 AC_DEFINE(USLEEP_RETURNS_VOID)
126 )
127
128
129 dnl <GNU-WIN32 hacks>
130
131 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
132 if test -n "$have_sys_un_h" ; then
133 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
134 fi
135
136 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
137
138 dnl I don't know what this prefixing of cygwin32_ is for.
139 dnl scmconfig.h wasn't updated with the test results.
140 dnl so use AC_CHECK_FUNCS for now.
141
142 dnl how about:
143 dnl save confdefs.h
144 dnl if test $ac_cv_cigwin = yes; then
145 dnl modify confdefs.h
146 dnl fi
147 dnl AC_CHECK_FUNCS...
148 dnl restore confdefs.h
149
150 dnl cp confdefs.h confdefs.h.bak
151 dnl for func in sethostent endhostent getnetent setnetent endnetent getprotoent endprotoent getservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof ; do
152 dnl cp confdefs.h.bak confdefs.h
153 dnl cat >> confdefs.h << EOF
154 dnl #ifdef __CYGWIN32__
155 dnl #define $func cygwin32_$func
156 dnl #endif
157 dnl EOF
158 dnl AC_CHECK_FUNC($func)
159 dnl done
160 dnl cp confdefs.h.bak confdefs.h
161
162 AC_CHECK_FUNCS(sethostent endhostent getnetent setnetent endnetent getprotoent endprotoent getservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof)
163
164 dnl </GNU-WIN32 hacks>
165
166 AC_CACHE_CHECK([for restartable system calls], scm_cv_restarts,
167 if test $ac_cv_func_sigaction = yes; then
168 [AC_TRY_COMPILE([#include <signal.h>],
169 [int a = SA_RESTART],
170 scm_cv_restarts=yes,
171 scm_cv_restarts=no)]
172 else
173 scm_cv_restarts=no
174 fi)
175 if test $scm_cv_restarts = yes; then
176 AC_DEFINE(HAVE_RESTARTS)
177 fi
178
179 if test "$ac_cv_header_regex_h" = yes ||
180 test "$ac_cv_header_rxposix_h" = yes ||
181 test "$ac_cv_header_rx_rxposix_h" = yes; then
182 GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
183 [AC_CHECK_LIB(rx, main)
184 GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
185 )
186 dnl The following should not be necessary, but for some reason
187 dnl autoheader misses it if we don't include it!
188 if test "$ac_cv_func_regcomp_norx" = yes ||
189 test "$ac_cv_func_regcomp_rx" = yes; then
190 AC_DEFINE(HAVE_REGCOMP)
191 fi
192 fi
193
194 AC_REPLACE_FUNCS(inet_aton putenv strerror)
195
196 # When testing for the presence of alloca, we need to add alloca.o
197 # explicitly to LIBOBJS to make sure that it is translated to
198 # `alloca.lo' for libtool later on. This can and should be done more cleanly.
199 AC_FUNC_ALLOCA
200 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
201
202 AC_STRUCT_ST_RDEV
203 AC_STRUCT_ST_BLKSIZE
204
205 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
206 # LIBOBJS, which we don't need. This seems more direct.
207 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
208 [AC_TRY_COMPILE([#include <sys/types.h>
209 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
210 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
211 if test $ac_cv_struct_st_blocks = yes; then
212 AC_DEFINE(HAVE_ST_BLOCKS)
213 fi
214
215 AC_STRUCT_TIMEZONE
216 GUILE_STRUCT_UTIMBUF
217
218 #--------------------------------------------------------------------
219 #
220 # Which way does the stack grow?
221 #
222 #--------------------------------------------------------------------
223
224 AC_TRY_RUN(aux (l) unsigned long l;
225 { int x; exit (l >= ((unsigned long)&x)); }
226 main () { int q; aux((unsigned long)&q); },
227 AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
228
229
230 AC_TRY_RUN(main () { exit (sizeof(float) != sizeof(long)); },
231 AC_DEFINE(SCM_SINGLES),,AC_DEFINE(SCM_SINGLES)
232 AC_MSG_WARN(Guessing that sizeof(long) == sizeof(float) -- see scmconfig.h.in))
233
234 AC_MSG_CHECKING(for struct linger)
235 AC_CACHE_VAL(scm_cv_struct_linger,
236 AC_TRY_COMPILE([
237 #include <sys/types.h>
238 #include <sys/socket.h>],
239 [struct linger lgr; lgr.l_linger = 100],
240 scm_cv_struct_linger="yes",
241 scm_cv_struct_linger="no"))
242 AC_MSG_RESULT($scm_cv_struct_linger)
243 if test $scm_cv_struct_linger = yes; then
244 AC_DEFINE(HAVE_STRUCT_LINGER)
245 fi
246
247 #--------------------------------------------------------------------
248 #
249 # How can you violate a stdio abstraction by setting a stream's fd?
250 #
251 #--------------------------------------------------------------------
252
253 AC_MSG_CHECKING(how to set a stream file descriptor)
254 AC_CACHE_VAL(scm_cv_fd_setter,
255 AC_TRY_COMPILE([#include <stdio.h>],
256 [stdout->_file = 1],
257 scm_cv_fd_setter="_file",
258 AC_TRY_COMPILE([#include <stdio.h>],
259 [stdout->_fileno = 1],
260 scm_cv_fd_setter="_fileno",
261 scm_cv_fd_setter="")))
262
263 if test "$scm_cv_fd_setter"; then
264 AC_MSG_RESULT($scm_cv_fd_setter)
265 AC_DEFINE_UNQUOTED(FD_SETTER, $scm_cv_fd_setter)
266 else
267 AC_MSG_RESULT(we couldn't do it!)
268 fi
269
270 #--------------------------------------------------------------------
271 # How to find out whether a FILE structure contains buffered data.
272 # From Tk we have the following list:
273 # _cnt: Most UNIX systems
274 # __cnt: HPUX
275 # _r: BSD
276 # readCount: Sprite
277 # Or, in GNU libc there are two fields, _gptr and _egptr, which
278 # have to be compared.
279 # These can also be known as _IO_read_ptr and _IO_read_end.
280 #--------------------------------------------------------------------
281
282 AC_MSG_CHECKING(how to get buffer char count from FILE structure)
283 AC_CACHE_VAL(scm_cv_struct_file_count,
284 AC_TRY_COMPILE([#include <stdio.h>],
285 [FILE *f = stdin; f->_cnt = 0],
286 scm_cv_struct_file_count="_cnt",
287 AC_TRY_COMPILE([#include <stdio.h>],
288 [FILE *f = stdin; f->_r = 0],
289 scm_cv_struct_file_count="_r",
290 AC_TRY_COMPILE([#include <stdio.h>],
291 [FILE *f = stdin; f->readCount = 0],
292 scm_cv_struct_file_count="readCount",
293 scm_cv_struct_file_count=""))))
294 if test "$scm_cv_struct_file_count"; then
295 AC_MSG_RESULT($scm_cv_struct_file_count)
296 AC_DEFINE_UNQUOTED(FILE_CNT_FIELD, $scm_cv_struct_file_count)
297 else
298 AC_CACHE_VAL(scm_cv_struct_file_gptr,
299 AC_TRY_COMPILE([#include <stdio.h>],
300 [FILE *f = stdin; f->_gptr = f->egptr;],
301 scm_cv_struct_file_gptr=1,
302 scm_cv_struct_file_gptr=""))
303 if test "$scm_cv_struct_gptr"; then
304 AC_MSG_RESULT(gptr)
305 AC_DEFINE_UNQUOTED(FILE_CNT_GPTR, $scm_cv_struct_file_gptr)
306 else
307 AC_CACHE_VAL(scm_cv_struct_file_readptr,
308 AC_TRY_COMPILE([#include <stdio.h>],
309 [FILE *f = stdin; f->_IO_read_ptr = f->_IO_read_end;],
310 scm_cv_struct_file_readptr=1))
311 if test "$scm_cv_struct_file_readptr"; then
312 AC_MSG_RESULT(read_ptr)
313 AC_DEFINE_UNQUOTED(FILE_CNT_READPTR, $scm_cv_struct_file_readptr)
314 else
315 AC_MSG_RESULT(we couldn't do it!)
316 fi
317 fi
318 fi
319
320 #--------------------------------------------------------------------
321 #
322 # Flags for thread support
323 #
324 #--------------------------------------------------------------------
325
326 ### What thread package has the user asked for?
327 AC_ARG_WITH(threads, [ --with-threads thread interface],
328 , with_threads=no)
329
330 ### Turn $with_threads into either the name of a threads package, like
331 ### `qt', or `no', meaning that threads should not be supported.
332 AC_MSG_CHECKING(whether to support threads)
333 case "$with_threads" in
334 "yes" | "qt" | "coop" | "")
335 with_threads=qt
336 ;;
337 "no" )
338 ;;
339 * )
340 AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
341 ;;
342 esac
343 AC_MSG_RESULT($with_threads)
344
345 ## Make sure the threads package we've chosen is actually supported on
346 ## the present platform.
347 case "${with_threads}" in
348 "qt" )
349 ## This configures the QuickThreads package, and sets or clears
350 ## the THREAD_PACKAGE variable if qthreads don't configure
351 ## correctly.
352 QTHREADS_CONFIGURE
353 ;;
354 esac
355
356 ## If we're using threads, bring in some other parts of Guile which
357 ## work with them.
358 if test "${THREAD_PACKAGE}" != "" ; then
359 AC_DEFINE(USE_THREADS, 1)
360
361 ## Include the Guile thread interface in the library...
362 LIBOBJS="$LIBOBJS threads.o"
363
364 ## ... and tell it which package to talk to.
365 case "${THREAD_PACKAGE}" in
366 "QT" )
367 AC_DEFINE(USE_COOP_THREADS, 1)
368 ;;
369 * )
370 AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
371 ;;
372 esac
373
374 ## Bring in scm_internal_select, if appropriate.
375 if test $ac_cv_func_gettimeofday = yes &&
376 test $ac_cv_func_select = yes; then
377 LIBOBJS="$LIBOBJS iselect.o"
378 AC_DEFINE(GUILE_ISELECT, 1)
379 fi
380 fi
381
382 ## If we're using GCC, ask for aggressive warnings.
383 case "$GCC" in
384 yes )
385 ## We had -Wstrict-prototypes in here for a bit, but Guile does too
386 ## much stuff with generic function pointers for that to really be
387 ## less than exasperating.
388 CFLAGS="$CFLAGS -Wall -Wpointer-arith -Wmissing-prototypes" ;;
389 esac
390
391 AC_PROG_AWK
392
393 ## If we're creating a shared library (using libtool!), then we'll
394 ## need to generate a list of .lo files corresponding to the .o files
395 ## given in LIBOBJS. We'll call it LIBLOBJS.
396 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
397
398 AC_SUBST(GUILE_MAJOR_VERSION)
399 AC_SUBST(GUILE_MINOR_VERSION)
400 AC_SUBST(GUILE_VERSION)
401
402 dnl Tell build-guile what flags guile users should link against.
403 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
404 AC_SUBST(GUILE_LIBS)
405
406 dnl timestamping the interpreter and scheme libraries:
407 dnl
408 dnl Help us notice when we're running one version of the Guile
409 dnl interpreter against a different version of the ice-9 Scheme code.
410 dnl This will definitely detect version skew due to differing
411 dnl snapshots and releases, but may not catch skew for the developers.
412 dnl Hopefully it will not detect skew when there is none; if that
413 dnl happens, the warnings will be useless, and we should remove this.
414 GUILE_STAMP="`date`"
415 AC_SUBST(GUILE_STAMP)
416
417 AC_SUBST(AWK)
418 AC_SUBST(LIBLOBJS)
419
420 AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf ice-9/Makefile ice-9/version.scm qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile build/Makefile], [chmod +x libguile/guile-snarf])
421
422 dnl Local Variables:
423 dnl comment-start: "dnl "
424 dnl comment-end: ""
425 dnl comment-start-skip: "\\bdnl\\b\\s *"
426 dnl End: