m4/sys_time_h.m4

   1 # Configure a replacement for <sys/time.h>.
   2 # serial 7
   3
   4 # Copyright (C) 2007, 2009-2012 Free Software Foundation, Inc.
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 # Written by Paul Eggert and Martin Lambers.
  10
  11 AC_DEFUN([gl_HEADER_SYS_TIME_H],
  12 [
  13   dnl Use AC_REQUIRE here, so that the REPLACE_GETTIMEOFDAY=0 statement
  14   dnl below is expanded once only, before all REPLACE_GETTIMEOFDAY=1
  15   dnl statements that occur in other macros.
  16   AC_REQUIRE([gl_HEADER_SYS_TIME_H_BODY])
  17 ])
  18
  19 AC_DEFUN([gl_HEADER_SYS_TIME_H_BODY],
  20 [
  21   AC_REQUIRE([AC_C_RESTRICT])
  22   AC_REQUIRE([gl_HEADER_SYS_TIME_H_DEFAULTS])
  23   AC_CHECK_HEADERS_ONCE([sys/time.h])
  24   gl_CHECK_NEXT_HEADERS([sys/time.h])
  25
  26   if test $ac_cv_header_sys_time_h != yes; then
  27     HAVE_SYS_TIME_H=0
  28   fi
  29
  30   dnl On native Windows with MSVC, 'struct timeval' is defined in <winsock2.h>
  31   dnl only. So include that header in the list.
  32   gl_PREREQ_SYS_H_WINSOCK2
  33   AC_CACHE_CHECK([for struct timeval], [gl_cv_sys_struct_timeval],
  34     [AC_COMPILE_IFELSE(
  35        [AC_LANG_PROGRAM(
  36           [[#if HAVE_SYS_TIME_H
  37              #include <sys/time.h>
  38             #endif
  39             #include <time.h>
  40             #if HAVE_WINSOCK2_H
  41             # include <winsock2.h>
  42             #endif
  43           ]],
  44           [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
  45        [gl_cv_sys_struct_timeval=yes],
  46        [gl_cv_sys_struct_timeval=no])])
  47   if test $gl_cv_sys_struct_timeval != yes; then
  48     HAVE_STRUCT_TIMEVAL=0
  49   fi
  50
  51   dnl Check for declarations of anything we want to poison if the
  52   dnl corresponding gnulib module is not in use.
  53   gl_WARN_ON_USE_PREPARE([[
  54 #if HAVE_SYS_TIME_H
  55 # include <sys/time.h>
  56 #endif
  57 #include <time.h>
  58     ]], [gettimeofday])
  59 ])
  60
  61 AC_DEFUN([gl_SYS_TIME_MODULE_INDICATOR],
  62 [
  63   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  64   AC_REQUIRE([gl_HEADER_SYS_TIME_H_DEFAULTS])
  65   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
  66   dnl Define it also as a C macro, for the benefit of the unit tests.
  67   gl_MODULE_INDICATOR_FOR_TESTS([$1])
  68 ])
  69
  70 AC_DEFUN([gl_HEADER_SYS_TIME_H_DEFAULTS],
  71 [
  72   GNULIB_GETTIMEOFDAY=0;     AC_SUBST([GNULIB_GETTIMEOFDAY])
  73   dnl Assume POSIX behavior unless another module says otherwise.
  74   HAVE_GETTIMEOFDAY=1;       AC_SUBST([HAVE_GETTIMEOFDAY])
  75   HAVE_STRUCT_TIMEVAL=1;     AC_SUBST([HAVE_STRUCT_TIMEVAL])
  76   HAVE_SYS_TIME_H=1;         AC_SUBST([HAVE_SYS_TIME_H])
  77   REPLACE_GETTIMEOFDAY=0;    AC_SUBST([REPLACE_GETTIMEOFDAY])
  78 ])