module/language/tree-il.scm

   1 ;;;;    Copyright (C) 2009, 2010, 2011, 2012, 2013 Free Software Foundation, Inc.
   2 ;;;;
   3 ;;;; This library is free software; you can redistribute it and/or
   4 ;;;; modify it under the terms of the GNU Lesser General Public
   5 ;;;; License as published by the Free Software Foundation; either
   6 ;;;; version 3 of the License, or (at your option) any later version.
   7 ;;;;
   8 ;;;; This library is distributed in the hope that it will be useful,
   9 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11 ;;;; Lesser General Public License for more details.
  12 ;;;;
  13 ;;;; You should have received a copy of the GNU Lesser General Public
  14 ;;;; License along with this library; if not, write to the Free Software
  15 ;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  16 ;;;;
  17 \f
  18
  19 (define-module (language tree-il)
  20   #:use-module (srfi srfi-1)
  21   #:use-module (srfi srfi-11)
  22   #:use-module (ice-9 match)
  23   #:use-module (system base syntax)
  24   #:export (tree-il-src
  25
  26             <void> void? make-void void-src
  27             <const> const? make-const const-src const-exp
  28             <primitive-ref> primitive-ref? make-primitive-ref primitive-ref-src primitive-ref-name
  29             <lexical-ref> lexical-ref? make-lexical-ref lexical-ref-src lexical-ref-name lexical-ref-gensym
  30             <lexical-set> lexical-set? make-lexical-set lexical-set-src lexical-set-name lexical-set-gensym lexical-set-exp
  31             <module-ref> module-ref? make-module-ref module-ref-src module-ref-mod module-ref-name module-ref-public?
  32             <module-set> module-set? make-module-set module-set-src module-set-mod module-set-name module-set-public? module-set-exp
  33             <toplevel-ref> toplevel-ref? make-toplevel-ref toplevel-ref-src toplevel-ref-name
  34             <toplevel-set> toplevel-set? make-toplevel-set toplevel-set-src toplevel-set-name toplevel-set-exp
  35             <toplevel-define> toplevel-define? make-toplevel-define toplevel-define-src toplevel-define-name toplevel-define-exp
  36             <conditional> conditional? make-conditional conditional-src conditional-test conditional-consequent conditional-alternate
  37             <call> call? make-call call-src call-proc call-args
  38             <primcall> primcall? make-primcall primcall-src primcall-name primcall-args
  39             <seq> seq? make-seq seq-src seq-head seq-tail
  40             <lambda> lambda? make-lambda lambda-src lambda-meta lambda-body
  41             <lambda-case> lambda-case? make-lambda-case lambda-case-src
  42                           lambda-case-req lambda-case-opt lambda-case-rest lambda-case-kw
  43                           lambda-case-inits lambda-case-gensyms
  44                           lambda-case-body lambda-case-alternate
  45             <let> let? make-let let-src let-names let-gensyms let-vals let-body
  46             <letrec> letrec? make-letrec letrec-src letrec-in-order? letrec-names letrec-gensyms letrec-vals letrec-body
  47             <fix> fix? make-fix fix-src fix-names fix-gensyms fix-vals fix-body
  48             <let-values> let-values? make-let-values let-values-src let-values-exp let-values-body
  49             <dynlet> dynlet? make-dynlet dynlet-src dynlet-fluids dynlet-vals dynlet-body
  50             <dynref> dynref? make-dynref dynref-src dynref-fluid
  51             <dynset> dynset? make-dynset dynset-src dynset-fluid dynset-exp
  52             <prompt> prompt? make-prompt prompt-src prompt-tag prompt-body prompt-handler
  53             <abort> abort? make-abort abort-src abort-tag abort-args abort-tail
  54
  55             list->seq
  56
  57             parse-tree-il
  58             unparse-tree-il
  59             tree-il->scheme
  60
  61             tree-il-fold
  62             make-tree-il-folder
  63             post-order
  64             pre-order
  65
  66             tree-il=?
  67             tree-il-hash))
  68
  69 (define (print-tree-il exp port)
  70   (format port "#<tree-il ~S>" (unparse-tree-il exp)))
  71
  72 (define-syntax borrow-core-vtables
  73   (lambda (x)
  74     (syntax-case x ()
  75       ((_)
  76        (let lp ((n 0) (out '()))
  77          (if (< n (vector-length %expanded-vtables))
  78              (lp (1+ n)
  79                  (let* ((vtable (vector-ref %expanded-vtables n))
  80                         (stem (struct-ref vtable (+ vtable-offset-user 0)))
  81                         (fields (struct-ref vtable (+ vtable-offset-user 2)))
  82                         (sfields (map
  83                                   (lambda (f) (datum->syntax x f))
  84                                   fields))
  85                         (type (datum->syntax x (symbol-append '< stem '>)))
  86                         (ctor (datum->syntax x (symbol-append 'make- stem)))
  87                         (pred (datum->syntax x (symbol-append stem '?))))
  88                    (let lp ((n 0) (fields fields)
  89                             (out (cons*
  90                                   #`(define (#,ctor #,@sfields)
  91                                       (make-struct #,type 0 #,@sfields))
  92                                   #`(define (#,pred x)
  93                                       (and (struct? x)
  94                                            (eq? (struct-vtable x) #,type)))
  95                                   #`(struct-set! #,type vtable-index-printer
  96                                                  print-tree-il)
  97                                   #`(define #,type
  98                                            (vector-ref %expanded-vtables #,n))
  99                                        out)))
 100                      (if (null? fields)
 101                          out
 102                          (lp (1+ n)
 103                              (cdr fields)
 104                              (let ((acc (datum->syntax
 105                                          x (symbol-append stem '- (car fields)))))
 106                                (cons #`(define #,acc
 107                                          (make-procedure-with-setter
 108                                           (lambda (x) (struct-ref x #,n))
 109                                           (lambda (x v) (struct-set! x #,n v))))
 110                                      out)))))))
 111              #`(begin #,@(reverse out))))))))
 112
 113 (borrow-core-vtables)
 114
 115   ;; (<void>)
 116   ;; (<const> exp)
 117   ;; (<primitive-ref> name)
 118   ;; (<lexical-ref> name gensym)
 119   ;; (<lexical-set> name gensym exp)
 120   ;; (<module-ref> mod name public?)
 121   ;; (<module-set> mod name public? exp)
 122   ;; (<toplevel-ref> name)
 123   ;; (<toplevel-set> name exp)
 124   ;; (<toplevel-define> name exp)
 125   ;; (<conditional> test consequent alternate)
 126   ;; (<call> proc args)
 127   ;; (<primcall> name args)
 128   ;; (<seq> head tail)
 129   ;; (<lambda> meta body)
 130   ;; (<lambda-case> req opt rest kw inits gensyms body alternate)
 131   ;; (<let> names gensyms vals body)
 132   ;; (<letrec> in-order? names gensyms vals body)
 133   ;; (<dynlet> fluids vals body)
 134
 135 (define-type (<tree-il> #:common-slots (src) #:printer print-tree-il)
 136   (<fix> names gensyms vals body)
 137   (<let-values> exp body)
 138   (<dynref> fluid)
 139   (<dynset> fluid exp)
 140   (<prompt> tag body handler)
 141   (<abort> tag args tail))
 142
 143 \f
 144
 145 ;; A helper.
 146 (define (list->seq loc exps)
 147   (if (null? (cdr exps))
 148       (car exps)
 149       (make-seq loc (car exps) (list->seq #f (cdr exps)))))
 150
 151 \f
 152
 153 (define (location x)
 154   (and (pair? x)
 155        (let ((props (source-properties x)))
 156          (and (pair? props) props))))
 157
 158 (define (parse-tree-il exp)
 159   (let ((loc (location exp))
 160         (retrans (lambda (x) (parse-tree-il x))))
 161     (match exp
 162      (('void)
 163       (make-void loc))
 164
 165      (('call proc . args)
 166       (make-call loc (retrans proc) (map retrans args)))
 167
 168      (('primcall name . args)
 169       (make-primcall loc name (map retrans args)))
 170
 171      (('if test consequent alternate)
 172       (make-conditional loc (retrans test) (retrans consequent) (retrans alternate)))
 173
 174      (('primitive (and name (? symbol?)))
 175       (make-primitive-ref loc name))
 176
 177      (('lexical (and name (? symbol?)))
 178       (make-lexical-ref loc name name))
 179
 180      (('lexical (and name (? symbol?)) (and sym (? symbol?)))
 181       (make-lexical-ref loc name sym))
 182
 183      (('set! ('lexical (and name (? symbol?))) exp)
 184       (make-lexical-set loc name name (retrans exp)))
 185
 186      (('set! ('lexical (and name (? symbol?)) (and sym (? symbol?))) exp)
 187       (make-lexical-set loc name sym (retrans exp)))
 188
 189      (('@ ((and mod (? symbol?)) ...) (and name (? symbol?)))
 190       (make-module-ref loc mod name #t))
 191
 192      (('set! ('@ ((and mod (? symbol?)) ...) (and name (? symbol?))) exp)
 193       (make-module-set loc mod name #t (retrans exp)))
 194
 195      (('@@ ((and mod (? symbol?)) ...) (and name (? symbol?)))
 196       (make-module-ref loc mod name #f))
 197
 198      (('set! ('@@ ((and mod (? symbol?)) ...) (and name (? symbol?))) exp)
 199       (make-module-set loc mod name #f (retrans exp)))
 200
 201      (('toplevel (and name (? symbol?)))
 202       (make-toplevel-ref loc name))
 203
 204      (('set! ('toplevel (and name (? symbol?))) exp)
 205       (make-toplevel-set loc name (retrans exp)))
 206
 207      (('define (and name (? symbol?)) exp)
 208       (make-toplevel-define loc name (retrans exp)))
 209
 210      (('lambda meta body)
 211       (make-lambda loc meta (retrans body)))
 212
 213      (('lambda-case ((req opt rest kw inits gensyms) body) alternate)
 214       (make-lambda-case loc req opt rest kw
 215                         (map retrans inits) gensyms
 216                         (retrans body)
 217                         (and=> alternate retrans)))
 218
 219      (('lambda-case ((req opt rest kw inits gensyms) body))
 220       (make-lambda-case loc req opt rest kw
 221                         (map retrans inits) gensyms
 222                         (retrans body)
 223                         #f))
 224
 225      (('const exp)
 226       (make-const loc exp))
 227
 228      (('seq head tail)
 229       (make-seq loc (retrans head) (retrans tail)))
 230
 231      ;; Convenience.
 232      (('begin . exps)
 233       (list->seq loc (map retrans exps)))
 234
 235      (('let names gensyms vals body)
 236       (make-let loc names gensyms (map retrans vals) (retrans body)))
 237
 238      (('letrec names gensyms vals body)
 239       (make-letrec loc #f names gensyms (map retrans vals) (retrans body)))
 240
 241      (('letrec* names gensyms vals body)
 242       (make-letrec loc #t names gensyms (map retrans vals) (retrans body)))
 243
 244      (('fix names gensyms vals body)
 245       (make-fix loc names gensyms (map retrans vals) (retrans body)))
 246
 247      (('let-values exp body)
 248       (make-let-values loc (retrans exp) (retrans body)))
 249
 250      (('dynlet fluids vals body)
 251       (make-dynlet loc (map retrans fluids) (map retrans vals) (retrans body)))
 252
 253      (('dynref fluid)
 254       (make-dynref loc (retrans fluid)))
 255
 256      (('dynset fluid exp)
 257       (make-dynset loc (retrans fluid) (retrans exp)))
 258
 259      (('prompt tag body handler)
 260       (make-prompt loc (retrans tag) (retrans body) (retrans handler)))
 261
 262      (('abort tag args tail)
 263       (make-abort loc (retrans tag) (map retrans args) (retrans tail)))
 264
 265      (else
 266       (error "unrecognized tree-il" exp)))))
 267
 268 (define (unparse-tree-il tree-il)
 269   (match tree-il
 270     (($ <void> src)
 271      '(void))
 272
 273     (($ <call> src proc args)
 274      `(call ,(unparse-tree-il proc) ,@(map unparse-tree-il args)))
 275
 276     (($ <primcall> src name args)
 277      `(primcall ,name ,@(map unparse-tree-il args)))
 278
 279     (($ <conditional> src test consequent alternate)
 280      `(if ,(unparse-tree-il test)
 281           ,(unparse-tree-il consequent)
 282           ,(unparse-tree-il alternate)))
 283
 284     (($ <primitive-ref> src name)
 285      `(primitive ,name))
 286
 287     (($ <lexical-ref> src name gensym)
 288      `(lexical ,name ,gensym))
 289
 290     (($ <lexical-set> src name gensym exp)
 291      `(set! (lexical ,name ,gensym) ,(unparse-tree-il exp)))
 292
 293     (($ <module-ref> src mod name public?)
 294      `(,(if public? '@ '@@) ,mod ,name))
 295
 296     (($ <module-set> src mod name public? exp)
 297      `(set! (,(if public? '@ '@@) ,mod ,name) ,(unparse-tree-il exp)))
 298
 299     (($ <toplevel-ref> src name)
 300      `(toplevel ,name))
 301
 302     (($ <toplevel-set> src name exp)
 303      `(set! (toplevel ,name) ,(unparse-tree-il exp)))
 304
 305     (($ <toplevel-define> src name exp)
 306      `(define ,name ,(unparse-tree-il exp)))
 307
 308     (($ <lambda> src meta body)
 309      (if body
 310          `(lambda ,meta ,(unparse-tree-il body))
 311          `(lambda ,meta (lambda-case))))
 312
 313     (($ <lambda-case> src req opt rest kw inits gensyms body alternate)
 314      `(lambda-case ((,req ,opt ,rest ,kw ,(map unparse-tree-il inits) ,gensyms)
 315                     ,(unparse-tree-il body))
 316                    . ,(if alternate (list (unparse-tree-il alternate)) '())))
 317
 318     (($ <const> src exp)
 319      `(const ,exp))
 320
 321     (($ <seq> src head tail)
 322      `(seq ,(unparse-tree-il head) ,(unparse-tree-il tail)))
 323
 324     (($ <let> src names gensyms vals body)
 325      `(let ,names ,gensyms ,(map unparse-tree-il vals) ,(unparse-tree-il body)))
 326
 327     (($ <letrec> src in-order? names gensyms vals body)
 328      `(,(if in-order? 'letrec* 'letrec) ,names ,gensyms
 329        ,(map unparse-tree-il vals) ,(unparse-tree-il body)))
 330
 331     (($ <fix> src names gensyms vals body)
 332      `(fix ,names ,gensyms ,(map unparse-tree-il vals) ,(unparse-tree-il body)))
 333
 334     (($ <let-values> src exp body)
 335      `(let-values ,(unparse-tree-il exp) ,(unparse-tree-il body)))
 336
 337     (($ <dynlet> src fluids vals body)
 338      `(dynlet ,(map unparse-tree-il fluids) ,(map unparse-tree-il vals)
 339               ,(unparse-tree-il body)))
 340
 341     (($ <dynref> src fluid)
 342      `(dynref ,(unparse-tree-il fluid)))
 343
 344     (($ <dynset> src fluid exp)
 345      `(dynset ,(unparse-tree-il fluid) ,(unparse-tree-il exp)))
 346
 347     (($ <prompt> src tag body handler)
 348      `(prompt ,(unparse-tree-il tag)
 349               ,(unparse-tree-il body)
 350               ,(unparse-tree-il handler)))
 351
 352     (($ <abort> src tag args tail)
 353      `(abort ,(unparse-tree-il tag) ,(map unparse-tree-il args)
 354              ,(unparse-tree-il tail)))))
 355
 356 (define* (tree-il->scheme e #:optional (env #f) (opts '()))
 357   (values ((@ (language scheme decompile-tree-il)
 358               decompile-tree-il)
 359            e env opts)))
 360
 361 \f
 362 (define-syntax-rule (make-tree-il-folder seed ...)
 363   (lambda (tree down up seed ...)
 364     (define (fold-values proc exps seed ...)
 365       (if (null? exps)
 366           (values seed ...)
 367           (let-values (((seed ...) (proc (car exps) seed ...)))
 368             (fold-values proc (cdr exps) seed ...))))
 369     (let foldts ((tree tree) (seed seed) ...)
 370       (let*-values
 371           (((seed ...) (down tree seed ...))
 372            ((seed ...)
 373             (match tree
 374               (($ <lexical-set> src name gensym exp)
 375                (foldts exp seed ...))
 376               (($ <module-set> src mod name public? exp)
 377                (foldts exp seed ...))
 378               (($ <toplevel-set> src name exp)
 379                (foldts exp seed ...))
 380               (($ <toplevel-define> src name exp)
 381                (foldts exp seed ...))
 382               (($ <conditional> src test consequent alternate)
 383                (let*-values (((seed ...) (foldts test seed ...))
 384                              ((seed ...) (foldts consequent seed ...)))
 385                  (foldts alternate seed ...)))
 386               (($ <call> src proc args)
 387                (let-values (((seed ...) (foldts proc seed ...)))
 388                  (fold-values foldts args seed ...)))
 389               (($ <primcall> src name args)
 390                (fold-values foldts args seed ...))
 391               (($ <seq> src head tail)
 392                (let-values (((seed ...) (foldts head seed ...)))
 393                  (foldts tail seed ...)))
 394               (($ <lambda> src meta body)
 395                (if body
 396                    (foldts body seed ...)
 397                    (values seed ...)))
 398               (($ <lambda-case> src req opt rest kw inits gensyms body
 399                               alternate)
 400                (let-values (((seed ...) (fold-values foldts inits seed ...)))
 401                  (if alternate
 402                      (let-values (((seed ...) (foldts body seed ...)))
 403                        (foldts alternate seed ...))
 404                      (foldts body seed ...))))
 405               (($ <let> src names gensyms vals body)
 406                (let*-values (((seed ...) (fold-values foldts vals seed ...)))
 407                  (foldts body seed ...)))
 408               (($ <letrec> src in-order? names gensyms vals body)
 409                (let*-values (((seed ...) (fold-values foldts vals seed ...)))
 410                  (foldts body seed ...)))
 411               (($ <fix> src names gensyms vals body)
 412                (let*-values (((seed ...) (fold-values foldts vals seed ...)))
 413                  (foldts body seed ...)))
 414               (($ <let-values> src exp body)
 415                (let*-values (((seed ...) (foldts exp seed ...)))
 416                  (foldts body seed ...)))
 417               (($ <dynlet> src fluids vals body)
 418                (let*-values (((seed ...) (fold-values foldts fluids seed ...))
 419                              ((seed ...) (fold-values foldts vals seed ...)))
 420                  (foldts body seed ...)))
 421               (($ <dynref> src fluid)
 422                (foldts fluid seed ...))
 423               (($ <dynset> src fluid exp)
 424                (let*-values (((seed ...) (foldts fluid seed ...)))
 425                  (foldts exp seed ...)))
 426               (($ <prompt> src tag body handler)
 427                (let*-values (((seed ...) (foldts tag seed ...))
 428                              ((seed ...) (foldts body seed ...)))
 429                  (foldts handler seed ...)))
 430               (($ <abort> src tag args tail)
 431                (let*-values (((seed ...) (foldts tag seed ...))
 432                              ((seed ...) (fold-values foldts args seed ...)))
 433                  (foldts tail seed ...)))
 434               (_
 435                (values seed ...)))))
 436         (up tree seed ...)))))
 437
 438 (define (tree-il-fold down up seed tree)
 439   "Traverse TREE, calling DOWN before visiting a sub-tree, and UP when
 440 after visiting it.  Each of these procedures is invoked as `(PROC TREE
 441 SEED)', where TREE is the sub-tree considered and SEED is the current
 442 result, intially seeded with SEED.
 443
 444 This is an implementation of `foldts' as described by Andy Wingo in
 445 ``Applications of fold to XML transformation''."
 446   ;; Multi-valued fold naturally puts the seeds at the end, whereas
 447   ;; normal fold puts the traversable at the end.  Adapt to the expected
 448   ;; argument order.
 449   ((make-tree-il-folder tree) tree down up seed))
 450
 451 (define (pre-post-order pre post x)
 452   (let lp ((x x))
 453     (post
 454      (match (pre x)
 455        (($ <void> src)
 456         (make-void src))
 457
 458        (($ <const> src exp)
 459         (make-const src exp))
 460
 461        (($ <primitive-ref> src name)
 462         (make-primitive-ref src name))
 463
 464        (($ <lexical-ref> src name gensym)
 465         (make-lexical-ref src name gensym))
 466
 467        (($ <lexical-set> src name gensym exp)
 468         (make-lexical-set src name gensym (lp exp)))
 469
 470        (($ <module-ref> src mod name public?)
 471         (make-module-ref src mod name public?))
 472
 473        (($ <module-set> src mod name public? exp)
 474         (make-module-set src mod name public? (lp exp)))
 475
 476        (($ <toplevel-ref> src name)
 477         (make-toplevel-ref src name))
 478
 479        (($ <toplevel-set> src name exp)
 480         (make-toplevel-set src name (lp exp)))
 481
 482        (($ <toplevel-define> src name exp)
 483         (make-toplevel-define src name (lp exp)))
 484
 485        (($ <conditional> src test consequent alternate)
 486         (make-conditional src (lp test) (lp consequent) (lp alternate)))
 487
 488        (($ <call> src proc args)
 489         (make-call src (lp proc) (map lp args)))
 490
 491        (($ <primcall> src name args)
 492         (make-primcall src name (map lp args)))
 493
 494        (($ <seq> src head tail)
 495         (make-seq src (lp head) (lp tail)))
 496
 497        (($ <lambda> src meta body)
 498         (make-lambda src meta (and body (lp body))))
 499
 500        (($ <lambda-case> src req opt rest kw inits gensyms body alternate)
 501         (make-lambda-case src req opt rest kw (map lp inits) gensyms (lp body)
 502                           (and alternate (lp alternate))))
 503
 504        (($ <let> src names gensyms vals body)
 505         (make-let src names gensyms (map lp vals) (lp body)))
 506
 507        (($ <letrec> src in-order? names gensyms vals body)
 508         (make-letrec src in-order? names gensyms (map lp vals) (lp body)))
 509
 510        (($ <fix> src names gensyms vals body)
 511         (make-fix src names gensyms (map lp vals) (lp body)))
 512
 513        (($ <let-values> src exp body)
 514         (make-let-values src (lp exp) (lp body)))
 515
 516        (($ <dynlet> src fluids vals body)
 517         (make-dynlet src (map lp fluids) (map lp vals) (lp body)))
 518
 519        (($ <dynref> src fluid)
 520         (make-dynref src (lp fluid)))
 521
 522        (($ <dynset> src fluid exp)
 523         (make-dynset src (lp fluid) (lp exp)))
 524
 525        (($ <prompt> src tag body handler)
 526         (make-prompt src (lp tag) (lp body) (lp handler)))
 527
 528        (($ <abort> src tag args tail)
 529         (make-abort src (lp tag) (map lp args) (lp tail)))))))
 530
 531 (define (post-order f x)
 532   (pre-post-order (lambda (x) x) f x))
 533
 534 (define (pre-order f x)
 535   (pre-post-order f (lambda (x) x) x))
 536
 537 ;; FIXME: We should have a better primitive than this.
 538 (define (struct-nfields x)
 539   (/ (string-length (symbol->string (struct-layout x))) 2))
 540
 541 (define (tree-il=? a b)
 542   (cond
 543    ((struct? a)
 544     (and (struct? b)
 545          (eq? (struct-vtable a) (struct-vtable b))
 546          ;; Assume that all structs are tree-il, so we skip over the
 547          ;; src slot.
 548          (let lp ((n (1- (struct-nfields a))))
 549            (or (zero? n)
 550                (and (tree-il=? (struct-ref a n) (struct-ref b n))
 551                     (lp (1- n)))))))
 552    ((pair? a)
 553     (and (pair? b)
 554          (tree-il=? (car a) (car b))
 555          (tree-il=? (cdr a) (cdr b))))
 556    (else
 557     (equal? a b))))
 558
 559 (define-syntax hash-bits
 560   (make-variable-transformer
 561    (lambda (x)
 562      (syntax-case x ()
 563        (var
 564         (identifier? #'var)
 565         (logcount most-positive-fixnum))))))
 566
 567 (define (tree-il-hash exp)
 568   (let ((hash-depth 4)
 569         (hash-width 3))
 570     (define (hash-exp exp depth)
 571       (define (rotate x bits)
 572         (logior (ash x (- bits))
 573                 (ash (logand x (1- (ash 1 bits))) (- hash-bits bits))))
 574       (define (mix h1 h2)
 575         (logxor h1 (rotate h2 8)))
 576       (define (hash-struct s)
 577         (let ((len (struct-nfields s))
 578               (h (hashq (struct-vtable s) most-positive-fixnum)))
 579           (if (zero? depth)
 580               h
 581               (let lp ((i (max (- len hash-width) 1)) (h h))
 582                 (if (< i len)
 583                     (lp (1+ i) (mix (hash-exp (struct-ref s i) (1+ depth)) h))
 584                     h)))))
 585       (define (hash-list l)
 586         (let ((h (hashq 'list most-positive-fixnum)))
 587           (if (zero? depth)
 588               h
 589               (let lp ((l l) (width 0) (h h))
 590                 (if (< width hash-width)
 591                     (lp (cdr l) (1+ width)
 592                         (mix (hash-exp (car l) (1+ depth)) h))
 593                     h)))))
 594       (cond
 595        ((struct? exp) (hash-struct exp))
 596        ((list? exp) (hash-list exp))
 597        (else (hash exp most-positive-fixnum))))
 598
 599     (hash-exp exp 0)))