configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   8   2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   9
  10 This file is part of GUILE
  11
  12 GUILE is free software; you can redistribute it and/or modify it under
  13 the terms of the GNU Lesser General Public License as published by the
  14 Free Software Foundation; either version 3, or (at your option) any
  15 later version.
  16
  17 GUILE is distributed in the hope that it will be useful, but WITHOUT
  18 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  19 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  20 License for more details.
  21
  22 You should have received a copy of the GNU Lesser General Public
  23 License along with GUILE; see the file COPYING.LESSER.  If not, write
  24 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  25 Floor, Boston, MA 02110-1301, USA.
  26
  27 ]])
  28
  29 AC_PREREQ(2.61)
  30
  31 AC_INIT([GNU Guile],
  32         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  33         [bug-guile@gnu.org])
  34 AC_CONFIG_AUX_DIR([build-aux])
  35 AC_CONFIG_MACRO_DIR([m4])
  36 AC_CONFIG_SRCDIR(GUILE-VERSION)
  37
  38 AM_INIT_AUTOMAKE([gnu no-define -Wall -Wno-override])
  39 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AC_SUBST([AM_DEFAULT_VERBOSITY],1)])
  40
  41 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  42 AC_CONFIG_SRCDIR([GUILE-VERSION])
  43
  44 . $srcdir/GUILE-VERSION
  45 GUILE_VERSION="$PACKAGE_VERSION"
  46
  47 AC_CONFIG_HEADERS([config.h])
  48 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  49
  50 #--------------------------------------------------------------------
  51
  52 AC_LANG([C])
  53
  54 dnl Some more checks for Win32
  55 AC_CANONICAL_HOST
  56
  57 AC_LIBTOOL_WIN32_DLL
  58
  59 AC_PROG_INSTALL
  60 AC_PROG_CC
  61 gl_EARLY
  62 AC_PROG_CPP
  63 AC_PROG_SED
  64 AC_PROG_AWK
  65 AC_PROG_LN_S
  66
  67 dnl Gnulib.
  68 gl_INIT
  69 dnl FIXME: remove me and the acinclude.m4 code when clock-gettime is
  70 dnl LGPL-compatible and can be imported normally.
  71 gl_CLOCK_TIME
  72
  73 AC_PROG_CC_C89
  74
  75 # for per-target cflags in the libguile subdir
  76 AM_PROG_CC_C_O
  77
  78 AC_LIBTOOL_DLOPEN
  79 AC_PROG_LIBTOOL
  80
  81 AM_CONDITIONAL([HAVE_SHARED_LIBRARIES], [test "x$enable_shared" = "xyes"])
  82
  83 AC_DEFINE_UNQUOTED([SHARED_LIBRARY_PATH_VARIABLE], ["$shlibpath_var"],
  84   [Name of the environment variable that tells the dynamic linker where
  85 to find shared libraries.])
  86
  87 dnl Check for libltdl.
  88 AC_LIB_HAVE_LINKFLAGS([ltdl], [], [#include <ltdl.h>],
  89   [lt_dlopenext ("foo");])
  90 if test "x$HAVE_LIBLTDL" != "xyes"; then
  91   AC_MSG_ERROR([GNU libltdl (Libtool) not found, see README.])
  92 fi
  93
  94 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  95 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  96
  97 AM_PATH_LISPDIR
  98
  99 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
 100   [Define to the host's GNU triplet.])
 101
 102 #--------------------------------------------------------------------
 103 #
 104 # User options (after above tests that may set default CFLAGS etc.)
 105 #
 106 #--------------------------------------------------------------------
 107
 108 GUILE_ERROR_ON_WARNING="no"
 109
 110 AC_ARG_ENABLE(error-on-warning,
 111   [  --enable-error-on-warning    treat compile warnings as errors],
 112   [case "${enableval}" in
 113      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 114      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 115      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 116    esac])
 117
 118 AC_ARG_ENABLE(debug-malloc,
 119   [  --enable-debug-malloc   include malloc debugging code],
 120   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 121     AC_DEFINE([GUILE_DEBUG_MALLOC], 1,
 122       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 123   fi)
 124
 125 SCM_I_GSC_GUILE_DEBUG=0
 126 AC_ARG_ENABLE(guile-debug,
 127   [AS_HELP_STRING([--enable-guile-debug],
 128                   [include internal debugging functions])],
 129   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 130     SCM_I_GSC_GUILE_DEBUG=1
 131   fi)
 132
 133 AC_ARG_ENABLE(posix,
 134   [  --disable-posix         omit non-essential POSIX interfaces],,
 135   enable_posix=yes)
 136
 137 AC_ARG_ENABLE(networking,
 138   [  --disable-networking    omit networking interfaces],,
 139   enable_networking=yes)
 140
 141 AC_ARG_ENABLE(regex,
 142   [  --disable-regex         omit regular expression interfaces],,
 143   enable_regex=yes)
 144
 145 AC_ARG_ENABLE([deprecated],
 146   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 147
 148 if test "$enable_deprecated" = no; then
 149   SCM_I_GSC_ENABLE_DEPRECATED=0
 150   warn_default=no
 151 else
 152   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 153     warn_default=summary
 154   elif test "$enable_deprecated" = shutup; then
 155     warn_default=no
 156   else
 157     warn_default=$enable_deprecated
 158   fi
 159   SCM_I_GSC_ENABLE_DEPRECATED=1
 160 fi
 161 AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default",
 162 [Define this to control the default warning level for deprecated features.])
 163
 164 dnl  Added the following configure option in January 2008 following
 165 dnl  investigation of problems with "64" system and library calls on
 166 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 167 dnl  system has stat64, it will have all the other 64 APIs too; but on
 168 dnl  Darwin, stat64 is there but other APIs are missing.
 169 dnl
 170 dnl  It also appears, from the Darwin docs, that most system call APIs
 171 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 172 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 173 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 174 dnl
 175 dnl  A similar problem has been reported for HP-UX:
 176 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 177 dnl
 178 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 179 dnl  better than no Guile at all, we provide this option to suppress
 180 dnl  trying to use "64" calls.
 181 dnl
 182 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 183 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 184 dnl  missing out on that.  If so, someone can work on that in the future.
 185 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 186 dnl  wasn't building before.
 187 AC_MSG_CHECKING([whether to use system and library "64" calls])
 188 AC_ARG_WITH([64-calls],
 189   AS_HELP_STRING([--without-64-calls],
 190                  [don't attempt to use system and library calls with "64" in their names]),
 191   [use_64_calls=$withval],
 192   [use_64_calls=yes
 193    case $host in
 194      *-apple-darwin* )
 195        use_64_calls=no
 196        ;;
 197      powerpc-ibm-aix* )
 198        use_64_calls=no
 199        ;;
 200    esac])
 201 AC_MSG_RESULT($use_64_calls)
 202 case "$use_64_calls" in
 203   y* )
 204     AC_DEFINE([GUILE_USE_64_CALLS], 1,
 205       [Define to 1 in order to try to use "64" versions of system and library calls.])
 206     ;;
 207 esac
 208
 209 #--------------------------------------------------------------------
 210
 211 dnl Check for dynamic linking
 212
 213 use_modules=yes
 214 AC_ARG_WITH(modules,
 215 [  --with-modules[=FILES]  Add support for dynamic modules],
 216 use_modules="$withval")
 217 test -z "$use_modules" && use_modules=yes
 218 DLPREOPEN=
 219 if test "$use_modules" != no; then
 220   if test "$use_modules" = yes; then
 221     DLPREOPEN="-dlpreopen force"
 222   else
 223     DLPREOPEN="-export-dynamic"
 224     for module in $use_modules; do
 225       DLPREOPEN="$DLPREOPEN -dlopen $module"
 226     done
 227   fi
 228 fi
 229
 230 dnl files which are destined for separate modules.
 231
 232 if test "$use_modules" != no; then
 233    AC_LIBOBJ([dynl])
 234 fi
 235
 236 if test "$enable_posix" = yes; then
 237    AC_LIBOBJ([posix])
 238    AC_DEFINE([HAVE_POSIX], 1,
 239      [Define this if you want support for non-essential POSIX system calls in Guile.])
 240 fi
 241
 242 if test "$enable_networking" = yes; then
 243    AC_LIBOBJ([net_db])
 244    AC_LIBOBJ([socket])
 245    AC_DEFINE([HAVE_NETWORKING], 1,
 246      [Define this if you want support for networking in Guile.])
 247 fi
 248
 249 if test "$enable_debug_malloc" = yes; then
 250    AC_LIBOBJ([debug-malloc])
 251 fi
 252
 253 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 254
 255 AC_C_CONST
 256
 257 # "volatile" is used in a couple of tests below.
 258 AC_C_VOLATILE
 259
 260 AC_C_INLINE
 261 if test "$ac_cv_c_inline" != no; then
 262   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 263 else
 264   SCM_I_GSC_C_INLINE=NULL
 265 fi
 266 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 267
 268 AC_C_BIGENDIAN
 269
 270 AC_C_LABELS_AS_VALUES
 271
 272 AC_CHECK_SIZEOF(char)
 273 AC_CHECK_SIZEOF(unsigned char)
 274 AC_CHECK_SIZEOF(short)
 275 AC_CHECK_SIZEOF(unsigned short)
 276 AC_CHECK_SIZEOF(int)
 277 AC_CHECK_SIZEOF(unsigned int)
 278 AC_CHECK_SIZEOF(long)
 279 AC_CHECK_SIZEOF(unsigned long)
 280 AC_CHECK_SIZEOF(size_t)
 281 AC_CHECK_SIZEOF(long long)
 282 AC_CHECK_SIZEOF(unsigned long long)
 283 AC_CHECK_SIZEOF(__int64)
 284 AC_CHECK_SIZEOF(unsigned __int64)
 285 AC_CHECK_SIZEOF(void *)
 286 AC_CHECK_SIZEOF(intptr_t)
 287 AC_CHECK_SIZEOF(uintptr_t)
 288 AC_CHECK_SIZEOF(ptrdiff_t)
 289 AC_CHECK_SIZEOF(size_t)
 290 AC_CHECK_SIZEOF(off_t)
 291
 292 if test "$ac_cv_sizeof_long" -gt "$ac_cv_sizeof_void_p"; then
 293   AC_MSG_ERROR(long does not fit into a void*)
 294 fi
 295
 296 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 297   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 298 else
 299   SCM_I_GSC_T_PTRDIFF='"long"'
 300 fi
 301 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 302
 303 AC_CHECK_HEADERS([stdint.h])
 304 AC_CHECK_HEADERS([inttypes.h])
 305
 306 AC_CHECK_SIZEOF(intmax_t)
 307
 308 SCM_I_GSC_NEEDS_STDINT_H=0
 309 SCM_I_GSC_NEEDS_INTTYPES_H=0
 310
 311 ### intptr and uintptr (try not to use inttypes if we don't have to)
 312 if test "$ac_cv_header_inttypes_h" = yes; then
 313   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 314     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 315 #include <stdio.h>])
 316     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 317       SCM_I_GSC_NEEDS_INTTYPES_H=1
 318     fi
 319   fi
 320   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 321     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 322 #include <stdio.h>])
 323     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 324       SCM_I_GSC_NEEDS_INTTYPES_H=1
 325     fi
 326   fi
 327 fi
 328
 329 ### See what's provided by stdint.h
 330 if test "$ac_cv_header_stdint_h" = yes; then
 331    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 332    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 333    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 334    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 335    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 336    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 337    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 338    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 339    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 340    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 341    AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>])
 342    AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>])
 343 fi
 344
 345 # so we don't get confused by the cache (wish there was a better way
 346 # to check particular headers for the same type...)
 347
 348 unset ac_cv_type_int8_t
 349 unset ac_cv_type_uint8_t
 350 unset ac_cv_type_int16_t
 351 unset ac_cv_type_uint16_t
 352 unset ac_cv_type_int32_t
 353 unset ac_cv_type_uint32_t
 354 unset ac_cv_type_int64_t
 355 unset ac_cv_type_uint64_t
 356 unset ac_cv_type_intmax_t
 357 unset ac_cv_type_uintmax_t
 358
 359 ### See what's provided by inttypes.h
 360 if test "$ac_cv_header_inttypes_h" = yes; then
 361   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 362   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 363   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 364   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 365   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 366   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 367   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 368   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 369   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 370   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 371   AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>])
 372   AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>])
 373 fi
 374
 375 # Try hard to find definitions for some required scm_t_*int* types.
 376
 377 ### Required type scm_t_int8
 378 if test "$scm_stdint_has_int8"; then
 379   SCM_I_GSC_T_INT8='"int8_t"'
 380   SCM_I_GSC_NEEDS_STDINT_H=1
 381 elif test "$scm_inttypes_has_int8"; then
 382   SCM_I_GSC_T_INT8='"int8_t"'
 383   SCM_I_GSC_NEEDS_INTTYPES_H=1
 384 elif test "$ac_cv_sizeof_char" -eq 1; then
 385   SCM_I_GSC_T_INT8='"signed char"'
 386 else
 387   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 388 fi
 389 AC_SUBST([SCM_I_GSC_T_INT8])
 390
 391 ### Required type scm_t_uint8
 392 if test "$scm_stdint_has_uint8"; then
 393   SCM_I_GSC_T_UINT8='"uint8_t"'
 394   SCM_I_GSC_NEEDS_STDINT_H=1
 395 elif test "$scm_inttypes_has_uint8"; then
 396   SCM_I_GSC_T_UINT8='"uint8_t"'
 397   SCM_I_GSC_NEEDS_INTTYPES_H=1
 398 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 399   SCM_I_GSC_T_UINT8='"unsigned char"'
 400 else
 401   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 402 fi
 403 AC_SUBST([SCM_I_GSC_T_UINT8])
 404
 405 ### Required type scm_t_int16 (ANSI C says int or short might work)
 406 if test "$scm_stdint_has_int16"; then
 407   SCM_I_GSC_T_INT16='"int16_t"'
 408   SCM_I_GSC_NEEDS_STDINT_H=1
 409 elif test "$scm_inttypes_has_int16"; then
 410   SCM_I_GSC_T_INT16='"int16_t"'
 411   SCM_I_GSC_NEEDS_INTTYPES_H=1
 412 elif test "$ac_cv_sizeof_int" -eq 2; then
 413   SCM_I_GSC_T_INT16='"int"'
 414 elif test "$ac_cv_sizeof_short" -eq 2; then
 415   SCM_I_GSC_T_INT16='"short"'
 416 else
 417   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 418 fi
 419 AC_SUBST([SCM_I_GSC_T_INT16])
 420
 421 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 422 if test "$scm_stdint_has_uint16"; then
 423   SCM_I_GSC_T_UINT16='"uint16_t"'
 424   SCM_I_GSC_NEEDS_STDINT_H=1
 425 elif test "$scm_inttypes_has_uint16"; then
 426   SCM_I_GSC_T_UINT16='"uint16_t"'
 427   SCM_I_GSC_NEEDS_INTTYPES_H=1
 428 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 429   SCM_I_GSC_T_UINT16='"unsigned int"'
 430 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 431   SCM_I_GSC_T_UINT16='"unsigned short"'
 432 else
 433   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 434 fi
 435 AC_SUBST([SCM_I_GSC_T_UINT16])
 436
 437
 438 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 439 if test "$scm_stdint_has_int32"; then
 440   SCM_I_GSC_T_INT32='"int32_t"'
 441   SCM_I_GSC_NEEDS_STDINT_H=1
 442 elif test "$scm_inttypes_has_int32"; then
 443   SCM_I_GSC_T_INT32='"int32_t"'
 444   SCM_I_GSC_NEEDS_INTTYPES_H=1
 445 elif test "$ac_cv_sizeof_int" -eq 4; then
 446   SCM_I_GSC_T_INT32='"int"'
 447 elif test "$ac_cv_sizeof_long" -eq 4; then
 448   SCM_I_GSC_T_INT32='"long"'
 449 elif test "$ac_cv_sizeof_short" -eq 4; then
 450   SCM_I_GSC_T_INT32='"short"'
 451 else
 452   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 453 fi
 454 AC_SUBST([SCM_I_GSC_T_INT32])
 455
 456 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 457 if test "$scm_stdint_has_uint32"; then
 458   SCM_I_GSC_T_UINT32='"uint32_t"'
 459   SCM_I_GSC_NEEDS_STDINT_H=1
 460 elif test "$scm_inttypes_has_uint32"; then
 461   SCM_I_GSC_T_UINT32='"uint32_t"'
 462   SCM_I_GSC_NEEDS_INTTYPES_H=1
 463 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 464   SCM_I_GSC_T_UINT32='"unsigned int"'
 465 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 466   SCM_I_GSC_T_UINT32='"unsigned long"'
 467 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 468   SCM_I_GSC_T_UINT32='"unsigned short"'
 469 else
 470   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 471 fi
 472 AC_SUBST([SCM_I_GSC_T_UINT32])
 473
 474 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 475 ### Also try 'long long' and '__int64' if we have it.
 476 SCM_I_GSC_T_INT64=0
 477 if test "$scm_stdint_has_int64"; then
 478   SCM_I_GSC_T_INT64='"int64_t"'
 479   SCM_I_GSC_NEEDS_STDINT_H=1
 480 elif test "$scm_inttypes_has_int64"; then
 481   SCM_I_GSC_T_INT64='"int64_t"'
 482   SCM_I_GSC_NEEDS_INTTYPES_H=1
 483 elif test "$ac_cv_sizeof_int" -eq 8; then
 484   SCM_I_GSC_T_INT64='"int"'
 485 elif test "$ac_cv_sizeof_long" -eq 8; then
 486   SCM_I_GSC_T_INT64='"long"'
 487 elif test "$ac_cv_sizeof_short" -eq 8; then
 488   SCM_I_GSC_T_INT64='"short"'
 489 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 490   SCM_I_GSC_T_INT64='"long long"'
 491 elif test "$ac_cv_sizeof___int64" -eq 8; then
 492   SCM_I_GSC_T_INT64='"__int64"'
 493 else
 494   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 495 fi
 496 AC_SUBST([SCM_I_GSC_T_INT64])
 497
 498
 499 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 500 ### Also try 'long long' and '__int64' if we have it.
 501 SCM_I_GSC_T_UINT64=0
 502 if test "$scm_stdint_has_uint64"; then
 503   SCM_I_GSC_T_UINT64='"uint64_t"'
 504   SCM_I_GSC_NEEDS_STDINT_H=1
 505 elif test "$scm_inttypes_has_uint64"; then
 506   SCM_I_GSC_T_UINT64='"uint64_t"'
 507   SCM_I_GSC_NEEDS_INTTYPES_H=1
 508 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 509   SCM_I_GSC_T_UINT64='"unsigned int"'
 510 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 511   SCM_I_GSC_T_UINT64='"unsigned long"'
 512 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 513   SCM_I_GSC_T_UINT64='"unsigned short"'
 514 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 515   SCM_I_GSC_T_UINT64='"unsigned long long"'
 516 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 517   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 518 else
 519   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 520 fi
 521 AC_SUBST([SCM_I_GSC_T_UINT64])
 522
 523 ### Required type scm_t_intmax
 524 ###
 525 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 526 ### none of them is available, we use 'long'.
 527 ###
 528 SCM_I_GSC_T_INTMAX=0
 529 if test "$scm_stdint_has_intmax"; then
 530   SCM_I_GSC_T_INTMAX='"intmax_t"'
 531   SCM_I_GSC_NEEDS_STDINT_H=1
 532 elif test "$scm_inttypes_has_intmax"; then
 533   SCM_I_GSC_T_INTMAX='"intmax_t"'
 534   SCM_I_GSC_NEEDS_INTTYPES_H=1
 535 elif test "$ac_cv_sizeof___int64" -ne 0; then
 536   SCM_I_GSC_T_INTMAX='"__int64"'
 537 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 538   SCM_I_GSC_T_INTMAX='"long long"'
 539 else
 540   SCM_I_GSC_T_INTMAX='"long"'
 541 fi
 542 AC_SUBST([SCM_I_GSC_T_INTMAX])
 543
 544 ### Required type scm_t_uintmax
 545 ###
 546 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 547 ### this order.  When none of them is available, we use 'unsigned long'.
 548 ###
 549 SCM_I_GSC_T_UINTMAX=0
 550 if test "$scm_stdint_has_uintmax"; then
 551   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 552   SCM_I_GSC_NEEDS_STDINT_H=1
 553 elif test "$scm_inttypes_has_uintmax"; then
 554   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 555   SCM_I_GSC_NEEDS_INTTYPES_H=1
 556 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 557   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 558 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 559   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 560 else
 561   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 562 fi
 563 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 564
 565 ### Required type scm_t_intptr
 566 ###
 567 SCM_I_GSC_T_INTPTR=0
 568 if test "$scm_stdint_has_intptr"; then
 569   SCM_I_GSC_T_INTPTR='"intptr_t"'
 570   SCM_I_GSC_NEEDS_STDINT_H=1
 571 elif test "$scm_inttypes_has_intptr"; then
 572   SCM_I_GSC_T_INTPTR='"intptr_t"'
 573   SCM_I_GSC_NEEDS_INTTYPES_H=1
 574 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 575   SCM_I_GSC_T_INTPTR='"int"'
 576 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 577   SCM_I_GSC_T_INTPTR='"long"'
 578 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 579   SCM_I_GSC_T_INTPTR='"long long"'
 580 else
 581   AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.])
 582 fi
 583 AC_SUBST([SCM_I_GSC_T_INTPTR])
 584
 585 ### Required type scm_t_uintptr
 586 ###
 587 SCM_I_GSC_T_UINTPTR=0
 588 if test "$scm_stdint_has_uintptr"; then
 589   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 590   SCM_I_GSC_NEEDS_STDINT_H=1
 591 elif test "$scm_inttypes_has_uintptr"; then
 592   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 593   SCM_I_GSC_NEEDS_INTTYPES_H=1
 594 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 595   SCM_I_GSC_T_UINTPTR='"unsigned int"'
 596 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 597   SCM_I_GSC_T_UINTPTR='"unsigned long"'
 598 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 599   SCM_I_GSC_T_UINTPTR='"unsigned long long"'
 600 else
 601   AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.])
 602 fi
 603 AC_SUBST([SCM_I_GSC_T_UINTPTR])
 604
 605
 606 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 607 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 608
 609 AC_HEADER_STDC
 610 AC_HEADER_TIME
 611 AC_HEADER_SYS_WAIT
 612 AC_HEADER_DIRENT
 613
 614 # Reason for checking:
 615 #
 616 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 617 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 618 #
 619 AC_CHECK_MEMBER([struct dirent64.d_name],
 620   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 621   [ #ifndef _LARGEFILE64_SOURCE
 622     # define _LARGEFILE64_SOURCE
 623     #endif
 624
 625     /* Per Autoconf manual.  */
 626     #include <sys/types.h>
 627     #ifdef HAVE_DIRENT_H
 628     # include <dirent.h>
 629     #else
 630     # define dirent direct
 631     # ifdef HAVE_SYS_NDIR_H
 632     #  include <sys/ndir.h>
 633     # endif
 634     # ifdef HAVE_SYS_DIR_H
 635     #  include <sys/dir.h>
 636     # endif
 637     # ifdef HAVE_NDIR_H
 638     #  include <ndir.h>
 639     # endif
 640     #endif ])
 641 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 642
 643 # Reasons for testing:
 644 #   complex.h - new in C99
 645 #   fenv.h - available in C99, but not older systems
 646 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 647 #     this file instead of <fenv.h>
 648 #   process.h - mingw specific
 649 #   langinfo.h, nl_types.h - SuS v2
 650 #   sched.h - missing on MinGW
 651 #
 652 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 653 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 654 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 655 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 656 direct.h langinfo.h nl_types.h machine/fpu.h poll.h sched.h])
 657
 658 # Reasons for testing:
 659 #   nl_item - lacking on Cygwin
 660 AC_CHECK_TYPES([nl_item], [], [],
 661   [[#ifdef HAVE_LANGINFO_H
 662     # include <langinfo.h>
 663     #endif
 664     #ifdef HAVE_NL_TYPES_H
 665     # include <nl_types.h>
 666     #endif]])
 667
 668 # "complex double" is new in C99, and "complex" is only a keyword if
 669 # <complex.h> is included
 670 AC_CHECK_TYPES(complex double,,,
 671 [#if HAVE_COMPLEX_H
 672 #include <complex.h>
 673 #endif])
 674
 675 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 676 # when testing.
 677 AC_CHECK_TYPE(socklen_t, ,
 678   [AC_DEFINE_UNQUOTED([socklen_t], int,
 679                       [Define to `int' if <sys/socket.h> does not define.])],
 680   [#if HAVE_SYS_TYPES_H
 681 #include <sys/types.h>
 682 #endif
 683 #include <sys/socket.h>
 684 ])
 685
 686 AC_CHECK_TYPES([struct ip_mreq], , , [#include <netinet/in.h>])
 687
 688 GUILE_HEADER_LIBC_WITH_UNISTD
 689
 690 AC_TYPE_GETGROUPS
 691 AC_TYPE_SIGNAL
 692 AC_TYPE_MODE_T
 693
 694 # On mingw -lm is empty, so this test is unnecessary, but it's
 695 # harmless so we don't hard-code to suppress it.
 696 #
 697 AC_CHECK_LIB(m, cos)
 698
 699 AC_CHECK_FUNCS(gethostbyname)
 700 if test $ac_cv_func_gethostbyname = no; then
 701     AC_CHECK_LIB(nsl, gethostbyname)
 702 fi
 703
 704 AC_CHECK_FUNCS(connect)
 705 if test $ac_cv_func_connect = no; then
 706     AC_CHECK_LIB(socket, connect)
 707 fi
 708
 709 dnl
 710 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 711 dnl
 712 EXTRA_DEFS=""
 713 case $host in
 714   *-*-mingw*)
 715     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 716       [Define if you have the <winsock2.h> header file.])])
 717     AC_CHECK_LIB(ws2_32, main)
 718     AC_LIBOBJ([win32-uname])
 719     AC_LIBOBJ([win32-dirent])
 720     if test "$enable_networking" = yes ; then
 721       AC_LIBOBJ([win32-socket])
 722     fi
 723     if test "$enable_shared" = yes ; then
 724       EXTRA_DEFS="-DSCM_IMPORT"
 725       AC_DEFINE([USE_DLL_IMPORT], 1,
 726         [Define if you need additional CPP macros on Win32 platforms.])
 727     fi
 728     ;;
 729 esac
 730 AC_SUBST(EXTRA_DEFS)
 731
 732 # Reasons for testing:
 733 #   crt_externs.h - Darwin specific
 734 #
 735 AC_CHECK_HEADERS([assert.h crt_externs.h])
 736
 737 # Reasons for testing:
 738 #   DINFINITY - OSF specific
 739 #   DQNAN - OSF specific
 740 #       (DINFINITY and DQNAN are actually global variables, not functions)
 741 #   chsize - an MS-DOS-ism, found in mingw
 742 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 743 #       for gcc to provide the "complex double" type but the system to not
 744 #       have functions like cexp and clog
 745 #   clog10 - not in mingw (though others like clog and csqrt are)
 746 #   fesetround - available in C99, but not older systems
 747 #   ftruncate - posix, but probably not older systems (current mingw
 748 #               has it as an inline for chsize)
 749 #   ioctl - not in mingw.
 750 #   gmtime_r - recent posix, not on old systems
 751 #   pipe - not in mingw
 752 #   _pipe - specific to mingw, taking 3 args
 753 #   poll - since posix 2001
 754 #   readdir_r - recent posix, not on old systems
 755 #   readdir64_r - not available on HP-UX 11.11
 756 #   stat64 - SuS largefile stuff, not on old systems
 757 #   sysconf - not on old systems
 758 #   truncate - not in mingw
 759 #   isblank - available as a GNU extension or in C99
 760 #   _NSGetEnviron - Darwin specific
 761 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 762 #   nl_langinfo - X/Open, not available on Windows.
 763 #   utimensat: posix.1-2008
 764 #   sched_getaffinity, sched_setaffinity: GNU extensions (glibc)
 765 #
 766 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid getsid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe poll readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo utimensat sched_getaffinity sched_setaffinity])
 767
 768 # Reasons for testing:
 769 #   netdb.h - not in mingw
 770 #   sys/param.h - not in mingw
 771 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 772 #       check this specifically, we need it for the timespec test below.
 773 #   sethostname - the function itself check because it's not in mingw,
 774 #       the DECL is checked because Solaris 10 doens't have in any header
 775 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 776 #       declaration isn't anywhere.
 777 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 778 #       only with `_XOPEN_SOURCE' or some such.
 779 #
 780 AC_CHECK_HEADERS([crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h sys/mman.h])
 781 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 782 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 783
 784 # crypt() may or may not be available, for instance in some countries there
 785 # are restrictions on cryptography.
 786 #
 787 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 788 # -lcrypt library (eg. Debian GNU/Linux).
 789 #
 790 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 791 # be careful to avoid -lcrypt in this case, since libtool will see there's
 792 # only a static libcrypt and decide to build only a static libguile.
 793 #
 794 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 795 # libraries already in that list.
 796 #
 797 AC_SEARCH_LIBS(crypt, crypt,
 798   [AC_DEFINE([HAVE_CRYPT],1,
 799              [Define to 1 if you have the `crypt' function.])])
 800
 801 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 802 # work; in the reported cases so far, 1.0fi works well instead.  According
 803 # to the C99 spec, the complex.h header must provide a working definition
 804 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 805 # is a workaround for the failure of some systems to conform to C99.
 806 if test "$ac_cv_type_complex_double" = yes; then
 807   AC_MSG_CHECKING([for i])
 808   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 809 #if HAVE_COMPLEX_H
 810 #include <complex.h>
 811 #endif
 812 complex double z;
 813 ]], [[
 814 z = _Complex_I;
 815 ]])],
 816     [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).])
 817      AC_MSG_RESULT([_Complex_I])],
 818     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 819 #if HAVE_COMPLEX_H
 820 #include <complex.h>
 821 #endif
 822 complex double z;
 823 ]],[[
 824 z = 1.0fi;
 825 ]])],
 826   [AC_DEFINE([GUILE_I],1.0fi)
 827    AC_MSG_RESULT([1.0fi])],
 828   [ac_cv_type_complex_double=no
 829    AC_MSG_RESULT([not available])])])
 830 fi
 831
 832 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 833 # csqrt(-i) returned a negative real part, when it should be positive
 834 # for the principal root.
 835 #
 836 if test "$ac_cv_type_complex_double" = yes; then
 837
 838   AC_CACHE_CHECK([whether csqrt is usable],
 839     guile_cv_use_csqrt,
 840     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 841 #include <complex.h>
 842 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 843    constant, we want to test libc. */
 844 volatile complex double z = - _Complex_I;
 845 int
 846 main (void)
 847 {
 848   z = csqrt (z);
 849   if (creal (z) > 0.0)
 850     return 0;  /* good */
 851   else
 852     return 1;  /* bad */
 853 }]])],
 854     [guile_cv_use_csqrt=yes],
 855     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 856     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 857   case $guile_cv_use_csqrt in
 858     yes*)
 859       AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free])
 860       ;;
 861   esac
 862 fi
 863
 864 AC_CACHE_SAVE
 865
 866 dnl GMP tests
 867 AC_LIB_HAVE_LINKFLAGS([gmp],
 868   [],
 869   [#include <gmp.h>],
 870   [mpz_import (0, 0, 0, 0, 0, 0, 0);])
 871
 872 if test "x$HAVE_LIBGMP" != "xyes"; then
 873   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README])
 874 fi
 875
 876 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 877 if test "x$LTLIBUNISTRING" = "x"; then
 878   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 879 fi
 880
 881 GUILE_LIBUNISTRING_WITH_ICONV_SUPPORT
 882 if test "x$ac_cv_libunistring_with_iconv_support" != "xyes"; then
 883   AC_MSG_ERROR([No iconv support.  Please recompile libunistring with iconv enabled.])
 884 fi
 885
 886 dnl Libffi is needed to compile Guile's foreign function interface, but its
 887 dnl interface isn't exposed in Guile's API.
 888 PKG_CHECK_MODULES(LIBFFI, libffi)
 889 AC_SUBST(LIBFFI_CFLAGS)
 890 AC_SUBST(LIBFFI_LIBS)
 891
 892 dnl figure out approriate ffi type for size_t
 893 AC_CHECK_SIZEOF(size_t)
 894 AC_CHECK_SIZEOF(ssize_t)
 895 ffi_size_type=uint$(($ac_cv_sizeof_size_t*8))
 896 ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8))
 897 AC_DEFINE_UNQUOTED([ffi_type_size_t], ffi_type_${ffi_size_type},
 898                    [ffi type for size_t])
 899 AC_DEFINE_UNQUOTED([ffi_type_ssize_t], ffi_type_${ffi_ssize_type},
 900                    [ffi type for ssize_t])
 901
 902 dnl i18n tests
 903 #AC_CHECK_HEADERS([libintl.h])
 904 #AC_CHECK_FUNCS(gettext)
 905 #if test $ac_cv_func_gettext = no; then
 906 #   AC_CHECK_LIB(intl, gettext)
 907 #fi
 908 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 909 AM_GNU_GETTEXT([external], [need-ngettext])
 910
 911 ### Some systems don't declare some functions.  On such systems, we
 912 ### need to at least provide our own K&R-style declarations.
 913
 914 ### GUILE_FUNC_DECLARED(function, headerfile)
 915
 916 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 917 ### not there, #define MISSING_FUNCTION_DECL.
 918 AC_DEFUN([GUILE_FUNC_DECLARED], [
 919   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 920     AC_EGREP_HEADER($1, $2,
 921                     guile_cv_func_$1_declared=yes,
 922                     guile_cv_func_$1_declared=no))
 923   if test [x$guile_cv_func_]$1[_declared] = xno; then
 924     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 925       [Define if the operating system supplies $1 without declaring it.])
 926   fi
 927 ])
 928
 929 GUILE_FUNC_DECLARED(sleep, unistd.h)
 930 GUILE_FUNC_DECLARED(usleep, unistd.h)
 931
 932 AC_CHECK_DECLS([strptime],,,
 933 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 934 #include <time.h>])
 935
 936 ### On some systems usleep has no return value.  If it does have one,
 937 ### we'd like to return it; otherwise, we'll fake it.
 938 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 939   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 940                    unistd.h,
 941                    [guile_cv_func_usleep_return_type=void],
 942                    [guile_cv_func_usleep_return_type=int])])
 943 case "$guile_cv_func_usleep_return_type" in
 944   "void" )
 945     AC_DEFINE([USLEEP_RETURNS_VOID], 1,
 946       [Define if the system headers declare usleep to return void.])
 947   ;;
 948 esac
 949
 950 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 951 if test -n "$have_sys_un_h" ; then
 952   AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1,
 953     [Define if the system supports Unix-domain (file-domain) sockets.])
 954 fi
 955
 956 AC_CHECK_FUNCS(getrlimit setrlimit)
 957
 958 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 959
 960 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 961                setnetent    getnetent    endnetent    dnl
 962                setprotoent  getprotoent  endprotoent  dnl
 963                setservent   getservent   endservent   dnl
 964                getnetbyaddr getnetbyname dnl
 965                inet_lnaof inet_makeaddr inet_netof hstrerror)
 966
 967 AC_CHECK_MEMBERS([struct sockaddr_in.sin_len],,,
 968 [#ifdef HAVE_SYS_TYPES_H
 969 #include <sys/types.h>
 970 #endif
 971 #include <netinet/in.h>])
 972
 973 AC_MSG_CHECKING(for __libc_stack_end)
 974 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 975 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 976 extern char *__libc_stack_end;]],
 977    [[printf("%p", (char*) __libc_stack_end);]])],
 978    [guile_cv_have_libc_stack_end=yes],
 979    [guile_cv_have_libc_stack_end=no])])
 980 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 981
 982 if test $guile_cv_have_libc_stack_end = yes; then
 983   AC_DEFINE([HAVE_LIBC_STACK_END], 1,
 984            [Define if you have the __libc_stack_end variable.])
 985 fi
 986
 987 dnl Some systems do not declare this.  Some systems do declare it, as a
 988 dnl macro.  With cygwin it may be in a DLL.
 989
 990 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 991 AC_CACHE_VAL(guile_cv_have_h_errno,
 992   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 993                                       [[int a = h_errno;]])],
 994   [guile_cv_have_h_errno=yes],
 995   [guile_cv_have_h_errno=no])])
 996 AC_MSG_RESULT($guile_cv_have_h_errno)
 997 if test $guile_cv_have_h_errno = yes; then
 998   AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.])
 999 fi
1000
1001 AC_MSG_CHECKING(whether uint32_t is defined)
1002 AC_CACHE_VAL(guile_cv_have_uint32_t,
1003   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1004                    #if HAVE_STDINT_H
1005                    #include <stdint.h>
1006                    #endif
1007                    #ifndef HAVE_NETDB_H
1008                    #include <netdb.h>
1009                    #endif]],
1010                    [[uint32_t a;]])],
1011                    [guile_cv_have_uint32_t=yes],
1012                    [guile_cv_have_uint32_t=no])])
1013 AC_MSG_RESULT($guile_cv_have_uint32_t)
1014 if test $guile_cv_have_uint32_t = yes; then
1015   AC_DEFINE([HAVE_UINT32_T], 1,
1016     [Define if uint32_t typedef is defined when netdb.h is include.])
1017 fi
1018
1019 AC_MSG_CHECKING(for working IPv6 support)
1020 AC_CACHE_VAL(guile_cv_have_ipv6,
1021 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1022 #ifdef HAVE_SYS_TYPES_H
1023 #include <sys/types.h>
1024 #endif
1025 #include <netinet/in.h>
1026 #include <sys/socket.h>]],
1027 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
1028 [guile_cv_have_ipv6=yes],
1029 [guile_cv_have_ipv6=no])])
1030 AC_MSG_RESULT($guile_cv_have_ipv6)
1031 if test $guile_cv_have_ipv6 = yes; then
1032   AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.])
1033 fi
1034
1035 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
1036 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
1037 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
1038 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1039 #ifdef HAVE_SYS_TYPES_H
1040 #include <sys/types.h>
1041 #endif
1042 #include <netinet/in.h>]],
1043 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
1044 [guile_cv_have_sin6_scope_id=yes],
1045 [guile_cv_have_sin6_scope_id=no])])
1046 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
1047 if test $guile_cv_have_sin6_scope_id = yes; then
1048   AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1,
1049     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
1050 fi
1051
1052 # struct sockaddr_in6 field sin_len is only present on BSD systems
1053 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1054 [#ifdef HAVE_SYS_TYPES_H
1055 #include <sys/types.h>
1056 #endif
1057 #include <netinet/in.h>])
1058
1059 AC_MSG_CHECKING(whether localtime caches TZ)
1060 AC_CACHE_VAL(guile_cv_localtime_cache,
1061 [if test x$ac_cv_func_tzset = xyes; then
1062 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1063 #if STDC_HEADERS
1064 # include <stdlib.h>
1065 #endif
1066 extern char **environ;
1067 unset_TZ ()
1068 {
1069   char **from, **to;
1070   for (to = from = environ; (*to = *from); from++)
1071     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1072       to++;
1073 }
1074 char TZ_GMT0[] = "TZ=GMT0";
1075 char TZ_PST8[] = "TZ=PST8";
1076 main()
1077 {
1078   time_t now = time ((time_t *) 0);
1079   int hour_GMT0, hour_unset;
1080   if (putenv (TZ_GMT0) != 0)
1081     exit (1);
1082   hour_GMT0 = localtime (&now)->tm_hour;
1083   unset_TZ ();
1084   hour_unset = localtime (&now)->tm_hour;
1085   if (putenv (TZ_PST8) != 0)
1086     exit (1);
1087   if (localtime (&now)->tm_hour == hour_GMT0)
1088     exit (1);
1089   unset_TZ ();
1090   if (localtime (&now)->tm_hour != hour_unset)
1091     exit (1);
1092   exit (0);
1093 }]])],
1094 [guile_cv_localtime_cache=no],
1095 [guile_cv_localtime_cache=yes],
1096 [# If we have tzset, assume the worst when cross-compiling.
1097 guile_cv_localtime_cache=yes])
1098 else
1099         # If we lack tzset, report that localtime does not cache TZ,
1100         # since we can't invalidate the cache if we don't have tzset.
1101         guile_cv_localtime_cache=no
1102 fi])dnl
1103 AC_MSG_RESULT($guile_cv_localtime_cache)
1104 if test $guile_cv_localtime_cache = yes; then
1105   AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.])
1106 fi
1107
1108 if test "$enable_regex" = yes; then
1109    if test "$ac_cv_header_regex_h" = yes ||
1110       test "$ac_cv_header_rxposix_h" = yes ||
1111       test "$ac_cv_header_rx_rxposix_h" = yes; then
1112      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1113      [AC_CHECK_LIB(rx, main)
1114       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1115      [AC_CHECK_LIB(regex, main)
1116       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1117      )
1118      dnl The following should not be necessary, but for some reason
1119      dnl autoheader misses it if we don't include it!
1120      if test "$ac_cv_func_regcomp_norx" = yes ||
1121         test "$ac_cv_func_regcomp_regex" = yes ||
1122         test "$ac_cv_func_regcomp_rx" = yes; then
1123        AC_DEFINE([HAVE_REGCOMP], 1,
1124          [This is included as part of a workaround for a autoheader bug.])
1125      fi
1126    fi
1127 fi
1128
1129 AC_REPLACE_FUNCS([strerror memmove mkstemp])
1130
1131 # Reasons for testing:
1132 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1133 #                                older systems
1134 #   sincos - GLIBC extension
1135 #
1136 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1137
1138 # C99 specifies isinf and isnan as macros.
1139 # HP-UX provides only macros, no functions.
1140 # glibc 2.3.2 provides both macros and functions.
1141 # IRIX 6.5 and Solaris 8 only provide functions.
1142 #
1143 # The following tests detect isinf and isnan either as functions or as
1144 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1145 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1146 #
1147 AC_MSG_CHECKING([for isinf])
1148 AC_LINK_IFELSE(AC_LANG_SOURCE(
1149 [[#include <math.h>
1150 volatile double x = 0.0;
1151 int main () { return (isinf(x) != 0); }]]),
1152   [AC_MSG_RESULT([yes])
1153    AC_DEFINE([HAVE_ISINF], 1,
1154              [Define to 1 if you have the `isinf' macro or function.])],
1155   [AC_MSG_RESULT([no])])
1156 AC_MSG_CHECKING([for isnan])
1157 AC_LINK_IFELSE(AC_LANG_SOURCE(
1158 [[#include <math.h>
1159 volatile double x = 0.0;
1160 int main () { return (isnan(x) != 0); }]]),
1161   [AC_MSG_RESULT([yes])
1162    AC_DEFINE([HAVE_ISNAN], 1,
1163              [Define to 1 if you have the `isnan' macro or function.])],
1164   [AC_MSG_RESULT([no])])
1165
1166 # Reasons for checking:
1167 #
1168 #     st_rdev
1169 #     st_blksize
1170 #     st_blocks   not in mingw
1171 #     tm_gmtoff   BSD+GNU, not in C99
1172 #
1173 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1174 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1175 #
1176 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,,
1177                  [#define _GNU_SOURCE
1178 AC_INCLUDES_DEFAULT
1179 ])
1180
1181 AC_STRUCT_TIMEZONE
1182 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1183 [#include <time.h>
1184 #ifdef TIME_WITH_SYS_TIME
1185 # include <sys/time.h>
1186 # include <time.h>
1187 #else
1188 # if HAVE_SYS_TIME_H
1189 #  include <sys/time.h>
1190 # else
1191 #  include <time.h>
1192 # endif
1193 #endif
1194 ])
1195 GUILE_STRUCT_UTIMBUF
1196
1197
1198 #--------------------------------------------------------------------
1199 #
1200 # What values do the iconv error handlers have?
1201 #
1202 # The only place that we need iconv in our public interfaces is for
1203 # the error handlers, which are just ints.  So we weaken our
1204 # dependency by looking up those values at configure-time.
1205 #--------------------------------------------------------------------
1206 SCM_I_GSC_ICONVEH_ERROR=0
1207 SCM_I_GSC_ICONVEH_QUESTION_MARK=1
1208 SCM_I_GSC_ICONVEH_ESCAPE_SEQUENCE=2
1209 AC_MSG_CHECKING([for iconveh_error])
1210 AC_RUN_IFELSE([AC_LANG_SOURCE(
1211 [AC_INCLUDES_DEFAULT
1212 #include <uniconv.h>
1213 int
1214 main (int argc, char *argv[])
1215 {
1216   if (argc > 1)
1217     printf ("%d\n", (int)iconveh_error);
1218   return 0;
1219 }])],
1220                [SCM_I_GSC_ICONVEH_ERROR=`./conftest$EXEEXT pretty-please`
1221                 AC_MSG_RESULT([$SCM_I_GSC_ICONVEH_ERROR])],
1222                [AC_MSG_FAILURE([failed to get iconveh_error])],
1223                [AC_MSG_WARN([assuming $SCM_I_GSC_ICONVEH_ERROR for cross-compilation])])
1224
1225 AC_MSG_CHECKING([for iconveh_question_mark])
1226 AC_RUN_IFELSE([AC_LANG_SOURCE(
1227 [AC_INCLUDES_DEFAULT
1228 #include <uniconv.h>
1229 int
1230 main (int argc, char *argv[])
1231 {
1232   if (argc > 1)
1233     printf ("%d\n", (int)iconveh_question_mark);
1234   return 0;
1235 }])],
1236                [SCM_I_GSC_ICONVEH_QUESTION_MARK=`./conftest$EXEEXT pretty-please`
1237                 AC_MSG_RESULT([$SCM_I_GSC_ICONVEH_QUESTION_MARK])],
1238                [AC_MSG_FAILURE([failed to get iconveh_question_mark])],
1239                [AC_MSG_WARN([assuming $SCM_I_GSC_ICONVEH_QUESTION_MARK for cross-compilation])])
1240
1241 AC_MSG_CHECKING([for iconveh_escape_sequence])
1242 AC_RUN_IFELSE([AC_LANG_SOURCE(
1243 [AC_INCLUDES_DEFAULT
1244 #include <uniconv.h>
1245 int
1246 main (int argc, char *argv[])
1247 {
1248   if (argc > 1)
1249     printf ("%d\n", (int)iconveh_escape_sequence);
1250   return 0;
1251 }])],
1252                [SCM_I_GSC_ICONVEH_ESCAPE_SEQUENCE=`./conftest$EXEEXT pretty-please`
1253                 AC_MSG_RESULT([$SCM_I_GSC_ICONVEH_ESCAPE_SEQUENCE])],
1254                [AC_MSG_FAILURE([failed to get iconveh_escape_sequence])],
1255                [AC_MSG_WARN([assuming $SCM_I_GSC_ICONVEH_ESCAPE_SEQUENCE for cross-compilation])])
1256
1257 AC_SUBST([SCM_I_GSC_ICONVEH_ERROR])
1258 AC_SUBST([SCM_I_GSC_ICONVEH_QUESTION_MARK])
1259 AC_SUBST([SCM_I_GSC_ICONVEH_ESCAPE_SEQUENCE])
1260
1261
1262 #--------------------------------------------------------------------
1263 #
1264 # Which way does the stack grow?
1265 #
1266 # Following code comes from Autoconf 2.61's internal _AC_LIBOBJ_ALLOCA
1267 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1268 # very similar code, so in future we could look at using that.
1269 #
1270 # An important detail is that the code involves find_stack_direction
1271 # calling _itself_ - which means that find_stack_direction (or at
1272 # least the second find_stack_direction() call) cannot be inlined.
1273 # If the code could be inlined, that might cause the test to give
1274 # an incorrect answer.
1275 #--------------------------------------------------------------------
1276
1277 SCM_I_GSC_STACK_GROWS_UP=0
1278 AC_RUN_IFELSE([AC_LANG_SOURCE(
1279 [AC_INCLUDES_DEFAULT
1280 int
1281 find_stack_direction ()
1282 {
1283   static char *addr = 0;
1284   auto char dummy;
1285   if (addr == 0)
1286     {
1287       addr = &dummy;
1288       return find_stack_direction ();
1289     }
1290   else
1291     return (&dummy > addr) ? 1 : -1;
1292 }
1293
1294 int
1295 main ()
1296 {
1297   return find_stack_direction () < 0;
1298 }])],
1299                [SCM_I_GSC_STACK_GROWS_UP=1],
1300                [],
1301                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1302
1303 #--------------------------------------------------------------------
1304 #
1305 # Boehm's GC library
1306 #
1307 #--------------------------------------------------------------------
1308 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1309
1310 save_LIBS="$LIBS"
1311 LIBS="$BDW_GC_LIBS $LIBS"
1312 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1313
1314 AC_CHECK_FUNCS([GC_do_blocking GC_call_with_gc_active GC_pthread_exit GC_pthread_cancel GC_allow_register_threads GC_pthread_sigmask GC_set_start_callback])
1315
1316 # Though the `GC_do_blocking ()' symbol is present in GC 7.1, it is not
1317 # declared, and has a different type (returning void instead of
1318 # void*).
1319 AC_CHECK_DECL([GC_do_blocking],
1320   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1321     [Define this if the `GC_do_blocking ()' function is declared])],
1322   [],
1323   [#include <gc/gc.h>])
1324
1325 # `GC_fn_type' is not available in GC 7.1 and earlier.
1326 AC_CHECK_TYPE([GC_fn_type],
1327   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1328     [Define this if the `GC_fn_type' type is available.])],
1329   [],
1330   [#include <gc/gc.h>])
1331
1332 # `GC_stack_base' is not available in GC 7.1 and earlier.
1333 AC_CHECK_TYPE([struct GC_stack_base],
1334   [AC_DEFINE([HAVE_GC_STACK_BASE], [1],
1335     [Define this if the `GC_stack_base' type is available.])],
1336   [],
1337   [#include <gc/gc.h>])
1338
1339 LIBS="$save_LIBS"
1340
1341
1342 AC_CHECK_SIZEOF(float)
1343 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1344     AC_DEFINE([SCM_SINGLES], 1,
1345               [Define this if floats are the same size as longs.])
1346 fi
1347
1348 AC_MSG_CHECKING(for struct linger)
1349 AC_CACHE_VAL(scm_cv_struct_linger,
1350         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1351 #include <sys/types.h>
1352 #include <sys/socket.h>]],
1353                           [[struct linger lgr;  lgr.l_linger = 100]])],
1354                           [scm_cv_struct_linger="yes"],
1355                           [scm_cv_struct_linger="no"]))
1356 AC_MSG_RESULT($scm_cv_struct_linger)
1357 if test $scm_cv_struct_linger = yes; then
1358         AC_DEFINE([HAVE_STRUCT_LINGER], 1,
1359           [Define this if your system defines struct linger, for use with the
1360            getsockopt and setsockopt system calls.])
1361 fi
1362
1363
1364 # On mingw, struct timespec is in <pthread.h>.
1365 #
1366 AC_MSG_CHECKING(for struct timespec)
1367 AC_CACHE_VAL(scm_cv_struct_timespec,
1368         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1369 #include <time.h>
1370 #if HAVE_PTHREAD_H
1371 #include <pthread.h>
1372 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1373           [scm_cv_struct_timespec="yes"],
1374           [scm_cv_struct_timespec="no"]))
1375 AC_MSG_RESULT($scm_cv_struct_timespec)
1376 if test $scm_cv_struct_timespec = yes; then
1377   AC_DEFINE([HAVE_STRUCT_TIMESPEC], 1,
1378     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1379 fi
1380
1381 #--------------------------------------------------------------------
1382 #
1383 # Flags for thread support
1384 #
1385 #--------------------------------------------------------------------
1386
1387 SCM_I_GSC_USE_PTHREAD_THREADS=0
1388 SCM_I_GSC_USE_NULL_THREADS=0
1389 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1390 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1391
1392 ### What thread package has the user asked for?
1393 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1394             , with_threads=yes)
1395
1396 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1397 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1398
1399 case "$with_threads" in
1400   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1401
1402     build_pthread_support="yes"
1403
1404     ACX_PTHREAD([CC="$PTHREAD_CC"
1405        LIBS="$PTHREAD_LIBS $LIBS"
1406        SCM_I_GSC_USE_PTHREAD_THREADS=1
1407        with_threads="pthreads"],
1408       [with_threads="null"
1409        build_pthread_support="no"])
1410
1411     old_CFLAGS="$CFLAGS"
1412     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1413
1414     # Reasons for testing:
1415     #     pthread_getattr_np - "np" meaning "non portable" says it
1416     #         all; not present on MacOS X or Solaris 10
1417     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1418     #         all; specific to MacOS X
1419     #     pthread_sigmask - not available on mingw
1420     #
1421     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1422
1423     # On past versions of Solaris, believe 8 through 10 at least, you
1424     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1425     # This is contrary to POSIX:
1426     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1427     # Check here if this style is required.
1428     #
1429     # glibc (2.3.6 at least) works both with or without braces, so the
1430     # test checks whether it works without.
1431     #
1432
1433     if test "$GCC" = "yes"; then
1434       # Since GCC only issues a warning for missing braces, so we need
1435       # `-Werror' to catch it.
1436       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1437     fi
1438
1439     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1440       guile_cv_need_braces_on_pthread_once_init,
1441       [AC_COMPILE_IFELSE([#include <pthread.h>
1442          pthread_once_t foo = PTHREAD_ONCE_INIT;],
1443         [guile_cv_need_braces_on_pthread_once_init=no],
1444         [guile_cv_need_braces_on_pthread_once_init=yes])])
1445     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1446       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1447     fi
1448
1449     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1450     # 6.5.30m with GCC 3.3.
1451     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1452       guile_cv_need_braces_on_pthread_mutex_initializer,
1453       [AC_COMPILE_IFELSE([#include <pthread.h>
1454          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;],
1455         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1456         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1457     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1458       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1459     fi
1460
1461     CFLAGS="$old_CFLAGS"
1462
1463     # On Solaris, sched_yield lives in -lrt.
1464     AC_SEARCH_LIBS(sched_yield, rt)
1465
1466   ;;
1467 esac
1468
1469 case "$with_threads" in
1470   "pthreads")
1471   ;;
1472   "no" | "null")
1473     SCM_I_GSC_USE_NULL_THREADS=1
1474     SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
1475     with_threads="null-threads"
1476   ;;
1477   * )
1478     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1479   ;;
1480 esac
1481
1482 AC_MSG_CHECKING(what kind of threads to support)
1483 AC_MSG_RESULT($with_threads)
1484
1485 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1486   [test "x$build_pthread_support" = "xyes"])
1487
1488
1489 ## Check whether pthread_attr_getstack works for the main thread
1490
1491 if test "$with_threads" = pthreads; then
1492
1493 AC_MSG_CHECKING([whether pthread_attr_getstack works for the main thread])
1494 old_CFLAGS="$CFLAGS"
1495 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1496 if test "$cross_compiling" = "no"; then
1497   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1498   #if HAVE_PTHREAD_ATTR_GETSTACK
1499   #include <pthread.h>
1500
1501   int main ()
1502   {
1503     pthread_attr_t attr;
1504     void *start, *end;
1505     size_t size;
1506
1507     pthread_getattr_np (pthread_self (), &attr);
1508     pthread_attr_getstack (&attr, &start, &size);
1509     end = (char *)start + size;
1510
1511     if ((void *)&attr < start || (void *)&attr >= end)
1512       return 1;
1513     else
1514       return 0;
1515   }
1516   #else
1517   int main ()
1518   {
1519     return 1;
1520   }
1521   #endif
1522   ]])],
1523   [works=yes
1524    AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])],
1525   [works=no],
1526   [])
1527 else
1528   works="assuming it doesn't"
1529 fi
1530 CFLAGS="$old_CFLAGS"
1531 AC_MSG_RESULT($works)
1532
1533 GUILE_THREAD_LOCAL_STORAGE
1534
1535 fi # with_threads=pthreads
1536
1537
1538 ## Cross building
1539 if test "$cross_compiling" = "yes"; then
1540   AC_MSG_CHECKING(cc for build)
1541   ## /usr/bin/cc still uses wrong assembler
1542   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1543   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1544 else
1545   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1546 fi
1547
1548 ## AC_MSG_CHECKING("if we are cross compiling")
1549 ## AC_MSG_RESULT($cross_compiling)
1550 if test "$cross_compiling" = "yes"; then
1551    AC_MSG_RESULT($CC_FOR_BUILD)
1552 fi
1553
1554 ## No need as yet to be more elaborate
1555 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1556
1557 AC_SUBST(cross_compiling)
1558 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1559 AC_SUBST(CCLD_FOR_BUILD)
1560
1561 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1562 ## --HOST is the platform that PACKAGE is compiled for.
1563 HOST_CC="$CC_FOR_BUILD"
1564 AC_SUBST(HOST_CC)
1565
1566 if test "$cross_compiling" = "yes"; then
1567   AC_MSG_CHECKING(guile for build)
1568   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1569 else
1570   GUILE_FOR_BUILD='this-value-will-never-be-used'
1571 fi
1572
1573 ## AC_MSG_CHECKING("if we are cross compiling")
1574 ## AC_MSG_RESULT($cross_compiling)
1575 if test "$cross_compiling" = "yes"; then
1576    AC_MSG_RESULT($GUILE_FOR_BUILD)
1577 fi
1578 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1579 AM_SUBST_NOTMAKE(GUILE_FOR_BUILD)
1580
1581 ## If we're using GCC, ask for aggressive warnings.
1582 GCC_CFLAGS=""
1583 case "$GCC" in
1584   yes )
1585     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1586     ## much stuff with generic function pointers for that to really be
1587     ## less than exasperating.
1588     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1589     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1590     ## -Wundef was removed because Gnulib prevented it (see
1591     ## <http://thread.gmane.org/gmane.lisp.guile.bugs/5329>.)
1592     POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \
1593       -Wdeclaration-after-statement \
1594       -Wswitch-enum"
1595     # Do this here so we don't screw up any of the tests above that might
1596     # not be "warning free"
1597     if test "${GUILE_ERROR_ON_WARNING}" = yes
1598     then
1599         POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror"
1600         enable_compile_warnings=no
1601     fi
1602
1603     for flag in $POTENTIAL_GCC_CFLAGS
1604     do
1605         gl_WARN_ADD([$flag], [GCC_CFLAGS])
1606     done
1607     ;;
1608 esac
1609
1610 AC_SUBST(GCC_CFLAGS)
1611
1612 # Check for GNU ld's "-z relro".
1613 GUILE_GNU_LD_RELRO
1614
1615
1616 ## If we're creating a shared library (using libtool!), then we'll
1617 ## need to generate a list of .lo files corresponding to the .o files
1618 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1619 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1620
1621 ## We also need to create corresponding .doc and .x files
1622 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1623 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1624
1625 # GNU Readline bindings.
1626 GUILE_READLINE
1627
1628 AC_SUBST(GUILE_MAJOR_VERSION)
1629 AC_SUBST(GUILE_MINOR_VERSION)
1630 AC_SUBST(GUILE_MICRO_VERSION)
1631 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1632 AC_SUBST(GUILE_VERSION)
1633
1634 #######################################################################
1635 # library versioning
1636
1637 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1638 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1639 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1640 AC_SUBST(LIBGUILE_INTERFACE)
1641
1642 AC_SUBST(LIBGUILE_I18N_MAJOR)
1643 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1644 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1645 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1646 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1647
1648
1649 #######################################################################
1650
1651 dnl Tell guile-config what flags guile users should compile and link
1652 dnl with, keeping only `-I' flags from $CPPFLAGS.
1653 GUILE_CFLAGS=""
1654 next_is_includedir=false
1655 for flag in $CPPFLAGS
1656 do
1657   if $next_is_includedir; then
1658     GUILE_CFLAGS="$GUILE_CFLAGS -I $flag"
1659     next_is_includedir=false
1660   else
1661     case "$flag" in
1662       -I)  next_is_includedir=true;;
1663       -I*) GUILE_CFLAGS="$GUILE_CFLAGS $flag";;
1664       *)   ;;
1665     esac
1666   fi
1667 done
1668
1669 GUILE_CFLAGS="$GUILE_CFLAGS $PTHREAD_CFLAGS"
1670 GUILE_LIBS="$LDFLAGS $LIBS"
1671
1672 AC_SUBST(GUILE_LIBS)
1673 AC_SUBST(GUILE_CFLAGS)
1674
1675 AC_SUBST(AWK)
1676 AC_SUBST(LIBLOBJS)
1677 AC_SUBST(EXTRA_DOT_DOC_FILES)
1678 AC_SUBST(EXTRA_DOT_X_FILES)
1679
1680 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1681 top_builddir_absolute=`pwd`
1682 AC_SUBST(top_builddir_absolute)
1683 top_srcdir_absolute=`(cd $srcdir && pwd)`
1684 AC_SUBST(top_srcdir_absolute)
1685
1686 dnl `sitedir' goes into libpath.h and the pkg-config file.
1687 pkgdatadir="$datadir/$PACKAGE_TARNAME"
1688 sitedir="$pkgdatadir/site/$GUILE_EFFECTIVE_VERSION"
1689 AC_SUBST([sitedir])
1690
1691 # Additional SCM_I_GSC definitions are above.
1692 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1693 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1694 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1695 AC_SUBST([SCM_I_GSC_C_INLINE])
1696 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1697
1698 AC_CONFIG_FILES([
1699   Makefile
1700   am/Makefile
1701   lib/Makefile
1702   benchmark-suite/Makefile
1703   gc-benchmarks/Makefile
1704   doc/Makefile
1705   doc/r5rs/Makefile
1706   doc/ref/Makefile
1707   emacs/Makefile
1708   examples/Makefile
1709   libguile/Makefile
1710   libguile/version.h
1711   guile-readline/Makefile
1712   test-suite/Makefile
1713   test-suite/standalone/Makefile
1714   test-suite/vm/Makefile
1715   meta/Makefile
1716   module/Makefile
1717 ])
1718
1719 AC_CONFIG_FILES([meta/guile-2.0.pc])
1720 AC_CONFIG_FILES([meta/guile-2.0-uninstalled.pc])
1721 AC_CONFIG_FILES([doc/ref/effective-version.texi])
1722
1723 GUILE_CONFIG_SCRIPT([check-guile])
1724 GUILE_CONFIG_SCRIPT([benchmark-guile])
1725 GUILE_CONFIG_SCRIPT([meta/guile])
1726 GUILE_CONFIG_SCRIPT([meta/uninstalled-env])
1727 GUILE_CONFIG_SCRIPT([meta/gdb-uninstalled-guile])
1728 GUILE_CONFIG_SCRIPT([meta/guild])
1729 GUILE_CONFIG_SCRIPT([libguile/guile-snarf])
1730 GUILE_CONFIG_SCRIPT([libguile/guile-snarf-docs])
1731 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-use-srfi])
1732 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-fast-slot-ref])
1733
1734 AC_OUTPUT
1735
1736 dnl Local Variables:
1737 dnl comment-start: "dnl "
1738 dnl comment-end: ""
1739 dnl comment-start-skip: "\\bdnl\\b\\s *"
1740 dnl End: