configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it
  12 under the terms of the GNU General Public License as published by
  13 the Free Software Foundation; either version 2, or (at your
  14 option) any later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but
  17 WITHOUT ANY WARRANTY; without even the implied warranty of
  18 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 General Public License for more details.
  20
  21 You should have received a copy of the GNU General Public License
  22 along with GUILE; see the file COPYING.  If not, write to the
  23 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 Boston, MA 02110-1301, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.53)
  29
  30 AC_INIT(m4_esyscmd(. ./GUILE-VERSION && echo -n ${PACKAGE}),
  31         m4_esyscmd(. ./GUILE-VERSION && echo -n ${GUILE_VERSION}),
  32         [bug-guile@gnu.org])
  33 AC_CONFIG_AUX_DIR([.])
  34 AC_CONFIG_SRCDIR(GUILE-VERSION)
  35 AM_INIT_AUTOMAKE([no-define])
  36
  37 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  38 AC_CONFIG_SRCDIR([GUILE-VERSION])
  39
  40 . $srcdir/GUILE-VERSION
  41
  42 AM_MAINTAINER_MODE
  43 AM_CONFIG_HEADER([config.h])
  44 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  45
  46 #--------------------------------------------------------------------
  47 #
  48 # Independent Subdirectories
  49 #
  50 #--------------------------------------------------------------------
  51
  52 AC_CONFIG_SUBDIRS(guile-readline)
  53
  54 #--------------------------------------------------------------------
  55
  56 dnl Some more checks for Win32
  57 AC_CYGWIN
  58 AC_MINGW32
  59 AC_LIBTOOL_WIN32_DLL
  60
  61 AC_PROG_INSTALL
  62 AC_PROG_CC
  63 AC_PROG_CPP
  64 AC_PROG_AWK
  65
  66 AC_AIX
  67 AC_ISC_POSIX
  68 AC_MINIX
  69
  70 AM_PROG_CC_STDC
  71
  72 AC_LIBTOOL_DLOPEN
  73 AC_PROG_LIBTOOL
  74 AC_CHECK_LIB([ltdl], [lt_dlinit], ,
  75   [AC_MSG_ERROR([libltdl not found.  See README.])])
  76
  77 AC_SUBST(DLPREOPEN)
  78
  79 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  80 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  81
  82 AM_PATH_LISPDIR
  83
  84 #--------------------------------------------------------------------
  85 #
  86 # User options (after above tests that may set default CFLAGS etc.)
  87 #
  88 #--------------------------------------------------------------------
  89
  90 GUILE_ERROR_ON_WARNING="yes"
  91
  92 AC_ARG_ENABLE(error-on-warning,
  93   [  --enable-error-on-warning    treat compile warnings as errors],
  94   [case "${enableval}" in
  95      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
  96      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
  97      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  98    esac])
  99
 100 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
 101 AC_ARG_ENABLE(debug-freelist,
 102   [  --enable-debug-freelist include garbage collector freelist debugging code],
 103   if test "$enable_debug_freelist" = y \
 104      || test "$enable_debug_freelist" = yes; then
 105     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
 106   fi)
 107
 108 AC_ARG_ENABLE(debug-malloc,
 109   [  --enable-debug-malloc   include malloc debugging code],
 110   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 111     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 112       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 113   fi)
 114
 115 SCM_I_GSC_GUILE_DEBUG=0
 116 AC_ARG_ENABLE(guile-debug,
 117   [AC_HELP_STRING([--enable-guile-debug],
 118                   [include internal debugging functions])],
 119   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 120     SCM_I_GSC_GUILE_DEBUG=1
 121   fi)
 122
 123 AC_ARG_ENABLE(posix,
 124   [  --disable-posix         omit posix interfaces],,
 125   enable_posix=yes)
 126
 127 AC_ARG_ENABLE(networking,
 128   [  --disable-networking    omit networking interfaces],,
 129   enable_networking=yes)
 130
 131 AC_ARG_ENABLE(regex,
 132   [  --disable-regex         omit regular expression interfaces],,
 133   enable_regex=yes)
 134
 135 AC_ARG_ENABLE([discouraged],
 136   AC_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 137
 138 if test "$enable_discouraged" = no; then
 139   SCM_I_GSC_ENABLE_DISCOURAGED=0
 140 else
 141   SCM_I_GSC_ENABLE_DISCOURAGED=1
 142 fi
 143
 144 AC_ARG_ENABLE([deprecated],
 145   AC_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 146
 147 if test "$enable_deprecated" = no; then
 148   SCM_I_GSC_ENABLE_DEPRECATED=0
 149 else
 150   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 151     warn_default=summary
 152   elif test "$enable_deprecated" = shutup; then
 153     warn_default=no
 154   else
 155     warn_default=$enable_deprecated
 156   fi
 157   SCM_I_GSC_ENABLE_DEPRECATED=1
 158   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 159   [Define this to control the default warning level for deprecated features.])
 160 fi
 161
 162 AC_ARG_ENABLE(elisp,
 163   [  --disable-elisp         omit Emacs Lisp support],,
 164   enable_elisp=yes)
 165
 166 #--------------------------------------------------------------------
 167
 168 dnl Check for dynamic linking
 169
 170 use_modules=yes
 171 AC_ARG_WITH(modules,
 172 [  --with-modules[=FILES]  Add support for dynamic modules],
 173 use_modules="$withval")
 174 test -z "$use_modules" && use_modules=yes
 175 DLPREOPEN=
 176 if test "$use_modules" != no; then
 177   if test "$use_modules" = yes; then
 178     DLPREOPEN="-dlpreopen force"
 179   else
 180     DLPREOPEN="-export-dynamic"
 181     for module in $use_modules; do
 182       DLPREOPEN="$DLPREOPEN -dlopen $module"
 183     done
 184   fi
 185 fi
 186
 187 dnl files which are destined for separate modules.
 188
 189 if test "$use_modules" != no; then
 190    AC_LIBOBJ([dynl])
 191 fi
 192
 193 if test "$enable_posix" = yes; then
 194    AC_LIBOBJ([filesys])
 195    AC_LIBOBJ([posix])
 196    AC_DEFINE(HAVE_POSIX, 1,
 197      [Define this if you want support for POSIX system calls in Guile.])
 198 fi
 199
 200 if test "$enable_networking" = yes; then
 201    AC_LIBOBJ([net_db])
 202    AC_LIBOBJ([socket])
 203    AC_DEFINE(HAVE_NETWORKING, 1,
 204      [Define this if you want support for networking in Guile.])
 205 fi
 206
 207 if test "$enable_debug_malloc" = yes; then
 208    AC_LIBOBJ([debug-malloc])
 209 fi
 210
 211 if test "$enable_elisp" = yes; then
 212   SCM_I_GSC_ENABLE_ELISP=1
 213 else
 214   SCM_I_GSC_ENABLE_ELISP=0
 215 fi
 216 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 217
 218 AC_C_CONST
 219
 220 AC_C_INLINE
 221 if test "$ac_cv_c_inline" != no; then
 222   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 223 else
 224   SCM_I_GSC_C_INLINE=NULL
 225 fi
 226 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 227
 228 AC_C_BIGENDIAN
 229
 230 AC_CHECK_SIZEOF(char)
 231 AC_CHECK_SIZEOF(unsigned char)
 232 AC_CHECK_SIZEOF(short)
 233 AC_CHECK_SIZEOF(unsigned short)
 234 AC_CHECK_SIZEOF(int)
 235 AC_CHECK_SIZEOF(unsigned int)
 236 AC_CHECK_SIZEOF(long)
 237 AC_CHECK_SIZEOF(unsigned long)
 238 AC_CHECK_SIZEOF(size_t)
 239 AC_CHECK_SIZEOF(long long)
 240 AC_CHECK_SIZEOF(unsigned long long)
 241 AC_CHECK_SIZEOF(__int64)
 242 AC_CHECK_SIZEOF(unsigned __int64)
 243 AC_CHECK_SIZEOF(void *)
 244 AC_CHECK_SIZEOF(intptr_t)
 245 AC_CHECK_SIZEOF(uintptr_t)
 246 AC_CHECK_SIZEOF(ptrdiff_t)
 247 AC_CHECK_SIZEOF(size_t)
 248 AC_CHECK_SIZEOF(off_t)
 249
 250 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 251   AC_MSG_ERROR(sizes of long and void* are not identical)
 252 fi
 253
 254 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 255   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 256 else
 257   SCM_I_GSC_T_PTRDIFF='"long"'
 258 fi
 259 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 260
 261 AC_CHECK_HEADERS([stdint.h])
 262 AC_CHECK_HEADERS([inttypes.h])
 263
 264 AC_CHECK_SIZEOF(intmax_t)
 265
 266 SCM_I_GSC_NEEDS_STDINT_H=0
 267 SCM_I_GSC_NEEDS_INTTYPES_H=0
 268
 269 ### intptr and uintptr (try not to use inttypes if we don't have to)
 270 if test "$ac_cv_header_inttypes_h" = yes; then
 271   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 272     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 273 #include <stdio.h>])
 274     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 275       SCM_I_GSC_NEEDS_INTTYPES_H=1
 276     fi
 277   fi
 278   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 279     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 280 #include <stdio.h>])
 281     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 282       SCM_I_GSC_NEEDS_INTTYPES_H=1
 283     fi
 284   fi
 285 fi
 286
 287 ### See what's provided by stdint.h
 288 if test "$ac_cv_header_stdint_h" = yes; then
 289    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 290    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 291    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 292    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 293    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 294    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 295    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 296    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 297    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 298    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 299 fi
 300
 301 # so we don't get confused by the cache (wish there was a better way
 302 # to check particular headers for the same type...)
 303
 304 unset ac_cv_type_int8_t
 305 unset ac_cv_type_uint8_t
 306 unset ac_cv_type_int16_t
 307 unset ac_cv_type_uint16_t
 308 unset ac_cv_type_int32_t
 309 unset ac_cv_type_uint32_t
 310 unset ac_cv_type_int64_t
 311 unset ac_cv_type_uint64_t
 312 unset ac_cv_type_intmax_t
 313 unset ac_cv_type_uintmax_t
 314
 315 ### See what's provided by inttypes.h
 316 if test "$ac_cv_header_inttypes_h" = yes; then
 317   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 318   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 319   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 320   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 321   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 322   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 323   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 324   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 325   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 326   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 327 fi
 328
 329 # Try hard to find definitions for some required scm_t_*int* types.
 330
 331 ### Required type scm_t_int8
 332 if test "$scm_stdint_has_int8"; then
 333   SCM_I_GSC_T_INT8='"int8_t"'
 334   SCM_I_GSC_NEEDS_STDINT_H=1
 335 elif test "$scm_inttypes_has_int8"; then
 336   SCM_I_GSC_T_INT8='"int8_t"'
 337   SCM_I_GSC_NEEDS_INTTYPES_H=1
 338 elif test "$ac_cv_sizeof_char" -eq 1; then
 339   SCM_I_GSC_T_INT8='"signed char"'
 340 else
 341   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 342 fi
 343 AC_SUBST([SCM_I_GSC_T_INT8])
 344
 345 ### Required type scm_t_uint8
 346 if test "$scm_stdint_has_uint8"; then
 347   SCM_I_GSC_T_UINT8='"uint8_t"'
 348   SCM_I_GSC_NEEDS_STDINT_H=1
 349 elif test "$scm_inttypes_has_uint8"; then
 350   SCM_I_GSC_T_UINT8='"uint8_t"'
 351   SCM_I_GSC_NEEDS_INTTYPES_H=1
 352 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 353   SCM_I_GSC_T_UINT8='"unsigned char"'
 354 else
 355   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 356 fi
 357 AC_SUBST([SCM_I_GSC_T_UINT8])
 358
 359 ### Required type scm_t_int16 (ANSI C says int or short might work)
 360 if test "$scm_stdint_has_int16"; then
 361   SCM_I_GSC_T_INT16='"int16_t"'
 362   SCM_I_GSC_NEEDS_STDINT_H=1
 363 elif test "$scm_inttypes_has_int16"; then
 364   SCM_I_GSC_T_INT16='"int16_t"'
 365   SCM_I_GSC_NEEDS_INTTYPES_H=1
 366 elif test "$ac_cv_sizeof_int" -eq 2; then
 367   SCM_I_GSC_T_INT16='"int"'
 368 elif test "$ac_cv_sizeof_short" -eq 2; then
 369   SCM_I_GSC_T_INT16='"short"'
 370 else
 371   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 372 fi
 373 AC_SUBST([SCM_I_GSC_T_INT16])
 374
 375 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 376 if test "$scm_stdint_has_uint16"; then
 377   SCM_I_GSC_T_UINT16='"uint16_t"'
 378   SCM_I_GSC_NEEDS_STDINT_H=1
 379 elif test "$scm_inttypes_has_uint16"; then
 380   SCM_I_GSC_T_UINT16='"uint16_t"'
 381   SCM_I_GSC_NEEDS_INTTYPES_H=1
 382 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 383   SCM_I_GSC_T_UINT16='"unsigned int"'
 384 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 385   SCM_I_GSC_T_UINT16='"unsigned short"'
 386 else
 387   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 388 fi
 389 AC_SUBST([SCM_I_GSC_T_UINT16])
 390
 391
 392 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 393 if test "$scm_stdint_has_int32"; then
 394   SCM_I_GSC_T_INT32='"int32_t"'
 395   SCM_I_GSC_NEEDS_STDINT_H=1
 396 elif test "$scm_inttypes_has_int32"; then
 397   SCM_I_GSC_T_INT32='"int32_t"'
 398   SCM_I_GSC_NEEDS_INTTYPES_H=1
 399 elif test "$ac_cv_sizeof_int" -eq 4; then
 400   SCM_I_GSC_T_INT32='"int"'
 401 elif test "$ac_cv_sizeof_long" -eq 4; then
 402   SCM_I_GSC_T_INT32='"long"'
 403 elif test "$ac_cv_sizeof_short" -eq 4; then
 404   SCM_I_GSC_T_INT32='"short"'
 405 else
 406   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 407 fi
 408 AC_SUBST([SCM_I_GSC_T_INT32])
 409
 410 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 411 if test "$scm_stdint_has_uint32"; then
 412   SCM_I_GSC_T_UINT32='"uint32_t"'
 413   SCM_I_GSC_NEEDS_STDINT_H=1
 414 elif test "$scm_inttypes_has_uint32"; then
 415   SCM_I_GSC_T_UINT32='"uint32_t"'
 416   SCM_I_GSC_NEEDS_INTTYPES_H=1
 417 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 418   SCM_I_GSC_T_UINT32='"unsigned int"'
 419 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 420   SCM_I_GSC_T_UINT32='"unsigned long"'
 421 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 422   SCM_I_GSC_T_UINT32='"unsigned short"'
 423 else
 424   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 425 fi
 426 AC_SUBST([SCM_I_GSC_T_UINT32])
 427
 428 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 429 ### Also try 'long long' and '__int64' if we have it.
 430 SCM_I_GSC_T_INT64=0
 431 if test "$scm_stdint_has_int64"; then
 432   SCM_I_GSC_T_INT64='"int64_t"'
 433   SCM_I_GSC_NEEDS_STDINT_H=1
 434 elif test "$scm_inttypes_has_int64"; then
 435   SCM_I_GSC_T_INT64='"int64_t"'
 436   SCM_I_GSC_NEEDS_INTTYPES_H=1
 437 elif test "$ac_cv_sizeof_int" -eq 8; then
 438   SCM_I_GSC_T_INT64='"int"'
 439 elif test "$ac_cv_sizeof_long" -eq 8; then
 440   SCM_I_GSC_T_INT64='"long"'
 441 elif test "$ac_cv_sizeof_short" -eq 8; then
 442   SCM_I_GSC_T_INT64='"short"'
 443 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 444   SCM_I_GSC_T_INT64='"long long"'
 445 elif test "$ac_cv_sizeof___int64" -eq 8; then
 446   SCM_I_GSC_T_INT64='"__int64"'
 447 else
 448   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 449 fi
 450 AC_SUBST([SCM_I_GSC_T_INT64])
 451
 452
 453 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 454 ### Also try 'long long' and '__int64' if we have it.
 455 SCM_I_GSC_T_UINT64=0
 456 if test "$scm_stdint_has_uint64"; then
 457   SCM_I_GSC_T_UINT64='"uint64_t"'
 458   SCM_I_GSC_NEEDS_STDINT_H=1
 459 elif test "$scm_inttypes_has_uint64"; then
 460   SCM_I_GSC_T_UINT64='"uint64_t"'
 461   SCM_I_GSC_NEEDS_INTTYPES_H=1
 462 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 463   SCM_I_GSC_T_UINT64='"unsigned int"'
 464 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 465   SCM_I_GSC_T_UINT64='"unsigned long"'
 466 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 467   SCM_I_GSC_T_UINT64='"unsigned short"'
 468 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 469   SCM_I_GSC_T_UINT64='"unsigned long long"'
 470 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 471   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 472 else
 473   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 474 fi
 475 AC_SUBST([SCM_I_GSC_T_UINT64])
 476
 477 ### Required type scm_t_intmax
 478 ###
 479 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 480 ### none of them is available, we use 'long'.
 481 ###
 482 SCM_I_GSC_T_INTMAX=0
 483 if test "$scm_stdint_has_intmax"; then
 484   SCM_I_GSC_T_INTMAX='"intmax_t"'
 485   SCM_I_GSC_NEEDS_STDINT_H=1
 486 elif test "$scm_inttypes_has_intmax"; then
 487   SCM_I_GSC_T_INTMAX='"intmax_t"'
 488   SCM_I_GSC_NEEDS_INTTYPES_H=1
 489 elif test "$ac_cv_sizeof___int64" -ne 0; then
 490   SCM_I_GSC_T_INTMAX='"__int64"'
 491 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 492   SCM_I_GSC_T_INTMAX='"long long"'
 493 else
 494   SCM_I_GSC_T_INTMAX='"long"'
 495 fi
 496 AC_SUBST([SCM_I_GSC_T_INTMAX])
 497
 498 ### Required type scm_t_uintmax
 499 ###
 500 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 501 ### this order.  When none of them is available, we use 'unsigned long'.
 502 ###
 503 SCM_I_GSC_T_UINTMAX=0
 504 if test "$scm_stdint_has_uintmax"; then
 505   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 506   SCM_I_GSC_NEEDS_STDINT_H=1
 507 elif test "$scm_inttypes_has_uintmax"; then
 508   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 509   SCM_I_GSC_NEEDS_INTTYPES_H=1
 510 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 511   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 512 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 513   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 514 else
 515   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 516 fi
 517 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 518
 519
 520 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 521 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 522
 523 AC_HEADER_STDC
 524 AC_HEADER_DIRENT
 525 AC_HEADER_TIME
 526 AC_HEADER_SYS_WAIT
 527
 528 # Reasons for testing:
 529 #   complex.h - new in C99
 530 #   fenv.h - available in C99, but not older systems
 531 #
 532 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h string.h \
 533 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 534 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 535 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 536 direct.h])
 537
 538 # "complex double" is new in C99, and "complex" is only a keyword if
 539 # <complex.h> is included
 540 AC_CHECK_TYPES(complex double,,,
 541 [#if HAVE_COMPLEX_H
 542 #include <complex.h>
 543 #endif])
 544
 545 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 546 # when testing.
 547 AC_CHECK_TYPE(socklen_t, ,
 548   [AC_DEFINE_UNQUOTED(socklen_t, int,
 549                       [Define to `int' if <sys/socket.h> does not define.])],
 550   [#if HAVE_SYS_TYPES_H
 551 #include <sys/types.h>
 552 #endif
 553 #include <sys/socket.h>
 554 ])
 555 AC_CHECK_TYPE(struct ip_mreq)
 556
 557 GUILE_HEADER_LIBC_WITH_UNISTD
 558
 559 AC_TYPE_GETGROUPS
 560 AC_TYPE_SIGNAL
 561 AC_TYPE_MODE_T
 562
 563 if test $MINGW32 = no; then
 564         AC_CHECK_LIB(m, main)
 565 fi
 566 AC_CHECK_FUNCS(gethostbyname)
 567 if test $ac_cv_func_gethostbyname = no; then
 568     AC_CHECK_LIB(nsl, gethostbyname)
 569 fi
 570
 571 AC_CHECK_FUNCS(connect)
 572 if test $ac_cv_func_connect = no; then
 573     AC_CHECK_LIB(socket, connect)
 574 fi
 575
 576 dnl
 577 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 578 dnl
 579 EXTRA_DEFS=""
 580 if test "$MINGW32" = "yes" ; then
 581     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 582       [Define if you have the <winsock2.h> header file.])])
 583     AC_CHECK_LIB(ws2_32, main)
 584     AC_LIBOBJ([win32-uname])
 585     AC_LIBOBJ([win32-dirent])
 586     if test "$enable_networking" = yes ; then
 587       AC_LIBOBJ([win32-socket])
 588     fi
 589     if test "$enable_shared" = yes ; then
 590       EXTRA_DEFS="-DSCM_IMPORT"
 591       AC_DEFINE(USE_DLL_IMPORT, 1,
 592         [Define if you need additional CPP macros on Win32 platforms.])
 593     fi
 594 fi
 595 AC_SUBST(EXTRA_DEFS)
 596
 597 # Reasons for testing:
 598 #   crt_externs.h - Darwin specific
 599 #
 600 AC_CHECK_HEADERS([assert.h crt_externs.h])
 601
 602 # Reasons for testing:
 603 #   DINFINITY - OSF specific
 604 #   DQNAN - OSF specific
 605 #       (DINFINITY and DQNAN are actually global variables, not functions)
 606 #   chsize - an MS-DOS-ism, found in mingw
 607 #   clog10 - not in mingw (though others like clog and csqrt are)
 608 #   fesetround - available in C99, but not older systems
 609 #   ftruncate - posix, but probably not older systems (current mingw
 610 #               has it as an inline for chsize)
 611 #   ioctl - not in mingw.
 612 #   gmtime_r - recent posix, not on old systems
 613 #   readdir_r - recent posix, not on old systems
 614 #   stat64 - SuS largefile stuff, not on old systems
 615 #   sysconf - not on old systems
 616 #   truncate - not in mingw
 617 #   isblank - available as a GNU extension or in C99
 618 #   _NSGetEnviron - Darwin specific
 619 #   strcoll_l, newlocale - GNU extensions (glibc)
 620 #
 621 AC_CHECK_FUNCS([DINFINITY DQNAN chsize clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid gettimeofday gmtime_r ioctl lstat mkdir mknod nice readdir_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale])
 622
 623 # Reasons for testing:
 624 #   netdb.h - not in mingw
 625 #   sys/param.h - not in mingw
 626 #   sethostname - the function itself check because it's not in mingw,
 627 #       the DECL is checked because Solaris 10 doens't have in any header
 628 #
 629 AC_CHECK_HEADERS(crypt.h netdb.h sys/param.h sys/resource.h sys/file.h)
 630 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 631 AC_CHECK_DECLS([sethostname])
 632
 633 # crypt() may or may not be available, for instance in some countries there
 634 # are restrictions on cryptography.
 635 #
 636 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 637 # -lcrypt library (eg. Debian GNU/Linux).
 638 #
 639 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 640 # be careful to avoid -lcrypt in this case, since libtool will see there's
 641 # only a static libcrypt and decide to build only a static libguile.
 642 #
 643 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 644 # libraries already in that list.
 645 #
 646 AC_SEARCH_LIBS(crypt, crypt,
 647   [AC_DEFINE(HAVE_CRYPT,1,
 648              [Define to 1 if you have the `crypt' function.])])
 649
 650 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 651 # csqrt(-i) returned a negative real part, when it should be positive
 652 # for the principal root.
 653 #
 654 if test "$ac_cv_type_complex_double" = yes; then
 655   AC_CACHE_CHECK([whether csqrt is usable],
 656     guile_cv_use_csqrt,
 657     [AC_TRY_RUN([
 658 #include <complex.h>
 659 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 660    constant, we want to test libc. */
 661 volatile complex double z = - _Complex_I;
 662 int
 663 main (void)
 664 {
 665   z = csqrt (z);
 666   if (creal (z) > 0.0)
 667     return 0;  /* good */
 668   else
 669     return 1;  /* bad */
 670 }],
 671     [guile_cv_use_csqrt=yes],
 672     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 673     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 674   case $guile_cv_use_csqrt in
 675     yes*)
 676       AC_DEFINE(HAVE_USABLE_CSQRT, 1, [Define to 1 if csqrt is bug-free])
 677       ;;
 678   esac
 679 fi
 680
 681
 682 dnl GMP tests
 683 AC_CHECK_LIB([gmp], [__gmpz_init], ,
 684   [AC_MSG_ERROR([GNU MP not found, see README])])
 685
 686 # mpz_import is a macro so we need to include <gmp.h>
 687 AC_TRY_LINK([#include <gmp.h>],
 688             [mpz_import (0, 0, 0, 0, 0, 0, 0);] , ,
 689   [AC_MSG_ERROR([At least GNU MP 4.1 is required, see README])])
 690
 691 dnl i18n tests
 692 #AC_CHECK_HEADERS([libintl.h])
 693 #AC_CHECK_FUNCS(gettext)
 694 #if test $ac_cv_func_gettext = no; then
 695 #   AC_CHECK_LIB(intl, gettext)
 696 #fi
 697 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 698 AM_GNU_GETTEXT([external], [need-ngettext])
 699
 700 ### Some systems don't declare some functions.  On such systems, we
 701 ### need to at least provide our own K&R-style declarations.
 702
 703 ### GUILE_FUNC_DECLARED(function, headerfile)
 704
 705 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 706 ### not there, #define MISSING_FUNCTION_DECL.
 707 AC_DEFUN([GUILE_FUNC_DECLARED], [
 708   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 709     AC_EGREP_HEADER($1, $2,
 710                     guile_cv_func_$1_declared=yes,
 711                     guile_cv_func_$1_declared=no))
 712   if test [x$guile_cv_func_]$1[_declared] = xno; then
 713     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 714       [Define if the operating system supplies $1 without declaring it.])
 715   fi
 716 ])
 717
 718 GUILE_FUNC_DECLARED(sleep, unistd.h)
 719 GUILE_FUNC_DECLARED(usleep, unistd.h)
 720
 721 AC_CHECK_DECLS([strptime],,,
 722 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 723 #include <time.h>])
 724
 725 ### On some systems usleep has no return value.  If it does have one,
 726 ### we'd like to return it; otherwise, we'll fake it.
 727 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 728   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 729                    unistd.h,
 730                    [guile_cv_func_usleep_return_type=void],
 731                    [guile_cv_func_usleep_return_type=int])])
 732 case "$guile_cv_func_usleep_return_type" in
 733   "void" )
 734     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 735       [Define if the system headers declare usleep to return void.])
 736   ;;
 737 esac
 738
 739 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 740 if test -n "$have_sys_un_h" ; then
 741   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 742     [Define if the system supports Unix-domain (file-domain) sockets.])
 743 fi
 744
 745 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 746
 747 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 748                setnetent    getnetent    endnetent    dnl
 749                setprotoent  getprotoent  endprotoent  dnl
 750                setservent   getservent   endservent   dnl
 751                getnetbyaddr getnetbyname dnl
 752                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 753                inet_pton inet_ntop)
 754
 755 # struct sockaddr field sin_len is only present on BSD systems.
 756 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 757 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 758 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 759 [#ifdef HAVE_SYS_TYPES_H
 760 #include <sys/types.h>
 761 #endif
 762 #include <netinet/in.h>])
 763
 764 AC_MSG_CHECKING(for __libc_stack_end)
 765 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 766 [AC_TRY_LINK([#include <stdio.h>
 767 extern char *__libc_stack_end;],
 768              [printf("%p", (char*) __libc_stack_end);],
 769              guile_cv_have_libc_stack_end=yes,
 770              guile_cv_have_libc_stack_end=no)])
 771 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 772
 773 if test $guile_cv_have_libc_stack_end = yes; then
 774   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 775            [Define if you have the __libc_stack_end variable.])
 776 fi
 777
 778 dnl Some systems do not declare this.  Some systems do declare it, as a
 779 dnl macro.  With cygwin it may be in a DLL.
 780
 781 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 782 AC_CACHE_VAL(guile_cv_have_h_errno,
 783 [AC_TRY_COMPILE([#include <netdb.h>],
 784 [int a = h_errno;],
 785 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 786 AC_MSG_RESULT($guile_cv_have_h_errno)
 787 if test $guile_cv_have_h_errno = yes; then
 788   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 789 fi
 790
 791 AC_MSG_CHECKING(whether uint32_t is defined)
 792 AC_CACHE_VAL(guile_cv_have_uint32_t,
 793   [AC_TRY_COMPILE([#include <sys/types.h>
 794                    #if HAVE_STDINT_H
 795                    #include <stdint.h>
 796                    #endif
 797                    #ifndef __MINGW32__
 798                    #include <netdb.h>
 799                    #endif],
 800                   [uint32_t a;],
 801                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 802 AC_MSG_RESULT($guile_cv_have_uint32_t)
 803 if test $guile_cv_have_uint32_t = yes; then
 804   AC_DEFINE(HAVE_UINT32_T, 1,
 805     [Define if uint32_t typedef is defined when netdb.h is include.])
 806 fi
 807
 808 AC_MSG_CHECKING(for working IPv6 support)
 809 AC_CACHE_VAL(guile_cv_have_ipv6,
 810 [AC_TRY_COMPILE([
 811 #ifdef HAVE_SYS_TYPES_H
 812 #include <sys/types.h>
 813 #endif
 814 #include <netinet/in.h>
 815 #include <sys/socket.h>],
 816 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 817 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 818 AC_MSG_RESULT($guile_cv_have_ipv6)
 819 if test $guile_cv_have_ipv6 = yes; then
 820   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 821 fi
 822
 823 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 824 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 825 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 826 [AC_TRY_COMPILE([
 827 #ifdef HAVE_SYS_TYPES_H
 828 #include <sys/types.h>
 829 #endif
 830 #include <netinet/in.h>],
 831 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 832 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 833 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 834 if test $guile_cv_have_sin6_scope_id = yes; then
 835   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 836     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 837 fi
 838
 839 # struct sockaddr_in6 field sin_len is only present on BSD systems
 840 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
 841 [#ifdef HAVE_SYS_TYPES_H
 842 #include <sys/types.h>
 843 #endif
 844 #include <netinet/in.h>])
 845
 846 AC_MSG_CHECKING(whether localtime caches TZ)
 847 AC_CACHE_VAL(guile_cv_localtime_cache,
 848 [if test x$ac_cv_func_tzset = xyes; then
 849 AC_TRY_RUN([#include <time.h>
 850 #if STDC_HEADERS
 851 # include <stdlib.h>
 852 #endif
 853 extern char **environ;
 854 unset_TZ ()
 855 {
 856   char **from, **to;
 857   for (to = from = environ; (*to = *from); from++)
 858     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 859       to++;
 860 }
 861 char TZ_GMT0[] = "TZ=GMT0";
 862 char TZ_PST8[] = "TZ=PST8";
 863 main()
 864 {
 865   time_t now = time ((time_t *) 0);
 866   int hour_GMT0, hour_unset;
 867   if (putenv (TZ_GMT0) != 0)
 868     exit (1);
 869   hour_GMT0 = localtime (&now)->tm_hour;
 870   unset_TZ ();
 871   hour_unset = localtime (&now)->tm_hour;
 872   if (putenv (TZ_PST8) != 0)
 873     exit (1);
 874   if (localtime (&now)->tm_hour == hour_GMT0)
 875     exit (1);
 876   unset_TZ ();
 877   if (localtime (&now)->tm_hour != hour_unset)
 878     exit (1);
 879   exit (0);
 880 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 881 [# If we have tzset, assume the worst when cross-compiling.
 882 guile_cv_localtime_cache=yes])
 883 else
 884         # If we lack tzset, report that localtime does not cache TZ,
 885         # since we can't invalidate the cache if we don't have tzset.
 886         guile_cv_localtime_cache=no
 887 fi])dnl
 888 AC_MSG_RESULT($guile_cv_localtime_cache)
 889 if test $guile_cv_localtime_cache = yes; then
 890   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
 891 fi
 892
 893 dnl Test whether system calls are restartable by default on the
 894 dnl current system.  If they are not, we put a loop around every system
 895 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 896 dnl change from the default behaviour.  On the other hand, if signals
 897 dnl are restartable then the loop is not installed and when libguile
 898 dnl initialises it also resets the behaviour of each signal to cause a
 899 dnl restart (in case a different runtime had a different default
 900 dnl behaviour for some reason: e.g., different versions of linux seem
 901 dnl to behave differently.)
 902
 903 AC_SYS_RESTARTABLE_SYSCALLS
 904
 905 if test "$enable_regex" = yes; then
 906    if test "$ac_cv_header_regex_h" = yes ||
 907       test "$ac_cv_header_rxposix_h" = yes ||
 908       test "$ac_cv_header_rx_rxposix_h" = yes; then
 909      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
 910      [AC_CHECK_LIB(rx, main)
 911       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
 912      [AC_CHECK_LIB(regex, main)
 913       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
 914      )
 915      dnl The following should not be necessary, but for some reason
 916      dnl autoheader misses it if we don't include it!
 917      if test "$ac_cv_func_regcomp_norx" = yes ||
 918         test "$ac_cv_func_regcomp_regex" = yes ||
 919         test "$ac_cv_func_regcomp_rx" = yes; then
 920        AC_DEFINE(HAVE_REGCOMP, 1,
 921          [This is included as part of a workaround for a autoheader bug.])
 922      fi
 923    fi
 924 fi
 925
 926 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 927
 928 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
 929
 930 # Reasons for testing:
 931 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
 932 #                                older systems
 933 #   sincos - GLIBC extension
 934 #
 935 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
 936
 937 # C99 specifies isinf and isnan as macros.
 938 # HP-UX provides only macros, no functions.
 939 # glibc 2.3.2 provides both macros and functions.
 940 # IRIX 6.5 and Solaris 8 only provide functions.
 941 #
 942 # The following tests detect isinf and isnan either as functions or as
 943 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
 944 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
 945 #
 946 AC_MSG_CHECKING([for isinf])
 947 AC_LINK_IFELSE(
 948 [#include <math.h>
 949 int main () { return (isinf(0.0) != 0); }],
 950   [AC_MSG_RESULT([yes])
 951    AC_DEFINE(HAVE_ISINF, 1,
 952              [Define to 1 if you have the `isinf' macro or function.])],
 953   [AC_MSG_RESULT([no])])
 954 AC_MSG_CHECKING([for isnan])
 955 AC_LINK_IFELSE(
 956 [#include <math.h>
 957 int main () { return (isnan(0.0) != 0); }],
 958   [AC_MSG_RESULT([yes])
 959    AC_DEFINE(HAVE_ISNAN, 1,
 960              [Define to 1 if you have the `isnan' macro or function.])],
 961   [AC_MSG_RESULT([no])])
 962
 963 # We must have a proper stack-using alloca in order for stack-copying
 964 # continuations to work properly.  If we don't find a native one,
 965 # abort.
 966
 967 AC_FUNC_ALLOCA
 968 if test "$ALLOCA" = "alloca.o"
 969 then
 970   AC_ERROR([No native alloca found.])
 971 fi
 972
 973 # Reasons for checking:
 974 #
 975 #     st_rdev
 976 #     st_blksize
 977 #     st_blocks   not in mingw
 978 #     tm_gmtoff   BSD+GNU, not in C99
 979 #
 980 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
 981 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
 982 #
 983 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks])
 984
 985 AC_STRUCT_TIMEZONE
 986 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
 987 [#include <time.h>
 988 #ifdef TIME_WITH_SYS_TIME
 989 # include <sys/time.h>
 990 # include <time.h>
 991 #else
 992 # if HAVE_SYS_TIME_H
 993 #  include <sys/time.h>
 994 # else
 995 #  include <time.h>
 996 # endif
 997 #endif
 998 ])
 999 GUILE_STRUCT_UTIMBUF
1000
1001
1002 #--------------------------------------------------------------------
1003 #
1004 # Which way does the stack grow?
1005 #
1006 #--------------------------------------------------------------------
1007
1008 SCM_I_GSC_STACK_GROWS_UP=0
1009 AC_TRY_RUN(aux (l) unsigned long l;
1010              { int x; exit (l >= ((unsigned long)&x)); }
1011            main () { int q; aux((unsigned long)&q); },
1012            [SCM_I_GSC_STACK_GROWS_UP=1],
1013            [],
1014            [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1015
1016 AC_CHECK_SIZEOF(float)
1017 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1018     AC_DEFINE(SCM_SINGLES, 1,
1019               [Define this if floats are the same size as longs.])
1020 fi
1021
1022 AC_MSG_CHECKING(for struct linger)
1023 AC_CACHE_VAL(scm_cv_struct_linger,
1024         AC_TRY_COMPILE([
1025 #include <sys/types.h>
1026 #include <sys/socket.h>],
1027                         [struct linger lgr;  lgr.l_linger = 100],
1028                         scm_cv_struct_linger="yes",
1029                         scm_cv_struct_linger="no"))
1030 AC_MSG_RESULT($scm_cv_struct_linger)
1031 if test $scm_cv_struct_linger = yes; then
1032         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
1033           [Define this if your system defines struct linger, for use with the
1034            getsockopt and setsockopt system calls.])
1035 fi
1036
1037
1038 AC_MSG_CHECKING(for struct timespec)
1039 AC_CACHE_VAL(scm_cv_struct_timespec,
1040         AC_TRY_COMPILE([
1041 #include <time.h>],
1042                         [struct timespec t;  t.tv_nsec = 100],
1043                         scm_cv_struct_timespec="yes",
1044                         scm_cv_struct_timespec="no"))
1045 AC_MSG_RESULT($scm_cv_struct_timespec)
1046 if test $scm_cv_struct_timespec = yes; then
1047   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
1048     [Define this if your system defines struct timespec via <time.h>.])
1049 fi
1050
1051 #--------------------------------------------------------------------
1052 #
1053 # Flags for thread support
1054 #
1055 #--------------------------------------------------------------------
1056
1057 SCM_I_GSC_USE_PTHREAD_THREADS=0
1058 SCM_I_GSC_USE_NULL_THREADS=0
1059 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1060 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1061
1062 ### What thread package has the user asked for?
1063 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1064             , with_threads=yes)
1065
1066 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1067
1068 case "$with_threads" in
1069   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1070     ACX_PTHREAD(CC="$PTHREAD_CC"
1071       LIBS="$PTHREAD_LIBS $LIBS"
1072       SCM_I_GSC_USE_PTHREAD_THREADS=1
1073       with_threads="pthreads",
1074       with_threads="null")
1075
1076     old_CFLAGS="$CFLAGS"
1077     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1078
1079     # Reasons for testing:
1080     #     pthread_getattr_np - "np" meaning "non portable" says it
1081     #         all; not present on MacOS X or Solaris 10
1082     #
1083     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np)
1084
1085     # On past versions of Solaris, believe 8 through 10 at least, you
1086     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1087     # This is contrary to posix:
1088     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1089     # Check here if this style is required.
1090     #
1091     # glibc (2.3.6 at least) works both with or without braces, so the
1092     # test checks whether it works without.
1093     #
1094     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1095       guile_cv_need_braces_on_pthread_once_init,
1096       [AC_TRY_COMPILE([#include <pthread.h>],
1097         [pthread_once_t foo = PTHREAD_ONCE_INIT;],
1098         [guile_cv_need_braces_on_pthread_once_init=no],
1099         [guile_cv_need_braces_on_pthread_once_init=yes])])
1100     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1101       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1102     fi
1103
1104     CFLAGS="$old_CFLAGS"
1105
1106     # On Solaris, sched_yield lives in -lrt.
1107     AC_SEARCH_LIBS(sched_yield, rt)
1108
1109   ;;
1110 esac
1111
1112 case "$with_threads" in
1113   "pthreads")
1114   ;;
1115   "no" | "null")
1116     SCM_I_GSC_USE_NULL_THREADS=1
1117     with_threads="null-threads"
1118   ;;
1119   * )
1120     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1121   ;;
1122 esac
1123
1124 AC_MSG_CHECKING(what kind of threads to support)
1125 AC_MSG_RESULT($with_threads)
1126
1127 ## Check whether pthread_attr_getstack works for the main thread
1128
1129 if test "$with_threads" = pthreads; then
1130
1131 AC_MSG_CHECKING(whether pthread_attr_getstack works for the main thread)
1132 old_CFLAGS="$CFLAGS"
1133 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1134 AC_TRY_RUN(
1135 [
1136 #if HAVE_PTHREAD_ATTR_GETSTACK
1137 #include <pthread.h>
1138
1139 int main ()
1140 {
1141   pthread_attr_t attr;
1142   void *start, *end;
1143   size_t size;
1144
1145   pthread_getattr_np (pthread_self (), &attr);
1146   pthread_attr_getstack (&attr, &start, &size);
1147   end = (char *)start + size;
1148
1149   if ((void *)&attr < start || (void *)&attr >= end)
1150     return 1;
1151   else
1152     return 0;
1153 }
1154 #else
1155 int main ()
1156 {
1157   return 1;
1158 }
1159 #endif
1160 ],
1161 [works=yes
1162 AC_DEFINE(PTHREAD_ATTR_GETSTACK_WORKS, [1], [Define when pthread_att_get_stack works for the main thread])],
1163 [works=no])
1164 CFLAGS="$old_CFLAGS"
1165 AC_MSG_RESULT($works)
1166
1167 fi # with_threads=pthreads
1168
1169
1170 ## Cross building
1171 if test "$cross_compiling" = "yes"; then
1172   AC_MSG_CHECKING(cc for build)
1173   ## /usr/bin/cc still uses wrong assembler
1174   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1175   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1176 else
1177   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1178 fi
1179
1180 ## AC_MSG_CHECKING("if we are cross compiling")
1181 ## AC_MSG_RESULT($cross_compiling)
1182 if test "$cross_compiling" = "yes"; then
1183    AC_MSG_RESULT($CC_FOR_BUILD)
1184 fi
1185
1186 ## No need as yet to be more elaborate
1187 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1188
1189 AC_SUBST(cross_compiling)
1190 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1191 AC_SUBST(CCLD_FOR_BUILD)
1192
1193 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1194 ## --HOST is the platform that PACKAGE is compiled for.
1195 HOST_CC="$CC_FOR_BUILD"
1196 AC_SUBST(HOST_CC)
1197
1198 if test "$cross_compiling" = "yes"; then
1199   AC_MSG_CHECKING(guile for build)
1200   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1201 else
1202   GUILE_FOR_BUILD='$(preinstguile)'
1203 fi
1204
1205 ## AC_MSG_CHECKING("if we are cross compiling")
1206 ## AC_MSG_RESULT($cross_compiling)
1207 if test "$cross_compiling" = "yes"; then
1208    AC_MSG_RESULT($GUILE_FOR_BUILD)
1209 fi
1210 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1211 AC_SUBST(GUILE_FOR_BUILD)
1212
1213 ## If we're using GCC, ask for aggressive warnings.
1214 case "$GCC" in
1215   yes )
1216     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1217     ## much stuff with generic function pointers for that to really be
1218     ## less than exasperating.
1219     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1220     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1221     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
1222     # Do this here so we don't screw up any of the tests above that might
1223     # not be "warning free"
1224     if test "${GUILE_ERROR_ON_WARNING}" = yes
1225     then
1226         CFLAGS="${CFLAGS} -Werror"
1227         enable_compile_warnings=no
1228     fi
1229     ;;
1230 esac
1231
1232 ## If we're creating a shared library (using libtool!), then we'll
1233 ## need to generate a list of .lo files corresponding to the .o files
1234 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1235 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1236
1237 ## We also need to create corresponding .doc and .x files
1238 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1239 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1240
1241 AC_SUBST(GUILE_MAJOR_VERSION)
1242 AC_SUBST(GUILE_MINOR_VERSION)
1243 AC_SUBST(GUILE_MICRO_VERSION)
1244 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1245 AC_SUBST(GUILE_VERSION)
1246
1247 #######################################################################
1248 # library versioning
1249
1250 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1251 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1252 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1253 AC_SUBST(LIBGUILE_INTERFACE)
1254
1255 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1256 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1257 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1258 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1259 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1260
1261 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1262 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1263 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1264 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1265 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1266
1267 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1268 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1269 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1270 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1271 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1272
1273 AC_SUBST(LIBGUILE_SRFI_SRFI_60_MAJOR)
1274 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_CURRENT)
1275 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_REVISION)
1276 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_AGE)
1277 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE)
1278
1279 AC_SUBST(LIBGUILE_I18N_MAJOR)
1280 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1281 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1282 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1283 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1284
1285
1286 #######################################################################
1287
1288 dnl Tell guile-config what flags guile users should compile and link with.
1289 GUILE_LIBS="$LDFLAGS $LIBS"
1290 GUILE_CFLAGS="$PTHREAD_CFLAGS"
1291 AC_SUBST(GUILE_LIBS)
1292 AC_SUBST(GUILE_CFLAGS)
1293
1294 AC_SUBST(AWK)
1295 AC_SUBST(LIBLOBJS)
1296 AC_SUBST(EXTRA_DOT_DOC_FILES)
1297 AC_SUBST(EXTRA_DOT_X_FILES)
1298
1299 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1300 top_builddir_absolute=`pwd`
1301 AC_SUBST(top_builddir_absolute)
1302 top_srcdir_absolute=`(cd $srcdir && pwd)`
1303 AC_SUBST(top_srcdir_absolute)
1304
1305 # Additional SCM_I_GSC definitions are above.
1306 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1307 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1308 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1309 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1310 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1311 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1312 AC_SUBST([SCM_I_GSC_C_INLINE])
1313 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1314
1315 AC_CONFIG_FILES([
1316   Makefile
1317   am/Makefile
1318   benchmark-suite/Makefile
1319   doc/Makefile
1320   doc/goops/Makefile
1321   doc/r5rs/Makefile
1322   doc/ref/Makefile
1323   doc/tutorial/Makefile
1324   emacs/Makefile
1325   examples/Makefile
1326   examples/box-dynamic-module/Makefile
1327   examples/box-dynamic/Makefile
1328   examples/box-module/Makefile
1329   examples/box/Makefile
1330   examples/modules/Makefile
1331   examples/safe/Makefile
1332   examples/scripts/Makefile
1333   guile-config/Makefile
1334   ice-9/Makefile
1335   ice-9/debugger/Makefile
1336   ice-9/debugging/Makefile
1337   lang/Makefile
1338   lang/elisp/Makefile
1339   lang/elisp/internals/Makefile
1340   lang/elisp/primitives/Makefile
1341   libguile/Makefile
1342   oop/Makefile
1343   oop/goops/Makefile
1344   scripts/Makefile
1345   srfi/Makefile
1346   test-suite/Makefile
1347   test-suite/standalone/Makefile
1348 ])
1349
1350 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1351 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1352 AC_CONFIG_FILES([guile-tools], [chmod +x guile-tools])
1353 AC_CONFIG_FILES([pre-inst-guile], [chmod +x pre-inst-guile])
1354 AC_CONFIG_FILES([pre-inst-guile-env], [chmod +x pre-inst-guile-env])
1355 AC_CONFIG_FILES([libguile/guile-snarf],
1356                 [chmod +x libguile/guile-snarf])
1357 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1358                 [chmod +x libguile/guile-doc-snarf])
1359 AC_CONFIG_FILES([libguile/guile-func-name-check],
1360                 [chmod +x libguile/guile-func-name-check])
1361 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1362                 [chmod +x libguile/guile-snarf-docs])
1363
1364 AC_OUTPUT
1365
1366 dnl Local Variables:
1367 dnl comment-start: "dnl "
1368 dnl comment-end: ""
1369 dnl comment-start-skip: "\\bdnl\\b\\s *"
1370 dnl End: