guile-readline/configure.ac

   1 AC_PREREQ(2.50)
   2
   3 dnl Don't use "echo -n", which is not portable (e.g., not available on
   4 dnl MacOS X).  Instead, use `patsubst' to remove the newline.
   5 AC_INIT(guile-readline,
   6         patsubst(m4_esyscmd(. ../GUILE-VERSION && echo ${GUILE_VERSION}), [
   7 ]),
   8         [bug-guile@gnu.org])
   9
  10 AC_CONFIG_AUX_DIR([../build-aux])
  11 AC_CONFIG_SRCDIR(readline.c)
  12 AM_CONFIG_HEADER([guile-readline-config.h])
  13 AM_INIT_AUTOMAKE([foreign no-define])
  14
  15 . $srcdir/../GUILE-VERSION
  16
  17 AC_PROG_INSTALL
  18 AC_PROG_CC
  19 AM_PROG_CC_STDC
  20 AC_LIBTOOL_WIN32_DLL
  21 AC_PROG_LIBTOOL
  22
  23 dnl
  24 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
  25 dnl
  26 AC_CYGWIN
  27 AC_MINGW32
  28 EXTRA_DEFS=""
  29 if test "$MINGW32" = "yes" ; then
  30     if test $enable_shared = yes ; then
  31       EXTRA_DEFS="-DSCM_IMPORT"
  32     fi
  33 fi
  34 AC_SUBST(EXTRA_DEFS)
  35
  36 for termlib in ncurses curses termcap terminfo termlib ; do
  37    AC_CHECK_LIB(${termlib}, tgoto,
  38                 [LIBS="-l${termlib} $LIBS"; break])
  39 done
  40
  41 AC_LIB_LINKFLAGS(readline)
  42 AC_CHECK_LIB(readline, readline)
  43 if test $ac_cv_lib_readline_readline = no; then
  44   AC_MSG_WARN([libreadline was not found on your system.])
  45 fi
  46
  47 AC_CHECK_FUNCS(siginterrupt rl_clear_signals rl_cleanup_after_signal)
  48
  49 dnl Check for modern readline naming
  50 AC_CHECK_FUNCS(rl_filename_completion_function)
  51
  52 dnl Check for rl_get_keymap.  We only use this for deciding whether to
  53 dnl install paren matching on the Guile command line (when using
  54 dnl readline for input), so it's completely optional.
  55 AC_CHECK_FUNCS(rl_get_keymap)
  56
  57 AC_CACHE_CHECK([for rl_getc_function pointer in readline],
  58                  ac_cv_var_rl_getc_function,
  59                  [AC_TRY_LINK([
  60 #include <stdio.h>
  61 #include <readline/readline.h>],
  62                               [printf ("%ld", (long) rl_getc_function)],
  63                               [ac_cv_var_rl_getc_function=yes],
  64                               [ac_cv_var_rl_getc_function=no])])
  65 if test "${ac_cv_var_rl_getc_function}" = "yes"; then
  66   AC_DEFINE(HAVE_RL_GETC_FUNCTION, 1,
  67     [Define if your readline library has the rl_getc_function variable.])
  68 fi
  69
  70 if test $ac_cv_lib_readline_readline = yes \
  71         -a $ac_cv_var_rl_getc_function = no; then
  72   AC_MSG_WARN([*** libreadline is too old on your system.])
  73   AC_MSG_WARN([*** You need readline version 2.1 or later.])
  74 fi
  75
  76 AC_CHECK_FUNCS(strdup)
  77
  78 . $srcdir/LIBGUILEREADLINE-VERSION
  79 AC_SUBST(LIBGUILEREADLINE_MAJOR)
  80 AC_SUBST(LIBGUILEREADLINE_INTERFACE_CURRENT)
  81 AC_SUBST(LIBGUILEREADLINE_INTERFACE_REVISION)
  82 AC_SUBST(LIBGUILEREADLINE_INTERFACE_AGE)
  83 AC_SUBST(LIBGUILEREADLINE_INTERFACE)
  84
  85 AC_SUBST(GUILE_EFFECTIVE_VERSION)
  86
  87 AC_CONFIG_FILES(Makefile ice-9/Makefile)
  88 AC_OUTPUT