configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_PREREQ(2.50)
  24
  25 AC_INIT
  26 AC_CONFIG_SRCDIR([Makefile.in])
  27 . $srcdir/GUILE-VERSION
  28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  29 AM_MAINTAINER_MODE
  30 AM_CONFIG_HEADER(libguile/scmconfig.h)
  31
  32 #--------------------------------------------------------------------
  33 #
  34 # Independent Subdirectories
  35 #
  36 #--------------------------------------------------------------------
  37
  38 AC_CONFIG_SUBDIRS(guile-readline)
  39
  40 #--------------------------------------------------------------------
  41 #
  42 # User options
  43 #
  44 #--------------------------------------------------------------------
  45
  46 AC_ARG_ENABLE(error-on-warning,
  47   [  --enable-error-on-warning    treat compile warnings as errors],
  48   [case "${enableval}" in
  49      yes | y) CFLAGS="${CFLAGS} -Werror"; enable_compile_warnings=no ;;
  50      no | n)  ;;
  51      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  52    esac])
  53
  54 AC_ARG_ENABLE(debug-freelist,
  55   [  --enable-debug-freelist include garbage collector freelist debugging code],
  56   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  57     AC_DEFINE(GUILE_DEBUG_FREELIST)
  58   fi)
  59
  60 AC_ARG_ENABLE(debug-malloc,
  61   [  --enable-debug-malloc   include malloc debugging code],
  62   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
  63     AC_DEFINE(GUILE_DEBUG_MALLOC)
  64   fi)
  65
  66 AC_ARG_ENABLE(guile-debug,
  67   [  --enable-guile-debug    include internal debugging functions],
  68   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  69     AC_DEFINE(GUILE_DEBUG)
  70   fi)
  71
  72 AC_ARG_ENABLE(arrays,
  73   [  --disable-arrays        omit array and uniform array support],,
  74   enable_arrays=yes)
  75
  76 AC_ARG_ENABLE(posix,
  77   [  --disable-posix         omit posix interfaces],,
  78   enable_posix=yes)
  79
  80 AC_ARG_ENABLE(networking,
  81   [  --disable-networking    omit networking interfaces],,
  82   enable_networking=yes)
  83
  84 AC_ARG_ENABLE(regex,
  85   [  --disable-regex         omit regular expression interfaces],,
  86   enable_regex=yes)
  87
  88 AC_ARG_ENABLE(htmldoc,
  89   [  --enable-htmldoc        build HTML documentation as well as Info],
  90   [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
  91      htmldoc_enabled=yes
  92      AC_PATH_PROG(TEXI2HTML, texi2html, not found)
  93      if test "$TEXI2HTML" = "not found"; then
  94        echo
  95        echo Building HTML documentation requires the \`texi2html\' program,
  96        echo which appears not to be present on your machine.
  97        echo
  98        echo \`texi2html\' is available from
  99        echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
 100        echo
 101        echo In the meantime, to build the guile-doc distribution
 102        echo without HTML enabled, please rerun \`./configure\' without
 103        echo the \`--enable-htmldoc\' option.
 104        exit -1
 105      fi
 106    fi])
 107
 108 AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)
 109
 110 AC_ARG_ENABLE(deprecated,
 111   [  --disable-deprecated    omit deprecated features [no]])
 112
 113 if test "$enable_deprecated" = no; then
 114   AC_DEFINE(SCM_ENABLE_DEPRECATED, 0)
 115 else
 116   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 117     warn_default=summary
 118   elif test "$enable_deprecated" = shutup; then
 119     warn_default=no
 120   else
 121     warn_default=$enable_deprecated
 122   fi
 123   AC_DEFINE(SCM_ENABLE_DEPRECATED, 1)
 124   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default")
 125 fi
 126
 127 dnl The --disable-debug used to control these two.  But now they are
 128 dnl a required part of the distribution.
 129 AC_DEFINE(DEBUG_EXTENSIONS)
 130 AC_DEFINE(READER_EXTENSIONS)
 131
 132 dnl files which are destined for separate modules.
 133
 134 if test "$enable_arrays" = yes; then
 135    LIBOBJS="$LIBOBJS ramap.o unif.o"
 136    AC_DEFINE(HAVE_ARRAYS)
 137 fi
 138
 139 if test "$enable_posix" = yes; then
 140    LIBOBJS="$LIBOBJS filesys.o posix.o"
 141    AC_DEFINE(HAVE_POSIX)
 142 fi
 143
 144 if test "$enable_networking" = yes; then
 145    LIBOBJS="$LIBOBJS net_db.o socket.o"
 146    AC_DEFINE(HAVE_NETWORKING)
 147 fi
 148
 149 if test "$enable_debug_malloc" = yes; then
 150    LIBOBJS="$LIBOBJS debug-malloc.o"
 151 fi
 152
 153 #--------------------------------------------------------------------
 154
 155 dnl Some more checks for Win32
 156 AC_CYGWIN
 157 AC_MINGW32
 158 AC_LIBTOOL_WIN32_DLL
 159
 160 AC_LIBLTDL_INSTALLABLE
 161 AC_CONFIG_SUBDIRS(libltdl)
 162
 163 AC_PROG_INSTALL
 164 AC_PROG_CC
 165 AC_PROG_CPP
 166 AC_LIBTOOL_DLOPEN
 167
 168 AC_AIX
 169 AC_ISC_POSIX
 170 AC_MINIX
 171
 172 AM_PROG_CC_STDC
 173 AM_PROG_LIBTOOL
 174
 175 AC_CHECK_PROG(have_makeinfo, maakeinfo, yes, no)
 176 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
 177
 178 AC_C_CONST
 179 AC_C_INLINE
 180 AC_C_BIGENDIAN
 181
 182 if test "$ac_cv_c_inline" != no; then
 183   AC_DEFINE(HAVE_INLINE)
 184 fi
 185
 186 AC_CHECK_SIZEOF(short)
 187 AC_CHECK_SIZEOF(int)
 188 AC_CHECK_SIZEOF(long)
 189 AC_CHECK_SIZEOF(size_t)
 190
 191 dnl Check for integral types that can represent the range of pointers.
 192 dnl If these types don't exist on this platform, they are replaced by
 193 dnl "unsigned long" and "long", respectively.
 194
 195 AC_CHECK_HEADERS(stdint.h)
 196 AC_CHECK_HEADERS(inttypes.h)
 197 AC_CHECK_SIZEOF(uintptr_t)
 198 AC_CHECK_SIZEOF(ptrdiff_t)
 199
 200 AC_CHECK_SIZEOF(long long)
 201
 202 AC_CHECK_SIZEOF(void *)
 203
 204 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 205   AC_MSG_ERROR(sizes of long and void* are not identical)
 206 fi
 207
 208 AC_HEADER_STDC
 209 AC_HEADER_DIRENT
 210 AC_HEADER_TIME
 211 AC_HEADER_SYS_WAIT
 212 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h direct.h)
 213 GUILE_HEADER_LIBC_WITH_UNISTD
 214
 215 AC_TYPE_GETGROUPS
 216 AC_TYPE_SIGNAL
 217 AC_TYPE_MODE_T
 218
 219 AC_CHECK_LIB(m, main)
 220 AC_CHECK_FUNCS(gethostbyname)
 221 if test $ac_cv_func_gethostbyname = no; then
 222     AC_CHECK_LIB(nsl, gethostbyname)
 223 fi
 224 AC_CHECK_FUNCS(connect)
 225 if test $ac_cv_func_connect = no; then
 226     AC_CHECK_LIB(socket, connect)
 227 fi
 228
 229 dnl
 230 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 231 dnl
 232 EXTRA_DEFS=""
 233 if test "$MINGW32" = "yes" ; then
 234     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 235       [Define if you have the <winsock2.h> header file.])])
 236     AC_CHECK_LIB(ws2_32, main)
 237     LIBOBJS="$LIBOBJS win32-uname.o win32-dirent.o"
 238     if test "$enable_networking" = yes ; then
 239       LIBOBJS="$LIBOBJS win32-socket.o"
 240     fi
 241     if test "$enable_shared" = yes ; then
 242       EXTRA_DEFS="-DSCM_IMPORT"
 243       AC_DEFINE(USE_DLL_IMPORT, 1,
 244         [Define if you need additional CPP macros on Win32 platforms.])
 245     fi
 246 fi
 247 AC_SUBST(EXTRA_DEFS)
 248
 249 dnl Check for dynamic linking
 250
 251 use_modules=yes
 252 AC_ARG_WITH(modules,
 253 [  --with-modules[=FILES]  Add support for dynamic modules],
 254 use_modules="$withval")
 255 test -z "$use_modules" && use_modules=yes
 256 DLPREOPEN=
 257 if test "$use_modules" != no; then
 258   AC_DEFINE(DYNAMIC_LINKING)
 259   if test "$use_modules" = yes; then
 260     DLPREOPEN="-dlpreopen force"
 261   else
 262     DLPREOPEN="-export-dynamic"
 263     for module in $use_modules; do
 264       DLPREOPEN="$DLPREOPEN -dlopen $module"
 265     done
 266   fi
 267 fi
 268 AC_SUBST(INCLTDL)
 269 AC_SUBST(LIBLTDL)
 270 AC_SUBST(DLPREOPEN)
 271
 272 AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer)
 273
 274 AC_CHECK_HEADERS(crypt.h sys/resource.h sys/file.h)
 275 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 276 AC_CHECK_LIB(crypt, crypt)
 277
 278 ### Some systems don't declare some functions.  On such systems, we
 279 ### need to at least provide our own K&R-style declarations.
 280
 281 ### GUILE_FUNC_DECLARED(function, headerfile)
 282
 283 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 284 ### not there, #define MISSING_FUNCTION_DECL.
 285 AC_DEFUN(GUILE_FUNC_DECLARED, [
 286   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 287     AC_EGREP_HEADER($1, $2,
 288                     guile_cv_func_$1_declared=yes,
 289                     guile_cv_func_$1_declared=no))
 290   if test [x$guile_cv_func_]$1[_declared] = xno; then
 291     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 292   fi
 293 ])
 294
 295 GUILE_FUNC_DECLARED(strptime, time.h)
 296 GUILE_FUNC_DECLARED(sleep, unistd.h)
 297 GUILE_FUNC_DECLARED(usleep, unistd.h)
 298
 299 ### On some systems usleep has no return value.  If it does have one,
 300 ### we'd like to return it; otherwise, we'll fake it.
 301 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 302   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 303                    unistd.h,
 304                    [guile_cv_func_usleep_return_type=void],
 305                    [guile_cv_func_usleep_return_type=int])])
 306 case "$guile_cv_func_usleep_return_type" in
 307   "void" )
 308     AC_DEFINE(USLEEP_RETURNS_VOID)
 309   ;;
 310 esac
 311
 312 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 313 if test -n "$have_sys_un_h" ; then
 314 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 315 fi
 316
 317 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 318
 319 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 320                setnetent    getnetent    endnetent    dnl
 321                setprotoent  getprotoent  endprotoent  dnl
 322                setservent   getservent   endservent   dnl
 323                getnetbyaddr getnetbyname dnl
 324                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 325                inet_pton inet_ntop)
 326
 327 dnl Some systems do not declare this.  Some systems do declare it, as a
 328 dnl macro.  With cygwin it may be in a DLL.
 329
 330 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 331 AC_CACHE_VAL(guile_cv_have_h_errno,
 332 [AC_TRY_COMPILE([#include <netdb.h>],
 333 [int a = h_errno;],
 334 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 335 AC_MSG_RESULT($guile_cv_have_h_errno)
 336 if test $guile_cv_have_h_errno = yes; then
 337   AC_DEFINE(HAVE_H_ERRNO)
 338 fi
 339
 340 AC_MSG_CHECKING(whether uint32_t is defined)
 341 AC_CACHE_VAL(guile_cv_have_uint32_t,
 342   [AC_TRY_COMPILE([#include <sys/types.h>
 343                    #include <netdb.h>],
 344                   [uint32_t a;],
 345                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 346 AC_MSG_RESULT($guile_cv_have_uint32_t)
 347 if test $guile_cv_have_uint32_t = yes; then
 348   AC_DEFINE(HAVE_UINT32_T)
 349 fi
 350
 351 AC_MSG_CHECKING(for working IPv6 support)
 352 AC_CACHE_VAL(guile_cv_have_ipv6,
 353 [AC_TRY_COMPILE([#include <netinet/in.h>
 354 #include <sys/socket.h>],
 355 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 356 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 357 AC_MSG_RESULT($guile_cv_have_ipv6)
 358 if test $guile_cv_have_ipv6 = yes; then
 359   AC_DEFINE(HAVE_IPV6)
 360 fi
 361
 362 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 363 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 364 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 365 [AC_TRY_COMPILE([#include <netinet/in.h>],
 366 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 367 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 368 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 369 if test $guile_cv_have_sin6_scope_id = yes; then
 370   AC_DEFINE(HAVE_SIN6_SCOPE_ID)
 371 fi
 372
 373 AC_MSG_CHECKING(whether localtime caches TZ)
 374 AC_CACHE_VAL(guile_cv_localtime_cache,
 375 [if test x$ac_cv_func_tzset = xyes; then
 376 AC_TRY_RUN([#include <time.h>
 377 #if STDC_HEADERS
 378 # include <stdlib.h>
 379 #endif
 380 extern char **environ;
 381 unset_TZ ()
 382 {
 383   char **from, **to;
 384   for (to = from = environ; (*to = *from); from++)
 385     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 386       to++;
 387 }
 388 char TZ_GMT0[] = "TZ=GMT0";
 389 char TZ_PST8[] = "TZ=PST8";
 390 main()
 391 {
 392   time_t now = time ((time_t *) 0);
 393   int hour_GMT0, hour_unset;
 394   if (putenv (TZ_GMT0) != 0)
 395     exit (1);
 396   hour_GMT0 = localtime (&now)->tm_hour;
 397   unset_TZ ();
 398   hour_unset = localtime (&now)->tm_hour;
 399   if (putenv (TZ_PST8) != 0)
 400     exit (1);
 401   if (localtime (&now)->tm_hour == hour_GMT0)
 402     exit (1);
 403   unset_TZ ();
 404   if (localtime (&now)->tm_hour != hour_unset)
 405     exit (1);
 406   exit (0);
 407 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 408 [# If we have tzset, assume the worst when cross-compiling.
 409 guile_cv_localtime_cache=yes])
 410 else
 411         # If we lack tzset, report that localtime does not cache TZ,
 412         # since we can't invalidate the cache if we don't have tzset.
 413         guile_cv_localtime_cache=no
 414 fi])dnl
 415 AC_MSG_RESULT($guile_cv_localtime_cache)
 416 if test $guile_cv_localtime_cache = yes; then
 417   AC_DEFINE(LOCALTIME_CACHE)
 418 fi
 419
 420 dnl Test whether system calls are restartable by default on the
 421 dnl current system.  If they are not, we put a loop around every system
 422 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 423 dnl change from the default behaviour.  On the other hand, if signals
 424 dnl are restartable then the loop is not installed and when libguile
 425 dnl initialises it also resets the behaviour of each signal to cause a
 426 dnl restart (in case a different runtime had a different default
 427 dnl behaviour for some reason: e.g., different versions of linux seem
 428 dnl to behave differently.)
 429
 430 AC_SYS_RESTARTABLE_SYSCALLS
 431
 432 if test "$enable_regex" = yes; then
 433    if test "$ac_cv_header_regex_h" = yes ||
 434       test "$ac_cv_header_rxposix_h" = yes ||
 435       test "$ac_cv_header_rx_rxposix_h" = yes; then
 436      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 437      [AC_CHECK_LIB(rx, main)
 438       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 439      [AC_CHECK_LIB(regex, main)
 440       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [LIBOBJS="regex-posix.o $LIBOBJS"])])]
 441      )
 442      dnl The following should not be necessary, but for some reason
 443      dnl autoheader misses it if we don't include it!
 444      if test "$ac_cv_func_regcomp_norx" = yes ||
 445         test "$ac_cv_func_regcomp_regex" = yes ||
 446         test "$ac_cv_func_regcomp_rx" = yes; then
 447        AC_DEFINE(HAVE_REGCOMP)
 448      fi
 449    fi
 450 fi
 451
 452 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 453
 454 # When testing for the presence of alloca, we need to add alloca.o
 455 # explicitly to LIBOBJS to make sure that it is translated to
 456 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 457 AC_FUNC_ALLOCA
 458 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 459
 460 AC_CHECK_MEMBERS([struct stat.st_rdev])
 461 AC_CHECK_MEMBERS([struct stat.st_blksize])
 462
 463 AC_STRUCT_ST_BLOCKS
 464
 465 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 466   [AC_TRY_CPP([#include <sys/stat.h>
 467                #ifndef S_ISLNK
 468                #error no S_ISLNK
 469                #endif],
 470                ac_cv_macro_S_ISLNK=yes,
 471                ac_cv_macro_S_ISLNK=no)])
 472 if test $ac_cv_macro_S_ISLNK = yes; then
 473   AC_DEFINE(HAVE_S_ISLNK)
 474 fi
 475
 476 AC_STRUCT_TIMEZONE
 477 GUILE_STRUCT_UTIMBUF
 478
 479 #--------------------------------------------------------------------
 480 #
 481 # Which way does the stack grow?
 482 #
 483 #--------------------------------------------------------------------
 484
 485 AC_TRY_RUN(aux (l) unsigned long l;
 486              { int x; exit (l >= ((unsigned long)&x)); }
 487            main () { int q; aux((unsigned long)&q); },
 488            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 489
 490 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 491     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 492                 [guile_cv_type_float_fits_long=yes],
 493                 [guile_cv_type_float_fits_long=no],
 494                 [guile_cv_type_float_fits_long=guess-yes])])
 495 case $guile_cv_type_float_fits_long in
 496   "yes" )
 497     AC_DEFINE(SCM_SINGLES)
 498   ;;
 499   "guess-yes" )
 500     AC_DEFINE(SCM_SINGLES)
 501     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 502     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 503   ;;
 504 esac
 505
 506
 507 AC_MSG_CHECKING(for struct linger)
 508 AC_CACHE_VAL(scm_cv_struct_linger,
 509         AC_TRY_COMPILE([
 510 #include <sys/types.h>
 511 #include <sys/socket.h>],
 512                         [struct linger lgr;  lgr.l_linger = 100],
 513                         scm_cv_struct_linger="yes",
 514                         scm_cv_struct_linger="no"))
 515 AC_MSG_RESULT($scm_cv_struct_linger)
 516 if test $scm_cv_struct_linger = yes; then
 517         AC_DEFINE(HAVE_STRUCT_LINGER)
 518 fi
 519
 520
 521 AC_MSG_CHECKING(for struct timespec)
 522 AC_CACHE_VAL(scm_cv_struct_timespec,
 523         AC_TRY_COMPILE([
 524 #include <time.h>],
 525                         [struct timespec t;  t.tv_nsec = 100],
 526                         scm_cv_struct_timespec="yes",
 527                         scm_cv_struct_timespec="no"))
 528 AC_MSG_RESULT($scm_cv_struct_timespec)
 529 if test $scm_cv_struct_timespec = yes; then
 530         AC_DEFINE(HAVE_STRUCT_TIMESPEC)
 531 fi
 532
 533 #--------------------------------------------------------------------
 534 #
 535 # Flags for thread support
 536 #
 537 #--------------------------------------------------------------------
 538
 539 ### What thread package has the user asked for?
 540 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 541             , with_threads=no)
 542
 543 ### Turn $with_threads into either the name of a threads package, like
 544 ### `qt', or `no', meaning that threads should not be supported.
 545 AC_MSG_CHECKING(whether to support threads)
 546 case "$with_threads" in
 547   "yes" | "qt" | "coop" | "")
 548     with_threads=qt
 549   ;;
 550   "no" )
 551   ;;
 552   * )
 553     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 554   ;;
 555 esac
 556 AC_MSG_RESULT($with_threads)
 557
 558 ## Make sure the threads package we've chosen is actually supported on
 559 ## the present platform.
 560 case "${with_threads}" in
 561   "qt" )
 562     ## This configures the QuickThreads package, and sets or clears
 563     ## the THREAD_PACKAGE variable if qthreads don't configure
 564     ## correctly.
 565     QTHREADS_CONFIGURE
 566    ;;
 567 esac
 568
 569 ## If we're using threads, bring in some other parts of Guile which
 570 ## work with them.
 571 if test "${THREAD_PACKAGE}" != "" ; then
 572   AC_DEFINE(USE_THREADS, 1)
 573
 574   ## Include the Guile thread interface in the library...
 575   LIBOBJS="$LIBOBJS threads.o"
 576
 577   ## ... and tell it which package to talk to.
 578   case "${THREAD_PACKAGE}" in
 579     "QT" )
 580       AC_DEFINE(USE_COOP_THREADS, 1)
 581     ;;
 582     * )
 583       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 584     ;;
 585   esac
 586
 587   ## Bring in scm_internal_select, if appropriate.
 588   if test $ac_cv_func_gettimeofday = yes &&
 589      test $ac_cv_func_select = yes; then
 590     AC_DEFINE(GUILE_ISELECT, 1)
 591   fi
 592
 593   AC_ARG_ENABLE(linuxthreads,
 594   [  --disable-linuxthreads  disable linuxthreads workaround],,
 595   enable_linuxthreads=yes)
 596
 597   ## Workaround for linuxthreads (optionally disabled)
 598   if test $host_os = linux-gnu -a "$enable_linuxthreads" = yes; then
 599     AC_DEFINE(GUILE_PTHREAD_COMPAT, 1)
 600     AC_CHECK_LIB(pthread, main)
 601   fi
 602 fi
 603 AC_SUBST(LIBGUILEQTHREADS_INTERFACE_CURRENT)
 604 AC_SUBST(LIBGUILEQTHREADS_INTERFACE_REVISION)
 605 AC_SUBST(LIBGUILEQTHREADS_INTERFACE_AGE)
 606 AC_SUBST(LIBGUILEQTHREADS_INTERFACE)
 607
 608 ## If we're using GCC, ask for aggressive warnings.
 609 case "$GCC" in
 610   yes )
 611     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 612     ## much stuff with generic function pointers for that to really be
 613     ## less than exasperating.
 614     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 615     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 616     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 617 esac
 618
 619 AC_PROG_AWK
 620
 621 ## Remove fileblocks.o from the object list.  This file gets added by
 622 ## the Autoconf macro AC_STRUCT_ST_BLOCKS.  But there is no need.
 623 LIBOBJS="`echo ${LIBOBJS} | sed 's/fileblocks\.o//g'`"
 624
 625 ## If we're creating a shared library (using libtool!), then we'll
 626 ## need to generate a list of .lo files corresponding to the .o files
 627 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 628 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 629
 630 ## We also need to create corresponding .doc and .x files
 631 EXTRA_DOT_DOC_FILES="`echo ${LIBOBJS} | sed 's/\.o/.doc/g'`"
 632 EXTRA_DOT_X_FILES="`echo ${LIBOBJS} | sed 's/\.o/.x/g'`"
 633
 634 AC_SUBST(GUILE_MAJOR_VERSION)
 635 AC_SUBST(GUILE_MINOR_VERSION)
 636 AC_SUBST(GUILE_MICRO_VERSION)
 637 AC_SUBST(GUILE_VERSION)
 638
 639 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
 640 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
 641 AC_SUBST(LIBGUILE_INTERFACE_AGE)
 642 AC_SUBST(LIBGUILE_INTERFACE)
 643
 644 dnl Tell guile-config what flags guile users should link against.
 645 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 646 AC_SUBST(GUILE_LIBS)
 647
 648 AC_SUBST(AWK)
 649 AC_SUBST(LIBLOBJS)
 650 AC_SUBST(EXTRA_DOT_DOC_FILES)
 651 AC_SUBST(EXTRA_DOT_X_FILES)
 652
 653 AC_CONFIG_FILES([
 654   Makefile
 655   libguile/Makefile
 656   libguile/guile-snarf
 657   libguile/guile-doc-snarf
 658   libguile/guile-func-name-check
 659   libguile/guile-snarf-docs
 660   libguile/guile-snarf-docs-texi
 661   libguile/version.h
 662   ice-9/Makefile
 663   oop/Makefile
 664   oop/goops/Makefile
 665   scripts/Makefile
 666   srfi/Makefile
 667   qt/Makefile
 668   qt/qt.h
 669   qt/md/Makefile
 670   qt/time/Makefile
 671   guile-config/Makefile
 672   doc/Makefile
 673   doc/ref/Makefile
 674   doc/tutorial/Makefile
 675   doc/goops/Makefile
 676   doc/r5rs/Makefile
 677   examples/Makefile
 678   examples/scripts/Makefile
 679   examples/box/Makefile
 680   examples/box-module/Makefile
 681   examples/box-dynamic/Makefile
 682   examples/box-dynamic-module/Makefile
 683   examples/modules/Makefile
 684   examples/safe/Makefile
 685   test-suite/Makefile
 686   check-guile
 687   guile-tools])
 688
 689 AC_CONFIG_COMMANDS(default,
 690   [ chmod +x libguile/guile-snarf \
 691              libguile/guile-doc-snarf \
 692              libguile/guile-func-name-check \
 693              libguile/guile-snarf-docs \
 694              libguile/guile-snarf-docs-texi \
 695              check-guile \
 696              guile-tools])
 697
 698 AC_OUTPUT
 699
 700 dnl Local Variables:
 701 dnl comment-start: "dnl "
 702 dnl comment-end: ""
 703 dnl comment-start-skip: "\\bdnl\\b\\s *"
 704 dnl End: