configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it
  12 under the terms of the GNU General Public License as published by
  13 the Free Software Foundation; either version 2, or (at your
  14 option) any later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but
  17 WITHOUT ANY WARRANTY; without even the implied warranty of
  18 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 General Public License for more details.
  20
  21 You should have received a copy of the GNU General Public License
  22 along with GUILE; see the file COPYING.  If not, write to the
  23 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 Boston, MA 02110-1301, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.53)
  29
  30 AC_INIT(m4_esyscmd(. ./GUILE-VERSION && echo -n ${PACKAGE}),
  31         m4_esyscmd(. ./GUILE-VERSION && echo -n ${GUILE_VERSION}))
  32 AC_CONFIG_AUX_DIR([.])
  33 AC_CONFIG_SRCDIR(GUILE-VERSION)
  34 AM_INIT_AUTOMAKE([no-define])
  35
  36 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  37 AC_CONFIG_SRCDIR([GUILE-VERSION])
  38
  39 . $srcdir/GUILE-VERSION
  40
  41 AM_MAINTAINER_MODE
  42 AM_CONFIG_HEADER([config.h])
  43 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  44
  45 #--------------------------------------------------------------------
  46 #
  47 # Independent Subdirectories
  48 #
  49 #--------------------------------------------------------------------
  50
  51 AC_CONFIG_SUBDIRS(guile-readline)
  52
  53 #--------------------------------------------------------------------
  54
  55 dnl Some more checks for Win32
  56 AC_CYGWIN
  57 AC_MINGW32
  58 AC_LIBTOOL_WIN32_DLL
  59
  60 AC_PROG_INSTALL
  61 AC_PROG_CC
  62 AC_PROG_CPP
  63 AC_PROG_AWK
  64
  65 AC_AIX
  66 AC_ISC_POSIX
  67 AC_MINIX
  68
  69 AM_PROG_CC_STDC
  70
  71 AC_LIBTOOL_DLOPEN
  72 AC_PROG_LIBTOOL
  73 AC_CHECK_LIB([ltdl], [lt_dlinit], ,
  74   [AC_MSG_ERROR([libltdl not found.  See README.])])
  75
  76 AC_SUBST(DLPREOPEN)
  77
  78 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  79 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  80
  81 AM_PATH_LISPDIR
  82
  83 #--------------------------------------------------------------------
  84 #
  85 # User options (after above tests that may set default CFLAGS etc.)
  86 #
  87 #--------------------------------------------------------------------
  88
  89 GUILE_ERROR_ON_WARNING="yes"
  90
  91 AC_ARG_ENABLE(error-on-warning,
  92   [  --enable-error-on-warning    treat compile warnings as errors],
  93   [case "${enableval}" in
  94      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
  95      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
  96      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  97    esac])
  98
  99 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
 100 AC_ARG_ENABLE(debug-freelist,
 101   [  --enable-debug-freelist include garbage collector freelist debugging code],
 102   if test "$enable_debug_freelist" = y \
 103      || test "$enable_debug_freelist" = yes; then
 104     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
 105   fi)
 106
 107 AC_ARG_ENABLE(debug-malloc,
 108   [  --enable-debug-malloc   include malloc debugging code],
 109   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 110     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 111       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 112   fi)
 113
 114 SCM_I_GSC_GUILE_DEBUG=0
 115 AC_ARG_ENABLE(guile-debug,
 116   [AC_HELP_STRING([--enable-guile-debug],
 117                   [include internal debugging functions])],
 118   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 119     SCM_I_GSC_GUILE_DEBUG=1
 120   fi)
 121
 122 AC_ARG_ENABLE(posix,
 123   [  --disable-posix         omit posix interfaces],,
 124   enable_posix=yes)
 125
 126 AC_ARG_ENABLE(networking,
 127   [  --disable-networking    omit networking interfaces],,
 128   enable_networking=yes)
 129
 130 AC_ARG_ENABLE(regex,
 131   [  --disable-regex         omit regular expression interfaces],,
 132   enable_regex=yes)
 133
 134 AC_ARG_ENABLE([discouraged],
 135   AC_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 136
 137 if test "$enable_discouraged" = no; then
 138   SCM_I_GSC_ENABLE_DISCOURAGED=0
 139 else
 140   SCM_I_GSC_ENABLE_DISCOURAGED=1
 141 fi
 142
 143 AC_ARG_ENABLE([deprecated],
 144   AC_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 145
 146 if test "$enable_deprecated" = no; then
 147   SCM_I_GSC_ENABLE_DEPRECATED=0
 148 else
 149   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 150     warn_default=summary
 151   elif test "$enable_deprecated" = shutup; then
 152     warn_default=no
 153   else
 154     warn_default=$enable_deprecated
 155   fi
 156   SCM_I_GSC_ENABLE_DEPRECATED=1
 157   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 158   [Define this to control the default warning level for deprecated features.])
 159 fi
 160
 161 AC_ARG_ENABLE(elisp,
 162   [  --disable-elisp         omit Emacs Lisp support],,
 163   enable_elisp=yes)
 164
 165 #--------------------------------------------------------------------
 166
 167 dnl Check for dynamic linking
 168
 169 use_modules=yes
 170 AC_ARG_WITH(modules,
 171 [  --with-modules[=FILES]  Add support for dynamic modules],
 172 use_modules="$withval")
 173 test -z "$use_modules" && use_modules=yes
 174 DLPREOPEN=
 175 if test "$use_modules" != no; then
 176   if test "$use_modules" = yes; then
 177     DLPREOPEN="-dlpreopen force"
 178   else
 179     DLPREOPEN="-export-dynamic"
 180     for module in $use_modules; do
 181       DLPREOPEN="$DLPREOPEN -dlopen $module"
 182     done
 183   fi
 184 fi
 185
 186 dnl files which are destined for separate modules.
 187
 188 if test "$use_modules" != no; then
 189    AC_LIBOBJ([dynl])
 190 fi
 191
 192 if test "$enable_posix" = yes; then
 193    AC_LIBOBJ([filesys])
 194    AC_LIBOBJ([posix])
 195    AC_DEFINE(HAVE_POSIX, 1,
 196      [Define this if you want support for POSIX system calls in Guile.])
 197 fi
 198
 199 if test "$enable_networking" = yes; then
 200    AC_LIBOBJ([net_db])
 201    AC_LIBOBJ([socket])
 202    AC_DEFINE(HAVE_NETWORKING, 1,
 203      [Define this if you want support for networking in Guile.])
 204 fi
 205
 206 if test "$enable_debug_malloc" = yes; then
 207    AC_LIBOBJ([debug-malloc])
 208 fi
 209
 210 if test "$enable_elisp" = yes; then
 211   SCM_I_GSC_ENABLE_ELISP=1
 212 else
 213   SCM_I_GSC_ENABLE_ELISP=0
 214 fi
 215
 216 AC_C_CONST
 217
 218 AC_C_INLINE
 219 if test "$ac_cv_c_inline" != no; then
 220   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 221 else
 222   SCM_I_GSC_C_INLINE=NULL
 223 fi
 224
 225 AC_C_BIGENDIAN
 226
 227 AC_CHECK_SIZEOF(char)
 228 AC_CHECK_SIZEOF(unsigned char)
 229 AC_CHECK_SIZEOF(short)
 230 AC_CHECK_SIZEOF(unsigned short)
 231 AC_CHECK_SIZEOF(int)
 232 AC_CHECK_SIZEOF(unsigned int)
 233 AC_CHECK_SIZEOF(long)
 234 AC_CHECK_SIZEOF(unsigned long)
 235 AC_CHECK_SIZEOF(size_t)
 236 AC_CHECK_SIZEOF(long long)
 237 AC_CHECK_SIZEOF(unsigned long long)
 238 AC_CHECK_SIZEOF(__int64)
 239 AC_CHECK_SIZEOF(unsigned __int64)
 240 AC_CHECK_SIZEOF(void *)
 241 AC_CHECK_SIZEOF(intptr_t)
 242 AC_CHECK_SIZEOF(uintptr_t)
 243 AC_CHECK_SIZEOF(ptrdiff_t)
 244 AC_CHECK_SIZEOF(size_t)
 245 AC_CHECK_SIZEOF(off_t)
 246
 247 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 248   AC_MSG_ERROR(sizes of long and void* are not identical)
 249 fi
 250
 251 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 252   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 253 else
 254   SCM_I_GSC_T_PTRDIFF='"long"'
 255 fi
 256 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 257
 258 AC_CHECK_HEADERS([stdint.h])
 259 AC_CHECK_HEADERS([inttypes.h])
 260
 261 AC_CHECK_SIZEOF(intmax_t)
 262
 263 SCM_I_GSC_NEEDS_STDINT_H=0
 264 SCM_I_GSC_NEEDS_INTTYPES_H=0
 265
 266 ### intptr and uintptr (try not to use inttypes if we don't have to)
 267 if test "$ac_cv_header_inttypes_h" = yes; then
 268   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 269     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 270 #include <stdio.h>])
 271     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 272       SCM_I_GSC_NEEDS_INTTYPES_H=1
 273     fi
 274   fi
 275   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 276     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 277 #include <stdio.h>])
 278     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 279       SCM_I_GSC_NEEDS_INTTYPES_H=1
 280     fi
 281   fi
 282 fi
 283
 284 ### See what's provided by stdint.h
 285 if test "$ac_cv_header_stdint_h" = yes; then
 286    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 287    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 288    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 289    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 290    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 291    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 292    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 293    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 294    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 295    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 296 fi
 297
 298 # so we don't get confused by the cache (wish there was a better way
 299 # to check particular headers for the same type...)
 300
 301 unset ac_cv_type_int8_t
 302 unset ac_cv_type_uint8_t
 303 unset ac_cv_type_int16_t
 304 unset ac_cv_type_uint16_t
 305 unset ac_cv_type_int32_t
 306 unset ac_cv_type_uint32_t
 307 unset ac_cv_type_int64_t
 308 unset ac_cv_type_uint64_t
 309 unset ac_cv_type_intmax_t
 310 unset ac_cv_type_uintmax_t
 311
 312 ### See what's provided by inttypes.h
 313 if test "$ac_cv_header_inttypes_h" = yes; then
 314   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 315   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 316   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 317   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 318   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 319   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 320   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 321   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 322   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 323   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 324 fi
 325
 326 # Try hard to find definitions for some required scm_t_*int* types.
 327
 328 ### Required type scm_t_int8
 329 if test "$scm_stdint_has_int8"; then
 330   SCM_I_GSC_T_INT8='"int8_t"'
 331   SCM_I_GSC_NEEDS_STDINT_H=1
 332 elif test "$scm_inttypes_has_int8"; then
 333   SCM_I_GSC_T_INT8='"int8_t"'
 334   SCM_I_GSC_NEEDS_INTTYPES_H=1
 335 elif test "$ac_cv_sizeof_char" -eq 1; then
 336   SCM_I_GSC_T_INT8='"signed char"'
 337 else
 338   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 339 fi
 340 AC_SUBST([SCM_I_GSC_T_INT8])
 341
 342 ### Required type scm_t_uint8
 343 if test "$scm_stdint_has_uint8"; then
 344   SCM_I_GSC_T_UINT8='"uint8_t"'
 345   SCM_I_GSC_NEEDS_STDINT_H=1
 346 elif test "$scm_inttypes_has_uint8"; then
 347   SCM_I_GSC_T_UINT8='"uint8_t"'
 348   SCM_I_GSC_NEEDS_INTTYPES_H=1
 349 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 350   SCM_I_GSC_T_UINT8='"unsigned char"'
 351 else
 352   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 353 fi
 354 AC_SUBST([SCM_I_GSC_T_UINT8])
 355
 356 ### Required type scm_t_int16 (ANSI C says int or short might work)
 357 if test "$scm_stdint_has_int16"; then
 358   SCM_I_GSC_T_INT16='"int16_t"'
 359   SCM_I_GSC_NEEDS_STDINT_H=1
 360 elif test "$scm_inttypes_has_int16"; then
 361   SCM_I_GSC_T_INT16='"int16_t"'
 362   SCM_I_GSC_NEEDS_INTTYPES_H=1
 363 elif test "$ac_cv_sizeof_int" -eq 2; then
 364   SCM_I_GSC_T_INT16='"int"'
 365 elif test "$ac_cv_sizeof_short" -eq 2; then
 366   SCM_I_GSC_T_INT16='"short"'
 367 else
 368   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 369 fi
 370 AC_SUBST([SCM_I_GSC_T_INT16])
 371
 372 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 373 if test "$scm_stdint_has_uint16"; then
 374   SCM_I_GSC_T_UINT16='"uint16_t"'
 375   SCM_I_GSC_NEEDS_STDINT_H=1
 376 elif test "$scm_inttypes_has_uint16"; then
 377   SCM_I_GSC_T_UINT16='"uint16_t"'
 378   SCM_I_GSC_NEEDS_INTTYPES_H=1
 379 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 380   SCM_I_GSC_T_UINT16='"unsigned int"'
 381 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 382   SCM_I_GSC_T_UINT16='"unsigned short"'
 383 else
 384   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 385 fi
 386 AC_SUBST([SCM_I_GSC_T_UINT16])
 387
 388
 389 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 390 if test "$scm_stdint_has_int32"; then
 391   SCM_I_GSC_T_INT32='"int32_t"'
 392   SCM_I_GSC_NEEDS_STDINT_H=1
 393 elif test "$scm_inttypes_has_int32"; then
 394   SCM_I_GSC_T_INT32='"int32_t"'
 395   SCM_I_GSC_NEEDS_INTTYPES_H=1
 396 elif test "$ac_cv_sizeof_int" -eq 4; then
 397   SCM_I_GSC_T_INT32='"int"'
 398 elif test "$ac_cv_sizeof_long" -eq 4; then
 399   SCM_I_GSC_T_INT32='"long"'
 400 elif test "$ac_cv_sizeof_short" -eq 4; then
 401   SCM_I_GSC_T_INT32='"short"'
 402 else
 403   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 404 fi
 405 AC_SUBST([SCM_I_GSC_T_INT32])
 406
 407 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 408 if test "$scm_stdint_has_uint32"; then
 409   SCM_I_GSC_T_UINT32='"uint32_t"'
 410   SCM_I_GSC_NEEDS_STDINT_H=1
 411 elif test "$scm_inttypes_has_uint32"; then
 412   SCM_I_GSC_T_UINT32='"uint32_t"'
 413   SCM_I_GSC_NEEDS_INTTYPES_H=1
 414 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 415   SCM_I_GSC_T_UINT32='"unsigned int"'
 416 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 417   SCM_I_GSC_T_UINT32='"unsigned long"'
 418 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 419   SCM_I_GSC_T_UINT32='"unsigned short"'
 420 else
 421   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 422 fi
 423 AC_SUBST([SCM_I_GSC_T_UINT32])
 424
 425 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 426 ### Also try 'long long' and '__int64' if we have it.
 427 SCM_I_GSC_T_INT64=0
 428 if test "$scm_stdint_has_int64"; then
 429   SCM_I_GSC_T_INT64='"int64_t"'
 430   SCM_I_GSC_NEEDS_STDINT_H=1
 431 elif test "$scm_inttypes_has_int64"; then
 432   SCM_I_GSC_T_INT64='"int64_t"'
 433   SCM_I_GSC_NEEDS_INTTYPES_H=1
 434 elif test "$ac_cv_sizeof_int" -eq 8; then
 435   SCM_I_GSC_T_INT64='"int"'
 436 elif test "$ac_cv_sizeof_long" -eq 8; then
 437   SCM_I_GSC_T_INT64='"long"'
 438 elif test "$ac_cv_sizeof_short" -eq 8; then
 439   SCM_I_GSC_T_INT64='"short"'
 440 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 441   SCM_I_GSC_T_INT64='"long long"'
 442 elif test "$ac_cv_sizeof___int64" -eq 8; then
 443   SCM_I_GSC_T_INT64='"__int64"'
 444 else
 445   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 446 fi
 447 AC_SUBST([SCM_I_GSC_T_INT64])
 448
 449
 450 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 451 ### Also try 'long long' and '__int64' if we have it.
 452 SCM_I_GSC_T_UINT64=0
 453 if test "$scm_stdint_has_uint64"; then
 454   SCM_I_GSC_T_UINT64='"uint64_t"'
 455   SCM_I_GSC_NEEDS_STDINT_H=1
 456 elif test "$scm_inttypes_has_uint64"; then
 457   SCM_I_GSC_T_UINT64='"uint64_t"'
 458   SCM_I_GSC_NEEDS_INTTYPES_H=1
 459 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 460   SCM_I_GSC_T_UINT64='"unsigned int"'
 461 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 462   SCM_I_GSC_T_UINT64='"unsigned long"'
 463 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 464   SCM_I_GSC_T_UINT64='"unsigned short"'
 465 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 466   SCM_I_GSC_T_UINT64='"unsigned long long"'
 467 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 468   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 469 else
 470   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 471 fi
 472 AC_SUBST([SCM_I_GSC_T_UINT64])
 473
 474 ### Required type scm_t_intmax
 475 ###
 476 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 477 ### none of them is available, we use 'long'.
 478 ###
 479 SCM_I_GSC_T_INTMAX=0
 480 if test "$scm_stdint_has_intmax"; then
 481   SCM_I_GSC_T_INTMAX='"intmax_t"'
 482   SCM_I_GSC_NEEDS_STDINT_H=1
 483 elif test "$scm_inttypes_has_intmax"; then
 484   SCM_I_GSC_T_INTMAX='"intmax_t"'
 485   SCM_I_GSC_NEEDS_INTTYPES_H=1
 486 elif test "$ac_cv_sizeof___int64" -ne 0; then
 487   SCM_I_GSC_T_INTMAX='"__int64"'
 488 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 489   SCM_I_GSC_T_INTMAX='"long long"'
 490 else
 491   SCM_I_GSC_T_INTMAX='"long"'
 492 fi
 493 AC_SUBST([SCM_I_GSC_T_INTMAX])
 494
 495 ### Required type scm_t_uintmax
 496 ###
 497 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 498 ### this order.  When none of them is available, we use 'unsigned long'.
 499 ###
 500 SCM_I_GSC_T_UINTMAX=0
 501 if test "$scm_stdint_has_uintmax"; then
 502   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 503   SCM_I_GSC_NEEDS_STDINT_H=1
 504 elif test "$scm_inttypes_has_uintmax"; then
 505   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 506   SCM_I_GSC_NEEDS_INTTYPES_H=1
 507 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 508   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 509 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 510   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 511 else
 512   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 513 fi
 514 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 515
 516
 517 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 518 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 519
 520 AC_HEADER_STDC
 521 AC_HEADER_DIRENT
 522 AC_HEADER_TIME
 523 AC_HEADER_SYS_WAIT
 524
 525 # Reasons for testing:
 526 #   fenv.h - available in C99, but not older systems
 527 #
 528 AC_CHECK_HEADERS([fenv.h io.h libc.h limits.h malloc.h memory.h string.h \
 529 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 530 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 531 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 532 direct.h])
 533
 534 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 535 # when testing.
 536 AC_CHECK_TYPE(socklen_t, ,
 537   [AC_DEFINE_UNQUOTED(socklen_t, int,
 538                       [Define to `int' if <sys/socket.h> does not define.])],
 539   [#if HAVE_SYS_TYPES_H
 540 #include <sys/types.h>
 541 #endif
 542 #include <sys/socket.h>
 543 ])
 544 AC_CHECK_TYPE(struct ip_mreq)
 545
 546 GUILE_HEADER_LIBC_WITH_UNISTD
 547
 548 AC_TYPE_GETGROUPS
 549 AC_TYPE_SIGNAL
 550 AC_TYPE_MODE_T
 551
 552 if test $MINGW32 = no; then
 553         AC_CHECK_LIB(m, main)
 554 fi
 555 AC_CHECK_FUNCS(gethostbyname)
 556 if test $ac_cv_func_gethostbyname = no; then
 557     AC_CHECK_LIB(nsl, gethostbyname)
 558 fi
 559
 560 AC_CHECK_FUNCS(connect)
 561 if test $ac_cv_func_connect = no; then
 562     AC_CHECK_LIB(socket, connect)
 563 fi
 564
 565 dnl
 566 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 567 dnl
 568 EXTRA_DEFS=""
 569 if test "$MINGW32" = "yes" ; then
 570     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 571       [Define if you have the <winsock2.h> header file.])])
 572     AC_CHECK_LIB(ws2_32, main)
 573     AC_LIBOBJ([win32-uname])
 574     AC_LIBOBJ([win32-dirent])
 575     if test "$enable_networking" = yes ; then
 576       AC_LIBOBJ([win32-socket])
 577     fi
 578     if test "$enable_shared" = yes ; then
 579       EXTRA_DEFS="-DSCM_IMPORT"
 580       AC_DEFINE(USE_DLL_IMPORT, 1,
 581         [Define if you need additional CPP macros on Win32 platforms.])
 582     fi
 583 fi
 584 AC_SUBST(EXTRA_DEFS)
 585
 586 # Reasons for testing:
 587 #   crt_externs.h - Darwin specific
 588 #
 589 AC_CHECK_HEADERS([assert.h crt_externs.h])
 590
 591 # Reasons for testing:
 592 #   DINFINITY - OSF specific
 593 #   DQNAN - OSF specific
 594 #       (DINFINITY and DQNAN are actually global variables, not functions)
 595 #   fesetround - available in C99, but not older systems
 596 #   ioctl - not in mingw.
 597 #   gmtime_r - recent posix, not on old systems
 598 #   readdir_r - recent posix, not on old systems
 599 #   stat64 - SuS largefile stuff, not on old systems
 600 #   sysconf - not on old systems
 601 #   isblank - available as a GNU extension or in C99
 602 #   _NSGetEnviron - Darwin specific
 603 #
 604 AC_CHECK_FUNCS([DINFINITY DQNAN ctermid fesetround ftime fchown getcwd geteuid gettimeofday gmtime_r ioctl lstat mkdir mknod nice readdir_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex unsetenv isblank _NSGetEnviron])
 605
 606 # Reasons for testing:
 607 #   netdb.h - not in mingw
 608 #   sys/param.h - not in mingw
 609 #
 610 AC_CHECK_HEADERS(crypt.h netdb.h sys/param.h sys/resource.h sys/file.h)
 611 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 612
 613 # crypt() may or may not be available, for instance in some countries there
 614 # are restrictions on cryptography.
 615 #
 616 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 617 # -lcrypt library (eg. Debian GNU/Linux).
 618 #
 619 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 620 # be careful to avoid -lcrypt in this case, since libtool will see there's
 621 # only a static libcrypt and decide to build only a static libguile.
 622 #
 623 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 624 # libraries already in that list.
 625 #
 626 AC_SEARCH_LIBS(crypt, crypt,
 627   [AC_DEFINE(HAVE_CRYPT,1,
 628              [Define to 1 if you have the `crypt' function.])])
 629
 630 dnl GMP tests
 631 AC_CHECK_LIB([gmp], [__gmpz_init], ,
 632   [AC_MSG_ERROR([GNU MP not found, see README])])
 633
 634 # mpz_import is a macro so we need to include <gmp.h>
 635 AC_TRY_LINK([#include <gmp.h>],
 636             [mpz_import (0, 0, 0, 0, 0, 0, 0);] , ,
 637   [AC_MSG_ERROR([At least GNU MP 4.1 is required, see README])])
 638
 639 dnl i18n tests
 640 #AC_CHECK_HEADERS([libintl.h])
 641 #AC_CHECK_FUNCS(gettext)
 642 #if test $ac_cv_func_gettext = no; then
 643 #   AC_CHECK_LIB(intl, gettext)
 644 #fi
 645 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 646 AM_GNU_GETTEXT([external], [need-ngettext])
 647
 648 ### Some systems don't declare some functions.  On such systems, we
 649 ### need to at least provide our own K&R-style declarations.
 650
 651 ### GUILE_FUNC_DECLARED(function, headerfile)
 652
 653 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 654 ### not there, #define MISSING_FUNCTION_DECL.
 655 AC_DEFUN([GUILE_FUNC_DECLARED], [
 656   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 657     AC_EGREP_HEADER($1, $2,
 658                     guile_cv_func_$1_declared=yes,
 659                     guile_cv_func_$1_declared=no))
 660   if test [x$guile_cv_func_]$1[_declared] = xno; then
 661     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 662       [Define if the operating system supplies $1 without declaring it.])
 663   fi
 664 ])
 665
 666 GUILE_FUNC_DECLARED(sleep, unistd.h)
 667 GUILE_FUNC_DECLARED(usleep, unistd.h)
 668
 669 AC_CHECK_DECLS([strptime],,,
 670 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 671 #include <time.h>])
 672
 673 ### On some systems usleep has no return value.  If it does have one,
 674 ### we'd like to return it; otherwise, we'll fake it.
 675 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 676   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 677                    unistd.h,
 678                    [guile_cv_func_usleep_return_type=void],
 679                    [guile_cv_func_usleep_return_type=int])])
 680 case "$guile_cv_func_usleep_return_type" in
 681   "void" )
 682     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 683       [Define if the system headers declare usleep to return void.])
 684   ;;
 685 esac
 686
 687 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 688 if test -n "$have_sys_un_h" ; then
 689   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 690     [Define if the system supports Unix-domain (file-domain) sockets.])
 691 fi
 692
 693 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 694
 695 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 696                setnetent    getnetent    endnetent    dnl
 697                setprotoent  getprotoent  endprotoent  dnl
 698                setservent   getservent   endservent   dnl
 699                getnetbyaddr getnetbyname dnl
 700                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 701                inet_pton inet_ntop)
 702
 703 # struct sockaddr field sin_len is only present on BSD systems.
 704 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 705 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 706 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 707 [#ifdef HAVE_SYS_TYPES_H
 708 #include <sys/types.h>
 709 #endif
 710 #include <netinet/in.h>])
 711
 712 AC_MSG_CHECKING(for __libc_stack_end)
 713 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 714 [AC_TRY_LINK([#include <stdio.h>
 715 extern char *__libc_stack_end;],
 716              [printf("%p", (char*) __libc_stack_end);],
 717              guile_cv_have_libc_stack_end=yes,
 718              guile_cv_have_libc_stack_end=no)])
 719 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 720
 721 if test $guile_cv_have_libc_stack_end = yes; then
 722   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 723            [Define if you have the __libc_stack_end variable.])
 724 fi
 725
 726 dnl Some systems do not declare this.  Some systems do declare it, as a
 727 dnl macro.  With cygwin it may be in a DLL.
 728
 729 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 730 AC_CACHE_VAL(guile_cv_have_h_errno,
 731 [AC_TRY_COMPILE([#include <netdb.h>],
 732 [int a = h_errno;],
 733 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 734 AC_MSG_RESULT($guile_cv_have_h_errno)
 735 if test $guile_cv_have_h_errno = yes; then
 736   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 737 fi
 738
 739 AC_MSG_CHECKING(whether uint32_t is defined)
 740 AC_CACHE_VAL(guile_cv_have_uint32_t,
 741   [AC_TRY_COMPILE([#include <sys/types.h>
 742                    #if HAVE_STDINT_H
 743                    #include <stdint.h>
 744                    #endif
 745                    #ifndef __MINGW32__
 746                    #include <netdb.h>
 747                    #endif],
 748                   [uint32_t a;],
 749                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 750 AC_MSG_RESULT($guile_cv_have_uint32_t)
 751 if test $guile_cv_have_uint32_t = yes; then
 752   AC_DEFINE(HAVE_UINT32_T, 1,
 753     [Define if uint32_t typedef is defined when netdb.h is include.])
 754 fi
 755
 756 AC_MSG_CHECKING(for working IPv6 support)
 757 AC_CACHE_VAL(guile_cv_have_ipv6,
 758 [AC_TRY_COMPILE([
 759 #ifdef HAVE_SYS_TYPES_H
 760 #include <sys/types.h>
 761 #endif
 762 #include <netinet/in.h>
 763 #include <sys/socket.h>],
 764 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 765 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 766 AC_MSG_RESULT($guile_cv_have_ipv6)
 767 if test $guile_cv_have_ipv6 = yes; then
 768   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 769 fi
 770
 771 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 772 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 773 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 774 [AC_TRY_COMPILE([
 775 #ifdef HAVE_SYS_TYPES_H
 776 #include <sys/types.h>
 777 #endif
 778 #include <netinet/in.h>],
 779 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 780 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 781 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 782 if test $guile_cv_have_sin6_scope_id = yes; then
 783   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 784     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 785 fi
 786
 787 # struct sockaddr_in6 field sin_len is only present on BSD systems
 788 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
 789 [#ifdef HAVE_SYS_TYPES_H
 790 #include <sys/types.h>
 791 #endif
 792 #include <netinet/in.h>])
 793
 794 AC_MSG_CHECKING(whether localtime caches TZ)
 795 AC_CACHE_VAL(guile_cv_localtime_cache,
 796 [if test x$ac_cv_func_tzset = xyes; then
 797 AC_TRY_RUN([#include <time.h>
 798 #if STDC_HEADERS
 799 # include <stdlib.h>
 800 #endif
 801 extern char **environ;
 802 unset_TZ ()
 803 {
 804   char **from, **to;
 805   for (to = from = environ; (*to = *from); from++)
 806     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 807       to++;
 808 }
 809 char TZ_GMT0[] = "TZ=GMT0";
 810 char TZ_PST8[] = "TZ=PST8";
 811 main()
 812 {
 813   time_t now = time ((time_t *) 0);
 814   int hour_GMT0, hour_unset;
 815   if (putenv (TZ_GMT0) != 0)
 816     exit (1);
 817   hour_GMT0 = localtime (&now)->tm_hour;
 818   unset_TZ ();
 819   hour_unset = localtime (&now)->tm_hour;
 820   if (putenv (TZ_PST8) != 0)
 821     exit (1);
 822   if (localtime (&now)->tm_hour == hour_GMT0)
 823     exit (1);
 824   unset_TZ ();
 825   if (localtime (&now)->tm_hour != hour_unset)
 826     exit (1);
 827   exit (0);
 828 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 829 [# If we have tzset, assume the worst when cross-compiling.
 830 guile_cv_localtime_cache=yes])
 831 else
 832         # If we lack tzset, report that localtime does not cache TZ,
 833         # since we can't invalidate the cache if we don't have tzset.
 834         guile_cv_localtime_cache=no
 835 fi])dnl
 836 AC_MSG_RESULT($guile_cv_localtime_cache)
 837 if test $guile_cv_localtime_cache = yes; then
 838   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
 839 fi
 840
 841 dnl Test whether system calls are restartable by default on the
 842 dnl current system.  If they are not, we put a loop around every system
 843 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 844 dnl change from the default behaviour.  On the other hand, if signals
 845 dnl are restartable then the loop is not installed and when libguile
 846 dnl initialises it also resets the behaviour of each signal to cause a
 847 dnl restart (in case a different runtime had a different default
 848 dnl behaviour for some reason: e.g., different versions of linux seem
 849 dnl to behave differently.)
 850
 851 AC_SYS_RESTARTABLE_SYSCALLS
 852
 853 if test "$enable_regex" = yes; then
 854    if test "$ac_cv_header_regex_h" = yes ||
 855       test "$ac_cv_header_rxposix_h" = yes ||
 856       test "$ac_cv_header_rx_rxposix_h" = yes; then
 857      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
 858      [AC_CHECK_LIB(rx, main)
 859       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
 860      [AC_CHECK_LIB(regex, main)
 861       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
 862      )
 863      dnl The following should not be necessary, but for some reason
 864      dnl autoheader misses it if we don't include it!
 865      if test "$ac_cv_func_regcomp_norx" = yes ||
 866         test "$ac_cv_func_regcomp_regex" = yes ||
 867         test "$ac_cv_func_regcomp_rx" = yes; then
 868        AC_DEFINE(HAVE_REGCOMP, 1,
 869          [This is included as part of a workaround for a autoheader bug.])
 870      fi
 871    fi
 872 fi
 873
 874 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 875
 876 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
 877
 878 # Reasons for testing:
 879 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
 880 #                                older systems
 881 #   dirfd - mainly BSD derived, not in older systems
 882 #   sincos - GLIBC extension
 883 #
 884 AC_CHECK_FUNCS(asinh acosh atanh copysign dirfd finite sincos trunc)
 885
 886 # C99 specifies isinf and isnan as macros.
 887 # HP-UX provides only macros, no functions.
 888 # glibc 2.3.2 provides both macros and functions.
 889 # IRIX 6.5 and Solaris 8 only provide functions.
 890 #
 891 # The following tests detect isinf and isnan either as functions or as
 892 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
 893 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
 894 #
 895 AC_MSG_CHECKING([for isinf])
 896 AC_LINK_IFELSE(
 897 [#include <math.h>
 898 int main () { return (isinf(0.0) != 0); }],
 899   [AC_MSG_RESULT([yes])
 900    AC_DEFINE(HAVE_ISINF, 1,
 901              [Define to 1 if you have the `isinf' macro or function.])],
 902   [AC_MSG_RESULT([no])])
 903 AC_MSG_CHECKING([for isnan])
 904 AC_LINK_IFELSE(
 905 [#include <math.h>
 906 int main () { return (isnan(0.0) != 0); }],
 907   [AC_MSG_RESULT([yes])
 908    AC_DEFINE(HAVE_ISNAN, 1,
 909              [Define to 1 if you have the `isnan' macro or function.])],
 910   [AC_MSG_RESULT([no])])
 911
 912 # We must have a proper stack-using alloca in order for stack-copying
 913 # continuations to work properly.  If we don't find a native one,
 914 # abort.
 915
 916 AC_FUNC_ALLOCA
 917 if test "$ALLOCA" = "alloca.o"
 918 then
 919   AC_ERROR([No native alloca found.])
 920 fi
 921
 922 # Reasons for checking:
 923 #
 924 #     st_rdev
 925 #     st_blksize
 926 #     st_blocks   not in mingw
 927 #
 928 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
 929 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
 930 #
 931 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks])
 932
 933 AC_STRUCT_TIMEZONE
 934 GUILE_STRUCT_UTIMBUF
 935
 936 #--------------------------------------------------------------------
 937 #
 938 # Which way does the stack grow?
 939 #
 940 #--------------------------------------------------------------------
 941
 942 SCM_I_GSC_STACK_GROWS_UP=0
 943 AC_TRY_RUN(aux (l) unsigned long l;
 944              { int x; exit (l >= ((unsigned long)&x)); }
 945            main () { int q; aux((unsigned long)&q); },
 946            [SCM_I_GSC_STACK_GROWS_UP=1],
 947            [],
 948            [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
 949
 950 AC_CHECK_SIZEOF(float)
 951 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
 952     AC_DEFINE(SCM_SINGLES, 1,
 953               [Define this if floats are the same size as longs.])
 954 fi
 955
 956 AC_MSG_CHECKING(for struct linger)
 957 AC_CACHE_VAL(scm_cv_struct_linger,
 958         AC_TRY_COMPILE([
 959 #include <sys/types.h>
 960 #include <sys/socket.h>],
 961                         [struct linger lgr;  lgr.l_linger = 100],
 962                         scm_cv_struct_linger="yes",
 963                         scm_cv_struct_linger="no"))
 964 AC_MSG_RESULT($scm_cv_struct_linger)
 965 if test $scm_cv_struct_linger = yes; then
 966         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
 967           [Define this if your system defines struct linger, for use with the
 968            getsockopt and setsockopt system calls.])
 969 fi
 970
 971
 972 AC_MSG_CHECKING(for struct timespec)
 973 AC_CACHE_VAL(scm_cv_struct_timespec,
 974         AC_TRY_COMPILE([
 975 #include <time.h>],
 976                         [struct timespec t;  t.tv_nsec = 100],
 977                         scm_cv_struct_timespec="yes",
 978                         scm_cv_struct_timespec="no"))
 979 AC_MSG_RESULT($scm_cv_struct_timespec)
 980 if test $scm_cv_struct_timespec = yes; then
 981   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
 982     [Define this if your system defines struct timespec via <time.h>.])
 983 fi
 984
 985 #--------------------------------------------------------------------
 986 #
 987 # Flags for thread support
 988 #
 989 #--------------------------------------------------------------------
 990
 991 SCM_I_GSC_USE_PTHREAD_THREADS=0
 992 SCM_I_GSC_USE_NULL_THREADS=0
 993 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
 994 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
 995
 996 ### What thread package has the user asked for?
 997 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 998             , with_threads=yes)
 999
1000 case "$with_threads" in
1001   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1002     ACX_PTHREAD(CC="$PTHREAD_CC"
1003       LIBS="$PTHREAD_LIBS $LIBS"
1004       SCM_I_GSC_USE_PTHREAD_THREADS=1
1005       with_threads="pthreads",
1006       with_threads="null")
1007
1008     old_CFLAGS="$CFLAGS"
1009     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1010     AC_CHECK_FUNCS(pthread_attr_getstack)
1011     CFLAGS="$old_CFLAGS"
1012
1013     # On Solaris, sched_yield lives in -lrt.
1014     AC_SEARCH_LIBS(sched_yield, rt)
1015
1016   ;;
1017 esac
1018
1019 case "$with_threads" in
1020   "pthreads")
1021   ;;
1022   "no" | "null")
1023     SCM_I_GSC_USE_NULL_THREADS=1
1024     with_threads="null-threads"
1025   ;;
1026   * )
1027     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1028   ;;
1029 esac
1030
1031 AC_MSG_CHECKING(what kind of threads to support)
1032 AC_MSG_RESULT($with_threads)
1033
1034 ## Check whether pthread_attr_getstack works for the main thread
1035
1036 if test "$with_threads" = pthreads; then
1037
1038 AC_MSG_CHECKING(whether pthread_attr_getstack works for the main thread)
1039 old_CFLAGS="$CFLAGS"
1040 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1041 AC_TRY_RUN(
1042 [
1043 #if HAVE_PTHREAD_ATTR_GETSTACK
1044 #include <pthread.h>
1045
1046 int main ()
1047 {
1048   pthread_attr_t attr;
1049   void *start, *end;
1050   size_t size;
1051
1052   pthread_getattr_np (pthread_self (), &attr);
1053   pthread_attr_getstack (&attr, &start, &size);
1054   end = (char *)start + size;
1055
1056   if ((void *)&attr < start || (void *)&attr >= end)
1057     return 1;
1058   else
1059     return 0;
1060 }
1061 #else
1062 int main ()
1063 {
1064   return 1;
1065 }
1066 #endif
1067 ],
1068 [works=yes
1069 AC_DEFINE(PTHREAD_ATTR_GETSTACK_WORKS, [1], [Define when pthread_att_get_stack works for the main thread])],
1070 [works=no])
1071 CFLAGS="$old_CFLAGS"
1072 AC_MSG_RESULT($works)
1073
1074 fi # with_threads=pthreads
1075
1076
1077 ## Cross building
1078 if test "$cross_compiling" = "yes"; then
1079   AC_MSG_CHECKING(cc for build)
1080   ## /usr/bin/cc still uses wrong assembler
1081   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1082   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1083 else
1084   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1085 fi
1086
1087 ## AC_MSG_CHECKING("if we are cross compiling")
1088 ## AC_MSG_RESULT($cross_compiling)
1089 if test "$cross_compiling" = "yes"; then
1090    AC_MSG_RESULT($CC_FOR_BUILD)
1091 fi
1092
1093 ## No need as yet to be more elaborate
1094 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1095
1096 AC_SUBST(cross_compiling)
1097 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1098 AC_SUBST(CCLD_FOR_BUILD)
1099
1100 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1101 ## --HOST is the platform that PACKAGE is compiled for.
1102 HOST_CC="$CC_FOR_BUILD"
1103 AC_SUBST(HOST_CC)
1104
1105 if test "$cross_compiling" = "yes"; then
1106   AC_MSG_CHECKING(guile for build)
1107   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1108 else
1109   GUILE_FOR_BUILD='$(preinstguile)'
1110 fi
1111
1112 ## AC_MSG_CHECKING("if we are cross compiling")
1113 ## AC_MSG_RESULT($cross_compiling)
1114 if test "$cross_compiling" = "yes"; then
1115    AC_MSG_RESULT($GUILE_FOR_BUILD)
1116 fi
1117 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1118 AC_SUBST(GUILE_FOR_BUILD)
1119
1120 ## If we're using GCC, ask for aggressive warnings.
1121 case "$GCC" in
1122   yes )
1123     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1124     ## much stuff with generic function pointers for that to really be
1125     ## less than exasperating.
1126     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1127     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1128     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
1129     # Do this here so we don't screw up any of the tests above that might
1130     # not be "warning free"
1131     if test "${GUILE_ERROR_ON_WARNING}" = yes
1132     then
1133         CFLAGS="${CFLAGS} -Werror"
1134         enable_compile_warnings=no
1135     fi
1136     ;;
1137 esac
1138
1139 ## If we're creating a shared library (using libtool!), then we'll
1140 ## need to generate a list of .lo files corresponding to the .o files
1141 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1142 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1143
1144 ## We also need to create corresponding .doc and .x files
1145 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1146 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1147
1148 AC_SUBST(GUILE_MAJOR_VERSION)
1149 AC_SUBST(GUILE_MINOR_VERSION)
1150 AC_SUBST(GUILE_MICRO_VERSION)
1151 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1152 AC_SUBST(GUILE_VERSION)
1153
1154 #######################################################################
1155 # library versioning
1156
1157 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1158 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1159 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1160 AC_SUBST(LIBGUILE_INTERFACE)
1161
1162 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1163 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1164 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1165 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1166 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1167
1168 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1169 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1170 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1171 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1172 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1173
1174 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1175 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1176 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1177 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1178 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1179
1180 AC_SUBST(LIBGUILE_SRFI_SRFI_60_MAJOR)
1181 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_CURRENT)
1182 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_REVISION)
1183 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_AGE)
1184 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE)
1185
1186 #######################################################################
1187
1188 dnl Tell guile-config what flags guile users should compile and link with.
1189 GUILE_LIBS="$LDFLAGS $LIBS"
1190 GUILE_CFLAGS="$PTHREAD_CFLAGS"
1191 AC_SUBST(GUILE_LIBS)
1192 AC_SUBST(GUILE_CFLAGS)
1193
1194 AC_SUBST(AWK)
1195 AC_SUBST(LIBLOBJS)
1196 AC_SUBST(EXTRA_DOT_DOC_FILES)
1197 AC_SUBST(EXTRA_DOT_X_FILES)
1198
1199 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1200 top_builddir_absolute=`pwd`
1201 AC_SUBST(top_builddir_absolute)
1202 top_srcdir_absolute=`(cd $srcdir && pwd)`
1203 AC_SUBST(top_srcdir_absolute)
1204
1205 # Additional SCM_I_GSC definitions are above.
1206 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1207 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1208 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1209 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1210 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1211 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1212 AC_SUBST([SCM_I_GSC_C_INLINE])
1213 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1214
1215 AC_CONFIG_FILES([
1216   Makefile
1217   am/Makefile
1218   benchmark-suite/Makefile
1219   doc/Makefile
1220   doc/goops/Makefile
1221   doc/r5rs/Makefile
1222   doc/ref/Makefile
1223   doc/tutorial/Makefile
1224   emacs/Makefile
1225   examples/Makefile
1226   examples/box-dynamic-module/Makefile
1227   examples/box-dynamic/Makefile
1228   examples/box-module/Makefile
1229   examples/box/Makefile
1230   examples/modules/Makefile
1231   examples/safe/Makefile
1232   examples/scripts/Makefile
1233   guile-config/Makefile
1234   ice-9/Makefile
1235   ice-9/debugger/Makefile
1236   ice-9/debugging/Makefile
1237   lang/Makefile
1238   lang/elisp/Makefile
1239   lang/elisp/internals/Makefile
1240   lang/elisp/primitives/Makefile
1241   libguile/Makefile
1242   oop/Makefile
1243   oop/goops/Makefile
1244   scripts/Makefile
1245   srfi/Makefile
1246   test-suite/Makefile
1247   test-suite/standalone/Makefile
1248 ])
1249
1250 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1251 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1252 AC_CONFIG_FILES([guile-tools], [chmod +x guile-tools])
1253 AC_CONFIG_FILES([pre-inst-guile], [chmod +x pre-inst-guile])
1254 AC_CONFIG_FILES([pre-inst-guile-env], [chmod +x pre-inst-guile-env])
1255 AC_CONFIG_FILES([libguile/guile-snarf],
1256                 [chmod +x libguile/guile-snarf])
1257 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1258                 [chmod +x libguile/guile-doc-snarf])
1259 AC_CONFIG_FILES([libguile/guile-func-name-check],
1260                 [chmod +x libguile/guile-func-name-check])
1261 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1262                 [chmod +x libguile/guile-snarf-docs])
1263
1264 AC_OUTPUT
1265
1266 dnl Local Variables:
1267 dnl comment-start: "dnl "
1268 dnl comment-end: ""
1269 dnl comment-start-skip: "\\bdnl\\b\\s *"
1270 dnl End: