test-suite/tests/foreign.test

   1 ;;;; foreign.test --- FFI.           -*- mode: scheme; coding: utf-8; -*-
   2 ;;;;
   3 ;;;;    Copyright (C) 2010, 2011, 2012, 2013 Free Software Foundation, Inc.
   4 ;;;;
   5 ;;;; This library is free software; you can redistribute it and/or
   6 ;;;; modify it under the terms of the GNU Lesser General Public
   7 ;;;; License as published by the Free Software Foundation; either
   8 ;;;; version 3 of the License, or (at your option) any later version.
   9 ;;;;
  10 ;;;; This library is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 ;;;; Lesser General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU Lesser General Public
  16 ;;;; License along with this library; if not, write to the Free Software
  17 ;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  18
  19 ;;;
  20 ;;; See also ../standalone/test-ffi for FFI tests.
  21 ;;;
  22
  23 (define-module (test-foreign)
  24   #:use-module (system foreign)
  25   #:use-module (rnrs bytevectors)
  26   #:use-module (srfi srfi-1)
  27   #:use-module (srfi srfi-26)
  28   #:use-module (ice-9 format)
  29   #:use-module (test-suite lib))
  30
  31 \f
  32 (with-test-prefix "dynamic-pointer"
  33
  34   (pass-if-exception
  35    "error message"
  36    '(misc-error . "^Symbol not found")
  37    (dynamic-func "does_not_exist___" (dynamic-link))))
  38
  39 \f
  40 (with-test-prefix "null pointer"
  41
  42   (pass-if "pointer?"
  43     (pointer? %null-pointer))
  44
  45   (pass-if "zero"
  46     (= 0 (pointer-address %null-pointer)))
  47
  48   (pass-if "null pointer identity"
  49     (eq? %null-pointer (make-pointer 0)))
  50
  51   (pass-if "null-pointer? %null-pointer"
  52     (null-pointer? %null-pointer))
  53
  54   (pass-if-exception "pointer->bytevector %null-pointer"
  55     exception:null-pointer-error
  56     (pointer->bytevector %null-pointer 7)))
  57
  58 \f
  59 (with-test-prefix "make-pointer"
  60
  61   (pass-if "pointer?"
  62     (pointer? (make-pointer 123)))
  63
  64   (pass-if "address preserved"
  65     (= 123 (pointer-address (make-pointer 123))))
  66
  67   (pass-if "equal?"
  68     (equal? (make-pointer 123) (make-pointer 123)))
  69
  70   (pass-if "equal? modulo finalizer"
  71     (let ((finalizer (dynamic-func "scm_is_pair" (dynamic-link))))
  72       (if (not finalizer)
  73           (throw 'unresolved)                     ; probably Windows
  74           (equal? (make-pointer 123)
  75                   (make-pointer 123 finalizer)))))
  76
  77   (pass-if "equal? modulo finalizer (set-pointer-finalizer!)"
  78     (let ((finalizer (dynamic-func "scm_is_pair" (dynamic-link)))
  79           (ptr       (make-pointer 123)))
  80       (if (not finalizer)
  81           (throw 'unresolved)                     ; probably Windows
  82           (begin
  83             (set-pointer-finalizer! ptr finalizer)
  84             (equal? (make-pointer 123) ptr)))))
  85
  86   (pass-if "not equal?"
  87     (not (equal? (make-pointer 123) (make-pointer 456)))))
  88
  89 \f
  90 (with-test-prefix "pointer<->scm"
  91
  92   (pass-if "immediates"
  93     (equal? (pointer->scm (scm->pointer #\newline))
  94             #\newline))
  95
  96   (pass-if "non-immediates"
  97     (equal? (pointer->scm (scm->pointer "Hello, world!"))
  98             "Hello, world!")))
  99
 100 \f
 101 (define-wrapped-pointer-type foo
 102   foo?
 103   wrap-foo unwrap-foo
 104   (lambda (x p)
 105     (format p "#<foo! ~a>" (pointer-address (unwrap-foo x)))))
 106
 107 (with-test-prefix "define-wrapped-pointer-type"
 108
 109   (pass-if "foo?"
 110     (foo? (wrap-foo %null-pointer)))
 111
 112   (pass-if "unwrap-foo"
 113     (let ((p (make-pointer 123)))
 114       (eq? p (unwrap-foo (wrap-foo p)))))
 115
 116   (pass-if "identity"
 117     (let ((p1 (make-pointer 123))
 118           (p2 (make-pointer 123)))
 119       (eq? (wrap-foo p1)
 120            (wrap-foo p2))))
 121
 122   (pass-if "printer"
 123     (string=? "#<foo! 123>"
 124               (with-output-to-string
 125                 (lambda ()
 126                   (write (wrap-foo (make-pointer 123))))))))
 127
 128 \f
 129 (with-test-prefix "pointer<->bytevector"
 130
 131   (pass-if "bijection"
 132     (let ((bv #vu8(0 1 2 3 4 5 6 7)))
 133       (equal? (pointer->bytevector (bytevector->pointer bv)
 134                                    (bytevector-length bv))
 135               bv)))
 136
 137   (pass-if "pointer from bits"
 138     (let* ((bytes (iota (sizeof '*)))
 139            (bv    (u8-list->bytevector bytes))
 140            (fold  (case (native-endianness)
 141                     ((little) fold-right)
 142                     ((big)    fold)
 143                     (else     (error "unsupported endianness")))))
 144       (= (pointer-address
 145           (make-pointer (bytevector-uint-ref bv 0 (native-endianness)
 146                                              (sizeof '*))))
 147          (fold (lambda (byte address)
 148                  (+ byte (* 256 address)))
 149                0
 150                bytes))))
 151
 152   (pass-if "dereference-pointer"
 153     (let* ((bytes (iota (sizeof '*)))
 154            (bv    (u8-list->bytevector bytes))
 155            (fold  (case (native-endianness)
 156                     ((little) fold-right)
 157                     ((big)    fold)
 158                     (else     (error "unsupported endianness")))))
 159       (= (pointer-address
 160           (dereference-pointer (bytevector->pointer bv)))
 161          (fold (lambda (byte address)
 162                  (+ byte (* 256 address)))
 163                0
 164                bytes)))))
 165
 166 \f
 167 (with-test-prefix "pointer<->string"
 168
 169   (pass-if-exception "%default-port-conversion-strategy is error"
 170     exception:encoding-error
 171     (let ((s "χαοσ"))
 172       (with-fluids ((%default-port-conversion-strategy 'error))
 173         (string->pointer s "ISO-8859-1"))))
 174
 175   (pass-if "%default-port-conversion-strategy is escape"
 176     (let ((s "teĥniko"))
 177       (equal? (with-fluids ((%default-port-conversion-strategy 'escape))
 178                 (pointer->string (string->pointer s "ISO-8859-1")))
 179               (format #f "te\\u~4,'0xniko"
 180                       (char->integer #\ĥ)))))
 181
 182   (pass-if "%default-port-conversion-strategy is substitute"
 183     (let ((s "teĥniko")
 184           (member (negate (negate member))))
 185       (member (with-fluids ((%default-port-conversion-strategy 'substitute))
 186                 (pointer->string (string->pointer s "ISO-8859-1")))
 187               '("te?niko"
 188
 189                 ;; This form is found on FreeBSD 8.2 and Darwin 10.8.0.
 190                 "te^hniko"))))
 191
 192   (pass-if "bijection"
 193     (let ((s "hello, world"))
 194       (string=? s (pointer->string (string->pointer s)))))
 195
 196   (pass-if "bijection [latin1]"
 197     (with-latin1-locale
 198       (let ((s "Szép jó napot!"))
 199         (string=? s (pointer->string (string->pointer s))))))
 200
 201   (pass-if "bijection, utf-8"
 202     (let ((s "hello, world"))
 203       (string=? s (pointer->string (string->pointer s "utf-8")
 204                                    -1 "utf-8"))))
 205
 206   (pass-if "bijection, utf-8 [latin1]"
 207     (let ((s "Szép jó napot!"))
 208       (string=? s (pointer->string (string->pointer s "utf-8")
 209                                    -1 "utf-8")))))
 210
 211
 212 \f
 213 (with-test-prefix "pointer->procedure"
 214
 215   (pass-if-exception "object instead of pointer"
 216     exception:wrong-type-arg
 217     (let ((p (pointer->procedure '* %null-pointer '(*))))
 218       (p #t))))
 219
 220 \f
 221 (with-test-prefix "procedure->pointer"
 222
 223   (define qsort
 224     ;; Bindings for libc's `qsort' function.
 225     (pointer->procedure void
 226                         (dynamic-func "qsort" (dynamic-link))
 227                         (list '* size_t size_t '*)))
 228
 229   (define (dereference-pointer-to-byte ptr)
 230     (let ((b (pointer->bytevector ptr 1)))
 231       (bytevector-u8-ref b 0)))
 232
 233   (define input
 234     '(7 1 127 3 5 4 77 2 9 0))
 235
 236   (pass-if "qsort"
 237     (if (defined? 'procedure->pointer)
 238         (let* ((called? #f)
 239                (cmp     (lambda (x y)
 240                           (set! called? #t)
 241                           (- (dereference-pointer-to-byte x)
 242                              (dereference-pointer-to-byte y))))
 243                (ptr     (procedure->pointer int cmp (list '* '*)))
 244                (bv      (u8-list->bytevector input)))
 245           (qsort (bytevector->pointer bv) (bytevector-length bv) 1
 246                  (procedure->pointer int cmp (list '* '*)))
 247           (and called?
 248                (equal? (bytevector->u8-list bv)
 249                        (sort input <))))
 250         (throw 'unresolved)))
 251
 252   (pass-if-exception "qsort, wrong return type"
 253     exception:wrong-type-arg
 254
 255     (if (defined? 'procedure->pointer)
 256         (let* ((cmp     (lambda (x y) #f)) ; wrong return type
 257                (ptr     (procedure->pointer int cmp (list '* '*)))
 258                (bv      (u8-list->bytevector input)))
 259           (qsort (bytevector->pointer bv) (bytevector-length bv) 1
 260                  (procedure->pointer int cmp (list '* '*)))
 261           #f)
 262         (throw 'unresolved)))
 263
 264   (pass-if-exception "qsort, wrong arity"
 265     exception:wrong-num-args
 266
 267     (if (defined? 'procedure->pointer)
 268         (let* ((cmp     (lambda (x y z) #f)) ; wrong arity
 269                (ptr     (procedure->pointer int cmp (list '* '*)))
 270                (bv      (u8-list->bytevector input)))
 271           (qsort (bytevector->pointer bv) (bytevector-length bv) 1
 272                  (procedure->pointer int cmp (list '* '*)))
 273           #f)
 274         (throw 'unresolved)))
 275
 276   (pass-if "bijection"
 277     (if (defined? 'procedure->pointer)
 278         (let* ((proc  (lambda (x y z)
 279                         (+ x y z 0.0)))
 280                (ret   double)
 281                (args  (list float int16 double))
 282                (proc* (pointer->procedure ret
 283                                           (procedure->pointer ret proc args)
 284                                           args))
 285                (arg1  (map (cut / <> 2.0) (iota 123)))
 286                (arg2  (iota 123 32000))
 287                (arg3  (map (cut / <> 4.0) (iota 123 100 4))))
 288           (equal? (map proc arg1 arg2 arg3)
 289                   (map proc* arg1 arg2 arg3)))
 290         (throw 'unresolved)))
 291
 292   (pass-if "procedures returning a pointer"
 293     (if (defined? 'procedure->pointer)
 294         (let* ((called? #f)
 295                (proc    (lambda (i) (set! called? #t) (make-pointer i)))
 296                (pointer (procedure->pointer '* proc (list int)))
 297                (proc*   (pointer->procedure '* pointer (list int)))
 298                (result  (proc* 777)))
 299           (and called? (equal? result (make-pointer 777))))
 300         (throw 'unresolved)))
 301
 302   (pass-if "procedures returning void"
 303     (if (defined? 'procedure->pointer)
 304         (let* ((called? #f)
 305                (proc    (lambda () (set! called? #t)))
 306                (pointer (procedure->pointer void proc '()))
 307                (proc*   (pointer->procedure void pointer '())))
 308           (proc*)
 309           called?)
 310         (throw 'unresolved)))
 311
 312   (pass-if "procedure is retained"
 313     ;; The lambda passed to `procedure->pointer' must remain live.
 314     (if (defined? 'procedure->pointer)
 315         (let* ((ptr   (procedure->pointer int
 316                                           (lambda (x) (+ x 7))
 317                                           (list int)))
 318                (procs (unfold (cut >= <> 10000)
 319                               (lambda (i)
 320                                 (pointer->procedure int ptr (list int)))
 321                               1+
 322                               0)))
 323           (gc) (gc) (gc)
 324           (every (cut = <> 9)
 325                  (map (lambda (f) (f 2)) procs)))
 326         (throw 'unresolved))))
 327
 328 \f
 329 (with-test-prefix "structs"
 330
 331   (pass-if "sizeof { int8, double }"
 332     (= (sizeof (list int8 double))
 333        (+ (alignof double) (sizeof double))))
 334
 335   (pass-if "sizeof { double, int8 }"
 336     (= (sizeof (list double int8))
 337        (+ (alignof double) (sizeof double))))
 338
 339   (pass-if "sizeof { short, int, long, pointer }"
 340     (let ((layout (list short int long '*)))
 341       (>= (sizeof layout)
 342           (reduce + 0.0 (map sizeof layout)))))
 343
 344   (pass-if "alignof { int8, double, int8 }"
 345     ;; alignment of the most strictly aligned component
 346     (let ((layout (list int8 double int8)))
 347       (= (alignof layout) (alignof double))))
 348
 349   (pass-if "parse-c-struct"
 350     (let ((layout (list int64 uint8))
 351           (data   (list -300 43)))
 352       (equal? (parse-c-struct (make-c-struct layout data)
 353                               layout)
 354               data)))
 355
 356   (pass-if "alignment constraints honored"
 357     (let ((layout (list int8 double))
 358           (data   (list -7 3.14)))
 359       (equal? (parse-c-struct (make-c-struct layout data)
 360                               layout)
 361               data)))
 362
 363   (pass-if "int8, pointer"
 364     (let ((layout (list uint8 '*))
 365           (data   (list 222 (make-pointer 7777))))
 366       (equal? (parse-c-struct (make-c-struct layout data)
 367                               layout)
 368               data)))
 369
 370   (pass-if "unsigned-long, int8, size_t"
 371     (let ((layout (list unsigned-long int8 size_t))
 372           (data   (list (expt 2 17) -128 (expt 2 18))))
 373       (equal? (parse-c-struct (make-c-struct layout data)
 374                               layout)
 375               data)))
 376
 377   (pass-if "long, int, pointer"
 378     (let ((layout (list long int '*))
 379           (data   (list (- (expt 2 17)) -222 (make-pointer 777))))
 380       (equal? (parse-c-struct (make-c-struct layout data)
 381                               layout)
 382               data)))
 383
 384   (pass-if "int8, pointer, short, double"
 385     (let ((layout (list int8 '* short double))
 386           (data   (list 77 %null-pointer -42 3.14)))
 387       (equal? (parse-c-struct (make-c-struct layout data)
 388                               layout)
 389               data)))
 390
 391   (pass-if "int8, { int8, double, int8 }, int16"
 392     (let ((layout (list int8 (list int8 double int8) int16))
 393           (data   (list 77 (list 42 4.2 55) 88)))
 394       (equal? (parse-c-struct (make-c-struct layout data)
 395                               layout)
 396               data))))