configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it
  12 under the terms of the GNU General Public License as published by
  13 the Free Software Foundation; either version 2, or (at your
  14 option) any later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but
  17 WITHOUT ANY WARRANTY; without even the implied warranty of
  18 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 General Public License for more details.
  20
  21 You should have received a copy of the GNU General Public License
  22 along with GUILE; see the file COPYING.  If not, write to the
  23 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 Boston, MA 02110-1301, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.53)
  29
  30 AC_INIT(m4_esyscmd(. ./GUILE-VERSION && echo -n ${PACKAGE}),
  31         m4_esyscmd(. ./GUILE-VERSION && echo -n ${GUILE_VERSION}))
  32 AC_CONFIG_SRCDIR(GUILE-VERSION)
  33 AM_INIT_AUTOMAKE([no-define])
  34
  35 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  36 AC_CONFIG_SRCDIR([GUILE-VERSION])
  37
  38 . $srcdir/GUILE-VERSION
  39
  40 AM_MAINTAINER_MODE
  41 AM_CONFIG_HEADER([config.h])
  42 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  43
  44 #--------------------------------------------------------------------
  45 #
  46 # Independent Subdirectories
  47 #
  48 #--------------------------------------------------------------------
  49
  50 AC_CONFIG_SUBDIRS(guile-readline)
  51
  52 #--------------------------------------------------------------------
  53
  54 dnl Some more checks for Win32
  55 AC_CYGWIN
  56 AC_MINGW32
  57 AC_LIBTOOL_WIN32_DLL
  58
  59 AC_PROG_INSTALL
  60 AC_PROG_CC
  61 AC_PROG_CPP
  62 AC_PROG_AWK
  63
  64 AC_AIX
  65 AC_ISC_POSIX
  66 AC_MINIX
  67
  68 AM_PROG_CC_STDC
  69
  70 AC_LIBTOOL_DLOPEN
  71 AC_PROG_LIBTOOL
  72 AC_CHECK_LIB([ltdl], [lt_dlinit], ,
  73   [AC_MSG_ERROR([libltdl not found.  See README.])])
  74
  75 AC_SUBST(DLPREOPEN)
  76
  77 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  78 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  79
  80 AM_PATH_LISPDIR
  81
  82 #--------------------------------------------------------------------
  83 #
  84 # User options (after above tests that may set default CFLAGS etc.)
  85 #
  86 #--------------------------------------------------------------------
  87
  88 GUILE_ERROR_ON_WARNING="yes"
  89
  90 AC_ARG_ENABLE(error-on-warning,
  91   [  --enable-error-on-warning    treat compile warnings as errors],
  92   [case "${enableval}" in
  93      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
  94      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
  95      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  96    esac])
  97
  98 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
  99 AC_ARG_ENABLE(debug-freelist,
 100   [  --enable-debug-freelist include garbage collector freelist debugging code],
 101   if test "$enable_debug_freelist" = y \
 102      || test "$enable_debug_freelist" = yes; then
 103     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
 104   fi)
 105
 106 AC_ARG_ENABLE(debug-malloc,
 107   [  --enable-debug-malloc   include malloc debugging code],
 108   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 109     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 110       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 111   fi)
 112
 113 SCM_I_GSC_GUILE_DEBUG=0
 114 AC_ARG_ENABLE(guile-debug,
 115   [AC_HELP_STRING([--enable-guile-debug],
 116                   [include internal debugging functions])],
 117   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 118     SCM_I_GSC_GUILE_DEBUG=1
 119   fi)
 120
 121 AC_ARG_ENABLE(arrays,
 122   [AC_HELP_STRING([--disable-arrays],[omit array and uniform array support])],
 123   ,
 124   enable_arrays=yes)
 125
 126 AC_ARG_ENABLE(posix,
 127   [  --disable-posix         omit posix interfaces],,
 128   enable_posix=yes)
 129
 130 AC_ARG_ENABLE(networking,
 131   [  --disable-networking    omit networking interfaces],,
 132   enable_networking=yes)
 133
 134 AC_ARG_ENABLE(regex,
 135   [  --disable-regex         omit regular expression interfaces],,
 136   enable_regex=yes)
 137
 138 AC_ARG_ENABLE([discouraged],
 139   AC_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 140
 141 if test "$enable_discouraged" = no; then
 142   SCM_I_GSC_ENABLE_DISCOURAGED=0
 143 else
 144   SCM_I_GSC_ENABLE_DISCOURAGED=1
 145 fi
 146
 147 AC_ARG_ENABLE([deprecated],
 148   AC_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 149
 150 if test "$enable_deprecated" = no; then
 151   SCM_I_GSC_ENABLE_DEPRECATED=0
 152 else
 153   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 154     warn_default=summary
 155   elif test "$enable_deprecated" = shutup; then
 156     warn_default=no
 157   else
 158     warn_default=$enable_deprecated
 159   fi
 160   SCM_I_GSC_ENABLE_DEPRECATED=1
 161   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 162   [Define this to control the default warning level for deprecated features.])
 163 fi
 164
 165 AC_ARG_ENABLE(elisp,
 166   [  --disable-elisp         omit Emacs Lisp support],,
 167   enable_elisp=yes)
 168
 169 #--------------------------------------------------------------------
 170
 171 dnl Check for dynamic linking
 172
 173 use_modules=yes
 174 AC_ARG_WITH(modules,
 175 [  --with-modules[=FILES]  Add support for dynamic modules],
 176 use_modules="$withval")
 177 test -z "$use_modules" && use_modules=yes
 178 DLPREOPEN=
 179 if test "$use_modules" != no; then
 180   if test "$use_modules" = yes; then
 181     DLPREOPEN="-dlpreopen force"
 182   else
 183     DLPREOPEN="-export-dynamic"
 184     for module in $use_modules; do
 185       DLPREOPEN="$DLPREOPEN -dlopen $module"
 186     done
 187   fi
 188 fi
 189
 190 dnl files which are destined for separate modules.
 191
 192 if test "$use_modules" != no; then
 193    AC_LIBOBJ([dynl])
 194 fi
 195
 196 if test "$enable_posix" = yes; then
 197    AC_LIBOBJ([filesys])
 198    AC_LIBOBJ([posix])
 199    AC_DEFINE(HAVE_POSIX, 1,
 200      [Define this if you want support for POSIX system calls in Guile.])
 201 fi
 202
 203 if test "$enable_networking" = yes; then
 204    AC_LIBOBJ([net_db])
 205    AC_LIBOBJ([socket])
 206    AC_DEFINE(HAVE_NETWORKING, 1,
 207      [Define this if you want support for networking in Guile.])
 208 fi
 209
 210 if test "$enable_debug_malloc" = yes; then
 211    AC_LIBOBJ([debug-malloc])
 212 fi
 213
 214 if test "$enable_elisp" = yes; then
 215   SCM_I_GSC_ENABLE_ELISP=1
 216 else
 217   SCM_I_GSC_ENABLE_ELISP=0
 218 fi
 219
 220 AC_C_CONST
 221
 222 AC_C_INLINE
 223 if test "$ac_cv_c_inline" != no; then
 224   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 225 else
 226   SCM_I_GSC_C_INLINE=NULL
 227 fi
 228
 229 AC_C_BIGENDIAN
 230
 231 AC_CHECK_SIZEOF(char)
 232 AC_CHECK_SIZEOF(unsigned char)
 233 AC_CHECK_SIZEOF(short)
 234 AC_CHECK_SIZEOF(unsigned short)
 235 AC_CHECK_SIZEOF(int)
 236 AC_CHECK_SIZEOF(unsigned int)
 237 AC_CHECK_SIZEOF(long)
 238 AC_CHECK_SIZEOF(unsigned long)
 239 AC_CHECK_SIZEOF(size_t)
 240 AC_CHECK_SIZEOF(long long)
 241 AC_CHECK_SIZEOF(unsigned long long)
 242 AC_CHECK_SIZEOF(__int64)
 243 AC_CHECK_SIZEOF(unsigned __int64)
 244 AC_CHECK_SIZEOF(void *)
 245 AC_CHECK_SIZEOF(intptr_t)
 246 AC_CHECK_SIZEOF(uintptr_t)
 247 AC_CHECK_SIZEOF(ptrdiff_t)
 248 AC_CHECK_SIZEOF(size_t)
 249
 250 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 251   AC_MSG_ERROR(sizes of long and void* are not identical)
 252 fi
 253
 254 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 255   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 256 else
 257   SCM_I_GSC_T_PTRDIFF='"long"'
 258 fi
 259 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 260
 261 AC_CHECK_HEADERS([stdint.h])
 262 AC_CHECK_HEADERS([inttypes.h])
 263
 264 AC_CHECK_SIZEOF(intmax_t)
 265
 266 SCM_I_GSC_NEEDS_STDINT_H=0
 267 SCM_I_GSC_NEEDS_INTTYPES_H=0
 268
 269 ### intptr and uintptr (try not to use inttypes if we don't have to)
 270 if test "$ac_cv_header_inttypes_h" = yes; then
 271   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 272     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 273 #include <stdio.h>])
 274     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 275       SCM_I_GSC_NEEDS_INTTYPES_H=1
 276     fi
 277   fi
 278   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 279     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 280 #include <stdio.h>])
 281     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 282       SCM_I_GSC_NEEDS_INTTYPES_H=1
 283     fi
 284   fi
 285 fi
 286
 287 ### See what's provided by stdint.h
 288 if test "$ac_cv_header_stdint_h" = yes; then
 289    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 290    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 291    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 292    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 293    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 294    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 295    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 296    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 297    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 298    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 299 fi
 300
 301 # so we don't get confused by the cache (wish there was a better way
 302 # to check particular headers for the same type...)
 303
 304 unset ac_cv_type_int8_t
 305 unset ac_cv_type_uint8_t
 306 unset ac_cv_type_int16_t
 307 unset ac_cv_type_uint16_t
 308 unset ac_cv_type_int32_t
 309 unset ac_cv_type_uint32_t
 310 unset ac_cv_type_int64_t
 311 unset ac_cv_type_uint64_t
 312 unset ac_cv_type_intmax_t
 313 unset ac_cv_type_uintmax_t
 314
 315 ### See what's provided by inttypes.h
 316 if test "$ac_cv_header_inttypes_h" = yes; then
 317   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 318   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 319   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 320   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 321   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 322   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 323   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 324   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 325   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 326   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 327 fi
 328
 329 # Try hard to find definitions for some required scm_t_*int* types.
 330
 331 ### Required type scm_t_int8
 332 if test "$scm_stdint_has_int8"; then
 333   SCM_I_GSC_T_INT8='"int8_t"'
 334   SCM_I_GSC_NEEDS_STDINT_H=1
 335 elif test "$scm_inttypes_has_int8"; then
 336   SCM_I_GSC_T_INT8='"int8_t"'
 337   SCM_I_GSC_NEEDS_INTTYPES_H=1
 338 elif test "$ac_cv_sizeof_char" -eq 1; then
 339   SCM_I_GSC_T_INT8='"signed char"'
 340 else
 341   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 342 fi
 343 AC_SUBST([SCM_I_GSC_T_INT8])
 344
 345 ### Required type scm_t_uint8
 346 if test "$scm_stdint_has_uint8"; then
 347   SCM_I_GSC_T_UINT8='"uint8_t"'
 348   SCM_I_GSC_NEEDS_STDINT_H=1
 349 elif test "$scm_inttypes_has_uint8"; then
 350   SCM_I_GSC_T_UINT8='"uint8_t"'
 351   SCM_I_GSC_NEEDS_INTTYPES_H=1
 352 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 353   SCM_I_GSC_T_UINT8='"unsigned char"'
 354 else
 355   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 356 fi
 357 AC_SUBST([SCM_I_GSC_T_UINT8])
 358
 359 ### Required type scm_t_int16 (ANSI C says int or short might work)
 360 if test "$scm_stdint_has_int16"; then
 361   SCM_I_GSC_T_INT16='"int16_t"'
 362   SCM_I_GSC_NEEDS_STDINT_H=1
 363 elif test "$scm_inttypes_has_int16"; then
 364   SCM_I_GSC_T_INT16='"int16_t"'
 365   SCM_I_GSC_NEEDS_INTTYPES_H=1
 366 elif test "$ac_cv_sizeof_int" -eq 2; then
 367   SCM_I_GSC_T_INT16='"int"'
 368 elif test "$ac_cv_sizeof_short" -eq 2; then
 369   SCM_I_GSC_T_INT16='"short"'
 370 else
 371   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 372 fi
 373 AC_SUBST([SCM_I_GSC_T_INT16])
 374
 375 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 376 if test "$scm_stdint_has_uint16"; then
 377   SCM_I_GSC_T_UINT16='"uint16_t"'
 378   SCM_I_GSC_NEEDS_STDINT_H=1
 379 elif test "$scm_inttypes_has_uint16"; then
 380   SCM_I_GSC_T_UINT16='"uint16_t"'
 381   SCM_I_GSC_NEEDS_INTTYPES_H=1
 382 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 383   SCM_I_GSC_T_UINT16='"unsigned int"'
 384 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 385   SCM_I_GSC_T_UINT16='"unsigned short"'
 386 else
 387   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 388 fi
 389 AC_SUBST([SCM_I_GSC_T_UINT16])
 390
 391
 392 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 393 if test "$scm_stdint_has_int32"; then
 394   SCM_I_GSC_T_INT32='"int32_t"'
 395   SCM_I_GSC_NEEDS_STDINT_H=1
 396 elif test "$scm_inttypes_has_int32"; then
 397   SCM_I_GSC_T_INT32='"int32_t"'
 398   SCM_I_GSC_NEEDS_INTTYPES_H=1
 399 elif test "$ac_cv_sizeof_int" -eq 4; then
 400   SCM_I_GSC_T_INT32='"int"'
 401 elif test "$ac_cv_sizeof_long" -eq 4; then
 402   SCM_I_GSC_T_INT32='"long"'
 403 elif test "$ac_cv_sizeof_short" -eq 4; then
 404   SCM_I_GSC_T_INT32='"short"'
 405 else
 406   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 407 fi
 408 AC_SUBST([SCM_I_GSC_T_INT32])
 409
 410 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 411 if test "$scm_stdint_has_uint32"; then
 412   SCM_I_GSC_T_UINT32='"uint32_t"'
 413   SCM_I_GSC_NEEDS_STDINT_H=1
 414 elif test "$scm_inttypes_has_uint32"; then
 415   SCM_I_GSC_T_UINT32='"uint32_t"'
 416   SCM_I_GSC_NEEDS_INTTYPES_H=1
 417 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 418   SCM_I_GSC_T_UINT32='"unsigned int"'
 419 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 420   SCM_I_GSC_T_UINT32='"unsigned long"'
 421 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 422   SCM_I_GSC_T_UINT32='"unsigned short"'
 423 else
 424   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 425 fi
 426 AC_SUBST([SCM_I_GSC_T_UINT32])
 427
 428 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 429 ### Also try 'long long' and '__int64' if we have it.
 430 SCM_I_GSC_T_INT64=0
 431 if test "$scm_stdint_has_int64"; then
 432   SCM_I_GSC_T_INT64='"int64_t"'
 433   SCM_I_GSC_NEEDS_STDINT_H=1
 434 elif test "$scm_inttypes_has_int64"; then
 435   SCM_I_GSC_T_INT64='"int64_t"'
 436   SCM_I_GSC_NEEDS_INTTYPES_H=1
 437 elif test "$ac_cv_sizeof_int" -eq 8; then
 438   SCM_I_GSC_T_INT64='"int"'
 439 elif test "$ac_cv_sizeof_long" -eq 8; then
 440   SCM_I_GSC_T_INT64='"long"'
 441 elif test "$ac_cv_sizeof_short" -eq 8; then
 442   SCM_I_GSC_T_INT64='"short"'
 443 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 444   SCM_I_GSC_T_INT64='"long long"'
 445 elif test "$ac_cv_sizeof___int64" -eq 8; then
 446   SCM_I_GSC_T_INT64='"__int64"'
 447 else
 448   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 449 fi
 450 AC_SUBST([SCM_I_GSC_T_INT64])
 451
 452
 453 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 454 ### Also try 'long long' and '__int64' if we have it.
 455 SCM_I_GSC_T_UINT64=0
 456 if test "$scm_stdint_has_uint64"; then
 457   SCM_I_GSC_T_UINT64='"uint64_t"'
 458   SCM_I_GSC_NEEDS_STDINT_H=1
 459 elif test "$scm_inttypes_has_uint64"; then
 460   SCM_I_GSC_T_UINT64='"uint64_t"'
 461   SCM_I_GSC_NEEDS_INTTYPES_H=1
 462 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 463   SCM_I_GSC_T_UINT64='"unsigned int"'
 464 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 465   SCM_I_GSC_T_UINT64='"unsigned long"'
 466 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 467   SCM_I_GSC_T_UINT64='"unsigned short"'
 468 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 469   SCM_I_GSC_T_UINT64='"unsigned long long"'
 470 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 471   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 472 else
 473   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 474 fi
 475 AC_SUBST([SCM_I_GSC_T_UINT64])
 476
 477 ### Required type scm_t_intmax
 478 ###
 479 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 480 ### none of them is available, we use 'long'.
 481 ###
 482 SCM_I_GSC_T_INTMAX=0
 483 if test "$scm_stdint_has_intmax"; then
 484   SCM_I_GSC_T_INTMAX='"intmax_t"'
 485   SCM_I_GSC_NEEDS_STDINT_H=1
 486 elif test "$scm_inttypes_has_intmax"; then
 487   SCM_I_GSC_T_INTMAX='"intmax_t"'
 488   SCM_I_GSC_NEEDS_INTTYPES_H=1
 489 elif test "$ac_cv_sizeof___int64" -ne 0; then
 490   SCM_I_GSC_T_INTMAX='"__int64"'
 491 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 492   SCM_I_GSC_T_INTMAX='"long long"'
 493 else
 494   SCM_I_GSC_T_INTMAX='"long"'
 495 fi
 496 AC_SUBST([SCM_I_GSC_T_INTMAX])
 497
 498 ### Required type scm_t_uintmax
 499 ###
 500 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 501 ### this order.  When none of them is available, we use 'unsigned long'.
 502 ###
 503 SCM_I_GSC_T_UINTMAX=0
 504 if test "$scm_stdint_has_uintmax"; then
 505   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 506   SCM_I_GSC_NEEDS_STDINT_H=1
 507 elif test "$scm_inttypes_has_uintmax"; then
 508   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 509   SCM_I_GSC_NEEDS_INTTYPES_H=1
 510 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 511   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 512 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 513   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 514 else
 515   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 516 fi
 517 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 518
 519
 520 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 521 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 522
 523 AC_CHECK_TYPE(socklen_t, int)
 524 AC_CHECK_TYPE(struct ip_mreq)
 525
 526 AC_HEADER_STDC
 527 AC_HEADER_DIRENT
 528 AC_HEADER_TIME
 529 AC_HEADER_SYS_WAIT
 530
 531 # Reasons for testing:
 532 #   fenv.h - available in C99, but not older systems
 533 #
 534 AC_CHECK_HEADERS([fenv.h io.h libc.h limits.h malloc.h memory.h string.h \
 535 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 536 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 537 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 538 direct.h])
 539
 540 GUILE_HEADER_LIBC_WITH_UNISTD
 541
 542 AC_TYPE_GETGROUPS
 543 AC_TYPE_SIGNAL
 544 AC_TYPE_MODE_T
 545
 546 if test $MINGW32 = no; then
 547         AC_CHECK_LIB(m, main)
 548 fi
 549 AC_CHECK_FUNCS(gethostbyname)
 550 if test $ac_cv_func_gethostbyname = no; then
 551     AC_CHECK_LIB(nsl, gethostbyname)
 552 fi
 553
 554 AC_CHECK_FUNCS(connect)
 555 if test $ac_cv_func_connect = no; then
 556     AC_CHECK_LIB(socket, connect)
 557 fi
 558
 559 dnl
 560 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 561 dnl
 562 EXTRA_DEFS=""
 563 if test "$MINGW32" = "yes" ; then
 564     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 565       [Define if you have the <winsock2.h> header file.])])
 566     AC_CHECK_LIB(ws2_32, main)
 567     AC_LIBOBJ([win32-uname])
 568     AC_LIBOBJ([win32-dirent])
 569     if test "$enable_networking" = yes ; then
 570       AC_LIBOBJ([win32-socket])
 571     fi
 572     if test "$enable_shared" = yes ; then
 573       EXTRA_DEFS="-DSCM_IMPORT"
 574       AC_DEFINE(USE_DLL_IMPORT, 1,
 575         [Define if you need additional CPP macros on Win32 platforms.])
 576     fi
 577 fi
 578 AC_SUBST(EXTRA_DEFS)
 579
 580 # Reasons for testing:
 581 #   crt_externs.h - Darwin specific
 582 #
 583 AC_CHECK_HEADERS([assert.h crt_externs.h])
 584
 585 # Reasons for testing:
 586 #   DINFINITY - OSF specific
 587 #   DQNAN - OSF specific
 588 #       (DINFINITY and DQNAN are actually global variables, not functions)
 589 #   fesetround - available in C99, but not older systems
 590 #   gmtime_r - recent posix, not on old systems
 591 #   readdir_r - recent posix, not on old systems
 592 #   sysconf - not on old systems
 593 #   _NSGetEnviron - Darwin specific
 594 #
 595 AC_CHECK_FUNCS([DINFINITY DQNAN ctermid fesetround ftime fchown getcwd geteuid gettimeofday gmtime_r lstat mkdir mknod nice readdir_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex unsetenv _NSGetEnviron])
 596
 597 # Reasons for testing:
 598 #   netdb.h - not in mingw
 599 #   sys/param.h - not in mingw
 600 #
 601 AC_CHECK_HEADERS(crypt.h netdb.h sys/param.h sys/resource.h sys/file.h)
 602 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 603
 604 # crypt() may or may not be available, for instance in some countries there
 605 # are restrictions on cryptography.
 606 #
 607 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 608 # -lcrypt library (eg. Debian GNU/Linux).
 609 #
 610 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 611 # be careful to avoid -lcrypt in this case, since libtool will see there's
 612 # only a static libcrypt and decide to build only a static libguile.
 613 #
 614 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 615 # libraries already in that list.
 616 #
 617 AC_SEARCH_LIBS(crypt, crypt,
 618   [AC_DEFINE(HAVE_CRYPT,1,
 619              [Define to 1 if you have the `crypt' function.])])
 620
 621 dnl GMP tests
 622 AC_CHECK_LIB([gmp], [__gmpz_init], ,
 623   [AC_MSG_ERROR([GNU MP not found, see README])])
 624
 625 # mpz_import is a macro so we need to include <gmp.h>
 626 AC_TRY_LINK([#include <gmp.h>],
 627             [mpz_import (0, 0, 0, 0, 0, 0, 0);] , ,
 628   [AC_MSG_ERROR([At least GNU MP 4.1 is required, see README])])
 629
 630 dnl i18n tests
 631 #AC_CHECK_HEADERS([libintl.h])
 632 #AC_CHECK_FUNCS(gettext)
 633 #if test $ac_cv_func_gettext = no; then
 634 #   AC_CHECK_LIB(intl, gettext)
 635 #fi
 636 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 637 AM_GNU_GETTEXT([external], [need-ngettext])
 638
 639 ### Some systems don't declare some functions.  On such systems, we
 640 ### need to at least provide our own K&R-style declarations.
 641
 642 ### GUILE_FUNC_DECLARED(function, headerfile)
 643
 644 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 645 ### not there, #define MISSING_FUNCTION_DECL.
 646 AC_DEFUN([GUILE_FUNC_DECLARED], [
 647   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 648     AC_EGREP_HEADER($1, $2,
 649                     guile_cv_func_$1_declared=yes,
 650                     guile_cv_func_$1_declared=no))
 651   if test [x$guile_cv_func_]$1[_declared] = xno; then
 652     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 653       [Define if the operating system supplies $1 without declaring it.])
 654   fi
 655 ])
 656
 657 GUILE_FUNC_DECLARED(sleep, unistd.h)
 658 GUILE_FUNC_DECLARED(usleep, unistd.h)
 659
 660 AC_CHECK_DECLS([strptime],,,
 661 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 662 #include <time.h>])
 663
 664 ### On some systems usleep has no return value.  If it does have one,
 665 ### we'd like to return it; otherwise, we'll fake it.
 666 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 667   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 668                    unistd.h,
 669                    [guile_cv_func_usleep_return_type=void],
 670                    [guile_cv_func_usleep_return_type=int])])
 671 case "$guile_cv_func_usleep_return_type" in
 672   "void" )
 673     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 674       [Define if the system headers declare usleep to return void.])
 675   ;;
 676 esac
 677
 678 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 679 if test -n "$have_sys_un_h" ; then
 680   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 681     [Define if the system supports Unix-domain (file-domain) sockets.])
 682 fi
 683
 684 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 685
 686 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 687                setnetent    getnetent    endnetent    dnl
 688                setprotoent  getprotoent  endprotoent  dnl
 689                setservent   getservent   endservent   dnl
 690                getnetbyaddr getnetbyname dnl
 691                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 692                inet_pton inet_ntop)
 693
 694 # struct sockaddr field sin_len is only present on BSD systems.
 695 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 696 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 697 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 698 [#ifdef HAVE_SYS_TYPES_H
 699 #include <sys/types.h>
 700 #endif
 701 #include <netinet/in.h>])
 702
 703 AC_MSG_CHECKING(for __libc_stack_end)
 704 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 705 [AC_TRY_LINK([#include <stdio.h>
 706 extern char *__libc_stack_end;],
 707              [printf("%p", (char*) __libc_stack_end);],
 708              guile_cv_have_libc_stack_end=yes,
 709              guile_cv_have_libc_stack_end=no)])
 710 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 711
 712 if test $guile_cv_have_libc_stack_end = yes; then
 713   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 714            [Define if you have the __libc_stack_end variable.])
 715 fi
 716
 717 dnl Some systems do not declare this.  Some systems do declare it, as a
 718 dnl macro.  With cygwin it may be in a DLL.
 719
 720 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 721 AC_CACHE_VAL(guile_cv_have_h_errno,
 722 [AC_TRY_COMPILE([#include <netdb.h>],
 723 [int a = h_errno;],
 724 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 725 AC_MSG_RESULT($guile_cv_have_h_errno)
 726 if test $guile_cv_have_h_errno = yes; then
 727   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 728 fi
 729
 730 AC_MSG_CHECKING(whether uint32_t is defined)
 731 AC_CACHE_VAL(guile_cv_have_uint32_t,
 732   [AC_TRY_COMPILE([#include <sys/types.h>
 733                    #if HAVE_STDINT_H
 734                    #include <stdint.h>
 735                    #endif
 736                    #ifndef __MINGW32__
 737                    #include <netdb.h>
 738                    #endif],
 739                   [uint32_t a;],
 740                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 741 AC_MSG_RESULT($guile_cv_have_uint32_t)
 742 if test $guile_cv_have_uint32_t = yes; then
 743   AC_DEFINE(HAVE_UINT32_T, 1,
 744     [Define if uint32_t typedef is defined when netdb.h is include.])
 745 fi
 746
 747 AC_MSG_CHECKING(for working IPv6 support)
 748 AC_CACHE_VAL(guile_cv_have_ipv6,
 749 [AC_TRY_COMPILE([
 750 #ifdef HAVE_SYS_TYPES_H
 751 #include <sys/types.h>
 752 #endif
 753 #include <netinet/in.h>
 754 #include <sys/socket.h>],
 755 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 756 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 757 AC_MSG_RESULT($guile_cv_have_ipv6)
 758 if test $guile_cv_have_ipv6 = yes; then
 759   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 760 fi
 761
 762 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 763 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 764 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 765 [AC_TRY_COMPILE([
 766 #ifdef HAVE_SYS_TYPES_H
 767 #include <sys/types.h>
 768 #endif
 769 #include <netinet/in.h>],
 770 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 771 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 772 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 773 if test $guile_cv_have_sin6_scope_id = yes; then
 774   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 775     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 776 fi
 777
 778 # struct sockaddr_in6 field sin_len is only present on BSD systems
 779 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
 780 [#ifdef HAVE_SYS_TYPES_H
 781 #include <sys/types.h>
 782 #endif
 783 #include <netinet/in.h>])
 784
 785 AC_MSG_CHECKING(whether localtime caches TZ)
 786 AC_CACHE_VAL(guile_cv_localtime_cache,
 787 [if test x$ac_cv_func_tzset = xyes; then
 788 AC_TRY_RUN([#include <time.h>
 789 #if STDC_HEADERS
 790 # include <stdlib.h>
 791 #endif
 792 extern char **environ;
 793 unset_TZ ()
 794 {
 795   char **from, **to;
 796   for (to = from = environ; (*to = *from); from++)
 797     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 798       to++;
 799 }
 800 char TZ_GMT0[] = "TZ=GMT0";
 801 char TZ_PST8[] = "TZ=PST8";
 802 main()
 803 {
 804   time_t now = time ((time_t *) 0);
 805   int hour_GMT0, hour_unset;
 806   if (putenv (TZ_GMT0) != 0)
 807     exit (1);
 808   hour_GMT0 = localtime (&now)->tm_hour;
 809   unset_TZ ();
 810   hour_unset = localtime (&now)->tm_hour;
 811   if (putenv (TZ_PST8) != 0)
 812     exit (1);
 813   if (localtime (&now)->tm_hour == hour_GMT0)
 814     exit (1);
 815   unset_TZ ();
 816   if (localtime (&now)->tm_hour != hour_unset)
 817     exit (1);
 818   exit (0);
 819 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 820 [# If we have tzset, assume the worst when cross-compiling.
 821 guile_cv_localtime_cache=yes])
 822 else
 823         # If we lack tzset, report that localtime does not cache TZ,
 824         # since we can't invalidate the cache if we don't have tzset.
 825         guile_cv_localtime_cache=no
 826 fi])dnl
 827 AC_MSG_RESULT($guile_cv_localtime_cache)
 828 if test $guile_cv_localtime_cache = yes; then
 829   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
 830 fi
 831
 832 dnl Test whether system calls are restartable by default on the
 833 dnl current system.  If they are not, we put a loop around every system
 834 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 835 dnl change from the default behaviour.  On the other hand, if signals
 836 dnl are restartable then the loop is not installed and when libguile
 837 dnl initialises it also resets the behaviour of each signal to cause a
 838 dnl restart (in case a different runtime had a different default
 839 dnl behaviour for some reason: e.g., different versions of linux seem
 840 dnl to behave differently.)
 841
 842 AC_SYS_RESTARTABLE_SYSCALLS
 843
 844 if test "$enable_regex" = yes; then
 845    if test "$ac_cv_header_regex_h" = yes ||
 846       test "$ac_cv_header_rxposix_h" = yes ||
 847       test "$ac_cv_header_rx_rxposix_h" = yes; then
 848      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
 849      [AC_CHECK_LIB(rx, main)
 850       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
 851      [AC_CHECK_LIB(regex, main)
 852       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
 853      )
 854      dnl The following should not be necessary, but for some reason
 855      dnl autoheader misses it if we don't include it!
 856      if test "$ac_cv_func_regcomp_norx" = yes ||
 857         test "$ac_cv_func_regcomp_regex" = yes ||
 858         test "$ac_cv_func_regcomp_rx" = yes; then
 859        AC_DEFINE(HAVE_REGCOMP, 1,
 860          [This is included as part of a workaround for a autoheader bug.])
 861      fi
 862    fi
 863 fi
 864
 865 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 866
 867 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
 868
 869 # Reasons for testing:
 870 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
 871 #                                older systems
 872 #   sincos - GLIBC extension
 873 #
 874 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
 875
 876 # C99 specifies isinf and isnan as macros.
 877 # HP-UX provides only macros, no functions.
 878 # glibc 2.3.2 provides both macros and functions.
 879 # IRIX 6.5 and Solaris 8 only provide functions.
 880 #
 881 # The following tests detect isinf and isnan either as functions or as
 882 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
 883 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
 884 #
 885 AC_MSG_CHECKING([for isinf])
 886 AC_LINK_IFELSE(
 887 [#include <math.h>
 888 int main () { return (isinf(0.0) != 0); }],
 889   [AC_MSG_RESULT([yes])
 890    AC_DEFINE(HAVE_ISINF, 1,
 891              [Define to 1 if you have the `isinf' macro or function.])],
 892   [AC_MSG_RESULT([no])])
 893 AC_MSG_CHECKING([for isnan])
 894 AC_LINK_IFELSE(
 895 [#include <math.h>
 896 #ifdef __MINGW32__
 897 #define isnan _isnan
 898 #endif
 899 int main () { return (isnan(0.0) != 0); }],
 900   [AC_MSG_RESULT([yes])
 901    AC_DEFINE(HAVE_ISNAN, 1,
 902              [Define to 1 if you have the `isnan' macro or function.])],
 903   [AC_MSG_RESULT([no])])
 904
 905 # We must have a proper stack-using alloca in order for stack-copying
 906 # continuations to work properly.  If we don't find a native one,
 907 # abort.
 908
 909 AC_FUNC_ALLOCA
 910 if test "$ALLOCA" = "alloca.o"
 911 then
 912   AC_ERROR([No native alloca found.])
 913 fi
 914
 915 AC_CHECK_MEMBERS([struct stat.st_rdev])
 916 AC_CHECK_MEMBERS([struct stat.st_blksize])
 917
 918 AC_STRUCT_ST_BLOCKS
 919
 920 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 921   [AC_TRY_CPP([#include <sys/stat.h>
 922                #ifndef S_ISLNK
 923                #error no S_ISLNK
 924                #endif],
 925                ac_cv_macro_S_ISLNK=yes,
 926                ac_cv_macro_S_ISLNK=no)])
 927 if test $ac_cv_macro_S_ISLNK = yes; then
 928   AC_DEFINE(HAVE_S_ISLNK, 1,
 929     [Define this if your system defines S_ISLNK in sys/stat.h.])
 930 fi
 931
 932 AC_STRUCT_TIMEZONE
 933 GUILE_STRUCT_UTIMBUF
 934
 935 #--------------------------------------------------------------------
 936 #
 937 # Which way does the stack grow?
 938 #
 939 #--------------------------------------------------------------------
 940
 941 SCM_I_GSC_STACK_GROWS_UP=0
 942 AC_TRY_RUN(aux (l) unsigned long l;
 943              { int x; exit (l >= ((unsigned long)&x)); }
 944            main () { int q; aux((unsigned long)&q); },
 945            [SCM_I_GSC_STACK_GROWS_UP=1],
 946            [],
 947            [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
 948
 949 AC_CHECK_SIZEOF(float)
 950 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
 951     AC_DEFINE(SCM_SINGLES, 1,
 952               [Define this if floats are the same size as longs.])
 953 fi
 954
 955 AC_MSG_CHECKING(for struct linger)
 956 AC_CACHE_VAL(scm_cv_struct_linger,
 957         AC_TRY_COMPILE([
 958 #include <sys/types.h>
 959 #include <sys/socket.h>],
 960                         [struct linger lgr;  lgr.l_linger = 100],
 961                         scm_cv_struct_linger="yes",
 962                         scm_cv_struct_linger="no"))
 963 AC_MSG_RESULT($scm_cv_struct_linger)
 964 if test $scm_cv_struct_linger = yes; then
 965         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
 966           [Define this if your system defines struct linger, for use with the
 967            getsockopt and setsockopt system calls.])
 968 fi
 969
 970
 971 AC_MSG_CHECKING(for struct timespec)
 972 AC_CACHE_VAL(scm_cv_struct_timespec,
 973         AC_TRY_COMPILE([
 974 #include <time.h>],
 975                         [struct timespec t;  t.tv_nsec = 100],
 976                         scm_cv_struct_timespec="yes",
 977                         scm_cv_struct_timespec="no"))
 978 AC_MSG_RESULT($scm_cv_struct_timespec)
 979 if test $scm_cv_struct_timespec = yes; then
 980   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
 981     [Define this if your system defines struct timespec via <time.h>.])
 982 fi
 983
 984 #--------------------------------------------------------------------
 985 #
 986 # Flags for thread support
 987 #
 988 #--------------------------------------------------------------------
 989
 990 SCM_I_GSC_USE_PTHREAD_THREADS=0
 991 SCM_I_GSC_USE_NULL_THREADS=0
 992 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
 993 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
 994
 995 ### What thread package has the user asked for?
 996 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 997             , with_threads=yes)
 998
 999 case "$with_threads" in
1000   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1001     ACX_PTHREAD(CC="$PTHREAD_CC"
1002       LIBS="$PTHREAD_LIBS $LIBS"
1003       SCM_I_GSC_USE_PTHREAD_THREADS=1
1004       with_threads="pthreads",
1005       with_threads="null")
1006
1007     old_CFLAGS="$CFLAGS"
1008     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1009     AC_CHECK_FUNCS(pthread_attr_getstack)
1010     CFLAGS="$old_CFLAGS"
1011
1012     # On Solaris, sched_yield lives in -lrt.
1013     AC_SEARCH_LIBS(sched_yield, rt)
1014
1015   ;;
1016 esac
1017
1018 case "$with_threads" in
1019   "pthreads")
1020   ;;
1021   "no" | "null")
1022     SCM_I_GSC_USE_NULL_THREADS=1
1023     with_threads="null-threads"
1024   ;;
1025   * )
1026     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1027   ;;
1028 esac
1029
1030 AC_MSG_CHECKING(what kind of threads to support)
1031 AC_MSG_RESULT($with_threads)
1032
1033 ## Cross building
1034 if test "$cross_compiling" = "yes"; then
1035   AC_MSG_CHECKING(cc for build)
1036   ## /usr/bin/cc still uses wrong assembler
1037   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1038   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1039 else
1040   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1041 fi
1042
1043 ## AC_MSG_CHECKING("if we are cross compiling")
1044 ## AC_MSG_RESULT($cross_compiling)
1045 if test "$cross_compiling" = "yes"; then
1046    AC_MSG_RESULT($CC_FOR_BUILD)
1047 fi
1048
1049 ## No need as yet to be more elaborate
1050 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1051
1052 AC_SUBST(cross_compiling)
1053 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1054 AC_SUBST(CCLD_FOR_BUILD)
1055
1056 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1057 ## --HOST is the platform that PACKAGE is compiled for.
1058 HOST_CC="$CC_FOR_BUILD"
1059 AC_SUBST(HOST_CC)
1060
1061 if test "$cross_compiling" = "yes"; then
1062   AC_MSG_CHECKING(guile for build)
1063   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1064 else
1065   GUILE_FOR_BUILD='$(preinstguile)'
1066 fi
1067
1068 ## AC_MSG_CHECKING("if we are cross compiling")
1069 ## AC_MSG_RESULT($cross_compiling)
1070 if test "$cross_compiling" = "yes"; then
1071    AC_MSG_RESULT($GUILE_FOR_BUILD)
1072 fi
1073 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1074 AC_SUBST(GUILE_FOR_BUILD)
1075
1076 ## If we're using GCC, ask for aggressive warnings.
1077 case "$GCC" in
1078   yes )
1079     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1080     ## much stuff with generic function pointers for that to really be
1081     ## less than exasperating.
1082     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1083     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1084     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
1085     # Do this here so we don't screw up any of the tests above that might
1086     # not be "warning free"
1087     if test "${GUILE_ERROR_ON_WARNING}" = yes
1088     then
1089         CFLAGS="${CFLAGS} -Werror"
1090         enable_compile_warnings=no
1091     fi
1092     ;;
1093 esac
1094
1095 ## NOTE the code below sets LIBOBJS directly and so is now forbidden
1096 ## -- I'm disabling it for now in the hopes that the newer autoconf
1097 ## will DTRT -- if not, we need to fix up the sed command to match the
1098 ## others...
1099 ##
1100 ## Remove fileblocks.o from the object list.  This file gets added by
1101 ## the Autoconf macro AC_STRUCT_ST_BLOCKS.  But there is no need.
1102 #LIBOBJS="`echo ${LIBOBJS} | sed 's/fileblocks\.o//g'`"
1103
1104 ## If we're creating a shared library (using libtool!), then we'll
1105 ## need to generate a list of .lo files corresponding to the .o files
1106 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1107 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1108
1109 ## We also need to create corresponding .doc and .x files
1110 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1111 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1112
1113 AC_SUBST(GUILE_MAJOR_VERSION)
1114 AC_SUBST(GUILE_MINOR_VERSION)
1115 AC_SUBST(GUILE_MICRO_VERSION)
1116 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1117 AC_SUBST(GUILE_VERSION)
1118
1119 #######################################################################
1120 # library versioning
1121
1122 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1123 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1124 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1125 AC_SUBST(LIBGUILE_INTERFACE)
1126
1127 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1128 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1129 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1130 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1131 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1132
1133 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1134 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1135 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1136 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1137 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1138
1139 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1140 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1141 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1142 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1143 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1144
1145 AC_SUBST(LIBGUILE_SRFI_SRFI_60_MAJOR)
1146 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_CURRENT)
1147 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_REVISION)
1148 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_AGE)
1149 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE)
1150
1151 #######################################################################
1152
1153 dnl Tell guile-config what flags guile users should compile and link with.
1154 GUILE_LIBS="$LDFLAGS $LIBS"
1155 GUILE_CFLAGS="$PTHREAD_CFLAGS"
1156 AC_SUBST(GUILE_LIBS)
1157 AC_SUBST(GUILE_CFLAGS)
1158
1159 AC_SUBST(AWK)
1160 AC_SUBST(LIBLOBJS)
1161 AC_SUBST(EXTRA_DOT_DOC_FILES)
1162 AC_SUBST(EXTRA_DOT_X_FILES)
1163
1164 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1165 top_builddir_absolute=`pwd`
1166 AC_SUBST(top_builddir_absolute)
1167 top_srcdir_absolute=`(cd $srcdir && pwd)`
1168 AC_SUBST(top_srcdir_absolute)
1169
1170 # Additional SCM_I_GSC definitions are above.
1171 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1172 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1173 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1174 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1175 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1176 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1177 AC_SUBST([SCM_I_GSC_C_INLINE])
1178 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1179
1180 AC_CONFIG_FILES([
1181   Makefile
1182   am/Makefile
1183   benchmark-suite/Makefile
1184   doc/Makefile
1185   doc/goops/Makefile
1186   doc/r5rs/Makefile
1187   doc/ref/Makefile
1188   doc/tutorial/Makefile
1189   examples/Makefile
1190   examples/box-dynamic-module/Makefile
1191   examples/box-dynamic/Makefile
1192   examples/box-module/Makefile
1193   examples/box/Makefile
1194   examples/modules/Makefile
1195   examples/safe/Makefile
1196   examples/scripts/Makefile
1197   guile-config/Makefile
1198   ice-9/Makefile
1199   ice-9/debugger/Makefile
1200   lang/Makefile
1201   lang/elisp/Makefile
1202   lang/elisp/internals/Makefile
1203   lang/elisp/primitives/Makefile
1204   libguile/Makefile
1205   oop/Makefile
1206   oop/goops/Makefile
1207   scripts/Makefile
1208   srfi/Makefile
1209   test-suite/Makefile
1210   test-suite/standalone/Makefile
1211 ])
1212
1213 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1214 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1215 AC_CONFIG_FILES([guile-tools], [chmod +x guile-tools])
1216 AC_CONFIG_FILES([pre-inst-guile], [chmod +x pre-inst-guile])
1217 AC_CONFIG_FILES([pre-inst-guile-env], [chmod +x pre-inst-guile-env])
1218 AC_CONFIG_FILES([libguile/guile-snarf],
1219                 [chmod +x libguile/guile-snarf])
1220 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1221                 [chmod +x libguile/guile-doc-snarf])
1222 AC_CONFIG_FILES([libguile/guile-func-name-check],
1223                 [chmod +x libguile/guile-func-name-check])
1224 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1225                 [chmod +x libguile/guile-snarf-docs])
1226
1227 AC_OUTPUT
1228
1229 dnl Local Variables:
1230 dnl comment-start: "dnl "
1231 dnl comment-end: ""
1232 dnl comment-start-skip: "\\bdnl\\b\\s *"
1233 dnl End: