m4/iconv.m4

   1 # iconv.m4 serial 15 (gettext-0.18.2)
   2 dnl Copyright (C) 2000-2002, 2007-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Bruno Haible.
   8
   9 AC_DEFUN([AM_ICONV_LINKFLAGS_BODY],
  10 [
  11   dnl Prerequisites of AC_LIB_LINKFLAGS_BODY.
  12   AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
  13   AC_REQUIRE([AC_LIB_RPATH])
  14
  15   dnl Search for libiconv and define LIBICONV, LTLIBICONV and INCICONV
  16   dnl accordingly.
  17   AC_LIB_LINKFLAGS_BODY([iconv])
  18 ])
  19
  20 AC_DEFUN([AM_ICONV_LINK],
  21 [
  22   dnl Some systems have iconv in libc, some have it in libiconv (OSF/1 and
  23   dnl those with the standalone portable GNU libiconv installed).
  24   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  25
  26   dnl Search for libiconv and define LIBICONV, LTLIBICONV and INCICONV
  27   dnl accordingly.
  28   AC_REQUIRE([AM_ICONV_LINKFLAGS_BODY])
  29
  30   dnl Add $INCICONV to CPPFLAGS before performing the following checks,
  31   dnl because if the user has installed libiconv and not disabled its use
  32   dnl via --without-libiconv-prefix, he wants to use it. The first
  33   dnl AC_LINK_IFELSE will then fail, the second AC_LINK_IFELSE will succeed.
  34   am_save_CPPFLAGS="$CPPFLAGS"
  35   AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCICONV])
  36
  37   AC_CACHE_CHECK([for iconv], [am_cv_func_iconv], [
  38     am_cv_func_iconv="no, consider installing GNU libiconv"
  39     am_cv_lib_iconv=no
  40     AC_LINK_IFELSE(
  41       [AC_LANG_PROGRAM(
  42          [[
  43 #include <stdlib.h>
  44 #include <iconv.h>
  45          ]],
  46          [[iconv_t cd = iconv_open("","");
  47            iconv(cd,NULL,NULL,NULL,NULL);
  48            iconv_close(cd);]])],
  49       [am_cv_func_iconv=yes])
  50     if test "$am_cv_func_iconv" != yes; then
  51       am_save_LIBS="$LIBS"
  52       LIBS="$LIBS $LIBICONV"
  53       AC_LINK_IFELSE(
  54         [AC_LANG_PROGRAM(
  55            [[
  56 #include <stdlib.h>
  57 #include <iconv.h>
  58            ]],
  59            [[iconv_t cd = iconv_open("","");
  60              iconv(cd,NULL,NULL,NULL,NULL);
  61              iconv_close(cd);]])],
  62         [am_cv_lib_iconv=yes]
  63         [am_cv_func_iconv=yes])
  64       LIBS="$am_save_LIBS"
  65     fi
  66   ])
  67   if test "$am_cv_func_iconv" = yes; then
  68     AC_CACHE_CHECK([for working iconv], [am_cv_func_iconv_works], [
  69       dnl This tests against bugs in AIX 5.1, AIX 6.1..7.1, HP-UX 11.11,
  70       dnl Solaris 10.
  71       am_save_LIBS="$LIBS"
  72       if test $am_cv_lib_iconv = yes; then
  73         LIBS="$LIBS $LIBICONV"
  74       fi
  75       AC_RUN_IFELSE(
  76         [AC_LANG_SOURCE([[
  77 #include <iconv.h>
  78 #include <string.h>
  79 int main ()
  80 {
  81   /* Test against AIX 5.1 bug: Failures are not distinguishable from successful
  82      returns.  */
  83   {
  84     iconv_t cd_utf8_to_88591 = iconv_open ("ISO8859-1", "UTF-8");
  85     if (cd_utf8_to_88591 != (iconv_t)(-1))
  86       {
  87         static const char input[] = "\342\202\254"; /* EURO SIGN */
  88         char buf[10];
  89         const char *inptr = input;
  90         size_t inbytesleft = strlen (input);
  91         char *outptr = buf;
  92         size_t outbytesleft = sizeof (buf);
  93         size_t res = iconv (cd_utf8_to_88591,
  94                             (char **) &inptr, &inbytesleft,
  95                             &outptr, &outbytesleft);
  96         if (res == 0)
  97           return 1;
  98       }
  99   }
 100   /* Test against Solaris 10 bug: Failures are not distinguishable from
 101      successful returns.  */
 102   {
 103     iconv_t cd_ascii_to_88591 = iconv_open ("ISO8859-1", "646");
 104     if (cd_ascii_to_88591 != (iconv_t)(-1))
 105       {
 106         static const char input[] = "\263";
 107         char buf[10];
 108         const char *inptr = input;
 109         size_t inbytesleft = strlen (input);
 110         char *outptr = buf;
 111         size_t outbytesleft = sizeof (buf);
 112         size_t res = iconv (cd_ascii_to_88591,
 113                             (char **) &inptr, &inbytesleft,
 114                             &outptr, &outbytesleft);
 115         if (res == 0)
 116           return 1;
 117       }
 118   }
 119   /* Test against AIX 6.1..7.1 bug: Buffer overrun.  */
 120   {
 121     iconv_t cd_88591_to_utf8 = iconv_open ("UTF-8", "ISO-8859-1");
 122     if (cd_88591_to_utf8 != (iconv_t)(-1))
 123       {
 124         static const char input[] = "\304";
 125         static char buf[2] = { (char)0xDE, (char)0xAD };
 126         const char *inptr = input;
 127         size_t inbytesleft = 1;
 128         char *outptr = buf;
 129         size_t outbytesleft = 1;
 130         size_t res = iconv (cd_88591_to_utf8,
 131                             (char **) &inptr, &inbytesleft,
 132                             &outptr, &outbytesleft);
 133         if (res != (size_t)(-1) || outptr - buf > 1 || buf[1] != (char)0xAD)
 134           return 1;
 135       }
 136   }
 137 #if 0 /* This bug could be worked around by the caller.  */
 138   /* Test against HP-UX 11.11 bug: Positive return value instead of 0.  */
 139   {
 140     iconv_t cd_88591_to_utf8 = iconv_open ("utf8", "iso88591");
 141     if (cd_88591_to_utf8 != (iconv_t)(-1))
 142       {
 143         static const char input[] = "\304rger mit b\366sen B\374bchen ohne Augenma\337";
 144         char buf[50];
 145         const char *inptr = input;
 146         size_t inbytesleft = strlen (input);
 147         char *outptr = buf;
 148         size_t outbytesleft = sizeof (buf);
 149         size_t res = iconv (cd_88591_to_utf8,
 150                             (char **) &inptr, &inbytesleft,
 151                             &outptr, &outbytesleft);
 152         if ((int)res > 0)
 153           return 1;
 154       }
 155   }
 156 #endif
 157   /* Test against HP-UX 11.11 bug: No converter from EUC-JP to UTF-8 is
 158      provided.  */
 159   if (/* Try standardized names.  */
 160       iconv_open ("UTF-8", "EUC-JP") == (iconv_t)(-1)
 161       /* Try IRIX, OSF/1 names.  */
 162       && iconv_open ("UTF-8", "eucJP") == (iconv_t)(-1)
 163       /* Try AIX names.  */
 164       && iconv_open ("UTF-8", "IBM-eucJP") == (iconv_t)(-1)
 165       /* Try HP-UX names.  */
 166       && iconv_open ("utf8", "eucJP") == (iconv_t)(-1))
 167     return 1;
 168   return 0;
 169 }]])],
 170         [am_cv_func_iconv_works=yes],
 171         [am_cv_func_iconv_works=no],
 172         [
 173 changequote(,)dnl
 174          case "$host_os" in
 175            aix* | hpux*) am_cv_func_iconv_works="guessing no" ;;
 176            *)            am_cv_func_iconv_works="guessing yes" ;;
 177          esac
 178 changequote([,])dnl
 179         ])
 180       LIBS="$am_save_LIBS"
 181     ])
 182     case "$am_cv_func_iconv_works" in
 183       *no) am_func_iconv=no am_cv_lib_iconv=no ;;
 184       *)   am_func_iconv=yes ;;
 185     esac
 186   else
 187     am_func_iconv=no am_cv_lib_iconv=no
 188   fi
 189   if test "$am_func_iconv" = yes; then
 190     AC_DEFINE([HAVE_ICONV], [1],
 191       [Define if you have the iconv() function and it works.])
 192   fi
 193   if test "$am_cv_lib_iconv" = yes; then
 194     AC_MSG_CHECKING([how to link with libiconv])
 195     AC_MSG_RESULT([$LIBICONV])
 196   else
 197     dnl If $LIBICONV didn't lead to a usable library, we don't need $INCICONV
 198     dnl either.
 199     CPPFLAGS="$am_save_CPPFLAGS"
 200     LIBICONV=
 201     LTLIBICONV=
 202   fi
 203   AC_SUBST([LIBICONV])
 204   AC_SUBST([LTLIBICONV])
 205 ])
 206
 207 dnl Define AM_ICONV using AC_DEFUN_ONCE for Autoconf >= 2.64, in order to
 208 dnl avoid warnings like
 209 dnl "warning: AC_REQUIRE: `AM_ICONV' was expanded before it was required".
 210 dnl This is tricky because of the way 'aclocal' is implemented:
 211 dnl - It requires defining an auxiliary macro whose name ends in AC_DEFUN.
 212 dnl   Otherwise aclocal's initial scan pass would miss the macro definition.
 213 dnl - It requires a line break inside the AC_DEFUN_ONCE and AC_DEFUN expansions.
 214 dnl   Otherwise aclocal would emit many "Use of uninitialized value $1"
 215 dnl   warnings.
 216 m4_define([gl_iconv_AC_DEFUN],
 217   m4_version_prereq([2.64],
 218     [[AC_DEFUN_ONCE(
 219         [$1], [$2])]],
 220     [m4_ifdef([gl_00GNULIB],
 221        [[AC_DEFUN_ONCE(
 222            [$1], [$2])]],
 223        [[AC_DEFUN(
 224            [$1], [$2])]])]))
 225 gl_iconv_AC_DEFUN([AM_ICONV],
 226 [
 227   AM_ICONV_LINK
 228   if test "$am_cv_func_iconv" = yes; then
 229     AC_MSG_CHECKING([for iconv declaration])
 230     AC_CACHE_VAL([am_cv_proto_iconv], [
 231       AC_COMPILE_IFELSE(
 232         [AC_LANG_PROGRAM(
 233            [[
 234 #include <stdlib.h>
 235 #include <iconv.h>
 236 extern
 237 #ifdef __cplusplus
 238 "C"
 239 #endif
 240 #if defined(__STDC__) || defined(__cplusplus)
 241 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 242 #else
 243 size_t iconv();
 244 #endif
 245            ]],
 246            [[]])],
 247         [am_cv_proto_iconv_arg1=""],
 248         [am_cv_proto_iconv_arg1="const"])
 249       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 250     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 251     AC_MSG_RESULT([
 252          $am_cv_proto_iconv])
 253     AC_DEFINE_UNQUOTED([ICONV_CONST], [$am_cv_proto_iconv_arg1],
 254       [Define as const if the declaration of iconv() needs const.])
 255   fi
 256 ])