configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   8   2007, 2008, 2009, 2010, 2011, 2012, 2013, 2014 Free Software Foundation, Inc.
   9
  10 This file is part of GUILE
  11
  12 GUILE is free software; you can redistribute it and/or modify it under
  13 the terms of the GNU Lesser General Public License as published by the
  14 Free Software Foundation; either version 3, or (at your option) any
  15 later version.
  16
  17 GUILE is distributed in the hope that it will be useful, but WITHOUT
  18 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  19 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  20 License for more details.
  21
  22 You should have received a copy of the GNU Lesser General Public
  23 License along with GUILE; see the file COPYING.LESSER.  If not, write
  24 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  25 Floor, Boston, MA 02110-1301, USA.
  26
  27 ]])
  28
  29 AC_PREREQ(2.61)
  30
  31 AC_INIT([GNU Guile],
  32         m4_esyscmd([build-aux/git-version-gen --match v2.0.\* .tarball-version]),
  33         [bug-guile@gnu.org])
  34 AC_CONFIG_AUX_DIR([build-aux])
  35 AC_CONFIG_MACRO_DIR([m4])
  36 AC_CONFIG_SRCDIR(GUILE-VERSION)
  37
  38 dnl Use `serial-tests' so the output `check-guile' is not hidden
  39 dnl (`parallel-tests' is the default in Automake 1.13.)
  40 dnl `serial-tests' was introduced in Automake 1.12.
  41 AM_INIT_AUTOMAKE([1.12 gnu no-define -Wall -Wno-override \
  42   serial-tests color-tests dist-xz])
  43 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AC_SUBST([AM_DEFAULT_VERBOSITY],1)])
  44
  45 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  46 AC_CONFIG_SRCDIR([GUILE-VERSION])
  47
  48 . $srcdir/GUILE-VERSION
  49 GUILE_VERSION="$PACKAGE_VERSION"
  50
  51 AC_CONFIG_HEADERS([config.h])
  52 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  53
  54 dnl We require the pkg.m4 set of macros from pkg-config.
  55 dnl Make sure it's available.
  56 m4_pattern_forbid([PKG_CHECK_MODULES])
  57
  58 #--------------------------------------------------------------------
  59
  60 AC_LANG([C])
  61
  62 dnl Some more checks for Win32
  63 AC_CANONICAL_HOST
  64
  65 AC_LIBTOOL_WIN32_DLL
  66
  67 AC_PROG_INSTALL
  68 AC_PROG_CC
  69 gl_EARLY
  70 AC_PROG_CPP
  71 AC_PROG_SED
  72 AC_PROG_AWK
  73 AC_PROG_LN_S
  74 AM_PROG_AR
  75
  76 dnl Gnulib.
  77 gl_INIT
  78
  79 dnl We provide our own lib/glthread/lock.h, so let other Gnulib modules
  80 dnl know that we have it.  This allows them to be compiled with adequate
  81 dnl locking support.  See <http://bugs.gnu.org/14404>.
  82 AC_DEFINE([GNULIB_LOCK], [1],
  83   [Define to allow Gnulib modules to use Guile's locks.])
  84
  85
  86 AC_PROG_CC_C89
  87
  88 # for per-target cflags in the libguile subdir
  89 AM_PROG_CC_C_O
  90
  91 AC_LIBTOOL_DLOPEN
  92 AC_PROG_LIBTOOL
  93
  94 AM_CONDITIONAL([HAVE_SHARED_LIBRARIES], [test "x$enable_shared" = "xyes"])
  95
  96 dnl Check for libltdl.
  97 AC_LIB_HAVE_LINKFLAGS([ltdl], [], [#include <ltdl.h>],
  98   [lt_dlopenext ("foo");])
  99 if test "x$HAVE_LIBLTDL" != "xyes"; then
 100   AC_MSG_ERROR([GNU libltdl (Libtool) not found, see README.])
 101 fi
 102
 103 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
 104 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
 105
 106 AM_PATH_LISPDIR
 107
 108 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
 109   [Define to the host's GNU triplet.])
 110
 111 #--------------------------------------------------------------------
 112 #
 113 # User options (after above tests that may set default CFLAGS etc.)
 114 #
 115 #--------------------------------------------------------------------
 116
 117 GUILE_ERROR_ON_WARNING="no"
 118
 119 AC_ARG_ENABLE(error-on-warning,
 120   [  --enable-error-on-warning    treat compile warnings as errors],
 121   [case "${enableval}" in
 122      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 123      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 124      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 125    esac])
 126
 127 AC_ARG_ENABLE(debug-malloc,
 128   [  --enable-debug-malloc   include malloc debugging code],
 129   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 130     AC_DEFINE([GUILE_DEBUG_MALLOC], 1,
 131       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 132   fi)
 133
 134 SCM_I_GSC_GUILE_DEBUG=0
 135 AC_ARG_ENABLE(guile-debug,
 136   [AS_HELP_STRING([--enable-guile-debug],
 137                   [include internal debugging functions])],
 138   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 139     SCM_I_GSC_GUILE_DEBUG=1
 140   fi)
 141
 142 AC_ARG_ENABLE(posix,
 143   [  --disable-posix         omit non-essential POSIX interfaces],,
 144   enable_posix=yes)
 145
 146 AC_ARG_ENABLE(networking,
 147   [  --disable-networking    omit networking interfaces],,
 148   enable_networking=yes)
 149
 150 AC_ARG_ENABLE(regex,
 151   [  --disable-regex         omit regular expression interfaces],,
 152   enable_regex=yes)
 153
 154 AC_ARG_ENABLE([deprecated],
 155   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 156
 157 if test "$enable_deprecated" = no; then
 158   SCM_I_GSC_ENABLE_DEPRECATED=0
 159   warn_default=no
 160 else
 161   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 162     warn_default=summary
 163   elif test "$enable_deprecated" = shutup; then
 164     warn_default=no
 165   else
 166     warn_default=$enable_deprecated
 167   fi
 168   SCM_I_GSC_ENABLE_DEPRECATED=1
 169 fi
 170 AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default",
 171 [Define this to control the default warning level for deprecated features.])
 172
 173 dnl  Added the following configure option in January 2008 following
 174 dnl  investigation of problems with "64" system and library calls on
 175 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 176 dnl  system has stat64, it will have all the other 64 APIs too; but on
 177 dnl  Darwin, stat64 is there but other APIs are missing.
 178 dnl
 179 dnl  It also appears, from the Darwin docs, that most system call APIs
 180 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 181 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 182 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 183 dnl
 184 dnl  A similar problem has been reported for HP-UX:
 185 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 186 dnl
 187 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 188 dnl  better than no Guile at all, we provide this option to suppress
 189 dnl  trying to use "64" calls.
 190 dnl
 191 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 192 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 193 dnl  missing out on that.  If so, someone can work on that in the future.
 194 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 195 dnl  wasn't building before.
 196 AC_MSG_CHECKING([whether to use system and library "64" calls])
 197 AC_ARG_WITH([64-calls],
 198   AS_HELP_STRING([--without-64-calls],
 199                  [don't attempt to use system and library calls with "64" in their names]),
 200   [use_64_calls=$withval],
 201   [use_64_calls=yes
 202    case $host in
 203      *-apple-darwin* )
 204        use_64_calls=no
 205        ;;
 206      powerpc-ibm-aix* )
 207        use_64_calls=no
 208        ;;
 209    esac])
 210 AC_MSG_RESULT($use_64_calls)
 211 case "$use_64_calls" in
 212   y* )
 213     AC_DEFINE([GUILE_USE_64_CALLS], 1,
 214       [Define to 1 in order to try to use "64" versions of system and library calls.])
 215     ;;
 216 esac
 217
 218 #--------------------------------------------------------------------
 219
 220 dnl Check for dynamic linking
 221
 222 use_modules=yes
 223 AC_ARG_WITH(modules,
 224 [  --with-modules[=FILES]  Add support for dynamic modules],
 225 use_modules="$withval")
 226 test -z "$use_modules" && use_modules=yes
 227 DLPREOPEN=
 228 if test "$use_modules" != no; then
 229   if test "$use_modules" = yes; then
 230     DLPREOPEN="-dlpreopen force"
 231   else
 232     DLPREOPEN="-export-dynamic"
 233     for module in $use_modules; do
 234       DLPREOPEN="$DLPREOPEN -dlopen $module"
 235     done
 236   fi
 237 fi
 238
 239 dnl files which are destined for separate modules.
 240
 241 if test "$use_modules" != no; then
 242    AC_LIBOBJ([dynl])
 243    AC_DEFINE([HAVE_MODULES], 1,
 244      [Define this if you want support for dynamically loaded modules in Guile.])
 245 fi
 246
 247 if test "$enable_posix" = yes; then
 248    AC_LIBOBJ([posix])
 249    AC_DEFINE([HAVE_POSIX], 1,
 250      [Define this if you want support for non-essential POSIX system calls in Guile.])
 251 fi
 252
 253 if test "$enable_networking" = yes; then
 254    AC_LIBOBJ([net_db])
 255    AC_LIBOBJ([socket])
 256    AC_DEFINE([HAVE_NETWORKING], 1,
 257      [Define this if you want support for networking in Guile.])
 258 fi
 259
 260 if test "$enable_debug_malloc" = yes; then
 261    AC_LIBOBJ([debug-malloc])
 262 fi
 263
 264 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 265
 266 AC_C_CONST
 267
 268 # "volatile" is used in a couple of tests below.
 269 AC_C_VOLATILE
 270
 271 AC_C_INLINE
 272 if test "$ac_cv_c_inline" != no; then
 273   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 274 else
 275   SCM_I_GSC_C_INLINE=NULL
 276 fi
 277 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 278
 279 AC_C_BIGENDIAN
 280
 281 AC_C_LABELS_AS_VALUES
 282
 283 AC_CHECK_SIZEOF(char)
 284 AC_CHECK_SIZEOF(unsigned char)
 285 AC_CHECK_SIZEOF(short)
 286 AC_CHECK_SIZEOF(unsigned short)
 287 AC_CHECK_SIZEOF(int)
 288 AC_CHECK_SIZEOF(unsigned int)
 289 AC_CHECK_SIZEOF(long)
 290 AC_CHECK_SIZEOF(unsigned long)
 291 AC_CHECK_SIZEOF(size_t)
 292 AC_CHECK_SIZEOF(long long)
 293 AC_CHECK_SIZEOF(unsigned long long)
 294 AC_CHECK_SIZEOF(__int64)
 295 AC_CHECK_SIZEOF(unsigned __int64)
 296 AC_CHECK_SIZEOF(void *)
 297 AC_CHECK_SIZEOF(intptr_t)
 298 AC_CHECK_SIZEOF(uintptr_t)
 299 AC_CHECK_SIZEOF(ptrdiff_t)
 300 AC_CHECK_SIZEOF(size_t)
 301 AC_CHECK_SIZEOF(off_t)
 302
 303 if test "$ac_cv_sizeof_long" -gt "$ac_cv_sizeof_void_p"; then
 304   AC_MSG_ERROR(long does not fit into a void*)
 305 fi
 306
 307 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 308   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 309 else
 310   SCM_I_GSC_T_PTRDIFF='"long"'
 311 fi
 312 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 313
 314 AC_CHECK_HEADERS([stdint.h])
 315 AC_CHECK_HEADERS([inttypes.h])
 316
 317 AC_CHECK_SIZEOF(intmax_t)
 318
 319 SCM_I_GSC_NEEDS_STDINT_H=0
 320 SCM_I_GSC_NEEDS_INTTYPES_H=0
 321
 322 ### intptr and uintptr (try not to use inttypes if we don't have to)
 323 if test "$ac_cv_header_inttypes_h" = yes; then
 324   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 325     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 326 #include <stdio.h>])
 327     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 328       SCM_I_GSC_NEEDS_INTTYPES_H=1
 329     fi
 330   fi
 331   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 332     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 333 #include <stdio.h>])
 334     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 335       SCM_I_GSC_NEEDS_INTTYPES_H=1
 336     fi
 337   fi
 338 fi
 339
 340 ### See what's provided by stdint.h
 341 if test "$ac_cv_header_stdint_h" = yes; then
 342    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 343    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 344    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 345    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 346    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 347    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 348    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 349    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 350    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 351    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 352    AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>])
 353    AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>])
 354 fi
 355
 356 # so we don't get confused by the cache (wish there was a better way
 357 # to check particular headers for the same type...)
 358
 359 unset ac_cv_type_int8_t
 360 unset ac_cv_type_uint8_t
 361 unset ac_cv_type_int16_t
 362 unset ac_cv_type_uint16_t
 363 unset ac_cv_type_int32_t
 364 unset ac_cv_type_uint32_t
 365 unset ac_cv_type_int64_t
 366 unset ac_cv_type_uint64_t
 367 unset ac_cv_type_intmax_t
 368 unset ac_cv_type_uintmax_t
 369
 370 ### See what's provided by inttypes.h
 371 if test "$ac_cv_header_inttypes_h" = yes; then
 372   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 373   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 374   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 375   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 376   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 377   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 378   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 379   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 380   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 381   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 382   AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>])
 383   AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>])
 384 fi
 385
 386 # Try hard to find definitions for some required scm_t_*int* types.
 387
 388 ### Required type scm_t_int8
 389 if test "$scm_stdint_has_int8"; then
 390   SCM_I_GSC_T_INT8='"int8_t"'
 391   SCM_I_GSC_NEEDS_STDINT_H=1
 392 elif test "$scm_inttypes_has_int8"; then
 393   SCM_I_GSC_T_INT8='"int8_t"'
 394   SCM_I_GSC_NEEDS_INTTYPES_H=1
 395 elif test "$ac_cv_sizeof_char" -eq 1; then
 396   SCM_I_GSC_T_INT8='"signed char"'
 397 else
 398   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 399 fi
 400 AC_SUBST([SCM_I_GSC_T_INT8])
 401
 402 ### Required type scm_t_uint8
 403 if test "$scm_stdint_has_uint8"; then
 404   SCM_I_GSC_T_UINT8='"uint8_t"'
 405   SCM_I_GSC_NEEDS_STDINT_H=1
 406 elif test "$scm_inttypes_has_uint8"; then
 407   SCM_I_GSC_T_UINT8='"uint8_t"'
 408   SCM_I_GSC_NEEDS_INTTYPES_H=1
 409 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 410   SCM_I_GSC_T_UINT8='"unsigned char"'
 411 else
 412   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 413 fi
 414 AC_SUBST([SCM_I_GSC_T_UINT8])
 415
 416 ### Required type scm_t_int16 (ANSI C says int or short might work)
 417 if test "$scm_stdint_has_int16"; then
 418   SCM_I_GSC_T_INT16='"int16_t"'
 419   SCM_I_GSC_NEEDS_STDINT_H=1
 420 elif test "$scm_inttypes_has_int16"; then
 421   SCM_I_GSC_T_INT16='"int16_t"'
 422   SCM_I_GSC_NEEDS_INTTYPES_H=1
 423 elif test "$ac_cv_sizeof_int" -eq 2; then
 424   SCM_I_GSC_T_INT16='"int"'
 425 elif test "$ac_cv_sizeof_short" -eq 2; then
 426   SCM_I_GSC_T_INT16='"short"'
 427 else
 428   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 429 fi
 430 AC_SUBST([SCM_I_GSC_T_INT16])
 431
 432 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 433 if test "$scm_stdint_has_uint16"; then
 434   SCM_I_GSC_T_UINT16='"uint16_t"'
 435   SCM_I_GSC_NEEDS_STDINT_H=1
 436 elif test "$scm_inttypes_has_uint16"; then
 437   SCM_I_GSC_T_UINT16='"uint16_t"'
 438   SCM_I_GSC_NEEDS_INTTYPES_H=1
 439 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 440   SCM_I_GSC_T_UINT16='"unsigned int"'
 441 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 442   SCM_I_GSC_T_UINT16='"unsigned short"'
 443 else
 444   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 445 fi
 446 AC_SUBST([SCM_I_GSC_T_UINT16])
 447
 448
 449 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 450 if test "$scm_stdint_has_int32"; then
 451   SCM_I_GSC_T_INT32='"int32_t"'
 452   SCM_I_GSC_NEEDS_STDINT_H=1
 453 elif test "$scm_inttypes_has_int32"; then
 454   SCM_I_GSC_T_INT32='"int32_t"'
 455   SCM_I_GSC_NEEDS_INTTYPES_H=1
 456 elif test "$ac_cv_sizeof_int" -eq 4; then
 457   SCM_I_GSC_T_INT32='"int"'
 458 elif test "$ac_cv_sizeof_long" -eq 4; then
 459   SCM_I_GSC_T_INT32='"long"'
 460 elif test "$ac_cv_sizeof_short" -eq 4; then
 461   SCM_I_GSC_T_INT32='"short"'
 462 else
 463   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 464 fi
 465 AC_SUBST([SCM_I_GSC_T_INT32])
 466
 467 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 468 if test "$scm_stdint_has_uint32"; then
 469   SCM_I_GSC_T_UINT32='"uint32_t"'
 470   SCM_I_GSC_NEEDS_STDINT_H=1
 471 elif test "$scm_inttypes_has_uint32"; then
 472   SCM_I_GSC_T_UINT32='"uint32_t"'
 473   SCM_I_GSC_NEEDS_INTTYPES_H=1
 474 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 475   SCM_I_GSC_T_UINT32='"unsigned int"'
 476 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 477   SCM_I_GSC_T_UINT32='"unsigned long"'
 478 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 479   SCM_I_GSC_T_UINT32='"unsigned short"'
 480 else
 481   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 482 fi
 483 AC_SUBST([SCM_I_GSC_T_UINT32])
 484
 485 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 486 ### Also try 'long long' and '__int64' if we have it.
 487 SCM_I_GSC_T_INT64=0
 488 if test "$scm_stdint_has_int64"; then
 489   SCM_I_GSC_T_INT64='"int64_t"'
 490   SCM_I_GSC_NEEDS_STDINT_H=1
 491 elif test "$scm_inttypes_has_int64"; then
 492   SCM_I_GSC_T_INT64='"int64_t"'
 493   SCM_I_GSC_NEEDS_INTTYPES_H=1
 494 elif test "$ac_cv_sizeof_int" -eq 8; then
 495   SCM_I_GSC_T_INT64='"int"'
 496 elif test "$ac_cv_sizeof_long" -eq 8; then
 497   SCM_I_GSC_T_INT64='"long"'
 498 elif test "$ac_cv_sizeof_short" -eq 8; then
 499   SCM_I_GSC_T_INT64='"short"'
 500 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 501   SCM_I_GSC_T_INT64='"long long"'
 502 elif test "$ac_cv_sizeof___int64" -eq 8; then
 503   SCM_I_GSC_T_INT64='"__int64"'
 504 else
 505   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 506 fi
 507 AC_SUBST([SCM_I_GSC_T_INT64])
 508
 509
 510 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 511 ### Also try 'long long' and '__int64' if we have it.
 512 SCM_I_GSC_T_UINT64=0
 513 if test "$scm_stdint_has_uint64"; then
 514   SCM_I_GSC_T_UINT64='"uint64_t"'
 515   SCM_I_GSC_NEEDS_STDINT_H=1
 516 elif test "$scm_inttypes_has_uint64"; then
 517   SCM_I_GSC_T_UINT64='"uint64_t"'
 518   SCM_I_GSC_NEEDS_INTTYPES_H=1
 519 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 520   SCM_I_GSC_T_UINT64='"unsigned int"'
 521 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 522   SCM_I_GSC_T_UINT64='"unsigned long"'
 523 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 524   SCM_I_GSC_T_UINT64='"unsigned short"'
 525 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 526   SCM_I_GSC_T_UINT64='"unsigned long long"'
 527 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 528   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 529 else
 530   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 531 fi
 532 AC_SUBST([SCM_I_GSC_T_UINT64])
 533
 534 ### Required type scm_t_intmax
 535 ###
 536 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 537 ### none of them is available, we use 'long'.
 538 ###
 539 SCM_I_GSC_T_INTMAX=0
 540 if test "$scm_stdint_has_intmax"; then
 541   SCM_I_GSC_T_INTMAX='"intmax_t"'
 542   SCM_I_GSC_NEEDS_STDINT_H=1
 543 elif test "$scm_inttypes_has_intmax"; then
 544   SCM_I_GSC_T_INTMAX='"intmax_t"'
 545   SCM_I_GSC_NEEDS_INTTYPES_H=1
 546 elif test "$ac_cv_sizeof___int64" -ne 0; then
 547   SCM_I_GSC_T_INTMAX='"__int64"'
 548 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 549   SCM_I_GSC_T_INTMAX='"long long"'
 550 else
 551   SCM_I_GSC_T_INTMAX='"long"'
 552 fi
 553 AC_SUBST([SCM_I_GSC_T_INTMAX])
 554
 555 ### Required type scm_t_uintmax
 556 ###
 557 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 558 ### this order.  When none of them is available, we use 'unsigned long'.
 559 ###
 560 SCM_I_GSC_T_UINTMAX=0
 561 if test "$scm_stdint_has_uintmax"; then
 562   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 563   SCM_I_GSC_NEEDS_STDINT_H=1
 564 elif test "$scm_inttypes_has_uintmax"; then
 565   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 566   SCM_I_GSC_NEEDS_INTTYPES_H=1
 567 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 568   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 569 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 570   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 571 else
 572   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 573 fi
 574 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 575
 576 ### Required type scm_t_intptr
 577 ###
 578 SCM_I_GSC_T_INTPTR=0
 579 if test "$scm_stdint_has_intptr"; then
 580   SCM_I_GSC_T_INTPTR='"intptr_t"'
 581   SCM_I_GSC_NEEDS_STDINT_H=1
 582 elif test "$scm_inttypes_has_intptr"; then
 583   SCM_I_GSC_T_INTPTR='"intptr_t"'
 584   SCM_I_GSC_NEEDS_INTTYPES_H=1
 585 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 586   SCM_I_GSC_T_INTPTR='"int"'
 587 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 588   SCM_I_GSC_T_INTPTR='"long"'
 589 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 590   SCM_I_GSC_T_INTPTR='"long long"'
 591 else
 592   AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.])
 593 fi
 594 AC_SUBST([SCM_I_GSC_T_INTPTR])
 595
 596 ### Required type scm_t_uintptr
 597 ###
 598 SCM_I_GSC_T_UINTPTR=0
 599 if test "$scm_stdint_has_uintptr"; then
 600   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 601   SCM_I_GSC_NEEDS_STDINT_H=1
 602 elif test "$scm_inttypes_has_uintptr"; then
 603   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 604   SCM_I_GSC_NEEDS_INTTYPES_H=1
 605 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 606   SCM_I_GSC_T_UINTPTR='"unsigned int"'
 607 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 608   SCM_I_GSC_T_UINTPTR='"unsigned long"'
 609 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 610   SCM_I_GSC_T_UINTPTR='"unsigned long long"'
 611 else
 612   AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.])
 613 fi
 614 AC_SUBST([SCM_I_GSC_T_UINTPTR])
 615
 616
 617 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 618 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 619
 620 AC_HEADER_STDC
 621 AC_HEADER_TIME
 622 AC_HEADER_SYS_WAIT
 623 AC_HEADER_DIRENT
 624
 625 # Reason for checking:
 626 #
 627 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 628 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 629 #
 630 AC_CHECK_MEMBER([struct dirent64.d_name],
 631   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 632   [ #ifndef _LARGEFILE64_SOURCE
 633     # define _LARGEFILE64_SOURCE
 634     #endif
 635
 636     /* Per Autoconf manual.  */
 637     #include <sys/types.h>
 638     #ifdef HAVE_DIRENT_H
 639     # include <dirent.h>
 640     #else
 641     # define dirent direct
 642     # ifdef HAVE_SYS_NDIR_H
 643     #  include <sys/ndir.h>
 644     # endif
 645     # ifdef HAVE_SYS_DIR_H
 646     #  include <sys/dir.h>
 647     # endif
 648     # ifdef HAVE_NDIR_H
 649     #  include <ndir.h>
 650     # endif
 651     #endif ])
 652 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 653
 654 # Reasons for testing:
 655 #   complex.h - new in C99
 656 #   fenv.h - available in C99, but not older systems
 657 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 658 #     this file instead of <fenv.h>
 659 #   process.h - mingw specific
 660 #   sched.h - missing on MinGW
 661 #   sys/sendfile.h - non-POSIX, found in glibc
 662 #
 663 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h memory.h process.h string.h \
 664 sys/dir.h sys/ioctl.h sys/select.h \
 665 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 666 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 667 direct.h machine/fpu.h sched.h sys/sendfile.h])
 668
 669 # "complex double" is new in C99, and "complex" is only a keyword if
 670 # <complex.h> is included
 671 AC_CHECK_TYPES(complex double,,,
 672 [#if HAVE_COMPLEX_H
 673 #include <complex.h>
 674 #endif])
 675
 676 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 677 # when testing.
 678 AC_CHECK_TYPE(socklen_t, ,
 679   [AC_DEFINE_UNQUOTED([socklen_t], int,
 680                       [Define to `int' if <sys/socket.h> does not define.])],
 681   [#if HAVE_SYS_TYPES_H
 682 #include <sys/types.h>
 683 #endif
 684 #include <sys/socket.h>
 685 ])
 686
 687 AC_CHECK_TYPES([struct ip_mreq], , , [#include <netinet/in.h>])
 688
 689 GUILE_HEADER_LIBC_WITH_UNISTD
 690
 691 AC_TYPE_GETGROUPS
 692 AC_TYPE_SIGNAL
 693 AC_TYPE_MODE_T
 694
 695 dnl Check whether we need -lm.
 696 LT_LIB_M
 697 LIBS="$LIBS $LIBM"
 698
 699 AC_CHECK_FUNCS(gethostbyname)
 700 if test $ac_cv_func_gethostbyname = no; then
 701     AC_CHECK_LIB(nsl, gethostbyname)
 702 fi
 703
 704 AC_CHECK_FUNCS(connect)
 705 if test $ac_cv_func_connect = no; then
 706     AC_CHECK_LIB(socket, connect)
 707 fi
 708
 709 dnl
 710 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 711 dnl
 712 EXTRA_DEFS=""
 713 case $host in
 714   *-*-mingw*)
 715     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 716       [Define if you have the <winsock2.h> header file.])])
 717     AC_CHECK_LIB(ws2_32, main)
 718     AC_LIBOBJ([win32-uname])
 719     if test "$enable_shared" = yes ; then
 720       EXTRA_DEFS="-DSCM_IMPORT"
 721       AC_DEFINE([USE_DLL_IMPORT], 1,
 722         [Define if you need additional CPP macros on Win32 platforms.])
 723     fi
 724     ;;
 725 esac
 726 AC_SUBST(EXTRA_DEFS)
 727
 728 # Reasons for testing:
 729 #   crt_externs.h - Darwin specific
 730 #
 731 AC_CHECK_HEADERS([assert.h crt_externs.h])
 732
 733 # Reasons for testing:
 734 #   DINFINITY - OSF specific
 735 #   DQNAN - OSF specific
 736 #       (DINFINITY and DQNAN are actually global variables, not functions)
 737 #   chsize - an MS-DOS-ism, found in mingw
 738 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 739 #       for gcc to provide the "complex double" type but the system to not
 740 #       have functions like cexp and clog
 741 #   clog10 - not in mingw (though others like clog and csqrt are)
 742 #   fesetround - available in C99, but not older systems
 743 #   ftruncate - posix, but probably not older systems (current mingw
 744 #               has it as an inline for chsize)
 745 #   ioctl - not in mingw.
 746 #   gmtime_r - recent posix, not on old systems
 747 #   readdir_r - recent posix, not on old systems
 748 #   readdir64_r - not available on HP-UX 11.11
 749 #   stat64 - SuS largefile stuff, not on old systems
 750 #   sysconf - not on old systems
 751 #   truncate - not in mingw
 752 #   isblank - available as a GNU extension or in C99
 753 #   _NSGetEnviron - Darwin specific
 754 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 755 #   fork - unavailable on Windows
 756 #   utimensat - posix.1-2008
 757 #   sched_getaffinity, sched_setaffinity - GNU extensions (glibc)
 758 #   sendfile - non-POSIX, found in glibc
 759 #
 760 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid         \
 761   fesetround ftime ftruncate fchown fchmod getcwd geteuid getsid        \
 762   gettimeofday gmtime_r ioctl lstat mkdir mknod nice                    \
 763   readdir_r readdir64_r readlink rename rmdir setegid seteuid           \
 764   setlocale setpgid setsid sigaction siginterrupt stat64                \
 765   strptime symlink sync sysconf tcgetpgrp tcsetpgrp uname waitpid       \
 766   strdup system usleep atexit on_exit chown link fcntl ttyname getpwent \
 767   getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp  \
 768   index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron     \
 769   strcoll strcoll_l newlocale utimensat sched_getaffinity               \
 770   sched_setaffinity sendfile])
 771
 772 # Reasons for testing:
 773 #   netdb.h - not in mingw
 774 #   sys/param.h - not in mingw
 775 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 776 #       check this specifically, we need it for the timespec test below.
 777 #   pthread_np.h - available on FreeBSD
 778 #   sethostname - the function itself check because it's not in mingw,
 779 #       the DECL is checked because Solaris 10 doens't have in any header
 780 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 781 #       declaration isn't anywhere.
 782 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 783 #       only with `_XOPEN_SOURCE' or some such.
 784 #
 785 AC_CHECK_HEADERS([crypt.h netdb.h pthread.h pthread_np.h sys/param.h sys/resource.h sys/file.h sys/mman.h])
 786 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 787 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 788
 789 # crypt() may or may not be available, for instance in some countries there
 790 # are restrictions on cryptography.
 791 #
 792 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 793 # -lcrypt library (eg. Debian GNU/Linux).
 794 #
 795 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 796 # be careful to avoid -lcrypt in this case, since libtool will see there's
 797 # only a static libcrypt and decide to build only a static libguile.
 798 #
 799 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 800 # libraries already in that list.
 801 #
 802 AC_SEARCH_LIBS(crypt, crypt,
 803   [AC_DEFINE([HAVE_CRYPT],1,
 804              [Define to 1 if you have the `crypt' function.])])
 805
 806 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 807 # work; in the reported cases so far, 1.0fi works well instead.  According
 808 # to the C99 spec, the complex.h header must provide a working definition
 809 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 810 # is a workaround for the failure of some systems to conform to C99.
 811 if test "$ac_cv_type_complex_double" = yes; then
 812   AC_MSG_CHECKING([for i])
 813   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 814 #if HAVE_COMPLEX_H
 815 #include <complex.h>
 816 #endif
 817 complex double z;
 818 ]], [[
 819 z = _Complex_I;
 820 ]])],
 821     [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).])
 822      AC_MSG_RESULT([_Complex_I])],
 823     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 824 #if HAVE_COMPLEX_H
 825 #include <complex.h>
 826 #endif
 827 complex double z;
 828 ]],[[
 829 z = 1.0fi;
 830 ]])],
 831   [AC_DEFINE([GUILE_I],1.0fi)
 832    AC_MSG_RESULT([1.0fi])],
 833   [ac_cv_type_complex_double=no
 834    AC_MSG_RESULT([not available])])])
 835 fi
 836
 837 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 838 # csqrt(-i) returned a negative real part, when it should be positive
 839 # for the principal root.
 840 #
 841 if test "$ac_cv_type_complex_double" = yes; then
 842
 843   AC_CACHE_CHECK([whether csqrt is usable],
 844     guile_cv_use_csqrt,
 845     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 846 #include <complex.h>
 847 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 848    constant, we want to test libc. */
 849 volatile complex double z = - _Complex_I;
 850 int
 851 main (void)
 852 {
 853   z = csqrt (z);
 854   if (creal (z) > 0.0)
 855     return 0;  /* good */
 856   else
 857     return 1;  /* bad */
 858 }]])],
 859     [guile_cv_use_csqrt=yes],
 860     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 861     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 862   case $guile_cv_use_csqrt in
 863     yes*)
 864       AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free])
 865       ;;
 866   esac
 867 fi
 868
 869 AC_CACHE_SAVE
 870
 871 dnl GMP tests
 872 AC_LIB_HAVE_LINKFLAGS([gmp],
 873   [],
 874   [#include <gmp.h>],
 875   [mpz_import (0, 0, 0, 0, 0, 0, 0);])
 876
 877 if test "x$HAVE_LIBGMP" != "xyes"; then
 878   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README])
 879 fi
 880
 881 dnl `mpz_inits' and `mpz_clears' appeared in GMP 5.0.0.
 882 save_CPPFLAGS="$CPPFLAGS"
 883 if test "x$LIBGMP_PREFIX" != "x"; then
 884    CPPFLAGS="-I$LIBGMP_PREFIX $CPPFLAGS"
 885 fi
 886 AC_CHECK_DECLS([mpz_inits], [], [], [[#include <gmp.h>]])
 887 CPPFLAGS="$save_CPPFLAGS"
 888
 889 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 890 if test "x$LTLIBUNISTRING" = "x"; then
 891   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 892 fi
 893
 894 GUILE_LIBUNISTRING_WITH_ICONV_SUPPORT
 895 if test "x$ac_cv_libunistring_with_iconv_support" != "xyes"; then
 896   AC_MSG_ERROR([No iconv support.  Please recompile libunistring with iconv enabled.])
 897 fi
 898
 899 dnl Libffi is needed to compile Guile's foreign function interface, but its
 900 dnl interface isn't exposed in Guile's API.
 901 PKG_CHECK_MODULES(LIBFFI, libffi)
 902 AC_SUBST(LIBFFI_CFLAGS)
 903 AC_SUBST(LIBFFI_LIBS)
 904
 905 dnl figure out approriate ffi type for size_t
 906 AC_CHECK_SIZEOF(size_t)
 907 AC_CHECK_SIZEOF(ssize_t)
 908 ffi_size_type=uint$(($ac_cv_sizeof_size_t*8))
 909 ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8))
 910 AC_DEFINE_UNQUOTED([ffi_type_size_t], ffi_type_${ffi_size_type},
 911                    [ffi type for size_t])
 912 AC_DEFINE_UNQUOTED([ffi_type_ssize_t], ffi_type_${ffi_ssize_type},
 913                    [ffi type for ssize_t])
 914
 915 dnl i18n tests
 916 #AC_CHECK_HEADERS([libintl.h])
 917 #AC_CHECK_FUNCS(gettext)
 918 #if test $ac_cv_func_gettext = no; then
 919 #   AC_CHECK_LIB(intl, gettext)
 920 #fi
 921 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 922 AM_GNU_GETTEXT([external], [need-ngettext])
 923
 924 ### Some systems don't declare some functions.  On such systems, we
 925 ### need to at least provide our own K&R-style declarations.
 926
 927 ### GUILE_FUNC_DECLARED(function, headerfile)
 928
 929 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 930 ### not there, #define MISSING_FUNCTION_DECL.
 931 AC_DEFUN([GUILE_FUNC_DECLARED], [
 932   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 933     AC_EGREP_HEADER($1, $2,
 934                     guile_cv_func_$1_declared=yes,
 935                     guile_cv_func_$1_declared=no))
 936   if test [x$guile_cv_func_]$1[_declared] = xno; then
 937     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 938       [Define if the operating system supplies $1 without declaring it.])
 939   fi
 940 ])
 941
 942 GUILE_FUNC_DECLARED(sleep, unistd.h)
 943 GUILE_FUNC_DECLARED(usleep, unistd.h)
 944
 945 AC_CHECK_DECLS([getlogin, alarm])
 946
 947 AC_CHECK_DECLS([strptime],,,
 948 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 949 #include <time.h>])
 950
 951 ### On some systems usleep has no return value.  If it does have one,
 952 ### we'd like to return it; otherwise, we'll fake it.
 953 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 954   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 955                    unistd.h,
 956                    [guile_cv_func_usleep_return_type=void],
 957                    [guile_cv_func_usleep_return_type=int])])
 958 case "$guile_cv_func_usleep_return_type" in
 959   "void" )
 960     AC_DEFINE([USLEEP_RETURNS_VOID], 1,
 961       [Define if the system headers declare usleep to return void.])
 962   ;;
 963 esac
 964
 965 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 966 if test -n "$have_sys_un_h" ; then
 967   AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1,
 968     [Define if the system supports Unix-domain (file-domain) sockets.])
 969 fi
 970
 971 AC_CHECK_FUNCS(getrlimit setrlimit)
 972
 973 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 974
 975 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 976                setnetent    getnetent    endnetent    dnl
 977                setprotoent  getprotoent  endprotoent  dnl
 978                setservent   getservent   endservent   dnl
 979                getnetbyaddr getnetbyname dnl
 980                inet_lnaof inet_makeaddr inet_netof hstrerror)
 981
 982 AC_CHECK_MEMBERS([struct sockaddr_in.sin_len],,,
 983 [#ifdef HAVE_SYS_TYPES_H
 984 #include <sys/types.h>
 985 #endif
 986 #include <netinet/in.h>])
 987
 988 AC_MSG_CHECKING(for __libc_stack_end)
 989 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 990 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 991 extern char *__libc_stack_end;]],
 992    [[printf("%p", (char*) __libc_stack_end);]])],
 993    [guile_cv_have_libc_stack_end=yes],
 994    [guile_cv_have_libc_stack_end=no])])
 995 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 996
 997 if test $guile_cv_have_libc_stack_end = yes; then
 998   AC_DEFINE([HAVE_LIBC_STACK_END], 1,
 999            [Define if you have the __libc_stack_end variable.])
1000 fi
1001
1002 dnl Some systems do not declare this.  Some systems do declare it, as a
1003 dnl macro.  With cygwin it may be in a DLL.
1004
1005 AC_MSG_CHECKING(whether netdb.h declares h_errno)
1006 AC_CACHE_VAL(guile_cv_have_h_errno,
1007   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1008                                       [[int a = h_errno;]])],
1009   [guile_cv_have_h_errno=yes],
1010   [guile_cv_have_h_errno=no])])
1011 AC_MSG_RESULT($guile_cv_have_h_errno)
1012 if test $guile_cv_have_h_errno = yes; then
1013   AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.])
1014 fi
1015
1016 AC_MSG_CHECKING(whether uint32_t is defined)
1017 AC_CACHE_VAL(guile_cv_have_uint32_t,
1018   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1019                    #if HAVE_STDINT_H
1020                    #include <stdint.h>
1021                    #endif
1022                    #ifndef HAVE_NETDB_H
1023                    #include <netdb.h>
1024                    #endif]],
1025                    [[uint32_t a;]])],
1026                    [guile_cv_have_uint32_t=yes],
1027                    [guile_cv_have_uint32_t=no])])
1028 AC_MSG_RESULT($guile_cv_have_uint32_t)
1029 if test $guile_cv_have_uint32_t = yes; then
1030   AC_DEFINE([HAVE_UINT32_T], 1,
1031     [Define if uint32_t typedef is defined when netdb.h is include.])
1032 fi
1033
1034 AC_MSG_CHECKING(for working IPv6 support)
1035 AC_CACHE_VAL(guile_cv_have_ipv6,
1036 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1037 #ifdef HAVE_SYS_TYPES_H
1038 #include <sys/types.h>
1039 #endif
1040 #include <netinet/in.h>
1041 #include <sys/socket.h>]],
1042 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
1043 [guile_cv_have_ipv6=yes],
1044 [guile_cv_have_ipv6=no])])
1045 AC_MSG_RESULT($guile_cv_have_ipv6)
1046 if test $guile_cv_have_ipv6 = yes; then
1047   AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.])
1048 fi
1049
1050 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
1051 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
1052 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
1053 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1054 #ifdef HAVE_SYS_TYPES_H
1055 #include <sys/types.h>
1056 #endif
1057 #include <netinet/in.h>]],
1058 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
1059 [guile_cv_have_sin6_scope_id=yes],
1060 [guile_cv_have_sin6_scope_id=no])])
1061 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
1062 if test $guile_cv_have_sin6_scope_id = yes; then
1063   AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1,
1064     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
1065 fi
1066
1067 # struct sockaddr_in6 field sin_len is only present on BSD systems
1068 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1069 [#ifdef HAVE_SYS_TYPES_H
1070 #include <sys/types.h>
1071 #endif
1072 #include <netinet/in.h>])
1073
1074 AC_MSG_CHECKING(whether localtime caches TZ)
1075 AC_CACHE_VAL(guile_cv_localtime_cache,
1076 [if test x$ac_cv_func_tzset = xyes; then
1077 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1078 #if STDC_HEADERS
1079 # include <stdlib.h>
1080 #endif
1081 extern char **environ;
1082 unset_TZ ()
1083 {
1084   char **from, **to;
1085   for (to = from = environ; (*to = *from); from++)
1086     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1087       to++;
1088 }
1089 char TZ_GMT0[] = "TZ=GMT0";
1090 char TZ_PST8[] = "TZ=PST8";
1091 main()
1092 {
1093   time_t now = time ((time_t *) 0);
1094   int hour_GMT0, hour_unset;
1095   if (putenv (TZ_GMT0) != 0)
1096     exit (1);
1097   hour_GMT0 = localtime (&now)->tm_hour;
1098   unset_TZ ();
1099   hour_unset = localtime (&now)->tm_hour;
1100   if (putenv (TZ_PST8) != 0)
1101     exit (1);
1102   if (localtime (&now)->tm_hour == hour_GMT0)
1103     exit (1);
1104   unset_TZ ();
1105   if (localtime (&now)->tm_hour != hour_unset)
1106     exit (1);
1107   exit (0);
1108 }]])],
1109 [guile_cv_localtime_cache=no],
1110 [guile_cv_localtime_cache=yes],
1111 [# If we have tzset, assume the worst when cross-compiling.
1112 guile_cv_localtime_cache=yes])
1113 else
1114         # If we lack tzset, report that localtime does not cache TZ,
1115         # since we can't invalidate the cache if we don't have tzset.
1116         guile_cv_localtime_cache=no
1117 fi])dnl
1118 AC_MSG_RESULT($guile_cv_localtime_cache)
1119 if test $guile_cv_localtime_cache = yes; then
1120   AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.])
1121 fi
1122
1123 if test "$enable_regex" = yes; then
1124    AC_LIBOBJ([regex-posix])
1125    AC_DEFINE([ENABLE_REGEX], 1, [Define when regex support is enabled.])
1126 fi
1127
1128 AC_REPLACE_FUNCS([strerror memmove mkstemp])
1129
1130 # Reasons for testing:
1131 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1132 #                                older systems
1133 #   sincos - GLIBC extension
1134 #
1135 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1136
1137 # C99 specifies isinf and isnan as macros.
1138 # HP-UX provides only macros, no functions.
1139 # glibc 2.3.2 provides both macros and functions.
1140 # IRIX 6.5 and Solaris 8 only provide functions.
1141 #
1142 # The following tests detect isinf and isnan either as functions or as
1143 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1144 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1145 #
1146 AC_MSG_CHECKING([for isinf])
1147 AC_LINK_IFELSE([AC_LANG_SOURCE(
1148 [[#include <math.h>
1149 volatile double x = 0.0;
1150 int main () { return (isinf(x) != 0); }]])],
1151   [AC_MSG_RESULT([yes])
1152    AC_DEFINE([HAVE_ISINF], 1,
1153              [Define to 1 if you have the `isinf' macro or function.])],
1154   [AC_MSG_RESULT([no])])
1155 AC_MSG_CHECKING([for isnan])
1156 AC_LINK_IFELSE([AC_LANG_SOURCE([[
1157 #include <math.h>
1158 volatile double x = 0.0;
1159 int main () { return (isnan(x) != 0); }]])],
1160   [AC_MSG_RESULT([yes])
1161    AC_DEFINE([HAVE_ISNAN], 1,
1162              [Define to 1 if you have the `isnan' macro or function.])],
1163   [AC_MSG_RESULT([no])])
1164
1165 # Reasons for checking:
1166 #
1167 #     st_rdev
1168 #     st_blksize
1169 #     st_blocks   not in mingw
1170 #     tm_gmtoff   BSD+GNU, not in C99
1171 #
1172 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1173 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1174 #
1175 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,,
1176                  [#define _GNU_SOURCE
1177 AC_INCLUDES_DEFAULT
1178 ])
1179
1180 AC_STRUCT_TIMEZONE
1181 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1182 [#include <time.h>
1183 #ifdef TIME_WITH_SYS_TIME
1184 # include <sys/time.h>
1185 # include <time.h>
1186 #else
1187 # if HAVE_SYS_TIME_H
1188 #  include <sys/time.h>
1189 # else
1190 #  include <time.h>
1191 # endif
1192 #endif
1193 ])
1194 GUILE_STRUCT_UTIMBUF
1195
1196
1197 #--------------------------------------------------------------------
1198 #
1199 # What values do the iconv error handlers have?
1200 #
1201 # The only place that we need iconv in our public interfaces is for
1202 # the error handlers, which are just ints.  So we weaken our
1203 # dependency by looking up those values at configure-time.
1204 #--------------------------------------------------------------------
1205 GUILE_UNISTRING_ICONVEH_VALUES
1206
1207 #--------------------------------------------------------------------
1208 #
1209 # Which way does the stack grow?
1210 #
1211 # Following code comes from Autoconf 2.69's internal _AC_LIBOBJ_ALLOCA
1212 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1213 # very similar code, so in future we could look at using that.
1214 #
1215 # An important detail is that the code involves find_stack_direction
1216 # calling _itself_ - which means that find_stack_direction (or at
1217 # least the second find_stack_direction() call) cannot be inlined.
1218 # If the code could be inlined, that might cause the test to give
1219 # an incorrect answer.
1220 #--------------------------------------------------------------------
1221
1222 SCM_I_GSC_STACK_GROWS_UP=0
1223 AC_RUN_IFELSE([AC_LANG_SOURCE(
1224 [AC_INCLUDES_DEFAULT
1225 int
1226 find_stack_direction (int *addr, int depth)
1227 {
1228   int dir, dummy = 0;
1229   if (! addr)
1230     addr = &dummy;
1231   *addr = addr < &dummy ? 1 : addr == &dummy ? 0 : -1;
1232   dir = depth ? find_stack_direction (addr, depth - 1) : 0;
1233   return dir + dummy;
1234 }
1235
1236 int
1237 main (int argc, char **argv)
1238 {
1239   return find_stack_direction (0, argc + !argv + 20) < 0;
1240 }])],
1241                [SCM_I_GSC_STACK_GROWS_UP=1],
1242                [],
1243                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1244
1245 #--------------------------------------------------------------------
1246 #
1247 # Boehm's GC library
1248 #
1249 #--------------------------------------------------------------------
1250 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1251
1252 save_LIBS="$LIBS"
1253 LIBS="$BDW_GC_LIBS $LIBS"
1254 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1255
1256 AC_CHECK_FUNCS([GC_do_blocking GC_call_with_gc_active GC_pthread_exit   \
1257   GC_pthread_cancel GC_allow_register_threads GC_pthread_sigmask        \
1258   GC_set_start_callback GC_get_heap_usage_safe                          \
1259   GC_get_free_space_divisor GC_gcollect_and_unmap GC_get_unmapped_bytes \
1260   GC_set_finalizer_notifier GC_set_finalize_on_demand                   \
1261   GC_set_all_interior_pointers GC_get_gc_no GC_set_java_finalization])
1262
1263 # Though the `GC_do_blocking ()' symbol is present in GC 7.1, it is not
1264 # declared, and has a different type (returning void instead of
1265 # void*).
1266 AC_CHECK_DECL([GC_do_blocking],
1267   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1268     [Define this if the `GC_do_blocking ()' function is declared])],
1269   [],
1270   [#include <gc/gc.h>])
1271
1272 # `GC_fn_type' is not available in GC 7.1 and earlier.
1273 AC_CHECK_TYPE([GC_fn_type],
1274   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1275     [Define this if the `GC_fn_type' type is available.])],
1276   [],
1277   [#include <gc/gc.h>])
1278
1279 # `GC_stack_base' is not available in GC 7.1 and earlier.
1280 AC_CHECK_TYPE([struct GC_stack_base],
1281   [AC_DEFINE([HAVE_GC_STACK_BASE], [1],
1282     [Define this if the `GC_stack_base' type is available.])],
1283   [],
1284   [#include <gc/gc.h>])
1285
1286 LIBS="$save_LIBS"
1287
1288
1289 AC_CHECK_SIZEOF(float)
1290 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1291     AC_DEFINE([SCM_SINGLES], 1,
1292               [Define this if floats are the same size as longs.])
1293 fi
1294
1295 AC_MSG_CHECKING(for struct linger)
1296 AC_CACHE_VAL(scm_cv_struct_linger,
1297         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1298 #include <sys/types.h>
1299 #include <sys/socket.h>]],
1300                           [[struct linger lgr;  lgr.l_linger = 100]])],
1301                           [scm_cv_struct_linger="yes"],
1302                           [scm_cv_struct_linger="no"]))
1303 AC_MSG_RESULT($scm_cv_struct_linger)
1304 if test $scm_cv_struct_linger = yes; then
1305         AC_DEFINE([HAVE_STRUCT_LINGER], 1,
1306           [Define this if your system defines struct linger, for use with the
1307            getsockopt and setsockopt system calls.])
1308 fi
1309
1310
1311 dnl Check for `struct timespec', for the sake of `gen-scmconfig'.  When
1312 dnl building Guile, we always have it, thanks to Gnulib; but scmconfig.h
1313 dnl must tell whether the system has it.
1314 dnl
1315 dnl On MinGW, struct timespec is in <pthread.h>.
1316 AC_MSG_CHECKING(for struct timespec)
1317 AC_CACHE_VAL(scm_cv_struct_timespec,
1318         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1319 #include <time.h>
1320 #if HAVE_PTHREAD_H
1321 #include <pthread.h>
1322 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1323           [scm_cv_struct_timespec="yes"],
1324           [scm_cv_struct_timespec="no"]))
1325 AC_MSG_RESULT($scm_cv_struct_timespec)
1326 if test $scm_cv_struct_timespec = yes; then
1327   dnl Don't call it `HAVE_STRUCT_TIMESPEC' because pthread-win32's
1328   dnl <pthread.h> checks whether that macro is defined.
1329   AC_DEFINE([HAVE_SYSTEM_STRUCT_TIMESPEC], 1,
1330     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1331 fi
1332
1333 #--------------------------------------------------------------------
1334 #
1335 # Flags for thread support
1336 #
1337 #--------------------------------------------------------------------
1338
1339 SCM_I_GSC_USE_PTHREAD_THREADS=0
1340 SCM_I_GSC_USE_NULL_THREADS=0
1341 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1342 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1343
1344 ### What thread package has the user asked for?
1345 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1346             , with_threads=yes)
1347
1348 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1349 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1350
1351 case "$with_threads" in
1352   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1353
1354     build_pthread_support="yes"
1355
1356     ACX_PTHREAD([CC="$PTHREAD_CC"
1357        LIBS="$PTHREAD_LIBS $LIBS"
1358        SCM_I_GSC_USE_PTHREAD_THREADS=1
1359        with_threads="pthreads"],
1360       [with_threads="null"
1361        build_pthread_support="no"])
1362
1363     old_CFLAGS="$CFLAGS"
1364     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1365
1366     # Reasons for testing:
1367     #     pthread_getattr_np - "np" meaning "non portable" says it
1368     #         all; not present on MacOS X or Solaris 10
1369     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1370     #         all; specific to MacOS X
1371     #     pthread_attr_get_np - "np" meaning "non portable" says it
1372     #         all; specific to FreeBSD
1373     #     pthread_sigmask - not available on mingw
1374     #
1375     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_attr_get_np pthread_sigmask)
1376
1377     # On past versions of Solaris, believe 8 through 10 at least, you
1378     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1379     # This is contrary to POSIX:
1380     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1381     # Check here if this style is required.
1382     #
1383     # glibc (2.3.6 at least) works both with or without braces, so the
1384     # test checks whether it works without.
1385     #
1386
1387     if test "$GCC" = "yes"; then
1388       # Since GCC only issues a warning for missing braces, so we need
1389       # `-Werror' to catch it.
1390       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1391     fi
1392
1393     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1394       guile_cv_need_braces_on_pthread_once_init,
1395       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>
1396          pthread_once_t foo = PTHREAD_ONCE_INIT;]])],
1397         [guile_cv_need_braces_on_pthread_once_init=no],
1398         [guile_cv_need_braces_on_pthread_once_init=yes])])
1399     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1400       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1401     fi
1402
1403     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1404     # 6.5.30m with GCC 3.3.
1405     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1406       guile_cv_need_braces_on_pthread_mutex_initializer,
1407       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>
1408          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;]])],
1409         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1410         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1411     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1412       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1413     fi
1414
1415     CFLAGS="$old_CFLAGS"
1416
1417     # On Solaris, sched_yield lives in -lrt.
1418     AC_SEARCH_LIBS(sched_yield, rt)
1419
1420   ;;
1421 esac
1422
1423 case "$with_threads" in
1424   "pthreads")
1425   ;;
1426   "no" | "null")
1427     SCM_I_GSC_USE_NULL_THREADS=1
1428     SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
1429     with_threads="null-threads"
1430   ;;
1431   * )
1432     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1433   ;;
1434 esac
1435
1436 AC_MSG_CHECKING(what kind of threads to support)
1437 AC_MSG_RESULT($with_threads)
1438
1439 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1440   [test "x$build_pthread_support" = "xyes"])
1441
1442
1443 if test "$with_threads" = pthreads; then
1444
1445 dnl Normally Gnulib's 'threadlib' module would define this macro, but
1446 dnl since we don't use it, define it by ourselves.
1447 AC_DEFINE([USE_POSIX_THREADS], [1],
1448   [Define to let Gnulib modules know that we use POSIX threads.])
1449
1450 AC_MSG_CHECKING([whether pthread_attr_getstack works for the main thread])
1451 old_CFLAGS="$CFLAGS"
1452 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1453 if test "$cross_compiling" = "no"; then
1454   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1455   #if HAVE_PTHREAD_ATTR_GETSTACK
1456   #include <pthread.h>
1457
1458   int main ()
1459   {
1460     pthread_attr_t attr;
1461     void *start, *end;
1462     size_t size;
1463
1464     pthread_getattr_np (pthread_self (), &attr);
1465     pthread_attr_getstack (&attr, &start, &size);
1466     end = (char *)start + size;
1467
1468     if ((void *)&attr < start || (void *)&attr >= end)
1469       return 1;
1470     else
1471       return 0;
1472   }
1473   #else
1474   int main ()
1475   {
1476     return 1;
1477   }
1478   #endif
1479   ]])],
1480   [works=yes
1481    AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])],
1482   [works=no],
1483   [])
1484 else
1485   works="assuming it doesn't"
1486 fi
1487 CFLAGS="$old_CFLAGS"
1488 AC_MSG_RESULT($works)
1489
1490 GUILE_THREAD_LOCAL_STORAGE
1491
1492 fi # with_threads=pthreads
1493
1494
1495 ## Cross building
1496 if test "$cross_compiling" = "yes"; then
1497   AC_MSG_CHECKING(cc for build)
1498   ## /usr/bin/cc still uses wrong assembler
1499   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1500   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1501 else
1502   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1503 fi
1504
1505 ## AC_MSG_CHECKING("if we are cross compiling")
1506 ## AC_MSG_RESULT($cross_compiling)
1507 if test "$cross_compiling" = "yes"; then
1508    AC_MSG_RESULT($CC_FOR_BUILD)
1509 fi
1510
1511 ## No need as yet to be more elaborate
1512 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1513
1514 AC_SUBST(cross_compiling)
1515 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1516 AC_SUBST(CCLD_FOR_BUILD)
1517
1518 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1519 ## --HOST is the platform that PACKAGE is compiled for.
1520 HOST_CC="$CC_FOR_BUILD"
1521 AC_SUBST(HOST_CC)
1522
1523 GUILE_CHECK_GUILE_FOR_BUILD
1524
1525 ## If we're using GCC, add flags to reduce strictness of undefined
1526 ## behavior, and ask for aggressive warnings.
1527 GCC_CFLAGS=""
1528 case "$GCC" in
1529   yes )
1530     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1531     ## much stuff with generic function pointers for that to really be
1532     ## less than exasperating.
1533     ## -Wundef was removed because Gnulib prevented it (see
1534     ## <http://thread.gmane.org/gmane.lisp.guile.bugs/5329>.)
1535
1536     ## Build with `-fno-strict-aliasing' and `-fwrapv' to prevent
1537     ## miscompilation on some platforms.  See
1538     ## <http://lists.gnu.org/archive/html/guile-devel/2012-01/msg00487.html>.
1539
1540     POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \
1541       -Wdeclaration-after-statement -Wpointer-arith \
1542       -Wswitch-enum -fno-strict-aliasing -fwrapv"
1543     # Do this here so we don't screw up any of the tests above that might
1544     # not be "warning free"
1545     if test "${GUILE_ERROR_ON_WARNING}" = yes
1546     then
1547         POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror"
1548         enable_compile_warnings=no
1549     fi
1550
1551     for flag in $POTENTIAL_GCC_CFLAGS
1552     do
1553         gl_WARN_ADD([$flag], [GCC_CFLAGS])
1554     done
1555     ;;
1556 esac
1557
1558 AC_SUBST(GCC_CFLAGS)
1559
1560 # Check for GNU ld's "-z relro".
1561 GUILE_GNU_LD_RELRO
1562
1563
1564 LIBLOBJS=""
1565 for file in $LIBOBJS; do
1566   file=`echo "$file" | sed 's,\.[[^.]]*$,.lo,'`
1567   LIBLOBJS="$LIBLOBJS libguile_${GUILE_EFFECTIVE_VERSION}_la-$file"
1568 done
1569
1570 ## We also need to create corresponding .doc and .x files
1571 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1572 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1573
1574 # GNU Readline bindings.
1575 GUILE_READLINE
1576
1577 AC_SUBST(GUILE_MAJOR_VERSION)
1578 AC_SUBST(GUILE_MINOR_VERSION)
1579 AC_SUBST(GUILE_MICRO_VERSION)
1580 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1581 AC_SUBST(GUILE_VERSION)
1582
1583 #######################################################################
1584 # library versioning
1585
1586 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1587 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1588 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1589 AC_SUBST(LIBGUILE_INTERFACE)
1590
1591 AC_SUBST(LIBGUILE_I18N_MAJOR)
1592 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1593 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1594 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1595 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1596
1597
1598 #######################################################################
1599
1600 dnl Tell guile-config what flags guile users should compile and link
1601 dnl with, keeping only `-I' flags from $CPPFLAGS.
1602 GUILE_CFLAGS=""
1603 next_is_includedir=false
1604 for flag in $CPPFLAGS
1605 do
1606   if $next_is_includedir; then
1607     GUILE_CFLAGS="$GUILE_CFLAGS -I $flag"
1608     next_is_includedir=false
1609   else
1610     case "$flag" in
1611       -I)  next_is_includedir=true;;
1612       -I*) GUILE_CFLAGS="$GUILE_CFLAGS $flag";;
1613       *)   ;;
1614     esac
1615   fi
1616 done
1617
1618 GUILE_CFLAGS="$GUILE_CFLAGS $PTHREAD_CFLAGS"
1619 GUILE_LIBS="$LDFLAGS $LIBS"
1620
1621 AC_SUBST(GUILE_LIBS)
1622 AC_SUBST(GUILE_CFLAGS)
1623
1624 AC_SUBST(AWK)
1625 AC_SUBST(LIBLOBJS)
1626 AC_SUBST(EXTRA_DOT_DOC_FILES)
1627 AC_SUBST(EXTRA_DOT_X_FILES)
1628
1629 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1630 top_builddir_absolute=`pwd`
1631 AC_SUBST(top_builddir_absolute)
1632 top_srcdir_absolute=`(cd $srcdir && pwd)`
1633 AC_SUBST(top_srcdir_absolute)
1634
1635 dnl Add -I flag so that lib/glthread/lock.h finds <libguile/threads.h>.
1636 CPPFLAGS="-I$top_srcdir_absolute $CPPFLAGS"
1637
1638 dnl `sitedir' goes into libpath.h and the pkg-config file.
1639 pkgdatadir="$datadir/$PACKAGE_TARNAME"
1640 sitedir="$pkgdatadir/site/$GUILE_EFFECTIVE_VERSION"
1641 AC_SUBST([sitedir])
1642
1643 # Additional SCM_I_GSC definitions are above.
1644 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1645 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1646 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1647 AC_SUBST([SCM_I_GSC_C_INLINE])
1648 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1649
1650 AC_CONFIG_FILES([
1651   Makefile
1652   am/Makefile
1653   lib/Makefile
1654   benchmark-suite/Makefile
1655   gc-benchmarks/Makefile
1656   doc/Makefile
1657   doc/r5rs/Makefile
1658   doc/ref/Makefile
1659   emacs/Makefile
1660   examples/Makefile
1661   libguile/Makefile
1662   libguile/version.h
1663   guile-readline/Makefile
1664   test-suite/Makefile
1665   test-suite/standalone/Makefile
1666   test-suite/vm/Makefile
1667   meta/Makefile
1668   module/Makefile
1669 ])
1670
1671 AC_CONFIG_FILES([meta/guile-2.0.pc])
1672 AC_CONFIG_FILES([meta/guile-2.0-uninstalled.pc])
1673
1674 GUILE_CONFIG_SCRIPT([check-guile])
1675 GUILE_CONFIG_SCRIPT([benchmark-guile])
1676 GUILE_CONFIG_SCRIPT([meta/guile])
1677 GUILE_CONFIG_SCRIPT([meta/uninstalled-env])
1678 GUILE_CONFIG_SCRIPT([meta/gdb-uninstalled-guile])
1679 GUILE_CONFIG_SCRIPT([libguile/guile-snarf])
1680 GUILE_CONFIG_SCRIPT([libguile/guile-snarf-docs])
1681 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-use-srfi])
1682 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-fast-slot-ref])
1683
1684 AC_OUTPUT
1685
1686 dnl Local Variables:
1687 dnl comment-start: "dnl "
1688 dnl comment-end: ""
1689 dnl comment-start-skip: "\\bdnl\\b\\s *"
1690 dnl End: