configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   8   2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   9
  10 This file is part of GUILE
  11
  12 GUILE is free software; you can redistribute it and/or modify it under
  13 the terms of the GNU Lesser General Public License as published by the
  14 Free Software Foundation; either version 3, or (at your option) any
  15 later version.
  16
  17 GUILE is distributed in the hope that it will be useful, but WITHOUT
  18 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  19 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  20 License for more details.
  21
  22 You should have received a copy of the GNU Lesser General Public
  23 License along with GUILE; see the file COPYING.LESSER.  If not, write
  24 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  25 Floor, Boston, MA 02110-1301, USA.
  26
  27 ]])
  28
  29 AC_PREREQ(2.61)
  30
  31 AC_INIT([GNU Guile],
  32         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  33         [bug-guile@gnu.org])
  34 AC_CONFIG_AUX_DIR([build-aux])
  35 AC_CONFIG_MACRO_DIR([m4])
  36 AC_CONFIG_SRCDIR(GUILE-VERSION)
  37
  38 AM_INIT_AUTOMAKE([gnu no-define -Wall -Wno-override])
  39 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AC_SUBST([AM_DEFAULT_VERBOSITY],1)])
  40
  41 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  42 AC_CONFIG_SRCDIR([GUILE-VERSION])
  43
  44 . $srcdir/GUILE-VERSION
  45 GUILE_VERSION="$PACKAGE_VERSION"
  46
  47 AC_CONFIG_HEADERS([config.h])
  48 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  49
  50 #--------------------------------------------------------------------
  51
  52 AC_LANG([C])
  53
  54 dnl Some more checks for Win32
  55 AC_CANONICAL_HOST
  56
  57 AC_LIBTOOL_WIN32_DLL
  58
  59 AC_PROG_INSTALL
  60 AC_PROG_CC
  61 gl_EARLY
  62 AC_PROG_CPP
  63 AC_PROG_SED
  64 AC_PROG_AWK
  65
  66 dnl Gnulib.
  67 gl_INIT
  68 dnl FIXME: remove me and the acinclude.m4 code when clock-gettime is
  69 dnl LGPL-compatible and can be imported normally.
  70 gl_CLOCK_TIME
  71
  72 AC_PROG_CC_C89
  73
  74 # for per-target cflags in the libguile subdir
  75 AM_PROG_CC_C_O
  76
  77 AC_LIBTOOL_DLOPEN
  78 AC_PROG_LIBTOOL
  79
  80 AM_CONDITIONAL([HAVE_SHARED_LIBRARIES], [test "x$enable_shared" = "xyes"])
  81
  82 AC_DEFINE_UNQUOTED([SHARED_LIBRARY_PATH_VARIABLE], ["$shlibpath_var"],
  83   [Name of the environment variable that tells the dynamic linker where
  84 to find shared libraries.])
  85
  86 dnl Check for libltdl.
  87 AC_LIB_HAVE_LINKFLAGS([ltdl], [], [#include <ltdl.h>],
  88   [lt_dlopenext ("foo");])
  89 if test "x$HAVE_LIBLTDL" != "xyes"; then
  90   AC_MSG_ERROR([GNU libltdl (Libtool) not found, see README.])
  91 fi
  92
  93 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  94 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  95
  96 AM_PATH_LISPDIR
  97
  98 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
  99   [Define to the host's GNU triplet.])
 100
 101 #--------------------------------------------------------------------
 102 #
 103 # User options (after above tests that may set default CFLAGS etc.)
 104 #
 105 #--------------------------------------------------------------------
 106
 107 GUILE_ERROR_ON_WARNING="no"
 108
 109 AC_ARG_ENABLE(error-on-warning,
 110   [  --enable-error-on-warning    treat compile warnings as errors],
 111   [case "${enableval}" in
 112      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 113      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 114      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 115    esac])
 116
 117 AC_ARG_ENABLE(debug-malloc,
 118   [  --enable-debug-malloc   include malloc debugging code],
 119   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 120     AC_DEFINE([GUILE_DEBUG_MALLOC], 1,
 121       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 122   fi)
 123
 124 SCM_I_GSC_GUILE_DEBUG=0
 125 AC_ARG_ENABLE(guile-debug,
 126   [AS_HELP_STRING([--enable-guile-debug],
 127                   [include internal debugging functions])],
 128   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 129     SCM_I_GSC_GUILE_DEBUG=1
 130   fi)
 131
 132 AC_ARG_ENABLE(posix,
 133   [  --disable-posix         omit non-essential POSIX interfaces],,
 134   enable_posix=yes)
 135
 136 AC_ARG_ENABLE(networking,
 137   [  --disable-networking    omit networking interfaces],,
 138   enable_networking=yes)
 139
 140 AC_ARG_ENABLE(regex,
 141   [  --disable-regex         omit regular expression interfaces],,
 142   enable_regex=yes)
 143
 144 AC_ARG_ENABLE([deprecated],
 145   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 146
 147 if test "$enable_deprecated" = no; then
 148   SCM_I_GSC_ENABLE_DEPRECATED=0
 149   warn_default=no
 150 else
 151   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 152     warn_default=summary
 153   elif test "$enable_deprecated" = shutup; then
 154     warn_default=no
 155   else
 156     warn_default=$enable_deprecated
 157   fi
 158   SCM_I_GSC_ENABLE_DEPRECATED=1
 159 fi
 160 AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default",
 161 [Define this to control the default warning level for deprecated features.])
 162
 163 dnl  Added the following configure option in January 2008 following
 164 dnl  investigation of problems with "64" system and library calls on
 165 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 166 dnl  system has stat64, it will have all the other 64 APIs too; but on
 167 dnl  Darwin, stat64 is there but other APIs are missing.
 168 dnl
 169 dnl  It also appears, from the Darwin docs, that most system call APIs
 170 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 171 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 172 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 173 dnl
 174 dnl  A similar problem has been reported for HP-UX:
 175 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 176 dnl
 177 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 178 dnl  better than no Guile at all, we provide this option to suppress
 179 dnl  trying to use "64" calls.
 180 dnl
 181 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 182 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 183 dnl  missing out on that.  If so, someone can work on that in the future.
 184 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 185 dnl  wasn't building before.
 186 AC_MSG_CHECKING([whether to use system and library "64" calls])
 187 AC_ARG_WITH([64-calls],
 188   AS_HELP_STRING([--without-64-calls],
 189                  [don't attempt to use system and library calls with "64" in their names]),
 190   [use_64_calls=$withval],
 191   [use_64_calls=yes
 192    case $host in
 193      *-apple-darwin* )
 194        use_64_calls=no
 195        ;;
 196      powerpc-ibm-aix* )
 197        use_64_calls=no
 198        ;;
 199    esac])
 200 AC_MSG_RESULT($use_64_calls)
 201 case "$use_64_calls" in
 202   y* )
 203     AC_DEFINE([GUILE_USE_64_CALLS], 1,
 204       [Define to 1 in order to try to use "64" versions of system and library calls.])
 205     ;;
 206 esac
 207
 208 #--------------------------------------------------------------------
 209
 210 dnl Check for dynamic linking
 211
 212 use_modules=yes
 213 AC_ARG_WITH(modules,
 214 [  --with-modules[=FILES]  Add support for dynamic modules],
 215 use_modules="$withval")
 216 test -z "$use_modules" && use_modules=yes
 217 DLPREOPEN=
 218 if test "$use_modules" != no; then
 219   if test "$use_modules" = yes; then
 220     DLPREOPEN="-dlpreopen force"
 221   else
 222     DLPREOPEN="-export-dynamic"
 223     for module in $use_modules; do
 224       DLPREOPEN="$DLPREOPEN -dlopen $module"
 225     done
 226   fi
 227 fi
 228
 229 dnl files which are destined for separate modules.
 230
 231 if test "$use_modules" != no; then
 232    AC_LIBOBJ([dynl])
 233 fi
 234
 235 if test "$enable_posix" = yes; then
 236    AC_LIBOBJ([posix])
 237    AC_DEFINE([HAVE_POSIX], 1,
 238      [Define this if you want support for non-essential POSIX system calls in Guile.])
 239 fi
 240
 241 if test "$enable_networking" = yes; then
 242    AC_LIBOBJ([net_db])
 243    AC_LIBOBJ([socket])
 244    AC_DEFINE([HAVE_NETWORKING], 1,
 245      [Define this if you want support for networking in Guile.])
 246 fi
 247
 248 if test "$enable_debug_malloc" = yes; then
 249    AC_LIBOBJ([debug-malloc])
 250 fi
 251
 252 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 253
 254 AC_C_CONST
 255
 256 # "volatile" is used in a couple of tests below.
 257 AC_C_VOLATILE
 258
 259 AC_C_INLINE
 260 if test "$ac_cv_c_inline" != no; then
 261   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 262 else
 263   SCM_I_GSC_C_INLINE=NULL
 264 fi
 265 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 266
 267 AC_C_BIGENDIAN
 268
 269 AC_C_LABELS_AS_VALUES
 270
 271 AC_CHECK_SIZEOF(char)
 272 AC_CHECK_SIZEOF(unsigned char)
 273 AC_CHECK_SIZEOF(short)
 274 AC_CHECK_SIZEOF(unsigned short)
 275 AC_CHECK_SIZEOF(int)
 276 AC_CHECK_SIZEOF(unsigned int)
 277 AC_CHECK_SIZEOF(long)
 278 AC_CHECK_SIZEOF(unsigned long)
 279 AC_CHECK_SIZEOF(size_t)
 280 AC_CHECK_SIZEOF(long long)
 281 AC_CHECK_SIZEOF(unsigned long long)
 282 AC_CHECK_SIZEOF(__int64)
 283 AC_CHECK_SIZEOF(unsigned __int64)
 284 AC_CHECK_SIZEOF(void *)
 285 AC_CHECK_SIZEOF(intptr_t)
 286 AC_CHECK_SIZEOF(uintptr_t)
 287 AC_CHECK_SIZEOF(ptrdiff_t)
 288 AC_CHECK_SIZEOF(size_t)
 289 AC_CHECK_SIZEOF(off_t)
 290
 291 if test "$ac_cv_sizeof_long" -gt "$ac_cv_sizeof_void_p"; then
 292   AC_MSG_ERROR(long does not fit into a void*)
 293 fi
 294
 295 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 296   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 297 else
 298   SCM_I_GSC_T_PTRDIFF='"long"'
 299 fi
 300 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 301
 302 AC_CHECK_HEADERS([stdint.h])
 303 AC_CHECK_HEADERS([inttypes.h])
 304
 305 AC_CHECK_SIZEOF(intmax_t)
 306
 307 SCM_I_GSC_NEEDS_STDINT_H=0
 308 SCM_I_GSC_NEEDS_INTTYPES_H=0
 309
 310 ### intptr and uintptr (try not to use inttypes if we don't have to)
 311 if test "$ac_cv_header_inttypes_h" = yes; then
 312   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 313     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 314 #include <stdio.h>])
 315     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 316       SCM_I_GSC_NEEDS_INTTYPES_H=1
 317     fi
 318   fi
 319   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 320     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 321 #include <stdio.h>])
 322     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 323       SCM_I_GSC_NEEDS_INTTYPES_H=1
 324     fi
 325   fi
 326 fi
 327
 328 ### See what's provided by stdint.h
 329 if test "$ac_cv_header_stdint_h" = yes; then
 330    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 331    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 332    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 333    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 334    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 335    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 336    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 337    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 338    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 339    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 340    AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>])
 341    AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>])
 342 fi
 343
 344 # so we don't get confused by the cache (wish there was a better way
 345 # to check particular headers for the same type...)
 346
 347 unset ac_cv_type_int8_t
 348 unset ac_cv_type_uint8_t
 349 unset ac_cv_type_int16_t
 350 unset ac_cv_type_uint16_t
 351 unset ac_cv_type_int32_t
 352 unset ac_cv_type_uint32_t
 353 unset ac_cv_type_int64_t
 354 unset ac_cv_type_uint64_t
 355 unset ac_cv_type_intmax_t
 356 unset ac_cv_type_uintmax_t
 357
 358 ### See what's provided by inttypes.h
 359 if test "$ac_cv_header_inttypes_h" = yes; then
 360   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 361   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 362   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 363   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 364   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 365   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 366   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 367   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 368   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 369   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 370   AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>])
 371   AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>])
 372 fi
 373
 374 # Try hard to find definitions for some required scm_t_*int* types.
 375
 376 ### Required type scm_t_int8
 377 if test "$scm_stdint_has_int8"; then
 378   SCM_I_GSC_T_INT8='"int8_t"'
 379   SCM_I_GSC_NEEDS_STDINT_H=1
 380 elif test "$scm_inttypes_has_int8"; then
 381   SCM_I_GSC_T_INT8='"int8_t"'
 382   SCM_I_GSC_NEEDS_INTTYPES_H=1
 383 elif test "$ac_cv_sizeof_char" -eq 1; then
 384   SCM_I_GSC_T_INT8='"signed char"'
 385 else
 386   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 387 fi
 388 AC_SUBST([SCM_I_GSC_T_INT8])
 389
 390 ### Required type scm_t_uint8
 391 if test "$scm_stdint_has_uint8"; then
 392   SCM_I_GSC_T_UINT8='"uint8_t"'
 393   SCM_I_GSC_NEEDS_STDINT_H=1
 394 elif test "$scm_inttypes_has_uint8"; then
 395   SCM_I_GSC_T_UINT8='"uint8_t"'
 396   SCM_I_GSC_NEEDS_INTTYPES_H=1
 397 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 398   SCM_I_GSC_T_UINT8='"unsigned char"'
 399 else
 400   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 401 fi
 402 AC_SUBST([SCM_I_GSC_T_UINT8])
 403
 404 ### Required type scm_t_int16 (ANSI C says int or short might work)
 405 if test "$scm_stdint_has_int16"; then
 406   SCM_I_GSC_T_INT16='"int16_t"'
 407   SCM_I_GSC_NEEDS_STDINT_H=1
 408 elif test "$scm_inttypes_has_int16"; then
 409   SCM_I_GSC_T_INT16='"int16_t"'
 410   SCM_I_GSC_NEEDS_INTTYPES_H=1
 411 elif test "$ac_cv_sizeof_int" -eq 2; then
 412   SCM_I_GSC_T_INT16='"int"'
 413 elif test "$ac_cv_sizeof_short" -eq 2; then
 414   SCM_I_GSC_T_INT16='"short"'
 415 else
 416   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 417 fi
 418 AC_SUBST([SCM_I_GSC_T_INT16])
 419
 420 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 421 if test "$scm_stdint_has_uint16"; then
 422   SCM_I_GSC_T_UINT16='"uint16_t"'
 423   SCM_I_GSC_NEEDS_STDINT_H=1
 424 elif test "$scm_inttypes_has_uint16"; then
 425   SCM_I_GSC_T_UINT16='"uint16_t"'
 426   SCM_I_GSC_NEEDS_INTTYPES_H=1
 427 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 428   SCM_I_GSC_T_UINT16='"unsigned int"'
 429 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 430   SCM_I_GSC_T_UINT16='"unsigned short"'
 431 else
 432   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 433 fi
 434 AC_SUBST([SCM_I_GSC_T_UINT16])
 435
 436
 437 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 438 if test "$scm_stdint_has_int32"; then
 439   SCM_I_GSC_T_INT32='"int32_t"'
 440   SCM_I_GSC_NEEDS_STDINT_H=1
 441 elif test "$scm_inttypes_has_int32"; then
 442   SCM_I_GSC_T_INT32='"int32_t"'
 443   SCM_I_GSC_NEEDS_INTTYPES_H=1
 444 elif test "$ac_cv_sizeof_int" -eq 4; then
 445   SCM_I_GSC_T_INT32='"int"'
 446 elif test "$ac_cv_sizeof_long" -eq 4; then
 447   SCM_I_GSC_T_INT32='"long"'
 448 elif test "$ac_cv_sizeof_short" -eq 4; then
 449   SCM_I_GSC_T_INT32='"short"'
 450 else
 451   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 452 fi
 453 AC_SUBST([SCM_I_GSC_T_INT32])
 454
 455 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 456 if test "$scm_stdint_has_uint32"; then
 457   SCM_I_GSC_T_UINT32='"uint32_t"'
 458   SCM_I_GSC_NEEDS_STDINT_H=1
 459 elif test "$scm_inttypes_has_uint32"; then
 460   SCM_I_GSC_T_UINT32='"uint32_t"'
 461   SCM_I_GSC_NEEDS_INTTYPES_H=1
 462 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 463   SCM_I_GSC_T_UINT32='"unsigned int"'
 464 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 465   SCM_I_GSC_T_UINT32='"unsigned long"'
 466 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 467   SCM_I_GSC_T_UINT32='"unsigned short"'
 468 else
 469   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 470 fi
 471 AC_SUBST([SCM_I_GSC_T_UINT32])
 472
 473 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 474 ### Also try 'long long' and '__int64' if we have it.
 475 SCM_I_GSC_T_INT64=0
 476 if test "$scm_stdint_has_int64"; then
 477   SCM_I_GSC_T_INT64='"int64_t"'
 478   SCM_I_GSC_NEEDS_STDINT_H=1
 479 elif test "$scm_inttypes_has_int64"; then
 480   SCM_I_GSC_T_INT64='"int64_t"'
 481   SCM_I_GSC_NEEDS_INTTYPES_H=1
 482 elif test "$ac_cv_sizeof_int" -eq 8; then
 483   SCM_I_GSC_T_INT64='"int"'
 484 elif test "$ac_cv_sizeof_long" -eq 8; then
 485   SCM_I_GSC_T_INT64='"long"'
 486 elif test "$ac_cv_sizeof_short" -eq 8; then
 487   SCM_I_GSC_T_INT64='"short"'
 488 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 489   SCM_I_GSC_T_INT64='"long long"'
 490 elif test "$ac_cv_sizeof___int64" -eq 8; then
 491   SCM_I_GSC_T_INT64='"__int64"'
 492 else
 493   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 494 fi
 495 AC_SUBST([SCM_I_GSC_T_INT64])
 496
 497
 498 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 499 ### Also try 'long long' and '__int64' if we have it.
 500 SCM_I_GSC_T_UINT64=0
 501 if test "$scm_stdint_has_uint64"; then
 502   SCM_I_GSC_T_UINT64='"uint64_t"'
 503   SCM_I_GSC_NEEDS_STDINT_H=1
 504 elif test "$scm_inttypes_has_uint64"; then
 505   SCM_I_GSC_T_UINT64='"uint64_t"'
 506   SCM_I_GSC_NEEDS_INTTYPES_H=1
 507 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 508   SCM_I_GSC_T_UINT64='"unsigned int"'
 509 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 510   SCM_I_GSC_T_UINT64='"unsigned long"'
 511 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 512   SCM_I_GSC_T_UINT64='"unsigned short"'
 513 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 514   SCM_I_GSC_T_UINT64='"unsigned long long"'
 515 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 516   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 517 else
 518   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 519 fi
 520 AC_SUBST([SCM_I_GSC_T_UINT64])
 521
 522 ### Required type scm_t_intmax
 523 ###
 524 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 525 ### none of them is available, we use 'long'.
 526 ###
 527 SCM_I_GSC_T_INTMAX=0
 528 if test "$scm_stdint_has_intmax"; then
 529   SCM_I_GSC_T_INTMAX='"intmax_t"'
 530   SCM_I_GSC_NEEDS_STDINT_H=1
 531 elif test "$scm_inttypes_has_intmax"; then
 532   SCM_I_GSC_T_INTMAX='"intmax_t"'
 533   SCM_I_GSC_NEEDS_INTTYPES_H=1
 534 elif test "$ac_cv_sizeof___int64" -ne 0; then
 535   SCM_I_GSC_T_INTMAX='"__int64"'
 536 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 537   SCM_I_GSC_T_INTMAX='"long long"'
 538 else
 539   SCM_I_GSC_T_INTMAX='"long"'
 540 fi
 541 AC_SUBST([SCM_I_GSC_T_INTMAX])
 542
 543 ### Required type scm_t_uintmax
 544 ###
 545 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 546 ### this order.  When none of them is available, we use 'unsigned long'.
 547 ###
 548 SCM_I_GSC_T_UINTMAX=0
 549 if test "$scm_stdint_has_uintmax"; then
 550   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 551   SCM_I_GSC_NEEDS_STDINT_H=1
 552 elif test "$scm_inttypes_has_uintmax"; then
 553   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 554   SCM_I_GSC_NEEDS_INTTYPES_H=1
 555 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 556   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 557 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 558   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 559 else
 560   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 561 fi
 562 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 563
 564 ### Required type scm_t_intptr
 565 ###
 566 SCM_I_GSC_T_INTPTR=0
 567 if test "$scm_stdint_has_intptr"; then
 568   SCM_I_GSC_T_INTPTR='"intptr_t"'
 569   SCM_I_GSC_NEEDS_STDINT_H=1
 570 elif test "$scm_inttypes_has_intptr"; then
 571   SCM_I_GSC_T_INTPTR='"intptr_t"'
 572   SCM_I_GSC_NEEDS_INTTYPES_H=1
 573 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 574   SCM_I_GSC_T_INTPTR='"int"'
 575 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 576   SCM_I_GSC_T_INTPTR='"long"'
 577 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 578   SCM_I_GSC_T_INTPTR='"long long"'
 579 else
 580   AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.])
 581 fi
 582 AC_SUBST([SCM_I_GSC_T_INTPTR])
 583
 584 ### Required type scm_t_uintptr
 585 ###
 586 SCM_I_GSC_T_UINTPTR=0
 587 if test "$scm_stdint_has_uintptr"; then
 588   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 589   SCM_I_GSC_NEEDS_STDINT_H=1
 590 elif test "$scm_inttypes_has_uintptr"; then
 591   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 592   SCM_I_GSC_NEEDS_INTTYPES_H=1
 593 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 594   SCM_I_GSC_T_UINTPTR='"unsigned int"'
 595 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 596   SCM_I_GSC_T_UINTPTR='"unsigned long"'
 597 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 598   SCM_I_GSC_T_UINTPTR='"unsigned long long"'
 599 else
 600   AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.])
 601 fi
 602 AC_SUBST([SCM_I_GSC_T_UINTPTR])
 603
 604
 605 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 606 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 607
 608 AC_HEADER_STDC
 609 AC_HEADER_TIME
 610 AC_HEADER_SYS_WAIT
 611 AC_HEADER_DIRENT
 612
 613 # Reason for checking:
 614 #
 615 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 616 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 617 #
 618 AC_CHECK_MEMBER([struct dirent64.d_name],
 619   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 620   [ #ifndef _LARGEFILE64_SOURCE
 621     # define _LARGEFILE64_SOURCE
 622     #endif
 623
 624     /* Per Autoconf manual.  */
 625     #include <sys/types.h>
 626     #ifdef HAVE_DIRENT_H
 627     # include <dirent.h>
 628     #else
 629     # define dirent direct
 630     # ifdef HAVE_SYS_NDIR_H
 631     #  include <sys/ndir.h>
 632     # endif
 633     # ifdef HAVE_SYS_DIR_H
 634     #  include <sys/dir.h>
 635     # endif
 636     # ifdef HAVE_NDIR_H
 637     #  include <ndir.h>
 638     # endif
 639     #endif ])
 640 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 641
 642 # Reasons for testing:
 643 #   complex.h - new in C99
 644 #   fenv.h - available in C99, but not older systems
 645 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 646 #     this file instead of <fenv.h>
 647 #   process.h - mingw specific
 648 #   langinfo.h, nl_types.h - SuS v2
 649 #   sched.h - missing on MinGW
 650 #
 651 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 652 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 653 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 654 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 655 direct.h langinfo.h nl_types.h machine/fpu.h poll.h sched.h])
 656
 657 # Reasons for testing:
 658 #   nl_item - lacking on Cygwin
 659 AC_CHECK_TYPES([nl_item], [], [],
 660   [[#ifdef HAVE_LANGINFO_H
 661     # include <langinfo.h>
 662     #endif
 663     #ifdef HAVE_NL_TYPES_H
 664     # include <nl_types.h>
 665     #endif]])
 666
 667 # "complex double" is new in C99, and "complex" is only a keyword if
 668 # <complex.h> is included
 669 AC_CHECK_TYPES(complex double,,,
 670 [#if HAVE_COMPLEX_H
 671 #include <complex.h>
 672 #endif])
 673
 674 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 675 # when testing.
 676 AC_CHECK_TYPE(socklen_t, ,
 677   [AC_DEFINE_UNQUOTED([socklen_t], int,
 678                       [Define to `int' if <sys/socket.h> does not define.])],
 679   [#if HAVE_SYS_TYPES_H
 680 #include <sys/types.h>
 681 #endif
 682 #include <sys/socket.h>
 683 ])
 684
 685 AC_CHECK_TYPES([struct ip_mreq], , , [#include <netinet/in.h>])
 686
 687 GUILE_HEADER_LIBC_WITH_UNISTD
 688
 689 AC_TYPE_GETGROUPS
 690 AC_TYPE_SIGNAL
 691 AC_TYPE_MODE_T
 692
 693 # On mingw -lm is empty, so this test is unnecessary, but it's
 694 # harmless so we don't hard-code to suppress it.
 695 #
 696 AC_CHECK_LIB(m, cos)
 697
 698 AC_CHECK_FUNCS(gethostbyname)
 699 if test $ac_cv_func_gethostbyname = no; then
 700     AC_CHECK_LIB(nsl, gethostbyname)
 701 fi
 702
 703 AC_CHECK_FUNCS(connect)
 704 if test $ac_cv_func_connect = no; then
 705     AC_CHECK_LIB(socket, connect)
 706 fi
 707
 708 dnl
 709 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 710 dnl
 711 EXTRA_DEFS=""
 712 case $host in
 713   *-*-mingw*)
 714     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 715       [Define if you have the <winsock2.h> header file.])])
 716     AC_CHECK_LIB(ws2_32, main)
 717     AC_LIBOBJ([win32-uname])
 718     AC_LIBOBJ([win32-dirent])
 719     if test "$enable_networking" = yes ; then
 720       AC_LIBOBJ([win32-socket])
 721     fi
 722     if test "$enable_shared" = yes ; then
 723       EXTRA_DEFS="-DSCM_IMPORT"
 724       AC_DEFINE([USE_DLL_IMPORT], 1,
 725         [Define if you need additional CPP macros on Win32 platforms.])
 726     fi
 727     ;;
 728 esac
 729 AC_SUBST(EXTRA_DEFS)
 730
 731 # Reasons for testing:
 732 #   crt_externs.h - Darwin specific
 733 #
 734 AC_CHECK_HEADERS([assert.h crt_externs.h])
 735
 736 # Reasons for testing:
 737 #   DINFINITY - OSF specific
 738 #   DQNAN - OSF specific
 739 #       (DINFINITY and DQNAN are actually global variables, not functions)
 740 #   chsize - an MS-DOS-ism, found in mingw
 741 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 742 #       for gcc to provide the "complex double" type but the system to not
 743 #       have functions like cexp and clog
 744 #   clog10 - not in mingw (though others like clog and csqrt are)
 745 #   fesetround - available in C99, but not older systems
 746 #   ftruncate - posix, but probably not older systems (current mingw
 747 #               has it as an inline for chsize)
 748 #   ioctl - not in mingw.
 749 #   gmtime_r - recent posix, not on old systems
 750 #   pipe - not in mingw
 751 #   _pipe - specific to mingw, taking 3 args
 752 #   poll - since posix 2001
 753 #   readdir_r - recent posix, not on old systems
 754 #   readdir64_r - not available on HP-UX 11.11
 755 #   stat64 - SuS largefile stuff, not on old systems
 756 #   sysconf - not on old systems
 757 #   truncate - not in mingw
 758 #   isblank - available as a GNU extension or in C99
 759 #   _NSGetEnviron - Darwin specific
 760 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 761 #   nl_langinfo - X/Open, not available on Windows.
 762 #   utimensat: posix.1-2008
 763 #   sched_getaffinity, sched_setaffinity: GNU extensions (glibc)
 764 #
 765 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid getsid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe poll readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo utimensat sched_getaffinity sched_setaffinity])
 766
 767 # Reasons for testing:
 768 #   netdb.h - not in mingw
 769 #   sys/param.h - not in mingw
 770 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 771 #       check this specifically, we need it for the timespec test below.
 772 #   sethostname - the function itself check because it's not in mingw,
 773 #       the DECL is checked because Solaris 10 doens't have in any header
 774 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 775 #       declaration isn't anywhere.
 776 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 777 #       only with `_XOPEN_SOURCE' or some such.
 778 #
 779 AC_CHECK_HEADERS([crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h sys/mman.h])
 780 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 781 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 782
 783 # crypt() may or may not be available, for instance in some countries there
 784 # are restrictions on cryptography.
 785 #
 786 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 787 # -lcrypt library (eg. Debian GNU/Linux).
 788 #
 789 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 790 # be careful to avoid -lcrypt in this case, since libtool will see there's
 791 # only a static libcrypt and decide to build only a static libguile.
 792 #
 793 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 794 # libraries already in that list.
 795 #
 796 AC_SEARCH_LIBS(crypt, crypt,
 797   [AC_DEFINE([HAVE_CRYPT],1,
 798              [Define to 1 if you have the `crypt' function.])])
 799
 800 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 801 # work; in the reported cases so far, 1.0fi works well instead.  According
 802 # to the C99 spec, the complex.h header must provide a working definition
 803 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 804 # is a workaround for the failure of some systems to conform to C99.
 805 if test "$ac_cv_type_complex_double" = yes; then
 806   AC_MSG_CHECKING([for i])
 807   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 808 #if HAVE_COMPLEX_H
 809 #include <complex.h>
 810 #endif
 811 complex double z;
 812 ]], [[
 813 z = _Complex_I;
 814 ]])],
 815     [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).])
 816      AC_MSG_RESULT([_Complex_I])],
 817     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 818 #if HAVE_COMPLEX_H
 819 #include <complex.h>
 820 #endif
 821 complex double z;
 822 ]],[[
 823 z = 1.0fi;
 824 ]])],
 825   [AC_DEFINE([GUILE_I],1.0fi)
 826    AC_MSG_RESULT([1.0fi])],
 827   [ac_cv_type_complex_double=no
 828    AC_MSG_RESULT([not available])])])
 829 fi
 830
 831 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 832 # csqrt(-i) returned a negative real part, when it should be positive
 833 # for the principal root.
 834 #
 835 if test "$ac_cv_type_complex_double" = yes; then
 836
 837   AC_CACHE_CHECK([whether csqrt is usable],
 838     guile_cv_use_csqrt,
 839     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 840 #include <complex.h>
 841 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 842    constant, we want to test libc. */
 843 volatile complex double z = - _Complex_I;
 844 int
 845 main (void)
 846 {
 847   z = csqrt (z);
 848   if (creal (z) > 0.0)
 849     return 0;  /* good */
 850   else
 851     return 1;  /* bad */
 852 }]])],
 853     [guile_cv_use_csqrt=yes],
 854     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 855     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 856   case $guile_cv_use_csqrt in
 857     yes*)
 858       AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free])
 859       ;;
 860   esac
 861 fi
 862
 863 AC_CACHE_SAVE
 864
 865 dnl GMP tests
 866 AC_LIB_HAVE_LINKFLAGS([gmp],
 867   [],
 868   [#include <gmp.h>],
 869   [mpz_import (0, 0, 0, 0, 0, 0, 0);])
 870
 871 if test "x$HAVE_LIBGMP" != "xyes"; then
 872   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README])
 873 fi
 874
 875 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 876 if test "x$LTLIBUNISTRING" = "x"; then
 877   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 878 fi
 879
 880 GUILE_LIBUNISTRING_WITH_ICONV_SUPPORT
 881 if test "x$ac_cv_libunistring_with_iconv_support" != "xyes"; then
 882   AC_MSG_ERROR([No iconv support.  Please recompile libunistring with iconv enabled.])
 883 fi
 884
 885 dnl Libffi is needed to compile Guile's foreign function interface, but its
 886 dnl interface isn't exposed in Guile's API.
 887 PKG_CHECK_MODULES(LIBFFI, libffi)
 888 AC_SUBST(LIBFFI_CFLAGS)
 889 AC_SUBST(LIBFFI_LIBS)
 890
 891 dnl figure out approriate ffi type for size_t
 892 AC_CHECK_SIZEOF(size_t)
 893 AC_CHECK_SIZEOF(ssize_t)
 894 ffi_size_type=uint$(($ac_cv_sizeof_size_t*8))
 895 ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8))
 896 AC_DEFINE_UNQUOTED([ffi_type_size_t], ffi_type_${ffi_size_type},
 897                    [ffi type for size_t])
 898 AC_DEFINE_UNQUOTED([ffi_type_ssize_t], ffi_type_${ffi_ssize_type},
 899                    [ffi type for ssize_t])
 900
 901 dnl i18n tests
 902 #AC_CHECK_HEADERS([libintl.h])
 903 #AC_CHECK_FUNCS(gettext)
 904 #if test $ac_cv_func_gettext = no; then
 905 #   AC_CHECK_LIB(intl, gettext)
 906 #fi
 907 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 908 AM_GNU_GETTEXT([external], [need-ngettext])
 909
 910 ### Some systems don't declare some functions.  On such systems, we
 911 ### need to at least provide our own K&R-style declarations.
 912
 913 ### GUILE_FUNC_DECLARED(function, headerfile)
 914
 915 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 916 ### not there, #define MISSING_FUNCTION_DECL.
 917 AC_DEFUN([GUILE_FUNC_DECLARED], [
 918   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 919     AC_EGREP_HEADER($1, $2,
 920                     guile_cv_func_$1_declared=yes,
 921                     guile_cv_func_$1_declared=no))
 922   if test [x$guile_cv_func_]$1[_declared] = xno; then
 923     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 924       [Define if the operating system supplies $1 without declaring it.])
 925   fi
 926 ])
 927
 928 GUILE_FUNC_DECLARED(sleep, unistd.h)
 929 GUILE_FUNC_DECLARED(usleep, unistd.h)
 930
 931 AC_CHECK_DECLS([strptime],,,
 932 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 933 #include <time.h>])
 934
 935 ### On some systems usleep has no return value.  If it does have one,
 936 ### we'd like to return it; otherwise, we'll fake it.
 937 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 938   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 939                    unistd.h,
 940                    [guile_cv_func_usleep_return_type=void],
 941                    [guile_cv_func_usleep_return_type=int])])
 942 case "$guile_cv_func_usleep_return_type" in
 943   "void" )
 944     AC_DEFINE([USLEEP_RETURNS_VOID], 1,
 945       [Define if the system headers declare usleep to return void.])
 946   ;;
 947 esac
 948
 949 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 950 if test -n "$have_sys_un_h" ; then
 951   AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1,
 952     [Define if the system supports Unix-domain (file-domain) sockets.])
 953 fi
 954
 955 AC_CHECK_FUNCS(getrlimit setrlimit)
 956
 957 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 958
 959 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 960                setnetent    getnetent    endnetent    dnl
 961                setprotoent  getprotoent  endprotoent  dnl
 962                setservent   getservent   endservent   dnl
 963                getnetbyaddr getnetbyname dnl
 964                inet_lnaof inet_makeaddr inet_netof hstrerror)
 965
 966 AC_CHECK_MEMBERS([struct sockaddr_in.sin_len],,,
 967 [#ifdef HAVE_SYS_TYPES_H
 968 #include <sys/types.h>
 969 #endif
 970 #include <netinet/in.h>])
 971
 972 AC_MSG_CHECKING(for __libc_stack_end)
 973 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 974 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 975 extern char *__libc_stack_end;]],
 976    [[printf("%p", (char*) __libc_stack_end);]])],
 977    [guile_cv_have_libc_stack_end=yes],
 978    [guile_cv_have_libc_stack_end=no])])
 979 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 980
 981 if test $guile_cv_have_libc_stack_end = yes; then
 982   AC_DEFINE([HAVE_LIBC_STACK_END], 1,
 983            [Define if you have the __libc_stack_end variable.])
 984 fi
 985
 986 dnl Some systems do not declare this.  Some systems do declare it, as a
 987 dnl macro.  With cygwin it may be in a DLL.
 988
 989 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 990 AC_CACHE_VAL(guile_cv_have_h_errno,
 991   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 992                                       [[int a = h_errno;]])],
 993   [guile_cv_have_h_errno=yes],
 994   [guile_cv_have_h_errno=no])])
 995 AC_MSG_RESULT($guile_cv_have_h_errno)
 996 if test $guile_cv_have_h_errno = yes; then
 997   AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.])
 998 fi
 999
1000 AC_MSG_CHECKING(whether uint32_t is defined)
1001 AC_CACHE_VAL(guile_cv_have_uint32_t,
1002   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1003                    #if HAVE_STDINT_H
1004                    #include <stdint.h>
1005                    #endif
1006                    #ifndef HAVE_NETDB_H
1007                    #include <netdb.h>
1008                    #endif]],
1009                    [[uint32_t a;]])],
1010                    [guile_cv_have_uint32_t=yes],
1011                    [guile_cv_have_uint32_t=no])])
1012 AC_MSG_RESULT($guile_cv_have_uint32_t)
1013 if test $guile_cv_have_uint32_t = yes; then
1014   AC_DEFINE([HAVE_UINT32_T], 1,
1015     [Define if uint32_t typedef is defined when netdb.h is include.])
1016 fi
1017
1018 AC_MSG_CHECKING(for working IPv6 support)
1019 AC_CACHE_VAL(guile_cv_have_ipv6,
1020 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1021 #ifdef HAVE_SYS_TYPES_H
1022 #include <sys/types.h>
1023 #endif
1024 #include <netinet/in.h>
1025 #include <sys/socket.h>]],
1026 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
1027 [guile_cv_have_ipv6=yes],
1028 [guile_cv_have_ipv6=no])])
1029 AC_MSG_RESULT($guile_cv_have_ipv6)
1030 if test $guile_cv_have_ipv6 = yes; then
1031   AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.])
1032 fi
1033
1034 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
1035 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
1036 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
1037 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1038 #ifdef HAVE_SYS_TYPES_H
1039 #include <sys/types.h>
1040 #endif
1041 #include <netinet/in.h>]],
1042 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
1043 [guile_cv_have_sin6_scope_id=yes],
1044 [guile_cv_have_sin6_scope_id=no])])
1045 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
1046 if test $guile_cv_have_sin6_scope_id = yes; then
1047   AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1,
1048     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
1049 fi
1050
1051 # struct sockaddr_in6 field sin_len is only present on BSD systems
1052 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1053 [#ifdef HAVE_SYS_TYPES_H
1054 #include <sys/types.h>
1055 #endif
1056 #include <netinet/in.h>])
1057
1058 AC_MSG_CHECKING(whether localtime caches TZ)
1059 AC_CACHE_VAL(guile_cv_localtime_cache,
1060 [if test x$ac_cv_func_tzset = xyes; then
1061 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1062 #if STDC_HEADERS
1063 # include <stdlib.h>
1064 #endif
1065 extern char **environ;
1066 unset_TZ ()
1067 {
1068   char **from, **to;
1069   for (to = from = environ; (*to = *from); from++)
1070     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1071       to++;
1072 }
1073 char TZ_GMT0[] = "TZ=GMT0";
1074 char TZ_PST8[] = "TZ=PST8";
1075 main()
1076 {
1077   time_t now = time ((time_t *) 0);
1078   int hour_GMT0, hour_unset;
1079   if (putenv (TZ_GMT0) != 0)
1080     exit (1);
1081   hour_GMT0 = localtime (&now)->tm_hour;
1082   unset_TZ ();
1083   hour_unset = localtime (&now)->tm_hour;
1084   if (putenv (TZ_PST8) != 0)
1085     exit (1);
1086   if (localtime (&now)->tm_hour == hour_GMT0)
1087     exit (1);
1088   unset_TZ ();
1089   if (localtime (&now)->tm_hour != hour_unset)
1090     exit (1);
1091   exit (0);
1092 }]])],
1093 [guile_cv_localtime_cache=no],
1094 [guile_cv_localtime_cache=yes],
1095 [# If we have tzset, assume the worst when cross-compiling.
1096 guile_cv_localtime_cache=yes])
1097 else
1098         # If we lack tzset, report that localtime does not cache TZ,
1099         # since we can't invalidate the cache if we don't have tzset.
1100         guile_cv_localtime_cache=no
1101 fi])dnl
1102 AC_MSG_RESULT($guile_cv_localtime_cache)
1103 if test $guile_cv_localtime_cache = yes; then
1104   AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.])
1105 fi
1106
1107 if test "$enable_regex" = yes; then
1108    if test "$ac_cv_header_regex_h" = yes ||
1109       test "$ac_cv_header_rxposix_h" = yes ||
1110       test "$ac_cv_header_rx_rxposix_h" = yes; then
1111      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1112      [AC_CHECK_LIB(rx, main)
1113       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1114      [AC_CHECK_LIB(regex, main)
1115       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1116      )
1117      dnl The following should not be necessary, but for some reason
1118      dnl autoheader misses it if we don't include it!
1119      if test "$ac_cv_func_regcomp_norx" = yes ||
1120         test "$ac_cv_func_regcomp_regex" = yes ||
1121         test "$ac_cv_func_regcomp_rx" = yes; then
1122        AC_DEFINE([HAVE_REGCOMP], 1,
1123          [This is included as part of a workaround for a autoheader bug.])
1124      fi
1125    fi
1126 fi
1127
1128 AC_REPLACE_FUNCS([strerror memmove mkstemp])
1129
1130 # Reasons for testing:
1131 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1132 #                                older systems
1133 #   sincos - GLIBC extension
1134 #
1135 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1136
1137 # C99 specifies isinf and isnan as macros.
1138 # HP-UX provides only macros, no functions.
1139 # glibc 2.3.2 provides both macros and functions.
1140 # IRIX 6.5 and Solaris 8 only provide functions.
1141 #
1142 # The following tests detect isinf and isnan either as functions or as
1143 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1144 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1145 #
1146 AC_MSG_CHECKING([for isinf])
1147 AC_LINK_IFELSE(AC_LANG_SOURCE(
1148 [[#include <math.h>
1149 volatile double x = 0.0;
1150 int main () { return (isinf(x) != 0); }]]),
1151   [AC_MSG_RESULT([yes])
1152    AC_DEFINE([HAVE_ISINF], 1,
1153              [Define to 1 if you have the `isinf' macro or function.])],
1154   [AC_MSG_RESULT([no])])
1155 AC_MSG_CHECKING([for isnan])
1156 AC_LINK_IFELSE(AC_LANG_SOURCE(
1157 [[#include <math.h>
1158 volatile double x = 0.0;
1159 int main () { return (isnan(x) != 0); }]]),
1160   [AC_MSG_RESULT([yes])
1161    AC_DEFINE([HAVE_ISNAN], 1,
1162              [Define to 1 if you have the `isnan' macro or function.])],
1163   [AC_MSG_RESULT([no])])
1164
1165 # Reasons for checking:
1166 #
1167 #     st_rdev
1168 #     st_blksize
1169 #     st_blocks   not in mingw
1170 #     tm_gmtoff   BSD+GNU, not in C99
1171 #
1172 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1173 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1174 #
1175 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,,
1176                  [#define _GNU_SOURCE
1177 AC_INCLUDES_DEFAULT
1178 ])
1179
1180 AC_STRUCT_TIMEZONE
1181 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1182 [#include <time.h>
1183 #ifdef TIME_WITH_SYS_TIME
1184 # include <sys/time.h>
1185 # include <time.h>
1186 #else
1187 # if HAVE_SYS_TIME_H
1188 #  include <sys/time.h>
1189 # else
1190 #  include <time.h>
1191 # endif
1192 #endif
1193 ])
1194 GUILE_STRUCT_UTIMBUF
1195
1196
1197 #--------------------------------------------------------------------
1198 #
1199 # What values do the iconv error handlers have?
1200 #
1201 # The only place that we need iconv in our public interfaces is for
1202 # the error handlers, which are just ints.  So we weaken our
1203 # dependency by looking up those values at configure-time.
1204 #--------------------------------------------------------------------
1205 SCM_I_GSC_ICONVEH_ERROR=0
1206 SCM_I_GSC_ICONVEH_QUESTION_MARK=1
1207 SCM_I_GSC_ICONVEH_ESCAPE_SEQUENCE=2
1208 AC_MSG_CHECKING([for iconveh_error])
1209 AC_RUN_IFELSE([AC_LANG_SOURCE(
1210 [AC_INCLUDES_DEFAULT
1211 #include <uniconv.h>
1212 int
1213 main (int argc, char *argv[])
1214 {
1215   if (argc > 1)
1216     printf ("%d\n", (int)iconveh_error);
1217   return 0;
1218 }])],
1219                [SCM_I_GSC_ICONVEH_ERROR=`./conftest$EXEEXT pretty-please`
1220                 AC_MSG_RESULT([$SCM_I_GSC_ICONVEH_ERROR])],
1221                [AC_MSG_FAILURE([failed to get iconveh_error])],
1222                [AC_MSG_WARN([assuming $SCM_I_GSC_ICONVEH_ERROR for cross-compilation])])
1223
1224 AC_MSG_CHECKING([for iconveh_question_mark])
1225 AC_RUN_IFELSE([AC_LANG_SOURCE(
1226 [AC_INCLUDES_DEFAULT
1227 #include <uniconv.h>
1228 int
1229 main (int argc, char *argv[])
1230 {
1231   if (argc > 1)
1232     printf ("%d\n", (int)iconveh_question_mark);
1233   return 0;
1234 }])],
1235                [SCM_I_GSC_ICONVEH_QUESTION_MARK=`./conftest$EXEEXT pretty-please`
1236                 AC_MSG_RESULT([$SCM_I_GSC_ICONVEH_QUESTION_MARK])],
1237                [AC_MSG_FAILURE([failed to get iconveh_question_mark])],
1238                [AC_MSG_WARN([assuming $SCM_I_GSC_ICONVEH_QUESTION_MARK for cross-compilation])])
1239
1240 AC_MSG_CHECKING([for iconveh_escape_sequence])
1241 AC_RUN_IFELSE([AC_LANG_SOURCE(
1242 [AC_INCLUDES_DEFAULT
1243 #include <uniconv.h>
1244 int
1245 main (int argc, char *argv[])
1246 {
1247   if (argc > 1)
1248     printf ("%d\n", (int)iconveh_escape_sequence);
1249   return 0;
1250 }])],
1251                [SCM_I_GSC_ICONVEH_ESCAPE_SEQUENCE=`./conftest$EXEEXT pretty-please`
1252                 AC_MSG_RESULT([$SCM_I_GSC_ICONVEH_ESCAPE_SEQUENCE])],
1253                [AC_MSG_FAILURE([failed to get iconveh_escape_sequence])],
1254                [AC_MSG_WARN([assuming $SCM_I_GSC_ICONVEH_ESCAPE_SEQUENCE for cross-compilation])])
1255
1256 AC_SUBST([SCM_I_GSC_ICONVEH_ERROR])
1257 AC_SUBST([SCM_I_GSC_ICONVEH_QUESTION_MARK])
1258 AC_SUBST([SCM_I_GSC_ICONVEH_ESCAPE_SEQUENCE])
1259
1260
1261 #--------------------------------------------------------------------
1262 #
1263 # Which way does the stack grow?
1264 #
1265 # Following code comes from Autoconf 2.61's internal _AC_LIBOBJ_ALLOCA
1266 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1267 # very similar code, so in future we could look at using that.
1268 #
1269 # An important detail is that the code involves find_stack_direction
1270 # calling _itself_ - which means that find_stack_direction (or at
1271 # least the second find_stack_direction() call) cannot be inlined.
1272 # If the code could be inlined, that might cause the test to give
1273 # an incorrect answer.
1274 #--------------------------------------------------------------------
1275
1276 SCM_I_GSC_STACK_GROWS_UP=0
1277 AC_RUN_IFELSE([AC_LANG_SOURCE(
1278 [AC_INCLUDES_DEFAULT
1279 int
1280 find_stack_direction ()
1281 {
1282   static char *addr = 0;
1283   auto char dummy;
1284   if (addr == 0)
1285     {
1286       addr = &dummy;
1287       return find_stack_direction ();
1288     }
1289   else
1290     return (&dummy > addr) ? 1 : -1;
1291 }
1292
1293 int
1294 main ()
1295 {
1296   return find_stack_direction () < 0;
1297 }])],
1298                [SCM_I_GSC_STACK_GROWS_UP=1],
1299                [],
1300                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1301
1302 #--------------------------------------------------------------------
1303 #
1304 # Boehm's GC library
1305 #
1306 #--------------------------------------------------------------------
1307 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1308
1309 save_LIBS="$LIBS"
1310 LIBS="$BDW_GC_LIBS $LIBS"
1311 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1312
1313 AC_CHECK_FUNCS([GC_do_blocking GC_call_with_gc_active GC_pthread_exit GC_pthread_cancel GC_allow_register_threads GC_pthread_sigmask GC_set_start_callback])
1314
1315 # Though the `GC_do_blocking ()' symbol is present in GC 7.1, it is not
1316 # declared, and has a different type (returning void instead of
1317 # void*).
1318 AC_CHECK_DECL([GC_do_blocking],
1319   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1320     [Define this if the `GC_do_blocking ()' function is declared])],
1321   [],
1322   [#include <gc/gc.h>])
1323
1324 # `GC_fn_type' is not available in GC 7.1 and earlier.
1325 AC_CHECK_TYPE([GC_fn_type],
1326   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1327     [Define this if the `GC_fn_type' type is available.])],
1328   [],
1329   [#include <gc/gc.h>])
1330
1331 # `GC_stack_base' is not available in GC 7.1 and earlier.
1332 AC_CHECK_TYPE([struct GC_stack_base],
1333   [AC_DEFINE([HAVE_GC_STACK_BASE], [1],
1334     [Define this if the `GC_stack_base' type is available.])],
1335   [],
1336   [#include <gc/gc.h>])
1337
1338 LIBS="$save_LIBS"
1339
1340
1341 AC_CHECK_SIZEOF(float)
1342 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1343     AC_DEFINE([SCM_SINGLES], 1,
1344               [Define this if floats are the same size as longs.])
1345 fi
1346
1347 AC_MSG_CHECKING(for struct linger)
1348 AC_CACHE_VAL(scm_cv_struct_linger,
1349         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1350 #include <sys/types.h>
1351 #include <sys/socket.h>]],
1352                           [[struct linger lgr;  lgr.l_linger = 100]])],
1353                           [scm_cv_struct_linger="yes"],
1354                           [scm_cv_struct_linger="no"]))
1355 AC_MSG_RESULT($scm_cv_struct_linger)
1356 if test $scm_cv_struct_linger = yes; then
1357         AC_DEFINE([HAVE_STRUCT_LINGER], 1,
1358           [Define this if your system defines struct linger, for use with the
1359            getsockopt and setsockopt system calls.])
1360 fi
1361
1362
1363 # On mingw, struct timespec is in <pthread.h>.
1364 #
1365 AC_MSG_CHECKING(for struct timespec)
1366 AC_CACHE_VAL(scm_cv_struct_timespec,
1367         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1368 #include <time.h>
1369 #if HAVE_PTHREAD_H
1370 #include <pthread.h>
1371 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1372           [scm_cv_struct_timespec="yes"],
1373           [scm_cv_struct_timespec="no"]))
1374 AC_MSG_RESULT($scm_cv_struct_timespec)
1375 if test $scm_cv_struct_timespec = yes; then
1376   AC_DEFINE([HAVE_STRUCT_TIMESPEC], 1,
1377     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1378 fi
1379
1380 #--------------------------------------------------------------------
1381 #
1382 # Flags for thread support
1383 #
1384 #--------------------------------------------------------------------
1385
1386 SCM_I_GSC_USE_PTHREAD_THREADS=0
1387 SCM_I_GSC_USE_NULL_THREADS=0
1388 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1389 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1390
1391 ### What thread package has the user asked for?
1392 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1393             , with_threads=yes)
1394
1395 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1396 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1397
1398 case "$with_threads" in
1399   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1400
1401     build_pthread_support="yes"
1402
1403     ACX_PTHREAD([CC="$PTHREAD_CC"
1404        LIBS="$PTHREAD_LIBS $LIBS"
1405        SCM_I_GSC_USE_PTHREAD_THREADS=1
1406        with_threads="pthreads"],
1407       [with_threads="null"
1408        build_pthread_support="no"])
1409
1410     old_CFLAGS="$CFLAGS"
1411     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1412
1413     # Reasons for testing:
1414     #     pthread_getattr_np - "np" meaning "non portable" says it
1415     #         all; not present on MacOS X or Solaris 10
1416     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1417     #         all; specific to MacOS X
1418     #     pthread_sigmask - not available on mingw
1419     #
1420     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1421
1422     # On past versions of Solaris, believe 8 through 10 at least, you
1423     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1424     # This is contrary to POSIX:
1425     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1426     # Check here if this style is required.
1427     #
1428     # glibc (2.3.6 at least) works both with or without braces, so the
1429     # test checks whether it works without.
1430     #
1431
1432     if test "$GCC" = "yes"; then
1433       # Since GCC only issues a warning for missing braces, so we need
1434       # `-Werror' to catch it.
1435       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1436     fi
1437
1438     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1439       guile_cv_need_braces_on_pthread_once_init,
1440       [AC_COMPILE_IFELSE([#include <pthread.h>
1441          pthread_once_t foo = PTHREAD_ONCE_INIT;],
1442         [guile_cv_need_braces_on_pthread_once_init=no],
1443         [guile_cv_need_braces_on_pthread_once_init=yes])])
1444     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1445       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1446     fi
1447
1448     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1449     # 6.5.30m with GCC 3.3.
1450     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1451       guile_cv_need_braces_on_pthread_mutex_initializer,
1452       [AC_COMPILE_IFELSE([#include <pthread.h>
1453          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;],
1454         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1455         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1456     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1457       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1458     fi
1459
1460     CFLAGS="$old_CFLAGS"
1461
1462     # On Solaris, sched_yield lives in -lrt.
1463     AC_SEARCH_LIBS(sched_yield, rt)
1464
1465   ;;
1466 esac
1467
1468 case "$with_threads" in
1469   "pthreads")
1470   ;;
1471   "no" | "null")
1472     SCM_I_GSC_USE_NULL_THREADS=1
1473     SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
1474     with_threads="null-threads"
1475   ;;
1476   * )
1477     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1478   ;;
1479 esac
1480
1481 AC_MSG_CHECKING(what kind of threads to support)
1482 AC_MSG_RESULT($with_threads)
1483
1484 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1485   [test "x$build_pthread_support" = "xyes"])
1486
1487
1488 ## Check whether pthread_attr_getstack works for the main thread
1489
1490 if test "$with_threads" = pthreads; then
1491
1492 AC_MSG_CHECKING([whether pthread_attr_getstack works for the main thread])
1493 old_CFLAGS="$CFLAGS"
1494 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1495 if test "$cross_compiling" = "no"; then
1496   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1497   #if HAVE_PTHREAD_ATTR_GETSTACK
1498   #include <pthread.h>
1499
1500   int main ()
1501   {
1502     pthread_attr_t attr;
1503     void *start, *end;
1504     size_t size;
1505
1506     pthread_getattr_np (pthread_self (), &attr);
1507     pthread_attr_getstack (&attr, &start, &size);
1508     end = (char *)start + size;
1509
1510     if ((void *)&attr < start || (void *)&attr >= end)
1511       return 1;
1512     else
1513       return 0;
1514   }
1515   #else
1516   int main ()
1517   {
1518     return 1;
1519   }
1520   #endif
1521   ]])],
1522   [works=yes
1523    AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])],
1524   [works=no],
1525   [])
1526 else
1527   works="assuming it doesn't"
1528 fi
1529 CFLAGS="$old_CFLAGS"
1530 AC_MSG_RESULT($works)
1531
1532 GUILE_THREAD_LOCAL_STORAGE
1533
1534 fi # with_threads=pthreads
1535
1536
1537 ## Cross building
1538 if test "$cross_compiling" = "yes"; then
1539   AC_MSG_CHECKING(cc for build)
1540   ## /usr/bin/cc still uses wrong assembler
1541   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1542   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1543 else
1544   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1545 fi
1546
1547 ## AC_MSG_CHECKING("if we are cross compiling")
1548 ## AC_MSG_RESULT($cross_compiling)
1549 if test "$cross_compiling" = "yes"; then
1550    AC_MSG_RESULT($CC_FOR_BUILD)
1551 fi
1552
1553 ## No need as yet to be more elaborate
1554 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1555
1556 AC_SUBST(cross_compiling)
1557 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1558 AC_SUBST(CCLD_FOR_BUILD)
1559
1560 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1561 ## --HOST is the platform that PACKAGE is compiled for.
1562 HOST_CC="$CC_FOR_BUILD"
1563 AC_SUBST(HOST_CC)
1564
1565 if test "$cross_compiling" = "yes"; then
1566   AC_MSG_CHECKING(guile for build)
1567   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1568 else
1569   GUILE_FOR_BUILD='this-value-will-never-be-used'
1570 fi
1571
1572 ## AC_MSG_CHECKING("if we are cross compiling")
1573 ## AC_MSG_RESULT($cross_compiling)
1574 if test "$cross_compiling" = "yes"; then
1575    AC_MSG_RESULT($GUILE_FOR_BUILD)
1576 fi
1577 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1578 AM_SUBST_NOTMAKE(GUILE_FOR_BUILD)
1579
1580 ## If we're using GCC, ask for aggressive warnings.
1581 GCC_CFLAGS=""
1582 case "$GCC" in
1583   yes )
1584     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1585     ## much stuff with generic function pointers for that to really be
1586     ## less than exasperating.
1587     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1588     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1589     ## -Wundef was removed because Gnulib prevented it (see
1590     ## <http://thread.gmane.org/gmane.lisp.guile.bugs/5329>.)
1591     POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \
1592       -Wdeclaration-after-statement \
1593       -Wswitch-enum"
1594     # Do this here so we don't screw up any of the tests above that might
1595     # not be "warning free"
1596     if test "${GUILE_ERROR_ON_WARNING}" = yes
1597     then
1598         POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror"
1599         enable_compile_warnings=no
1600     fi
1601
1602     for flag in $POTENTIAL_GCC_CFLAGS
1603     do
1604         gl_WARN_ADD([$flag], [GCC_CFLAGS])
1605     done
1606     ;;
1607 esac
1608
1609 AC_SUBST(GCC_CFLAGS)
1610
1611 # Check for GNU ld's "-z relro".
1612 GUILE_GNU_LD_RELRO
1613
1614
1615 ## If we're creating a shared library (using libtool!), then we'll
1616 ## need to generate a list of .lo files corresponding to the .o files
1617 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1618 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1619
1620 ## We also need to create corresponding .doc and .x files
1621 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1622 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1623
1624 # GNU Readline bindings.
1625 GUILE_READLINE
1626
1627 AC_SUBST(GUILE_MAJOR_VERSION)
1628 AC_SUBST(GUILE_MINOR_VERSION)
1629 AC_SUBST(GUILE_MICRO_VERSION)
1630 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1631 AC_SUBST(GUILE_VERSION)
1632
1633 #######################################################################
1634 # library versioning
1635
1636 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1637 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1638 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1639 AC_SUBST(LIBGUILE_INTERFACE)
1640
1641 AC_SUBST(LIBGUILE_I18N_MAJOR)
1642 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1643 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1644 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1645 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1646
1647
1648 #######################################################################
1649
1650 dnl Tell guile-config what flags guile users should compile and link
1651 dnl with, keeping only `-I' flags from $CPPFLAGS.
1652 GUILE_CFLAGS=""
1653 next_is_includedir=false
1654 for flag in $CPPFLAGS
1655 do
1656   if $next_is_includedir; then
1657     GUILE_CFLAGS="$GUILE_CFLAGS -I $flag"
1658     next_is_includedir=false
1659   else
1660     case "$flag" in
1661       -I)  next_is_includedir=true;;
1662       -I*) GUILE_CFLAGS="$GUILE_CFLAGS $flag";;
1663       *)   ;;
1664     esac
1665   fi
1666 done
1667
1668 GUILE_CFLAGS="$GUILE_CFLAGS $PTHREAD_CFLAGS"
1669 GUILE_LIBS="$LDFLAGS $LIBS"
1670
1671 AC_SUBST(GUILE_LIBS)
1672 AC_SUBST(GUILE_CFLAGS)
1673
1674 AC_SUBST(AWK)
1675 AC_SUBST(LIBLOBJS)
1676 AC_SUBST(EXTRA_DOT_DOC_FILES)
1677 AC_SUBST(EXTRA_DOT_X_FILES)
1678
1679 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1680 top_builddir_absolute=`pwd`
1681 AC_SUBST(top_builddir_absolute)
1682 top_srcdir_absolute=`(cd $srcdir && pwd)`
1683 AC_SUBST(top_srcdir_absolute)
1684
1685 dnl `sitedir' goes into libpath.h and the pkg-config file.
1686 pkgdatadir="$datadir/$PACKAGE_TARNAME"
1687 sitedir="$pkgdatadir/site/$GUILE_EFFECTIVE_VERSION"
1688 AC_SUBST([sitedir])
1689
1690 # Additional SCM_I_GSC definitions are above.
1691 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1692 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1693 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1694 AC_SUBST([SCM_I_GSC_C_INLINE])
1695 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1696
1697 AC_CONFIG_FILES([
1698   Makefile
1699   am/Makefile
1700   lib/Makefile
1701   benchmark-suite/Makefile
1702   gc-benchmarks/Makefile
1703   doc/Makefile
1704   doc/r5rs/Makefile
1705   doc/ref/Makefile
1706   emacs/Makefile
1707   examples/Makefile
1708   libguile/Makefile
1709   libguile/version.h
1710   guile-readline/Makefile
1711   test-suite/Makefile
1712   test-suite/standalone/Makefile
1713   test-suite/vm/Makefile
1714   meta/Makefile
1715   module/Makefile
1716 ])
1717
1718 AC_CONFIG_FILES([meta/guile-2.2.pc])
1719 AC_CONFIG_FILES([meta/guile-2.2-uninstalled.pc])
1720 AC_CONFIG_FILES([doc/ref/effective-version.texi])
1721
1722 GUILE_CONFIG_SCRIPT([check-guile])
1723 GUILE_CONFIG_SCRIPT([benchmark-guile])
1724 GUILE_CONFIG_SCRIPT([meta/guile])
1725 GUILE_CONFIG_SCRIPT([meta/uninstalled-env])
1726 GUILE_CONFIG_SCRIPT([meta/gdb-uninstalled-guile])
1727 GUILE_CONFIG_SCRIPT([meta/guile-tools])
1728 GUILE_CONFIG_SCRIPT([libguile/guile-snarf])
1729 GUILE_CONFIG_SCRIPT([libguile/guile-snarf-docs])
1730 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-use-srfi])
1731 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-fast-slot-ref])
1732
1733 AC_OUTPUT
1734
1735 dnl Local Variables:
1736 dnl comment-start: "dnl "
1737 dnl comment-end: ""
1738 dnl comment-start-skip: "\\bdnl\\b\\s *"
1739 dnl End: