configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   8   2007, 2008, 2009, 2010, 2011, 2012, 2013 Free Software Foundation, Inc.
   9
  10 This file is part of GUILE
  11
  12 GUILE is free software; you can redistribute it and/or modify it under
  13 the terms of the GNU Lesser General Public License as published by the
  14 Free Software Foundation; either version 3, or (at your option) any
  15 later version.
  16
  17 GUILE is distributed in the hope that it will be useful, but WITHOUT
  18 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  19 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  20 License for more details.
  21
  22 You should have received a copy of the GNU Lesser General Public
  23 License along with GUILE; see the file COPYING.LESSER.  If not, write
  24 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  25 Floor, Boston, MA 02110-1301, USA.
  26
  27 ]])
  28
  29 AC_PREREQ(2.61)
  30
  31 AC_INIT([GNU Guile],
  32         m4_esyscmd([build-aux/git-version-gen --match v2.0.\* .tarball-version]),
  33         [bug-guile@gnu.org])
  34 AC_CONFIG_AUX_DIR([build-aux])
  35 AC_CONFIG_MACRO_DIR([m4])
  36 AC_CONFIG_SRCDIR(GUILE-VERSION)
  37
  38 dnl Use `serial-tests' so the output `check-guile' is not hidden
  39 dnl (`parallel-tests' is the default in Automake 1.13.)
  40 dnl `serial-tests' was introduced in Automake 1.12.
  41 AM_INIT_AUTOMAKE([1.12 gnu no-define -Wall -Wno-override \
  42   serial-tests color-tests dist-xz])
  43 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AC_SUBST([AM_DEFAULT_VERBOSITY],1)])
  44
  45 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  46 AC_CONFIG_SRCDIR([GUILE-VERSION])
  47
  48 . $srcdir/GUILE-VERSION
  49 GUILE_VERSION="$PACKAGE_VERSION"
  50
  51 AC_CONFIG_HEADERS([config.h])
  52 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  53
  54 #--------------------------------------------------------------------
  55
  56 AC_LANG([C])
  57
  58 dnl Some more checks for Win32
  59 AC_CANONICAL_HOST
  60
  61 AC_LIBTOOL_WIN32_DLL
  62
  63 AC_PROG_INSTALL
  64 AC_PROG_CC
  65 gl_EARLY
  66 AC_PROG_CPP
  67 AC_PROG_SED
  68 AC_PROG_AWK
  69 AC_PROG_LN_S
  70 AM_PROG_AR
  71
  72 dnl Gnulib.
  73 gl_INIT
  74
  75 AC_PROG_CC_C89
  76
  77 # for per-target cflags in the libguile subdir
  78 AM_PROG_CC_C_O
  79
  80 AC_LIBTOOL_DLOPEN
  81 AC_PROG_LIBTOOL
  82
  83 AM_CONDITIONAL([HAVE_SHARED_LIBRARIES], [test "x$enable_shared" = "xyes"])
  84
  85 dnl Check for libltdl.
  86 AC_LIB_HAVE_LINKFLAGS([ltdl], [], [#include <ltdl.h>],
  87   [lt_dlopenext ("foo");])
  88 if test "x$HAVE_LIBLTDL" != "xyes"; then
  89   AC_MSG_ERROR([GNU libltdl (Libtool) not found, see README.])
  90 fi
  91
  92 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  93 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  94
  95 AM_PATH_LISPDIR
  96
  97 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
  98   [Define to the host's GNU triplet.])
  99
 100 #--------------------------------------------------------------------
 101 #
 102 # User options (after above tests that may set default CFLAGS etc.)
 103 #
 104 #--------------------------------------------------------------------
 105
 106 GUILE_ERROR_ON_WARNING="no"
 107
 108 AC_ARG_ENABLE(error-on-warning,
 109   [  --enable-error-on-warning    treat compile warnings as errors],
 110   [case "${enableval}" in
 111      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 112      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 113      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 114    esac])
 115
 116 AC_ARG_ENABLE(debug-malloc,
 117   [  --enable-debug-malloc   include malloc debugging code],
 118   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 119     AC_DEFINE([GUILE_DEBUG_MALLOC], 1,
 120       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 121   fi)
 122
 123 SCM_I_GSC_GUILE_DEBUG=0
 124 AC_ARG_ENABLE(guile-debug,
 125   [AS_HELP_STRING([--enable-guile-debug],
 126                   [include internal debugging functions])],
 127   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 128     SCM_I_GSC_GUILE_DEBUG=1
 129   fi)
 130
 131 AC_ARG_ENABLE(posix,
 132   [  --disable-posix         omit non-essential POSIX interfaces],,
 133   enable_posix=yes)
 134
 135 AC_ARG_ENABLE(networking,
 136   [  --disable-networking    omit networking interfaces],,
 137   enable_networking=yes)
 138
 139 AC_ARG_ENABLE(regex,
 140   [  --disable-regex         omit regular expression interfaces],,
 141   enable_regex=yes)
 142
 143 AC_ARG_ENABLE([deprecated],
 144   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 145
 146 if test "$enable_deprecated" = no; then
 147   SCM_I_GSC_ENABLE_DEPRECATED=0
 148   warn_default=no
 149 else
 150   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 151     warn_default=summary
 152   elif test "$enable_deprecated" = shutup; then
 153     warn_default=no
 154   else
 155     warn_default=$enable_deprecated
 156   fi
 157   SCM_I_GSC_ENABLE_DEPRECATED=1
 158 fi
 159 AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default",
 160 [Define this to control the default warning level for deprecated features.])
 161
 162 dnl  Added the following configure option in January 2008 following
 163 dnl  investigation of problems with "64" system and library calls on
 164 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 165 dnl  system has stat64, it will have all the other 64 APIs too; but on
 166 dnl  Darwin, stat64 is there but other APIs are missing.
 167 dnl
 168 dnl  It also appears, from the Darwin docs, that most system call APIs
 169 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 170 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 171 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 172 dnl
 173 dnl  A similar problem has been reported for HP-UX:
 174 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 175 dnl
 176 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 177 dnl  better than no Guile at all, we provide this option to suppress
 178 dnl  trying to use "64" calls.
 179 dnl
 180 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 181 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 182 dnl  missing out on that.  If so, someone can work on that in the future.
 183 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 184 dnl  wasn't building before.
 185 AC_MSG_CHECKING([whether to use system and library "64" calls])
 186 AC_ARG_WITH([64-calls],
 187   AS_HELP_STRING([--without-64-calls],
 188                  [don't attempt to use system and library calls with "64" in their names]),
 189   [use_64_calls=$withval],
 190   [use_64_calls=yes
 191    case $host in
 192      *-apple-darwin* )
 193        use_64_calls=no
 194        ;;
 195      powerpc-ibm-aix* )
 196        use_64_calls=no
 197        ;;
 198    esac])
 199 AC_MSG_RESULT($use_64_calls)
 200 case "$use_64_calls" in
 201   y* )
 202     AC_DEFINE([GUILE_USE_64_CALLS], 1,
 203       [Define to 1 in order to try to use "64" versions of system and library calls.])
 204     ;;
 205 esac
 206
 207 #--------------------------------------------------------------------
 208
 209 dnl Check for dynamic linking
 210
 211 use_modules=yes
 212 AC_ARG_WITH(modules,
 213 [  --with-modules[=FILES]  Add support for dynamic modules],
 214 use_modules="$withval")
 215 test -z "$use_modules" && use_modules=yes
 216 DLPREOPEN=
 217 if test "$use_modules" != no; then
 218   if test "$use_modules" = yes; then
 219     DLPREOPEN="-dlpreopen force"
 220   else
 221     DLPREOPEN="-export-dynamic"
 222     for module in $use_modules; do
 223       DLPREOPEN="$DLPREOPEN -dlopen $module"
 224     done
 225   fi
 226 fi
 227
 228 dnl files which are destined for separate modules.
 229
 230 if test "$use_modules" != no; then
 231    AC_LIBOBJ([dynl])
 232    AC_DEFINE([HAVE_MODULES], 1,
 233      [Define this if you want support for dynamically loaded modules in Guile.])
 234 fi
 235
 236 if test "$enable_posix" = yes; then
 237    AC_LIBOBJ([posix])
 238    AC_DEFINE([HAVE_POSIX], 1,
 239      [Define this if you want support for non-essential POSIX system calls in Guile.])
 240 fi
 241
 242 if test "$enable_networking" = yes; then
 243    AC_LIBOBJ([net_db])
 244    AC_LIBOBJ([socket])
 245    AC_DEFINE([HAVE_NETWORKING], 1,
 246      [Define this if you want support for networking in Guile.])
 247 fi
 248
 249 if test "$enable_debug_malloc" = yes; then
 250    AC_LIBOBJ([debug-malloc])
 251 fi
 252
 253 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 254
 255 AC_C_CONST
 256
 257 # "volatile" is used in a couple of tests below.
 258 AC_C_VOLATILE
 259
 260 AC_C_INLINE
 261 if test "$ac_cv_c_inline" != no; then
 262   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 263 else
 264   SCM_I_GSC_C_INLINE=NULL
 265 fi
 266 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 267
 268 AC_C_BIGENDIAN
 269
 270 AC_C_LABELS_AS_VALUES
 271
 272 AC_CHECK_SIZEOF(char)
 273 AC_CHECK_SIZEOF(unsigned char)
 274 AC_CHECK_SIZEOF(short)
 275 AC_CHECK_SIZEOF(unsigned short)
 276 AC_CHECK_SIZEOF(int)
 277 AC_CHECK_SIZEOF(unsigned int)
 278 AC_CHECK_SIZEOF(long)
 279 AC_CHECK_SIZEOF(unsigned long)
 280 AC_CHECK_SIZEOF(size_t)
 281 AC_CHECK_SIZEOF(long long)
 282 AC_CHECK_SIZEOF(unsigned long long)
 283 AC_CHECK_SIZEOF(__int64)
 284 AC_CHECK_SIZEOF(unsigned __int64)
 285 AC_CHECK_SIZEOF(void *)
 286 AC_CHECK_SIZEOF(intptr_t)
 287 AC_CHECK_SIZEOF(uintptr_t)
 288 AC_CHECK_SIZEOF(ptrdiff_t)
 289 AC_CHECK_SIZEOF(size_t)
 290 AC_CHECK_SIZEOF(off_t)
 291
 292 if test "$ac_cv_sizeof_long" -gt "$ac_cv_sizeof_void_p"; then
 293   AC_MSG_ERROR(long does not fit into a void*)
 294 fi
 295
 296 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 297   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 298 else
 299   SCM_I_GSC_T_PTRDIFF='"long"'
 300 fi
 301 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 302
 303 AC_CHECK_HEADERS([stdint.h])
 304 AC_CHECK_HEADERS([inttypes.h])
 305
 306 AC_CHECK_SIZEOF(intmax_t)
 307
 308 SCM_I_GSC_NEEDS_STDINT_H=0
 309 SCM_I_GSC_NEEDS_INTTYPES_H=0
 310
 311 ### intptr and uintptr (try not to use inttypes if we don't have to)
 312 if test "$ac_cv_header_inttypes_h" = yes; then
 313   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 314     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 315 #include <stdio.h>])
 316     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 317       SCM_I_GSC_NEEDS_INTTYPES_H=1
 318     fi
 319   fi
 320   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 321     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 322 #include <stdio.h>])
 323     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 324       SCM_I_GSC_NEEDS_INTTYPES_H=1
 325     fi
 326   fi
 327 fi
 328
 329 ### See what's provided by stdint.h
 330 if test "$ac_cv_header_stdint_h" = yes; then
 331    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 332    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 333    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 334    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 335    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 336    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 337    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 338    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 339    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 340    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 341    AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>])
 342    AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>])
 343 fi
 344
 345 # so we don't get confused by the cache (wish there was a better way
 346 # to check particular headers for the same type...)
 347
 348 unset ac_cv_type_int8_t
 349 unset ac_cv_type_uint8_t
 350 unset ac_cv_type_int16_t
 351 unset ac_cv_type_uint16_t
 352 unset ac_cv_type_int32_t
 353 unset ac_cv_type_uint32_t
 354 unset ac_cv_type_int64_t
 355 unset ac_cv_type_uint64_t
 356 unset ac_cv_type_intmax_t
 357 unset ac_cv_type_uintmax_t
 358
 359 ### See what's provided by inttypes.h
 360 if test "$ac_cv_header_inttypes_h" = yes; then
 361   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 362   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 363   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 364   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 365   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 366   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 367   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 368   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 369   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 370   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 371   AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>])
 372   AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>])
 373 fi
 374
 375 # Try hard to find definitions for some required scm_t_*int* types.
 376
 377 ### Required type scm_t_int8
 378 if test "$scm_stdint_has_int8"; then
 379   SCM_I_GSC_T_INT8='"int8_t"'
 380   SCM_I_GSC_NEEDS_STDINT_H=1
 381 elif test "$scm_inttypes_has_int8"; then
 382   SCM_I_GSC_T_INT8='"int8_t"'
 383   SCM_I_GSC_NEEDS_INTTYPES_H=1
 384 elif test "$ac_cv_sizeof_char" -eq 1; then
 385   SCM_I_GSC_T_INT8='"signed char"'
 386 else
 387   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 388 fi
 389 AC_SUBST([SCM_I_GSC_T_INT8])
 390
 391 ### Required type scm_t_uint8
 392 if test "$scm_stdint_has_uint8"; then
 393   SCM_I_GSC_T_UINT8='"uint8_t"'
 394   SCM_I_GSC_NEEDS_STDINT_H=1
 395 elif test "$scm_inttypes_has_uint8"; then
 396   SCM_I_GSC_T_UINT8='"uint8_t"'
 397   SCM_I_GSC_NEEDS_INTTYPES_H=1
 398 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 399   SCM_I_GSC_T_UINT8='"unsigned char"'
 400 else
 401   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 402 fi
 403 AC_SUBST([SCM_I_GSC_T_UINT8])
 404
 405 ### Required type scm_t_int16 (ANSI C says int or short might work)
 406 if test "$scm_stdint_has_int16"; then
 407   SCM_I_GSC_T_INT16='"int16_t"'
 408   SCM_I_GSC_NEEDS_STDINT_H=1
 409 elif test "$scm_inttypes_has_int16"; then
 410   SCM_I_GSC_T_INT16='"int16_t"'
 411   SCM_I_GSC_NEEDS_INTTYPES_H=1
 412 elif test "$ac_cv_sizeof_int" -eq 2; then
 413   SCM_I_GSC_T_INT16='"int"'
 414 elif test "$ac_cv_sizeof_short" -eq 2; then
 415   SCM_I_GSC_T_INT16='"short"'
 416 else
 417   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 418 fi
 419 AC_SUBST([SCM_I_GSC_T_INT16])
 420
 421 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 422 if test "$scm_stdint_has_uint16"; then
 423   SCM_I_GSC_T_UINT16='"uint16_t"'
 424   SCM_I_GSC_NEEDS_STDINT_H=1
 425 elif test "$scm_inttypes_has_uint16"; then
 426   SCM_I_GSC_T_UINT16='"uint16_t"'
 427   SCM_I_GSC_NEEDS_INTTYPES_H=1
 428 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 429   SCM_I_GSC_T_UINT16='"unsigned int"'
 430 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 431   SCM_I_GSC_T_UINT16='"unsigned short"'
 432 else
 433   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 434 fi
 435 AC_SUBST([SCM_I_GSC_T_UINT16])
 436
 437
 438 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 439 if test "$scm_stdint_has_int32"; then
 440   SCM_I_GSC_T_INT32='"int32_t"'
 441   SCM_I_GSC_NEEDS_STDINT_H=1
 442 elif test "$scm_inttypes_has_int32"; then
 443   SCM_I_GSC_T_INT32='"int32_t"'
 444   SCM_I_GSC_NEEDS_INTTYPES_H=1
 445 elif test "$ac_cv_sizeof_int" -eq 4; then
 446   SCM_I_GSC_T_INT32='"int"'
 447 elif test "$ac_cv_sizeof_long" -eq 4; then
 448   SCM_I_GSC_T_INT32='"long"'
 449 elif test "$ac_cv_sizeof_short" -eq 4; then
 450   SCM_I_GSC_T_INT32='"short"'
 451 else
 452   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 453 fi
 454 AC_SUBST([SCM_I_GSC_T_INT32])
 455
 456 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 457 if test "$scm_stdint_has_uint32"; then
 458   SCM_I_GSC_T_UINT32='"uint32_t"'
 459   SCM_I_GSC_NEEDS_STDINT_H=1
 460 elif test "$scm_inttypes_has_uint32"; then
 461   SCM_I_GSC_T_UINT32='"uint32_t"'
 462   SCM_I_GSC_NEEDS_INTTYPES_H=1
 463 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 464   SCM_I_GSC_T_UINT32='"unsigned int"'
 465 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 466   SCM_I_GSC_T_UINT32='"unsigned long"'
 467 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 468   SCM_I_GSC_T_UINT32='"unsigned short"'
 469 else
 470   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 471 fi
 472 AC_SUBST([SCM_I_GSC_T_UINT32])
 473
 474 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 475 ### Also try 'long long' and '__int64' if we have it.
 476 SCM_I_GSC_T_INT64=0
 477 if test "$scm_stdint_has_int64"; then
 478   SCM_I_GSC_T_INT64='"int64_t"'
 479   SCM_I_GSC_NEEDS_STDINT_H=1
 480 elif test "$scm_inttypes_has_int64"; then
 481   SCM_I_GSC_T_INT64='"int64_t"'
 482   SCM_I_GSC_NEEDS_INTTYPES_H=1
 483 elif test "$ac_cv_sizeof_int" -eq 8; then
 484   SCM_I_GSC_T_INT64='"int"'
 485 elif test "$ac_cv_sizeof_long" -eq 8; then
 486   SCM_I_GSC_T_INT64='"long"'
 487 elif test "$ac_cv_sizeof_short" -eq 8; then
 488   SCM_I_GSC_T_INT64='"short"'
 489 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 490   SCM_I_GSC_T_INT64='"long long"'
 491 elif test "$ac_cv_sizeof___int64" -eq 8; then
 492   SCM_I_GSC_T_INT64='"__int64"'
 493 else
 494   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 495 fi
 496 AC_SUBST([SCM_I_GSC_T_INT64])
 497
 498
 499 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 500 ### Also try 'long long' and '__int64' if we have it.
 501 SCM_I_GSC_T_UINT64=0
 502 if test "$scm_stdint_has_uint64"; then
 503   SCM_I_GSC_T_UINT64='"uint64_t"'
 504   SCM_I_GSC_NEEDS_STDINT_H=1
 505 elif test "$scm_inttypes_has_uint64"; then
 506   SCM_I_GSC_T_UINT64='"uint64_t"'
 507   SCM_I_GSC_NEEDS_INTTYPES_H=1
 508 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 509   SCM_I_GSC_T_UINT64='"unsigned int"'
 510 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 511   SCM_I_GSC_T_UINT64='"unsigned long"'
 512 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 513   SCM_I_GSC_T_UINT64='"unsigned short"'
 514 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 515   SCM_I_GSC_T_UINT64='"unsigned long long"'
 516 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 517   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 518 else
 519   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 520 fi
 521 AC_SUBST([SCM_I_GSC_T_UINT64])
 522
 523 ### Required type scm_t_intmax
 524 ###
 525 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 526 ### none of them is available, we use 'long'.
 527 ###
 528 SCM_I_GSC_T_INTMAX=0
 529 if test "$scm_stdint_has_intmax"; then
 530   SCM_I_GSC_T_INTMAX='"intmax_t"'
 531   SCM_I_GSC_NEEDS_STDINT_H=1
 532 elif test "$scm_inttypes_has_intmax"; then
 533   SCM_I_GSC_T_INTMAX='"intmax_t"'
 534   SCM_I_GSC_NEEDS_INTTYPES_H=1
 535 elif test "$ac_cv_sizeof___int64" -ne 0; then
 536   SCM_I_GSC_T_INTMAX='"__int64"'
 537 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 538   SCM_I_GSC_T_INTMAX='"long long"'
 539 else
 540   SCM_I_GSC_T_INTMAX='"long"'
 541 fi
 542 AC_SUBST([SCM_I_GSC_T_INTMAX])
 543
 544 ### Required type scm_t_uintmax
 545 ###
 546 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 547 ### this order.  When none of them is available, we use 'unsigned long'.
 548 ###
 549 SCM_I_GSC_T_UINTMAX=0
 550 if test "$scm_stdint_has_uintmax"; then
 551   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 552   SCM_I_GSC_NEEDS_STDINT_H=1
 553 elif test "$scm_inttypes_has_uintmax"; then
 554   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 555   SCM_I_GSC_NEEDS_INTTYPES_H=1
 556 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 557   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 558 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 559   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 560 else
 561   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 562 fi
 563 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 564
 565 ### Required type scm_t_intptr
 566 ###
 567 SCM_I_GSC_T_INTPTR=0
 568 if test "$scm_stdint_has_intptr"; then
 569   SCM_I_GSC_T_INTPTR='"intptr_t"'
 570   SCM_I_GSC_NEEDS_STDINT_H=1
 571 elif test "$scm_inttypes_has_intptr"; then
 572   SCM_I_GSC_T_INTPTR='"intptr_t"'
 573   SCM_I_GSC_NEEDS_INTTYPES_H=1
 574 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 575   SCM_I_GSC_T_INTPTR='"int"'
 576 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 577   SCM_I_GSC_T_INTPTR='"long"'
 578 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 579   SCM_I_GSC_T_INTPTR='"long long"'
 580 else
 581   AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.])
 582 fi
 583 AC_SUBST([SCM_I_GSC_T_INTPTR])
 584
 585 ### Required type scm_t_uintptr
 586 ###
 587 SCM_I_GSC_T_UINTPTR=0
 588 if test "$scm_stdint_has_uintptr"; then
 589   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 590   SCM_I_GSC_NEEDS_STDINT_H=1
 591 elif test "$scm_inttypes_has_uintptr"; then
 592   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 593   SCM_I_GSC_NEEDS_INTTYPES_H=1
 594 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 595   SCM_I_GSC_T_UINTPTR='"unsigned int"'
 596 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 597   SCM_I_GSC_T_UINTPTR='"unsigned long"'
 598 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 599   SCM_I_GSC_T_UINTPTR='"unsigned long long"'
 600 else
 601   AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.])
 602 fi
 603 AC_SUBST([SCM_I_GSC_T_UINTPTR])
 604
 605
 606 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 607 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 608
 609 AC_HEADER_STDC
 610 AC_HEADER_TIME
 611 AC_HEADER_SYS_WAIT
 612 AC_HEADER_DIRENT
 613
 614 # Reason for checking:
 615 #
 616 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 617 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 618 #
 619 AC_CHECK_MEMBER([struct dirent64.d_name],
 620   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 621   [ #ifndef _LARGEFILE64_SOURCE
 622     # define _LARGEFILE64_SOURCE
 623     #endif
 624
 625     /* Per Autoconf manual.  */
 626     #include <sys/types.h>
 627     #ifdef HAVE_DIRENT_H
 628     # include <dirent.h>
 629     #else
 630     # define dirent direct
 631     # ifdef HAVE_SYS_NDIR_H
 632     #  include <sys/ndir.h>
 633     # endif
 634     # ifdef HAVE_SYS_DIR_H
 635     #  include <sys/dir.h>
 636     # endif
 637     # ifdef HAVE_NDIR_H
 638     #  include <ndir.h>
 639     # endif
 640     #endif ])
 641 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 642
 643 # Reasons for testing:
 644 #   complex.h - new in C99
 645 #   fenv.h - available in C99, but not older systems
 646 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 647 #     this file instead of <fenv.h>
 648 #   process.h - mingw specific
 649 #   sched.h - missing on MinGW
 650 #
 651 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h memory.h process.h string.h \
 652 sys/dir.h sys/ioctl.h sys/select.h \
 653 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 654 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 655 direct.h machine/fpu.h poll.h sched.h])
 656
 657 # "complex double" is new in C99, and "complex" is only a keyword if
 658 # <complex.h> is included
 659 AC_CHECK_TYPES(complex double,,,
 660 [#if HAVE_COMPLEX_H
 661 #include <complex.h>
 662 #endif])
 663
 664 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 665 # when testing.
 666 AC_CHECK_TYPE(socklen_t, ,
 667   [AC_DEFINE_UNQUOTED([socklen_t], int,
 668                       [Define to `int' if <sys/socket.h> does not define.])],
 669   [#if HAVE_SYS_TYPES_H
 670 #include <sys/types.h>
 671 #endif
 672 #include <sys/socket.h>
 673 ])
 674
 675 AC_CHECK_TYPES([struct ip_mreq], , , [#include <netinet/in.h>])
 676
 677 GUILE_HEADER_LIBC_WITH_UNISTD
 678
 679 AC_TYPE_GETGROUPS
 680 AC_TYPE_SIGNAL
 681 AC_TYPE_MODE_T
 682
 683 # On mingw -lm is empty, so this test is unnecessary, but it's
 684 # harmless so we don't hard-code to suppress it.
 685 #
 686 AC_CHECK_LIB(m, cos)
 687
 688 AC_CHECK_FUNCS(gethostbyname)
 689 if test $ac_cv_func_gethostbyname = no; then
 690     AC_CHECK_LIB(nsl, gethostbyname)
 691 fi
 692
 693 AC_CHECK_FUNCS(connect)
 694 if test $ac_cv_func_connect = no; then
 695     AC_CHECK_LIB(socket, connect)
 696 fi
 697
 698 dnl
 699 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 700 dnl
 701 EXTRA_DEFS=""
 702 case $host in
 703   *-*-mingw*)
 704     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 705       [Define if you have the <winsock2.h> header file.])])
 706     AC_CHECK_LIB(ws2_32, main)
 707     AC_LIBOBJ([win32-uname])
 708     if test "$enable_networking" = yes ; then
 709       AC_LIBOBJ([win32-socket])
 710     fi
 711     if test "$enable_shared" = yes ; then
 712       EXTRA_DEFS="-DSCM_IMPORT"
 713       AC_DEFINE([USE_DLL_IMPORT], 1,
 714         [Define if you need additional CPP macros on Win32 platforms.])
 715     fi
 716     ;;
 717 esac
 718 AC_SUBST(EXTRA_DEFS)
 719
 720 # Reasons for testing:
 721 #   crt_externs.h - Darwin specific
 722 #
 723 AC_CHECK_HEADERS([assert.h crt_externs.h])
 724
 725 # Reasons for testing:
 726 #   DINFINITY - OSF specific
 727 #   DQNAN - OSF specific
 728 #       (DINFINITY and DQNAN are actually global variables, not functions)
 729 #   chsize - an MS-DOS-ism, found in mingw
 730 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 731 #       for gcc to provide the "complex double" type but the system to not
 732 #       have functions like cexp and clog
 733 #   clog10 - not in mingw (though others like clog and csqrt are)
 734 #   fesetround - available in C99, but not older systems
 735 #   ftruncate - posix, but probably not older systems (current mingw
 736 #               has it as an inline for chsize)
 737 #   ioctl - not in mingw.
 738 #   gmtime_r - recent posix, not on old systems
 739 #   pipe - not in mingw
 740 #   _pipe - specific to mingw, taking 3 args
 741 #   poll - since posix 2001
 742 #   readdir_r - recent posix, not on old systems
 743 #   readdir64_r - not available on HP-UX 11.11
 744 #   stat64 - SuS largefile stuff, not on old systems
 745 #   sysconf - not on old systems
 746 #   truncate - not in mingw
 747 #   isblank - available as a GNU extension or in C99
 748 #   _NSGetEnviron - Darwin specific
 749 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 750 #   fork - unavailable on Windows
 751 #   utimensat: posix.1-2008
 752 #   sched_getaffinity, sched_setaffinity: GNU extensions (glibc)
 753 #
 754 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown fchmod getcwd geteuid getsid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe poll readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale utimensat sched_getaffinity sched_setaffinity])
 755
 756 AM_CONDITIONAL([HAVE_FORK], [test "x$ac_cv_func_fork" = "xyes"])
 757
 758 # Reasons for testing:
 759 #   netdb.h - not in mingw
 760 #   sys/param.h - not in mingw
 761 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 762 #       check this specifically, we need it for the timespec test below.
 763 #   pthread_np.h - available on FreeBSD
 764 #   sethostname - the function itself check because it's not in mingw,
 765 #       the DECL is checked because Solaris 10 doens't have in any header
 766 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 767 #       declaration isn't anywhere.
 768 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 769 #       only with `_XOPEN_SOURCE' or some such.
 770 #
 771 AC_CHECK_HEADERS([crypt.h netdb.h pthread.h pthread_np.h sys/param.h sys/resource.h sys/file.h sys/mman.h])
 772 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 773 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 774
 775 # crypt() may or may not be available, for instance in some countries there
 776 # are restrictions on cryptography.
 777 #
 778 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 779 # -lcrypt library (eg. Debian GNU/Linux).
 780 #
 781 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 782 # be careful to avoid -lcrypt in this case, since libtool will see there's
 783 # only a static libcrypt and decide to build only a static libguile.
 784 #
 785 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 786 # libraries already in that list.
 787 #
 788 AC_SEARCH_LIBS(crypt, crypt,
 789   [AC_DEFINE([HAVE_CRYPT],1,
 790              [Define to 1 if you have the `crypt' function.])])
 791
 792 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 793 # work; in the reported cases so far, 1.0fi works well instead.  According
 794 # to the C99 spec, the complex.h header must provide a working definition
 795 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 796 # is a workaround for the failure of some systems to conform to C99.
 797 if test "$ac_cv_type_complex_double" = yes; then
 798   AC_MSG_CHECKING([for i])
 799   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 800 #if HAVE_COMPLEX_H
 801 #include <complex.h>
 802 #endif
 803 complex double z;
 804 ]], [[
 805 z = _Complex_I;
 806 ]])],
 807     [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).])
 808      AC_MSG_RESULT([_Complex_I])],
 809     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 810 #if HAVE_COMPLEX_H
 811 #include <complex.h>
 812 #endif
 813 complex double z;
 814 ]],[[
 815 z = 1.0fi;
 816 ]])],
 817   [AC_DEFINE([GUILE_I],1.0fi)
 818    AC_MSG_RESULT([1.0fi])],
 819   [ac_cv_type_complex_double=no
 820    AC_MSG_RESULT([not available])])])
 821 fi
 822
 823 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 824 # csqrt(-i) returned a negative real part, when it should be positive
 825 # for the principal root.
 826 #
 827 if test "$ac_cv_type_complex_double" = yes; then
 828
 829   AC_CACHE_CHECK([whether csqrt is usable],
 830     guile_cv_use_csqrt,
 831     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 832 #include <complex.h>
 833 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 834    constant, we want to test libc. */
 835 volatile complex double z = - _Complex_I;
 836 int
 837 main (void)
 838 {
 839   z = csqrt (z);
 840   if (creal (z) > 0.0)
 841     return 0;  /* good */
 842   else
 843     return 1;  /* bad */
 844 }]])],
 845     [guile_cv_use_csqrt=yes],
 846     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 847     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 848   case $guile_cv_use_csqrt in
 849     yes*)
 850       AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free])
 851       ;;
 852   esac
 853 fi
 854
 855 AC_CACHE_SAVE
 856
 857 dnl GMP tests
 858 AC_LIB_HAVE_LINKFLAGS([gmp],
 859   [],
 860   [#include <gmp.h>],
 861   [mpz_import (0, 0, 0, 0, 0, 0, 0);])
 862
 863 if test "x$HAVE_LIBGMP" != "xyes"; then
 864   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README])
 865 fi
 866
 867 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 868 if test "x$LTLIBUNISTRING" = "x"; then
 869   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 870 fi
 871
 872 GUILE_LIBUNISTRING_WITH_ICONV_SUPPORT
 873 if test "x$ac_cv_libunistring_with_iconv_support" != "xyes"; then
 874   AC_MSG_ERROR([No iconv support.  Please recompile libunistring with iconv enabled.])
 875 fi
 876
 877 dnl Libffi is needed to compile Guile's foreign function interface, but its
 878 dnl interface isn't exposed in Guile's API.
 879 PKG_CHECK_MODULES(LIBFFI, libffi)
 880 AC_SUBST(LIBFFI_CFLAGS)
 881 AC_SUBST(LIBFFI_LIBS)
 882
 883 dnl figure out approriate ffi type for size_t
 884 AC_CHECK_SIZEOF(size_t)
 885 AC_CHECK_SIZEOF(ssize_t)
 886 ffi_size_type=uint$(($ac_cv_sizeof_size_t*8))
 887 ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8))
 888 AC_DEFINE_UNQUOTED([ffi_type_size_t], ffi_type_${ffi_size_type},
 889                    [ffi type for size_t])
 890 AC_DEFINE_UNQUOTED([ffi_type_ssize_t], ffi_type_${ffi_ssize_type},
 891                    [ffi type for ssize_t])
 892
 893 dnl i18n tests
 894 #AC_CHECK_HEADERS([libintl.h])
 895 #AC_CHECK_FUNCS(gettext)
 896 #if test $ac_cv_func_gettext = no; then
 897 #   AC_CHECK_LIB(intl, gettext)
 898 #fi
 899 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 900 AM_GNU_GETTEXT([external], [need-ngettext])
 901
 902 ### Some systems don't declare some functions.  On such systems, we
 903 ### need to at least provide our own K&R-style declarations.
 904
 905 ### GUILE_FUNC_DECLARED(function, headerfile)
 906
 907 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 908 ### not there, #define MISSING_FUNCTION_DECL.
 909 AC_DEFUN([GUILE_FUNC_DECLARED], [
 910   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 911     AC_EGREP_HEADER($1, $2,
 912                     guile_cv_func_$1_declared=yes,
 913                     guile_cv_func_$1_declared=no))
 914   if test [x$guile_cv_func_]$1[_declared] = xno; then
 915     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 916       [Define if the operating system supplies $1 without declaring it.])
 917   fi
 918 ])
 919
 920 GUILE_FUNC_DECLARED(sleep, unistd.h)
 921 GUILE_FUNC_DECLARED(usleep, unistd.h)
 922
 923 AC_CHECK_DECLS([strptime],,,
 924 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 925 #include <time.h>])
 926
 927 ### On some systems usleep has no return value.  If it does have one,
 928 ### we'd like to return it; otherwise, we'll fake it.
 929 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 930   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 931                    unistd.h,
 932                    [guile_cv_func_usleep_return_type=void],
 933                    [guile_cv_func_usleep_return_type=int])])
 934 case "$guile_cv_func_usleep_return_type" in
 935   "void" )
 936     AC_DEFINE([USLEEP_RETURNS_VOID], 1,
 937       [Define if the system headers declare usleep to return void.])
 938   ;;
 939 esac
 940
 941 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 942 if test -n "$have_sys_un_h" ; then
 943   AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1,
 944     [Define if the system supports Unix-domain (file-domain) sockets.])
 945 fi
 946
 947 AC_CHECK_FUNCS(getrlimit setrlimit)
 948
 949 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 950
 951 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 952                setnetent    getnetent    endnetent    dnl
 953                setprotoent  getprotoent  endprotoent  dnl
 954                setservent   getservent   endservent   dnl
 955                getnetbyaddr getnetbyname dnl
 956                inet_lnaof inet_makeaddr inet_netof hstrerror)
 957
 958 AC_CHECK_MEMBERS([struct sockaddr_in.sin_len],,,
 959 [#ifdef HAVE_SYS_TYPES_H
 960 #include <sys/types.h>
 961 #endif
 962 #include <netinet/in.h>])
 963
 964 AC_MSG_CHECKING(for __libc_stack_end)
 965 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 966 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 967 extern char *__libc_stack_end;]],
 968    [[printf("%p", (char*) __libc_stack_end);]])],
 969    [guile_cv_have_libc_stack_end=yes],
 970    [guile_cv_have_libc_stack_end=no])])
 971 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 972
 973 if test $guile_cv_have_libc_stack_end = yes; then
 974   AC_DEFINE([HAVE_LIBC_STACK_END], 1,
 975            [Define if you have the __libc_stack_end variable.])
 976 fi
 977
 978 dnl Some systems do not declare this.  Some systems do declare it, as a
 979 dnl macro.  With cygwin it may be in a DLL.
 980
 981 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 982 AC_CACHE_VAL(guile_cv_have_h_errno,
 983   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 984                                       [[int a = h_errno;]])],
 985   [guile_cv_have_h_errno=yes],
 986   [guile_cv_have_h_errno=no])])
 987 AC_MSG_RESULT($guile_cv_have_h_errno)
 988 if test $guile_cv_have_h_errno = yes; then
 989   AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.])
 990 fi
 991
 992 AC_MSG_CHECKING(whether uint32_t is defined)
 993 AC_CACHE_VAL(guile_cv_have_uint32_t,
 994   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 995                    #if HAVE_STDINT_H
 996                    #include <stdint.h>
 997                    #endif
 998                    #ifndef HAVE_NETDB_H
 999                    #include <netdb.h>
1000                    #endif]],
1001                    [[uint32_t a;]])],
1002                    [guile_cv_have_uint32_t=yes],
1003                    [guile_cv_have_uint32_t=no])])
1004 AC_MSG_RESULT($guile_cv_have_uint32_t)
1005 if test $guile_cv_have_uint32_t = yes; then
1006   AC_DEFINE([HAVE_UINT32_T], 1,
1007     [Define if uint32_t typedef is defined when netdb.h is include.])
1008 fi
1009
1010 AC_MSG_CHECKING(for working IPv6 support)
1011 AC_CACHE_VAL(guile_cv_have_ipv6,
1012 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1013 #ifdef HAVE_SYS_TYPES_H
1014 #include <sys/types.h>
1015 #endif
1016 #include <netinet/in.h>
1017 #include <sys/socket.h>]],
1018 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
1019 [guile_cv_have_ipv6=yes],
1020 [guile_cv_have_ipv6=no])])
1021 AC_MSG_RESULT($guile_cv_have_ipv6)
1022 if test $guile_cv_have_ipv6 = yes; then
1023   AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.])
1024 fi
1025
1026 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
1027 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
1028 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
1029 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1030 #ifdef HAVE_SYS_TYPES_H
1031 #include <sys/types.h>
1032 #endif
1033 #include <netinet/in.h>]],
1034 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
1035 [guile_cv_have_sin6_scope_id=yes],
1036 [guile_cv_have_sin6_scope_id=no])])
1037 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
1038 if test $guile_cv_have_sin6_scope_id = yes; then
1039   AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1,
1040     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
1041 fi
1042
1043 # struct sockaddr_in6 field sin_len is only present on BSD systems
1044 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1045 [#ifdef HAVE_SYS_TYPES_H
1046 #include <sys/types.h>
1047 #endif
1048 #include <netinet/in.h>])
1049
1050 AC_MSG_CHECKING(whether localtime caches TZ)
1051 AC_CACHE_VAL(guile_cv_localtime_cache,
1052 [if test x$ac_cv_func_tzset = xyes; then
1053 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1054 #if STDC_HEADERS
1055 # include <stdlib.h>
1056 #endif
1057 extern char **environ;
1058 unset_TZ ()
1059 {
1060   char **from, **to;
1061   for (to = from = environ; (*to = *from); from++)
1062     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1063       to++;
1064 }
1065 char TZ_GMT0[] = "TZ=GMT0";
1066 char TZ_PST8[] = "TZ=PST8";
1067 main()
1068 {
1069   time_t now = time ((time_t *) 0);
1070   int hour_GMT0, hour_unset;
1071   if (putenv (TZ_GMT0) != 0)
1072     exit (1);
1073   hour_GMT0 = localtime (&now)->tm_hour;
1074   unset_TZ ();
1075   hour_unset = localtime (&now)->tm_hour;
1076   if (putenv (TZ_PST8) != 0)
1077     exit (1);
1078   if (localtime (&now)->tm_hour == hour_GMT0)
1079     exit (1);
1080   unset_TZ ();
1081   if (localtime (&now)->tm_hour != hour_unset)
1082     exit (1);
1083   exit (0);
1084 }]])],
1085 [guile_cv_localtime_cache=no],
1086 [guile_cv_localtime_cache=yes],
1087 [# If we have tzset, assume the worst when cross-compiling.
1088 guile_cv_localtime_cache=yes])
1089 else
1090         # If we lack tzset, report that localtime does not cache TZ,
1091         # since we can't invalidate the cache if we don't have tzset.
1092         guile_cv_localtime_cache=no
1093 fi])dnl
1094 AC_MSG_RESULT($guile_cv_localtime_cache)
1095 if test $guile_cv_localtime_cache = yes; then
1096   AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.])
1097 fi
1098
1099 if test "$enable_regex" = yes; then
1100    AC_LIBOBJ([regex-posix])
1101    AC_DEFINE([ENABLE_REGEX], 1, [Define when regex support is enabled.])
1102 fi
1103
1104 AC_REPLACE_FUNCS([strerror memmove mkstemp])
1105
1106 # Reasons for testing:
1107 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1108 #                                older systems
1109 #   sincos - GLIBC extension
1110 #
1111 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1112
1113 # C99 specifies isinf and isnan as macros.
1114 # HP-UX provides only macros, no functions.
1115 # glibc 2.3.2 provides both macros and functions.
1116 # IRIX 6.5 and Solaris 8 only provide functions.
1117 #
1118 # The following tests detect isinf and isnan either as functions or as
1119 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1120 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1121 #
1122 AC_MSG_CHECKING([for isinf])
1123 AC_LINK_IFELSE([AC_LANG_SOURCE(
1124 [[#include <math.h>
1125 volatile double x = 0.0;
1126 int main () { return (isinf(x) != 0); }]])],
1127   [AC_MSG_RESULT([yes])
1128    AC_DEFINE([HAVE_ISINF], 1,
1129              [Define to 1 if you have the `isinf' macro or function.])],
1130   [AC_MSG_RESULT([no])])
1131 AC_MSG_CHECKING([for isnan])
1132 AC_LINK_IFELSE([AC_LANG_SOURCE([[
1133 #include <math.h>
1134 volatile double x = 0.0;
1135 int main () { return (isnan(x) != 0); }]])],
1136   [AC_MSG_RESULT([yes])
1137    AC_DEFINE([HAVE_ISNAN], 1,
1138              [Define to 1 if you have the `isnan' macro or function.])],
1139   [AC_MSG_RESULT([no])])
1140
1141 # Reasons for checking:
1142 #
1143 #     st_rdev
1144 #     st_blksize
1145 #     st_blocks   not in mingw
1146 #     tm_gmtoff   BSD+GNU, not in C99
1147 #
1148 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1149 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1150 #
1151 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,,
1152                  [#define _GNU_SOURCE
1153 AC_INCLUDES_DEFAULT
1154 ])
1155
1156 AC_STRUCT_TIMEZONE
1157 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1158 [#include <time.h>
1159 #ifdef TIME_WITH_SYS_TIME
1160 # include <sys/time.h>
1161 # include <time.h>
1162 #else
1163 # if HAVE_SYS_TIME_H
1164 #  include <sys/time.h>
1165 # else
1166 #  include <time.h>
1167 # endif
1168 #endif
1169 ])
1170 GUILE_STRUCT_UTIMBUF
1171
1172
1173 #--------------------------------------------------------------------
1174 #
1175 # What values do the iconv error handlers have?
1176 #
1177 # The only place that we need iconv in our public interfaces is for
1178 # the error handlers, which are just ints.  So we weaken our
1179 # dependency by looking up those values at configure-time.
1180 #--------------------------------------------------------------------
1181 GUILE_UNISTRING_ICONVEH_VALUES
1182
1183 #--------------------------------------------------------------------
1184 #
1185 # Which way does the stack grow?
1186 #
1187 # Following code comes from Autoconf 2.69's internal _AC_LIBOBJ_ALLOCA
1188 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1189 # very similar code, so in future we could look at using that.
1190 #
1191 # An important detail is that the code involves find_stack_direction
1192 # calling _itself_ - which means that find_stack_direction (or at
1193 # least the second find_stack_direction() call) cannot be inlined.
1194 # If the code could be inlined, that might cause the test to give
1195 # an incorrect answer.
1196 #--------------------------------------------------------------------
1197
1198 SCM_I_GSC_STACK_GROWS_UP=0
1199 AC_RUN_IFELSE([AC_LANG_SOURCE(
1200 [AC_INCLUDES_DEFAULT
1201 int
1202 find_stack_direction (int *addr, int depth)
1203 {
1204   int dir, dummy = 0;
1205   if (! addr)
1206     addr = &dummy;
1207   *addr = addr < &dummy ? 1 : addr == &dummy ? 0 : -1;
1208   dir = depth ? find_stack_direction (addr, depth - 1) : 0;
1209   return dir + dummy;
1210 }
1211
1212 int
1213 main (int argc, char **argv)
1214 {
1215   return find_stack_direction (0, argc + !argv + 20) < 0;
1216 }])],
1217                [SCM_I_GSC_STACK_GROWS_UP=1],
1218                [],
1219                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1220
1221 #--------------------------------------------------------------------
1222 #
1223 # Boehm's GC library
1224 #
1225 #--------------------------------------------------------------------
1226 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1227
1228 save_LIBS="$LIBS"
1229 LIBS="$BDW_GC_LIBS $LIBS"
1230 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1231
1232 AC_CHECK_FUNCS([GC_do_blocking GC_call_with_gc_active GC_pthread_exit   \
1233   GC_pthread_cancel GC_allow_register_threads GC_pthread_sigmask        \
1234   GC_set_start_callback GC_get_heap_usage_safe                          \
1235   GC_get_free_space_divisor GC_gcollect_and_unmap GC_get_unmapped_bytes \
1236   GC_set_finalizer_notifier GC_set_finalize_on_demand                   \
1237   GC_set_all_interior_pointers GC_get_gc_no GC_set_java_finalization])
1238
1239 # Though the `GC_do_blocking ()' symbol is present in GC 7.1, it is not
1240 # declared, and has a different type (returning void instead of
1241 # void*).
1242 AC_CHECK_DECL([GC_do_blocking],
1243   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1244     [Define this if the `GC_do_blocking ()' function is declared])],
1245   [],
1246   [#include <gc/gc.h>])
1247
1248 # `GC_fn_type' is not available in GC 7.1 and earlier.
1249 AC_CHECK_TYPE([GC_fn_type],
1250   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1251     [Define this if the `GC_fn_type' type is available.])],
1252   [],
1253   [#include <gc/gc.h>])
1254
1255 # `GC_stack_base' is not available in GC 7.1 and earlier.
1256 AC_CHECK_TYPE([struct GC_stack_base],
1257   [AC_DEFINE([HAVE_GC_STACK_BASE], [1],
1258     [Define this if the `GC_stack_base' type is available.])],
1259   [],
1260   [#include <gc/gc.h>])
1261
1262 LIBS="$save_LIBS"
1263
1264
1265 AC_CHECK_SIZEOF(float)
1266 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1267     AC_DEFINE([SCM_SINGLES], 1,
1268               [Define this if floats are the same size as longs.])
1269 fi
1270
1271 AC_MSG_CHECKING(for struct linger)
1272 AC_CACHE_VAL(scm_cv_struct_linger,
1273         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1274 #include <sys/types.h>
1275 #include <sys/socket.h>]],
1276                           [[struct linger lgr;  lgr.l_linger = 100]])],
1277                           [scm_cv_struct_linger="yes"],
1278                           [scm_cv_struct_linger="no"]))
1279 AC_MSG_RESULT($scm_cv_struct_linger)
1280 if test $scm_cv_struct_linger = yes; then
1281         AC_DEFINE([HAVE_STRUCT_LINGER], 1,
1282           [Define this if your system defines struct linger, for use with the
1283            getsockopt and setsockopt system calls.])
1284 fi
1285
1286
1287 # On mingw, struct timespec is in <pthread.h>.
1288 #
1289 AC_MSG_CHECKING(for struct timespec)
1290 AC_CACHE_VAL(scm_cv_struct_timespec,
1291         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1292 #include <time.h>
1293 #if HAVE_PTHREAD_H
1294 #include <pthread.h>
1295 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1296           [scm_cv_struct_timespec="yes"],
1297           [scm_cv_struct_timespec="no"]))
1298 AC_MSG_RESULT($scm_cv_struct_timespec)
1299 if test $scm_cv_struct_timespec = yes; then
1300   AC_DEFINE([HAVE_STRUCT_TIMESPEC], 1,
1301     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1302 fi
1303
1304 #--------------------------------------------------------------------
1305 #
1306 # Flags for thread support
1307 #
1308 #--------------------------------------------------------------------
1309
1310 SCM_I_GSC_USE_PTHREAD_THREADS=0
1311 SCM_I_GSC_USE_NULL_THREADS=0
1312 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1313 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1314
1315 ### What thread package has the user asked for?
1316 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1317             , with_threads=yes)
1318
1319 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1320 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1321
1322 case "$with_threads" in
1323   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1324
1325     build_pthread_support="yes"
1326
1327     ACX_PTHREAD([CC="$PTHREAD_CC"
1328        LIBS="$PTHREAD_LIBS $LIBS"
1329        SCM_I_GSC_USE_PTHREAD_THREADS=1
1330        with_threads="pthreads"],
1331       [with_threads="null"
1332        build_pthread_support="no"])
1333
1334     old_CFLAGS="$CFLAGS"
1335     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1336
1337     # Reasons for testing:
1338     #     pthread_getattr_np - "np" meaning "non portable" says it
1339     #         all; not present on MacOS X or Solaris 10
1340     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1341     #         all; specific to MacOS X
1342     #     pthread_attr_get_np - "np" meaning "non portable" says it
1343     #         all; specific to FreeBSD
1344     #     pthread_sigmask - not available on mingw
1345     #
1346     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_attr_get_np pthread_sigmask)
1347
1348     # On past versions of Solaris, believe 8 through 10 at least, you
1349     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1350     # This is contrary to POSIX:
1351     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1352     # Check here if this style is required.
1353     #
1354     # glibc (2.3.6 at least) works both with or without braces, so the
1355     # test checks whether it works without.
1356     #
1357
1358     if test "$GCC" = "yes"; then
1359       # Since GCC only issues a warning for missing braces, so we need
1360       # `-Werror' to catch it.
1361       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1362     fi
1363
1364     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1365       guile_cv_need_braces_on_pthread_once_init,
1366       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>
1367          pthread_once_t foo = PTHREAD_ONCE_INIT;]])],
1368         [guile_cv_need_braces_on_pthread_once_init=no],
1369         [guile_cv_need_braces_on_pthread_once_init=yes])])
1370     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1371       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1372     fi
1373
1374     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1375     # 6.5.30m with GCC 3.3.
1376     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1377       guile_cv_need_braces_on_pthread_mutex_initializer,
1378       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>
1379          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;]])],
1380         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1381         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1382     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1383       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1384     fi
1385
1386     CFLAGS="$old_CFLAGS"
1387
1388     # On Solaris, sched_yield lives in -lrt.
1389     AC_SEARCH_LIBS(sched_yield, rt)
1390
1391   ;;
1392 esac
1393
1394 case "$with_threads" in
1395   "pthreads")
1396   ;;
1397   "no" | "null")
1398     SCM_I_GSC_USE_NULL_THREADS=1
1399     SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
1400     with_threads="null-threads"
1401   ;;
1402   * )
1403     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1404   ;;
1405 esac
1406
1407 AC_MSG_CHECKING(what kind of threads to support)
1408 AC_MSG_RESULT($with_threads)
1409
1410 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1411   [test "x$build_pthread_support" = "xyes"])
1412
1413
1414 ## Check whether pthread_attr_getstack works for the main thread
1415
1416 if test "$with_threads" = pthreads; then
1417
1418 AC_MSG_CHECKING([whether pthread_attr_getstack works for the main thread])
1419 old_CFLAGS="$CFLAGS"
1420 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1421 if test "$cross_compiling" = "no"; then
1422   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1423   #if HAVE_PTHREAD_ATTR_GETSTACK
1424   #include <pthread.h>
1425
1426   int main ()
1427   {
1428     pthread_attr_t attr;
1429     void *start, *end;
1430     size_t size;
1431
1432     pthread_getattr_np (pthread_self (), &attr);
1433     pthread_attr_getstack (&attr, &start, &size);
1434     end = (char *)start + size;
1435
1436     if ((void *)&attr < start || (void *)&attr >= end)
1437       return 1;
1438     else
1439       return 0;
1440   }
1441   #else
1442   int main ()
1443   {
1444     return 1;
1445   }
1446   #endif
1447   ]])],
1448   [works=yes
1449    AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])],
1450   [works=no],
1451   [])
1452 else
1453   works="assuming it doesn't"
1454 fi
1455 CFLAGS="$old_CFLAGS"
1456 AC_MSG_RESULT($works)
1457
1458 GUILE_THREAD_LOCAL_STORAGE
1459
1460 fi # with_threads=pthreads
1461
1462
1463 ## Cross building
1464 if test "$cross_compiling" = "yes"; then
1465   AC_MSG_CHECKING(cc for build)
1466   ## /usr/bin/cc still uses wrong assembler
1467   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1468   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1469 else
1470   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1471 fi
1472
1473 ## AC_MSG_CHECKING("if we are cross compiling")
1474 ## AC_MSG_RESULT($cross_compiling)
1475 if test "$cross_compiling" = "yes"; then
1476    AC_MSG_RESULT($CC_FOR_BUILD)
1477 fi
1478
1479 ## No need as yet to be more elaborate
1480 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1481
1482 AC_SUBST(cross_compiling)
1483 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1484 AC_SUBST(CCLD_FOR_BUILD)
1485
1486 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1487 ## --HOST is the platform that PACKAGE is compiled for.
1488 HOST_CC="$CC_FOR_BUILD"
1489 AC_SUBST(HOST_CC)
1490
1491 GUILE_CHECK_GUILE_FOR_BUILD
1492
1493 ## If we're using GCC, ask for aggressive warnings.
1494 GCC_CFLAGS=""
1495 case "$GCC" in
1496   yes )
1497     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1498     ## much stuff with generic function pointers for that to really be
1499     ## less than exasperating.
1500     ## -Wundef was removed because Gnulib prevented it (see
1501     ## <http://thread.gmane.org/gmane.lisp.guile.bugs/5329>.)
1502
1503     ## Build with `-fno-strict-aliasing' to prevent miscompilation on
1504     ## some platforms.  See
1505     ## <http://lists.gnu.org/archive/html/guile-devel/2012-01/msg00487.html>.
1506
1507     POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \
1508       -Wdeclaration-after-statement -Wpointer-arith \
1509       -Wswitch-enum -fno-strict-aliasing"
1510     # Do this here so we don't screw up any of the tests above that might
1511     # not be "warning free"
1512     if test "${GUILE_ERROR_ON_WARNING}" = yes
1513     then
1514         POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror"
1515         enable_compile_warnings=no
1516     fi
1517
1518     for flag in $POTENTIAL_GCC_CFLAGS
1519     do
1520         gl_WARN_ADD([$flag], [GCC_CFLAGS])
1521     done
1522     ;;
1523 esac
1524
1525 AC_SUBST(GCC_CFLAGS)
1526
1527 # Check for GNU ld's "-z relro".
1528 GUILE_GNU_LD_RELRO
1529
1530
1531 ## If we're creating a shared library (using libtool!), then we'll
1532 ## need to generate a list of .lo files corresponding to the .o files
1533 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1534 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1535
1536 ## We also need to create corresponding .doc and .x files
1537 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1538 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1539
1540 # GNU Readline bindings.
1541 GUILE_READLINE
1542
1543 AC_SUBST(GUILE_MAJOR_VERSION)
1544 AC_SUBST(GUILE_MINOR_VERSION)
1545 AC_SUBST(GUILE_MICRO_VERSION)
1546 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1547 AC_SUBST(GUILE_VERSION)
1548
1549 #######################################################################
1550 # library versioning
1551
1552 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1553 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1554 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1555 AC_SUBST(LIBGUILE_INTERFACE)
1556
1557 AC_SUBST(LIBGUILE_I18N_MAJOR)
1558 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1559 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1560 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1561 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1562
1563
1564 #######################################################################
1565
1566 dnl Tell guile-config what flags guile users should compile and link
1567 dnl with, keeping only `-I' flags from $CPPFLAGS.
1568 GUILE_CFLAGS=""
1569 next_is_includedir=false
1570 for flag in $CPPFLAGS
1571 do
1572   if $next_is_includedir; then
1573     GUILE_CFLAGS="$GUILE_CFLAGS -I $flag"
1574     next_is_includedir=false
1575   else
1576     case "$flag" in
1577       -I)  next_is_includedir=true;;
1578       -I*) GUILE_CFLAGS="$GUILE_CFLAGS $flag";;
1579       *)   ;;
1580     esac
1581   fi
1582 done
1583
1584 GUILE_CFLAGS="$GUILE_CFLAGS $PTHREAD_CFLAGS"
1585 GUILE_LIBS="$LDFLAGS $LIBS"
1586
1587 AC_SUBST(GUILE_LIBS)
1588 AC_SUBST(GUILE_CFLAGS)
1589
1590 AC_SUBST(AWK)
1591 AC_SUBST(LIBLOBJS)
1592 AC_SUBST(EXTRA_DOT_DOC_FILES)
1593 AC_SUBST(EXTRA_DOT_X_FILES)
1594
1595 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1596 top_builddir_absolute=`pwd`
1597 AC_SUBST(top_builddir_absolute)
1598 top_srcdir_absolute=`(cd $srcdir && pwd)`
1599 AC_SUBST(top_srcdir_absolute)
1600
1601 dnl `sitedir' goes into libpath.h and the pkg-config file.
1602 pkgdatadir="$datadir/$PACKAGE_TARNAME"
1603 sitedir="$pkgdatadir/site/$GUILE_EFFECTIVE_VERSION"
1604 AC_SUBST([sitedir])
1605
1606 dnl Name of the `guile' program.
1607 guile_program_name="`echo guile | "$SED" "$program_transform_name"`"
1608 AC_SUBST([guile_program_name])
1609
1610 # Additional SCM_I_GSC definitions are above.
1611 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1612 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1613 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1614 AC_SUBST([SCM_I_GSC_C_INLINE])
1615 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1616
1617 AC_CONFIG_FILES([
1618   Makefile
1619   am/Makefile
1620   lib/Makefile
1621   benchmark-suite/Makefile
1622   gc-benchmarks/Makefile
1623   doc/Makefile
1624   doc/r5rs/Makefile
1625   doc/ref/Makefile
1626   emacs/Makefile
1627   examples/Makefile
1628   libguile/Makefile
1629   libguile/version.h
1630   guile-readline/Makefile
1631   test-suite/Makefile
1632   test-suite/standalone/Makefile
1633   test-suite/vm/Makefile
1634   meta/Makefile
1635   module/Makefile
1636 ])
1637
1638 AC_CONFIG_FILES([meta/guile-2.0.pc])
1639 AC_CONFIG_FILES([meta/guile-2.0-uninstalled.pc])
1640 AC_CONFIG_FILES([doc/ref/effective-version.texi])
1641
1642 GUILE_CONFIG_SCRIPT([check-guile])
1643 GUILE_CONFIG_SCRIPT([benchmark-guile])
1644 GUILE_CONFIG_SCRIPT([meta/guile])
1645 GUILE_CONFIG_SCRIPT([meta/uninstalled-env])
1646 GUILE_CONFIG_SCRIPT([meta/gdb-uninstalled-guile])
1647 GUILE_CONFIG_SCRIPT([meta/guild])
1648 GUILE_CONFIG_SCRIPT([libguile/guile-snarf])
1649 GUILE_CONFIG_SCRIPT([libguile/guile-snarf-docs])
1650 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-use-srfi])
1651 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-fast-slot-ref])
1652
1653 AC_OUTPUT
1654
1655 dnl Local Variables:
1656 dnl comment-start: "dnl "
1657 dnl comment-end: ""
1658 dnl comment-start-skip: "\\bdnl\\b\\s *"
1659 dnl End: