configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_INIT(Makefile.in)
  24 . $srcdir/GUILE-VERSION
  25 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  26 AM_MAINTAINER_MODE
  27 AM_CONFIG_HEADER(libguile/scmconfig.h)
  28
  29 #--------------------------------------------------------------------
  30 #
  31 # Independent Subdirectories
  32 #
  33 #--------------------------------------------------------------------
  34
  35 AC_CONFIG_SUBDIRS(guile-readline)
  36
  37 #--------------------------------------------------------------------
  38 #
  39 # User options
  40 #
  41 #--------------------------------------------------------------------
  42
  43 AC_ARG_ENABLE(dynamic-linking,
  44   [  --enable-dynamic-linking  Include support for dynamic linking],,
  45   enable_dynamic_linking=yes)
  46
  47 AC_ARG_ENABLE(guile-debug,
  48   [  --enable-guile-debug    Include internal debugging functions],
  49   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  50     AC_DEFINE(GUILE_DEBUG)
  51   fi)
  52
  53 AC_ARG_ENABLE(lang,
  54   [  --enable-lang           Include multilanguage support (experimental)],
  55   if test "$enable_lang" = y || test "$enable_lang" = yes; then
  56     AC_DEFINE(GUILE_LANG)
  57     LIBOBJS="$LIBOBJS lang.o"
  58   fi)
  59
  60 dnl The --disable-debug used to control these two.  But now they are
  61 dnl a required part of the distribution.
  62 AC_DEFINE(DEBUG_EXTENSIONS)
  63 AC_DEFINE(READER_EXTENSIONS)
  64
  65 #--------------------------------------------------------------------
  66
  67 AC_PROG_CC
  68 AC_PROG_CPP
  69 AM_PROG_LIBTOOL
  70
  71 AC_AIX
  72 AC_ISC_POSIX
  73 AC_MINIX
  74
  75 AM_PROG_CC_STDC
  76
  77 AC_C_CONST
  78 AC_C_INLINE
  79 AC_CHECK_SIZEOF(int)
  80 AC_CHECK_SIZEOF(long)
  81 AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
  82                AC_TRY_COMPILE(,
  83                               [long long a],
  84                               scm_cv_long_longs=yes,
  85                               scm_cv_long_longs=no))
  86 if test "$scm_cv_long_longs" = yes; then
  87   AC_DEFINE(HAVE_LONG_LONGS)
  88 fi
  89
  90 AC_HEADER_STDC
  91 AC_HEADER_DIRENT
  92 AC_HEADER_TIME
  93 AC_HEADER_SYS_WAIT
  94 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
  95 GUILE_HEADER_LIBC_WITH_UNISTD
  96
  97 AC_TYPE_GETGROUPS
  98 AC_TYPE_SIGNAL
  99 AC_TYPE_MODE_T
 100
 101 AC_CHECK_LIB(m, main)
 102 AC_CHECK_FUNCS(gethostbyname)
 103 if test $ac_cv_func_gethostbyname = no; then
 104     AC_CHECK_LIB(nsl, gethostbyname)
 105 fi
 106 AC_CHECK_FUNCS(connect)
 107 if test $ac_cv_func_connect = no; then
 108     AC_CHECK_LIB(socket, connect)
 109 fi
 110
 111 # Checks for dynamic linking
 112
 113 if test "$enable_dynamic_linking" = "yes"; then
 114
 115 AC_CHECK_LIB(dl,dlopen)
 116 if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 117   AC_CHECK_FUNCS(dlopen)
 118   AC_DEFINE(DYNAMIC_LINKING)
 119 else
 120 AC_CHECK_LIB(dld,dld_link)
 121 if test "$ac_cv_lib_dld_dld_link" = "yes"; then
 122   AC_DEFINE(DYNAMIC_LINKING)
 123 else
 124 AC_CHECK_FUNCS(shl_load)
 125 if test "$ac_cv_func_shl_load" = "yes"; then
 126   AC_DEFINE(DYNAMIC_LINKING)
 127 else
 128 AC_CHECK_FUNCS(dlopen)
 129 if test "$ac_cv_func_dlopen" = "yes"; then
 130   AC_DEFINE(DYNAMIC_LINKING)
 131 fi
 132 fi
 133 fi
 134 fi
 135
 136 fi
 137
 138 GUILE_DLSYM_USCORE
 139
 140 AC_CHECK_FUNCS(ctermid ftime getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid bzero strdup system usleep)
 141
 142 ### Some systems don't declare some functions.  On such systems, we
 143 ### need to at least provide our own K&R-style declarations.
 144
 145 ### GUILE_FUNC_DECLARED(function, headerfile)
 146
 147 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 148 ### not there, #define MISSING_FUNCTION_DECL.
 149 AC_DEFUN(GUILE_FUNC_DECLARED, [
 150   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 151     AC_EGREP_HEADER($1, $2,
 152                     guile_cv_func_$1_declared=yes,
 153                     guile_cv_func_$1_declared=no))
 154   if test [x$guile_cv_func_]$1[_declared] = xno; then
 155     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 156   fi
 157 ])
 158
 159 GUILE_FUNC_DECLARED(strptime, time.h)
 160 GUILE_FUNC_DECLARED(bzero, string.h)
 161 GUILE_FUNC_DECLARED(sleep, unistd.h)
 162 GUILE_FUNC_DECLARED(usleep, unistd.h)
 163
 164 ### On some systems usleep has no return value.  If it does have one,
 165 ### we'd like to return it; otherwise, we'll fake it.
 166 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 167   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 168                    /usr/include/unistd.h,
 169                    [guile_cv_func_usleep_return_type=void],
 170                    [guile_cv_func_usleep_return_type=int])])
 171 case "$guile_cv_func_usleep_return_type" in
 172   "void" )
 173     AC_DEFINE(USLEEP_RETURNS_VOID)
 174   ;;
 175 esac
 176
 177 dnl <GNU-WIN32 hacks>
 178
 179 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 180 if test -n "$have_sys_un_h" ; then
 181 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 182 fi
 183
 184 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 185
 186 dnl I don't know what this prefixing of cygwin32_ is for.
 187 dnl scmconfig.h wasn't updated with the test results.
 188 dnl so use AC_CHECK_FUNCS for now.
 189
 190 dnl how about:
 191 dnl save confdefs.h
 192 dnl if test $ac_cv_cigwin = yes; then
 193 dnl   modify confdefs.h
 194 dnl fi
 195 dnl AC_CHECK_FUNCS...
 196 dnl restore confdefs.h
 197
 198 dnl cp confdefs.h confdefs.h.bak
 199 dnl for func in gethostent sethostent endhostent getnetent setnetent endnetent getprotoent setprotoent endprotoent getservent setservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof ; do
 200 dnl cp confdefs.h.bak confdefs.h
 201 dnl cat >> confdefs.h << EOF
 202 dnl #ifdef __CYGWIN32__
 203 dnl #define $func cygwin32_$func
 204 dnl #endif
 205 dnl EOF
 206 dnl AC_CHECK_FUNC($func)
 207 dnl done
 208 dnl cp confdefs.h.bak confdefs.h
 209
 210 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 211                setnetent    getnetent    endnetent    dnl
 212                setprotoent  getprotoent  endprotoent  dnl
 213                setservent   getservent   endservent   dnl
 214                getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof)
 215
 216 dnl </GNU-WIN32 hacks>
 217
 218 AC_CACHE_CHECK([for restartable system calls], scm_cv_restarts,
 219         if test $ac_cv_func_sigaction = yes; then
 220                 [AC_TRY_COMPILE([#include <signal.h>],
 221                                 [int a = SA_RESTART],
 222                                 scm_cv_restarts=yes,
 223                                 scm_cv_restarts=no)]
 224         else
 225                 scm_cv_restarts=no
 226         fi)
 227 if test $scm_cv_restarts = yes; then
 228         AC_DEFINE(HAVE_RESTARTS)
 229 fi
 230
 231 if test "$ac_cv_header_regex_h" = yes ||
 232    test "$ac_cv_header_rxposix_h" = yes ||
 233    test "$ac_cv_header_rx_rxposix_h" = yes; then
 234   GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 235   [AC_CHECK_LIB(rx, main)
 236    GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 237   )
 238   dnl The following should not be necessary, but for some reason
 239   dnl autoheader misses it if we don't include it!
 240   if test "$ac_cv_func_regcomp_norx" = yes ||
 241      test "$ac_cv_func_regcomp_rx" = yes; then
 242     AC_DEFINE(HAVE_REGCOMP)
 243   fi
 244 fi
 245
 246 AC_REPLACE_FUNCS(inet_aton putenv strerror)
 247
 248 # When testing for the presence of alloca, we need to add alloca.o
 249 # explicitly to LIBOBJS to make sure that it is translated to
 250 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 251 AC_FUNC_ALLOCA
 252 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 253
 254 AC_STRUCT_ST_RDEV
 255 AC_STRUCT_ST_BLKSIZE
 256
 257 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 258 # LIBOBJS, which we don't need.  This seems more direct.
 259 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 260 [AC_TRY_COMPILE([#include <sys/types.h>
 261 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 262 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 263 if test $ac_cv_struct_st_blocks = yes; then
 264   AC_DEFINE(HAVE_ST_BLOCKS)
 265 fi
 266
 267 AC_STRUCT_TIMEZONE
 268 GUILE_STRUCT_UTIMBUF
 269
 270 #--------------------------------------------------------------------
 271 #
 272 # Which way does the stack grow?
 273 #
 274 #--------------------------------------------------------------------
 275
 276 AC_TRY_RUN(aux (l) unsigned long l;
 277              { int x; exit (l >= ((unsigned long)&x)); }
 278            main () { int q; aux((unsigned long)&q); },
 279            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 280
 281 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 282     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 283                 [guile_cv_type_float_fits_long=yes],
 284                 [guile_cv_type_float_fits_long=no],
 285                 [guile_cv_type_float_fits_long=guess-yes])])
 286 case $guile_cv_type_float_fits_long in
 287   "yes" )
 288     AC_DEFINE(SCM_SINGLES)
 289   ;;
 290   "guess-yes" )
 291     AC_DEFINE(SCM_SINGLES)
 292     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 293     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 294   ;;
 295 esac
 296
 297
 298 AC_MSG_CHECKING(for struct linger)
 299 AC_CACHE_VAL(scm_cv_struct_linger,
 300         AC_TRY_COMPILE([
 301 #include <sys/types.h>
 302 #include <sys/socket.h>],
 303                         [struct linger lgr;  lgr.l_linger = 100],
 304                         scm_cv_struct_linger="yes",
 305                         scm_cv_struct_linger="no"))
 306 AC_MSG_RESULT($scm_cv_struct_linger)
 307 if test $scm_cv_struct_linger = yes; then
 308         AC_DEFINE(HAVE_STRUCT_LINGER)
 309 fi
 310
 311 #--------------------------------------------------------------------
 312 #
 313 # How can you violate a stdio abstraction by setting a stream's fd?
 314 #
 315 #--------------------------------------------------------------------
 316
 317 dnl  AC_MSG_CHECKING(how to set a stream file descriptor)
 318 dnl  AC_CACHE_VAL(scm_cv_fd_setter,
 319 dnl     AC_TRY_COMPILE([#include <stdio.h>],
 320 dnl                     [stdout->_file = 1],
 321 dnl                     scm_cv_fd_setter="_file",
 322 dnl     AC_TRY_COMPILE([#include <stdio.h>],
 323 dnl                     [stdout->__file = 1],
 324 dnl                     scm_cv_fd_setter="__file",
 325 dnl     AC_TRY_COMPILE([#include <stdio.h>],
 326 dnl                     [stdout->_fileno = 1],
 327 dnl                     scm_cv_fd_setter="_fileno",
 328 dnl                     scm_cv_fd_setter=""))))
 329
 330 dnl  if test "$scm_cv_fd_setter"; then
 331 dnl     AC_MSG_RESULT($scm_cv_fd_setter)
 332 dnl     AC_DEFINE_UNQUOTED(FD_SETTER, $scm_cv_fd_setter)
 333 dnl  else
 334 dnl     AC_MSG_RESULT(we couldn't do it!)
 335 dnl  fi
 336
 337 #--------------------------------------------------------------------
 338 # How to find out whether a FILE structure contains buffered data.
 339 # From Tk we have the following list:
 340 #               _cnt:           Most UNIX systems
 341 #               __cnt:          HPUX and SCO
 342 #               _r:             BSD
 343 #               readCount:      Sprite
 344 #       Or, in GNU libc there are two fields, _gptr and _egptr, which
 345 #       have to be compared.
 346 #       These can also be known as _IO_read_ptr and _IO_read_end.
 347 #--------------------------------------------------------------------
 348
 349 dnl  AC_MSG_CHECKING(how to get buffer char count from FILE structure)
 350 dnl  AC_CACHE_VAL(scm_cv_struct_file_count,
 351 dnl     AC_TRY_COMPILE([#include <stdio.h>],
 352 dnl                     [FILE *f = stdin; f->_cnt = 0],
 353 dnl                     scm_cv_struct_file_count="_cnt",
 354 dnl     AC_TRY_COMPILE([#include <stdio.h>],
 355 dnl                     [FILE *f = stdin; f->__cnt = 0],
 356 dnl                     scm_cv_struct_file_count="__cnt",
 357 dnl     AC_TRY_COMPILE([#include <stdio.h>],
 358 dnl                     [FILE *f = stdin; f->_r = 0],
 359 dnl                     scm_cv_struct_file_count="_r",
 360 dnl     AC_TRY_COMPILE([#include <stdio.h>],
 361 dnl                     [FILE *f = stdin; f->readCount = 0],
 362 dnl                     scm_cv_struct_file_count="readCount",
 363 dnl     scm_cv_struct_file_count="")))))
 364 dnl  if test "$scm_cv_struct_file_count"; then
 365 dnl     AC_MSG_RESULT($scm_cv_struct_file_count)
 366 dnl     AC_DEFINE_UNQUOTED(FILE_CNT_FIELD, $scm_cv_struct_file_count)
 367 dnl  else
 368 dnl  AC_CACHE_VAL(scm_cv_struct_file_gptr,
 369 dnl     AC_TRY_COMPILE([#include <stdio.h>],
 370 dnl                     [FILE *f = stdin; f->_gptr = f->egptr;],
 371 dnl                     scm_cv_struct_file_gptr=1,
 372 dnl     scm_cv_struct_file_gptr=""))
 373 dnl  if test "$scm_cv_struct_gptr"; then
 374 dnl     AC_MSG_RESULT(gptr)
 375 dnl     AC_DEFINE_UNQUOTED(FILE_CNT_GPTR, $scm_cv_struct_file_gptr)
 376 dnl  else
 377 dnl  AC_CACHE_VAL(scm_cv_struct_file_readptr,
 378 dnl     AC_TRY_COMPILE([#include <stdio.h>],
 379 dnl                     [FILE *f = stdin; f->_IO_read_ptr = f->_IO_read_end;],
 380 dnl                     scm_cv_struct_file_readptr=1))
 381 dnl  if test "$scm_cv_struct_file_readptr"; then
 382 dnl     AC_MSG_RESULT(read_ptr)
 383 dnl     AC_DEFINE_UNQUOTED(FILE_CNT_READPTR, $scm_cv_struct_file_readptr)
 384 dnl  else
 385 dnl     AC_MSG_RESULT(we couldn't do it!)
 386 dnl  fi
 387 dnl  fi
 388 dnl  fi
 389
 390 #--------------------------------------------------------------------
 391 #
 392 # Flags for thread support
 393 #
 394 #--------------------------------------------------------------------
 395
 396 ### What thread package has the user asked for?
 397 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 398             , with_threads=no)
 399
 400 ### Turn $with_threads into either the name of a threads package, like
 401 ### `qt', or `no', meaning that threads should not be supported.
 402 AC_MSG_CHECKING(whether to support threads)
 403 case "$with_threads" in
 404   "yes" | "qt" | "coop" | "")
 405     with_threads=qt
 406   ;;
 407   "no" )
 408   ;;
 409   * )
 410     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 411   ;;
 412 esac
 413 AC_MSG_RESULT($with_threads)
 414
 415 ## Make sure the threads package we've chosen is actually supported on
 416 ## the present platform.
 417 case "${with_threads}" in
 418   "qt" )
 419     ## This configures the QuickThreads package, and sets or clears
 420     ## the THREAD_PACKAGE variable if qthreads don't configure
 421     ## correctly.
 422     QTHREADS_CONFIGURE
 423    ;;
 424 esac
 425
 426 ## If we're using threads, bring in some other parts of Guile which
 427 ## work with them.
 428 if test "${THREAD_PACKAGE}" != "" ; then
 429   AC_DEFINE(USE_THREADS, 1)
 430
 431   ## Include the Guile thread interface in the library...
 432   LIBOBJS="$LIBOBJS threads.o"
 433
 434   ## ... and tell it which package to talk to.
 435   case "${THREAD_PACKAGE}" in
 436     "QT" )
 437       AC_DEFINE(USE_COOP_THREADS, 1)
 438     ;;
 439     * )
 440       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 441     ;;
 442   esac
 443
 444   ## Bring in scm_internal_select, if appropriate.
 445   if test $ac_cv_func_gettimeofday = yes &&
 446      test $ac_cv_func_select = yes; then
 447     LIBOBJS="$LIBOBJS iselect.o"
 448     AC_DEFINE(GUILE_ISELECT, 1)
 449   fi
 450 fi
 451
 452
 453 ## If we're using GCC, ask for aggressive warnings.
 454 case "$GCC" in
 455   yes )
 456     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 457     ## much stuff with generic function pointers for that to really be
 458     ## less than exasperating.
 459     CFLAGS="$CFLAGS -Wall -Wpointer-arith -Wmissing-prototypes" ;;
 460 esac
 461
 462 AC_PROG_AWK
 463
 464 ## If we're creating a shared library (using libtool!), then we'll
 465 ## need to generate a list of .lo files corresponding to the .o files
 466 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 467 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 468
 469 AC_SUBST(GUILE_MAJOR_VERSION)
 470 AC_SUBST(GUILE_MINOR_VERSION)
 471 AC_SUBST(GUILE_VERSION)
 472
 473 dnl Tell guile-config what flags guile users should link against.
 474 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 475 AC_SUBST(GUILE_LIBS)
 476
 477 dnl timestamping the interpreter and scheme libraries:
 478 dnl
 479 dnl Help us notice when we're running one version of the Guile
 480 dnl interpreter against a different version of the ice-9 Scheme code.
 481 dnl This will definitely detect version skew due to differing
 482 dnl snapshots and releases, but may not catch skew for the developers.
 483 dnl Hopefully it will not detect skew when there is none; if that
 484 dnl happens, the warnings will be useless, and we should remove this.
 485 GUILE_STAMP="`date`"
 486 AC_SUBST(GUILE_STAMP)
 487
 488 AC_SUBST(AWK)
 489 AC_SUBST(LIBLOBJS)
 490
 491 AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf libguile/versiondat.h ice-9/Makefile ice-9/version.scm qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile guile-config/Makefile doc/Makefile], [chmod +x libguile/guile-snarf])
 492
 493 dnl Local Variables:
 494 dnl comment-start: "dnl "
 495 dnl comment-end: ""
 496 dnl comment-start-skip: "\\bdnl\\b\\s *"
 497 dnl End: