configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   8   2007, 2008, 2009, 2010, 2011, 2012 Free Software Foundation, Inc.
   9
  10 This file is part of GUILE
  11
  12 GUILE is free software; you can redistribute it and/or modify it under
  13 the terms of the GNU Lesser General Public License as published by the
  14 Free Software Foundation; either version 3, or (at your option) any
  15 later version.
  16
  17 GUILE is distributed in the hope that it will be useful, but WITHOUT
  18 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  19 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  20 License for more details.
  21
  22 You should have received a copy of the GNU Lesser General Public
  23 License along with GUILE; see the file COPYING.LESSER.  If not, write
  24 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  25 Floor, Boston, MA 02110-1301, USA.
  26
  27 ]])
  28
  29 AC_PREREQ(2.61)
  30
  31 AC_INIT([GNU Guile],
  32         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  33         [bug-guile@gnu.org])
  34 AC_CONFIG_AUX_DIR([build-aux])
  35 AC_CONFIG_MACRO_DIR([m4])
  36 AC_CONFIG_SRCDIR(GUILE-VERSION)
  37
  38 dnl `AM_SUBST_NOTMAKE' was introduced in Automake 1.11.
  39 AM_INIT_AUTOMAKE([1.11 gnu no-define -Wall -Wno-override dist-xz])
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AC_SUBST([AM_DEFAULT_VERBOSITY],1)])
  41
  42 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  43 AC_CONFIG_SRCDIR([GUILE-VERSION])
  44
  45 . $srcdir/GUILE-VERSION
  46 GUILE_VERSION="$PACKAGE_VERSION"
  47
  48 AC_CONFIG_HEADERS([config.h])
  49 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  50
  51 #--------------------------------------------------------------------
  52
  53 AC_LANG([C])
  54
  55 dnl Some more checks for Win32
  56 AC_CANONICAL_HOST
  57
  58 AC_LIBTOOL_WIN32_DLL
  59
  60 AC_PROG_INSTALL
  61 AC_PROG_CC
  62 gl_EARLY
  63 AC_PROG_CPP
  64 AC_PROG_SED
  65 AC_PROG_AWK
  66 AC_PROG_LN_S
  67
  68 dnl Gnulib.
  69 gl_INIT
  70 dnl FIXME: remove me and the acinclude.m4 code when clock-gettime is
  71 dnl fixed for clock_getcpuclockid and can be imported normally from
  72 dnl gnulib.  See
  73 dnl <http://lists.gnu.org/archive/html/bug-gnulib/2011-06/msg00227.html>
  74 dnl for details.
  75 gl_CLOCK_TIME
  76
  77 AC_PROG_CC_C89
  78
  79 # for per-target cflags in the libguile subdir
  80 AM_PROG_CC_C_O
  81
  82 AC_LIBTOOL_DLOPEN
  83 AC_PROG_LIBTOOL
  84
  85 AM_CONDITIONAL([HAVE_SHARED_LIBRARIES], [test "x$enable_shared" = "xyes"])
  86
  87 AC_DEFINE_UNQUOTED([SHARED_LIBRARY_PATH_VARIABLE], ["$shlibpath_var"],
  88   [Name of the environment variable that tells the dynamic linker where
  89 to find shared libraries.])
  90
  91 dnl Check for libltdl.
  92 AC_LIB_HAVE_LINKFLAGS([ltdl], [], [#include <ltdl.h>],
  93   [lt_dlopenext ("foo");])
  94 if test "x$HAVE_LIBLTDL" != "xyes"; then
  95   AC_MSG_ERROR([GNU libltdl (Libtool) not found, see README.])
  96 fi
  97
  98 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  99 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
 100
 101 AM_PATH_LISPDIR
 102
 103 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
 104   [Define to the host's GNU triplet.])
 105
 106 #--------------------------------------------------------------------
 107 #
 108 # User options (after above tests that may set default CFLAGS etc.)
 109 #
 110 #--------------------------------------------------------------------
 111
 112 GUILE_ERROR_ON_WARNING="no"
 113
 114 AC_ARG_ENABLE(error-on-warning,
 115   [  --enable-error-on-warning    treat compile warnings as errors],
 116   [case "${enableval}" in
 117      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 118      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 119      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 120    esac])
 121
 122 AC_ARG_ENABLE(debug-malloc,
 123   [  --enable-debug-malloc   include malloc debugging code],
 124   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 125     AC_DEFINE([GUILE_DEBUG_MALLOC], 1,
 126       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 127   fi)
 128
 129 SCM_I_GSC_GUILE_DEBUG=0
 130 AC_ARG_ENABLE(guile-debug,
 131   [AS_HELP_STRING([--enable-guile-debug],
 132                   [include internal debugging functions])],
 133   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 134     SCM_I_GSC_GUILE_DEBUG=1
 135   fi)
 136
 137 AC_ARG_ENABLE(posix,
 138   [  --disable-posix         omit non-essential POSIX interfaces],,
 139   enable_posix=yes)
 140
 141 AC_ARG_ENABLE(networking,
 142   [  --disable-networking    omit networking interfaces],,
 143   enable_networking=yes)
 144
 145 AC_ARG_ENABLE(regex,
 146   [  --disable-regex         omit regular expression interfaces],,
 147   enable_regex=yes)
 148
 149 AC_ARG_ENABLE([deprecated],
 150   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 151
 152 if test "$enable_deprecated" = no; then
 153   SCM_I_GSC_ENABLE_DEPRECATED=0
 154   warn_default=no
 155 else
 156   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 157     warn_default=summary
 158   elif test "$enable_deprecated" = shutup; then
 159     warn_default=no
 160   else
 161     warn_default=$enable_deprecated
 162   fi
 163   SCM_I_GSC_ENABLE_DEPRECATED=1
 164 fi
 165 AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default",
 166 [Define this to control the default warning level for deprecated features.])
 167
 168 dnl  Added the following configure option in January 2008 following
 169 dnl  investigation of problems with "64" system and library calls on
 170 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 171 dnl  system has stat64, it will have all the other 64 APIs too; but on
 172 dnl  Darwin, stat64 is there but other APIs are missing.
 173 dnl
 174 dnl  It also appears, from the Darwin docs, that most system call APIs
 175 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 176 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 177 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 178 dnl
 179 dnl  A similar problem has been reported for HP-UX:
 180 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 181 dnl
 182 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 183 dnl  better than no Guile at all, we provide this option to suppress
 184 dnl  trying to use "64" calls.
 185 dnl
 186 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 187 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 188 dnl  missing out on that.  If so, someone can work on that in the future.
 189 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 190 dnl  wasn't building before.
 191 AC_MSG_CHECKING([whether to use system and library "64" calls])
 192 AC_ARG_WITH([64-calls],
 193   AS_HELP_STRING([--without-64-calls],
 194                  [don't attempt to use system and library calls with "64" in their names]),
 195   [use_64_calls=$withval],
 196   [use_64_calls=yes
 197    case $host in
 198      *-apple-darwin* )
 199        use_64_calls=no
 200        ;;
 201      powerpc-ibm-aix* )
 202        use_64_calls=no
 203        ;;
 204    esac])
 205 AC_MSG_RESULT($use_64_calls)
 206 case "$use_64_calls" in
 207   y* )
 208     AC_DEFINE([GUILE_USE_64_CALLS], 1,
 209       [Define to 1 in order to try to use "64" versions of system and library calls.])
 210     ;;
 211 esac
 212
 213 #--------------------------------------------------------------------
 214
 215 dnl Check for dynamic linking
 216
 217 use_modules=yes
 218 AC_ARG_WITH(modules,
 219 [  --with-modules[=FILES]  Add support for dynamic modules],
 220 use_modules="$withval")
 221 test -z "$use_modules" && use_modules=yes
 222 DLPREOPEN=
 223 if test "$use_modules" != no; then
 224   if test "$use_modules" = yes; then
 225     DLPREOPEN="-dlpreopen force"
 226   else
 227     DLPREOPEN="-export-dynamic"
 228     for module in $use_modules; do
 229       DLPREOPEN="$DLPREOPEN -dlopen $module"
 230     done
 231   fi
 232 fi
 233
 234 dnl files which are destined for separate modules.
 235
 236 if test "$use_modules" != no; then
 237    AC_LIBOBJ([dynl])
 238    AC_DEFINE([HAVE_MODULES], 1,
 239      [Define this if you want support for dynamically loaded modules in Guile.])
 240 fi
 241
 242 if test "$enable_posix" = yes; then
 243    AC_LIBOBJ([posix])
 244    AC_DEFINE([HAVE_POSIX], 1,
 245      [Define this if you want support for non-essential POSIX system calls in Guile.])
 246 fi
 247
 248 if test "$enable_networking" = yes; then
 249    AC_LIBOBJ([net_db])
 250    AC_LIBOBJ([socket])
 251    AC_DEFINE([HAVE_NETWORKING], 1,
 252      [Define this if you want support for networking in Guile.])
 253 fi
 254
 255 if test "$enable_debug_malloc" = yes; then
 256    AC_LIBOBJ([debug-malloc])
 257 fi
 258
 259 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 260
 261 AC_C_CONST
 262
 263 # "volatile" is used in a couple of tests below.
 264 AC_C_VOLATILE
 265
 266 AC_C_INLINE
 267 if test "$ac_cv_c_inline" != no; then
 268   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 269 else
 270   SCM_I_GSC_C_INLINE=NULL
 271 fi
 272 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 273
 274 AC_C_BIGENDIAN
 275
 276 AC_C_LABELS_AS_VALUES
 277
 278 AC_CHECK_SIZEOF(char)
 279 AC_CHECK_SIZEOF(unsigned char)
 280 AC_CHECK_SIZEOF(short)
 281 AC_CHECK_SIZEOF(unsigned short)
 282 AC_CHECK_SIZEOF(int)
 283 AC_CHECK_SIZEOF(unsigned int)
 284 AC_CHECK_SIZEOF(long)
 285 AC_CHECK_SIZEOF(unsigned long)
 286 AC_CHECK_SIZEOF(size_t)
 287 AC_CHECK_SIZEOF(long long)
 288 AC_CHECK_SIZEOF(unsigned long long)
 289 AC_CHECK_SIZEOF(__int64)
 290 AC_CHECK_SIZEOF(unsigned __int64)
 291 AC_CHECK_SIZEOF(void *)
 292 AC_CHECK_SIZEOF(intptr_t)
 293 AC_CHECK_SIZEOF(uintptr_t)
 294 AC_CHECK_SIZEOF(ptrdiff_t)
 295 AC_CHECK_SIZEOF(size_t)
 296 AC_CHECK_SIZEOF(off_t)
 297
 298 if test "$ac_cv_sizeof_long" -gt "$ac_cv_sizeof_void_p"; then
 299   AC_MSG_ERROR(long does not fit into a void*)
 300 fi
 301
 302 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 303   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 304 else
 305   SCM_I_GSC_T_PTRDIFF='"long"'
 306 fi
 307 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 308
 309 AC_CHECK_HEADERS([stdint.h])
 310 AC_CHECK_HEADERS([inttypes.h])
 311
 312 AC_CHECK_SIZEOF(intmax_t)
 313
 314 SCM_I_GSC_NEEDS_STDINT_H=0
 315 SCM_I_GSC_NEEDS_INTTYPES_H=0
 316
 317 ### intptr and uintptr (try not to use inttypes if we don't have to)
 318 if test "$ac_cv_header_inttypes_h" = yes; then
 319   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 320     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 321 #include <stdio.h>])
 322     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 323       SCM_I_GSC_NEEDS_INTTYPES_H=1
 324     fi
 325   fi
 326   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 327     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 328 #include <stdio.h>])
 329     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 330       SCM_I_GSC_NEEDS_INTTYPES_H=1
 331     fi
 332   fi
 333 fi
 334
 335 ### See what's provided by stdint.h
 336 if test "$ac_cv_header_stdint_h" = yes; then
 337    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 338    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 339    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 340    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 341    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 342    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 343    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 344    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 345    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 346    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 347    AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>])
 348    AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>])
 349 fi
 350
 351 # so we don't get confused by the cache (wish there was a better way
 352 # to check particular headers for the same type...)
 353
 354 unset ac_cv_type_int8_t
 355 unset ac_cv_type_uint8_t
 356 unset ac_cv_type_int16_t
 357 unset ac_cv_type_uint16_t
 358 unset ac_cv_type_int32_t
 359 unset ac_cv_type_uint32_t
 360 unset ac_cv_type_int64_t
 361 unset ac_cv_type_uint64_t
 362 unset ac_cv_type_intmax_t
 363 unset ac_cv_type_uintmax_t
 364
 365 ### See what's provided by inttypes.h
 366 if test "$ac_cv_header_inttypes_h" = yes; then
 367   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 368   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 369   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 370   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 371   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 372   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 373   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 374   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 375   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 376   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 377   AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>])
 378   AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>])
 379 fi
 380
 381 # Try hard to find definitions for some required scm_t_*int* types.
 382
 383 ### Required type scm_t_int8
 384 if test "$scm_stdint_has_int8"; then
 385   SCM_I_GSC_T_INT8='"int8_t"'
 386   SCM_I_GSC_NEEDS_STDINT_H=1
 387 elif test "$scm_inttypes_has_int8"; then
 388   SCM_I_GSC_T_INT8='"int8_t"'
 389   SCM_I_GSC_NEEDS_INTTYPES_H=1
 390 elif test "$ac_cv_sizeof_char" -eq 1; then
 391   SCM_I_GSC_T_INT8='"signed char"'
 392 else
 393   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 394 fi
 395 AC_SUBST([SCM_I_GSC_T_INT8])
 396
 397 ### Required type scm_t_uint8
 398 if test "$scm_stdint_has_uint8"; then
 399   SCM_I_GSC_T_UINT8='"uint8_t"'
 400   SCM_I_GSC_NEEDS_STDINT_H=1
 401 elif test "$scm_inttypes_has_uint8"; then
 402   SCM_I_GSC_T_UINT8='"uint8_t"'
 403   SCM_I_GSC_NEEDS_INTTYPES_H=1
 404 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 405   SCM_I_GSC_T_UINT8='"unsigned char"'
 406 else
 407   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 408 fi
 409 AC_SUBST([SCM_I_GSC_T_UINT8])
 410
 411 ### Required type scm_t_int16 (ANSI C says int or short might work)
 412 if test "$scm_stdint_has_int16"; then
 413   SCM_I_GSC_T_INT16='"int16_t"'
 414   SCM_I_GSC_NEEDS_STDINT_H=1
 415 elif test "$scm_inttypes_has_int16"; then
 416   SCM_I_GSC_T_INT16='"int16_t"'
 417   SCM_I_GSC_NEEDS_INTTYPES_H=1
 418 elif test "$ac_cv_sizeof_int" -eq 2; then
 419   SCM_I_GSC_T_INT16='"int"'
 420 elif test "$ac_cv_sizeof_short" -eq 2; then
 421   SCM_I_GSC_T_INT16='"short"'
 422 else
 423   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 424 fi
 425 AC_SUBST([SCM_I_GSC_T_INT16])
 426
 427 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 428 if test "$scm_stdint_has_uint16"; then
 429   SCM_I_GSC_T_UINT16='"uint16_t"'
 430   SCM_I_GSC_NEEDS_STDINT_H=1
 431 elif test "$scm_inttypes_has_uint16"; then
 432   SCM_I_GSC_T_UINT16='"uint16_t"'
 433   SCM_I_GSC_NEEDS_INTTYPES_H=1
 434 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 435   SCM_I_GSC_T_UINT16='"unsigned int"'
 436 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 437   SCM_I_GSC_T_UINT16='"unsigned short"'
 438 else
 439   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 440 fi
 441 AC_SUBST([SCM_I_GSC_T_UINT16])
 442
 443
 444 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 445 if test "$scm_stdint_has_int32"; then
 446   SCM_I_GSC_T_INT32='"int32_t"'
 447   SCM_I_GSC_NEEDS_STDINT_H=1
 448 elif test "$scm_inttypes_has_int32"; then
 449   SCM_I_GSC_T_INT32='"int32_t"'
 450   SCM_I_GSC_NEEDS_INTTYPES_H=1
 451 elif test "$ac_cv_sizeof_int" -eq 4; then
 452   SCM_I_GSC_T_INT32='"int"'
 453 elif test "$ac_cv_sizeof_long" -eq 4; then
 454   SCM_I_GSC_T_INT32='"long"'
 455 elif test "$ac_cv_sizeof_short" -eq 4; then
 456   SCM_I_GSC_T_INT32='"short"'
 457 else
 458   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 459 fi
 460 AC_SUBST([SCM_I_GSC_T_INT32])
 461
 462 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 463 if test "$scm_stdint_has_uint32"; then
 464   SCM_I_GSC_T_UINT32='"uint32_t"'
 465   SCM_I_GSC_NEEDS_STDINT_H=1
 466 elif test "$scm_inttypes_has_uint32"; then
 467   SCM_I_GSC_T_UINT32='"uint32_t"'
 468   SCM_I_GSC_NEEDS_INTTYPES_H=1
 469 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 470   SCM_I_GSC_T_UINT32='"unsigned int"'
 471 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 472   SCM_I_GSC_T_UINT32='"unsigned long"'
 473 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 474   SCM_I_GSC_T_UINT32='"unsigned short"'
 475 else
 476   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 477 fi
 478 AC_SUBST([SCM_I_GSC_T_UINT32])
 479
 480 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 481 ### Also try 'long long' and '__int64' if we have it.
 482 SCM_I_GSC_T_INT64=0
 483 if test "$scm_stdint_has_int64"; then
 484   SCM_I_GSC_T_INT64='"int64_t"'
 485   SCM_I_GSC_NEEDS_STDINT_H=1
 486 elif test "$scm_inttypes_has_int64"; then
 487   SCM_I_GSC_T_INT64='"int64_t"'
 488   SCM_I_GSC_NEEDS_INTTYPES_H=1
 489 elif test "$ac_cv_sizeof_int" -eq 8; then
 490   SCM_I_GSC_T_INT64='"int"'
 491 elif test "$ac_cv_sizeof_long" -eq 8; then
 492   SCM_I_GSC_T_INT64='"long"'
 493 elif test "$ac_cv_sizeof_short" -eq 8; then
 494   SCM_I_GSC_T_INT64='"short"'
 495 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 496   SCM_I_GSC_T_INT64='"long long"'
 497 elif test "$ac_cv_sizeof___int64" -eq 8; then
 498   SCM_I_GSC_T_INT64='"__int64"'
 499 else
 500   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 501 fi
 502 AC_SUBST([SCM_I_GSC_T_INT64])
 503
 504
 505 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 506 ### Also try 'long long' and '__int64' if we have it.
 507 SCM_I_GSC_T_UINT64=0
 508 if test "$scm_stdint_has_uint64"; then
 509   SCM_I_GSC_T_UINT64='"uint64_t"'
 510   SCM_I_GSC_NEEDS_STDINT_H=1
 511 elif test "$scm_inttypes_has_uint64"; then
 512   SCM_I_GSC_T_UINT64='"uint64_t"'
 513   SCM_I_GSC_NEEDS_INTTYPES_H=1
 514 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 515   SCM_I_GSC_T_UINT64='"unsigned int"'
 516 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 517   SCM_I_GSC_T_UINT64='"unsigned long"'
 518 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 519   SCM_I_GSC_T_UINT64='"unsigned short"'
 520 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 521   SCM_I_GSC_T_UINT64='"unsigned long long"'
 522 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 523   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 524 else
 525   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 526 fi
 527 AC_SUBST([SCM_I_GSC_T_UINT64])
 528
 529 ### Required type scm_t_intmax
 530 ###
 531 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 532 ### none of them is available, we use 'long'.
 533 ###
 534 SCM_I_GSC_T_INTMAX=0
 535 if test "$scm_stdint_has_intmax"; then
 536   SCM_I_GSC_T_INTMAX='"intmax_t"'
 537   SCM_I_GSC_NEEDS_STDINT_H=1
 538 elif test "$scm_inttypes_has_intmax"; then
 539   SCM_I_GSC_T_INTMAX='"intmax_t"'
 540   SCM_I_GSC_NEEDS_INTTYPES_H=1
 541 elif test "$ac_cv_sizeof___int64" -ne 0; then
 542   SCM_I_GSC_T_INTMAX='"__int64"'
 543 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 544   SCM_I_GSC_T_INTMAX='"long long"'
 545 else
 546   SCM_I_GSC_T_INTMAX='"long"'
 547 fi
 548 AC_SUBST([SCM_I_GSC_T_INTMAX])
 549
 550 ### Required type scm_t_uintmax
 551 ###
 552 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 553 ### this order.  When none of them is available, we use 'unsigned long'.
 554 ###
 555 SCM_I_GSC_T_UINTMAX=0
 556 if test "$scm_stdint_has_uintmax"; then
 557   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 558   SCM_I_GSC_NEEDS_STDINT_H=1
 559 elif test "$scm_inttypes_has_uintmax"; then
 560   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 561   SCM_I_GSC_NEEDS_INTTYPES_H=1
 562 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 563   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 564 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 565   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 566 else
 567   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 568 fi
 569 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 570
 571 ### Required type scm_t_intptr
 572 ###
 573 SCM_I_GSC_T_INTPTR=0
 574 if test "$scm_stdint_has_intptr"; then
 575   SCM_I_GSC_T_INTPTR='"intptr_t"'
 576   SCM_I_GSC_NEEDS_STDINT_H=1
 577 elif test "$scm_inttypes_has_intptr"; then
 578   SCM_I_GSC_T_INTPTR='"intptr_t"'
 579   SCM_I_GSC_NEEDS_INTTYPES_H=1
 580 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 581   SCM_I_GSC_T_INTPTR='"int"'
 582 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 583   SCM_I_GSC_T_INTPTR='"long"'
 584 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 585   SCM_I_GSC_T_INTPTR='"long long"'
 586 else
 587   AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.])
 588 fi
 589 AC_SUBST([SCM_I_GSC_T_INTPTR])
 590
 591 ### Required type scm_t_uintptr
 592 ###
 593 SCM_I_GSC_T_UINTPTR=0
 594 if test "$scm_stdint_has_uintptr"; then
 595   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 596   SCM_I_GSC_NEEDS_STDINT_H=1
 597 elif test "$scm_inttypes_has_uintptr"; then
 598   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 599   SCM_I_GSC_NEEDS_INTTYPES_H=1
 600 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 601   SCM_I_GSC_T_UINTPTR='"unsigned int"'
 602 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 603   SCM_I_GSC_T_UINTPTR='"unsigned long"'
 604 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 605   SCM_I_GSC_T_UINTPTR='"unsigned long long"'
 606 else
 607   AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.])
 608 fi
 609 AC_SUBST([SCM_I_GSC_T_UINTPTR])
 610
 611
 612 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 613 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 614
 615 AC_HEADER_STDC
 616 AC_HEADER_TIME
 617 AC_HEADER_SYS_WAIT
 618 AC_HEADER_DIRENT
 619
 620 # Reason for checking:
 621 #
 622 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 623 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 624 #
 625 AC_CHECK_MEMBER([struct dirent64.d_name],
 626   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 627   [ #ifndef _LARGEFILE64_SOURCE
 628     # define _LARGEFILE64_SOURCE
 629     #endif
 630
 631     /* Per Autoconf manual.  */
 632     #include <sys/types.h>
 633     #ifdef HAVE_DIRENT_H
 634     # include <dirent.h>
 635     #else
 636     # define dirent direct
 637     # ifdef HAVE_SYS_NDIR_H
 638     #  include <sys/ndir.h>
 639     # endif
 640     # ifdef HAVE_SYS_DIR_H
 641     #  include <sys/dir.h>
 642     # endif
 643     # ifdef HAVE_NDIR_H
 644     #  include <ndir.h>
 645     # endif
 646     #endif ])
 647 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 648
 649 # Reasons for testing:
 650 #   complex.h - new in C99
 651 #   fenv.h - available in C99, but not older systems
 652 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 653 #     this file instead of <fenv.h>
 654 #   process.h - mingw specific
 655 #   sched.h - missing on MinGW
 656 #
 657 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h memory.h process.h string.h \
 658 sys/dir.h sys/ioctl.h sys/select.h \
 659 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 660 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 661 direct.h machine/fpu.h poll.h sched.h])
 662
 663 # "complex double" is new in C99, and "complex" is only a keyword if
 664 # <complex.h> is included
 665 AC_CHECK_TYPES(complex double,,,
 666 [#if HAVE_COMPLEX_H
 667 #include <complex.h>
 668 #endif])
 669
 670 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 671 # when testing.
 672 AC_CHECK_TYPE(socklen_t, ,
 673   [AC_DEFINE_UNQUOTED([socklen_t], int,
 674                       [Define to `int' if <sys/socket.h> does not define.])],
 675   [#if HAVE_SYS_TYPES_H
 676 #include <sys/types.h>
 677 #endif
 678 #include <sys/socket.h>
 679 ])
 680
 681 AC_CHECK_TYPES([struct ip_mreq], , , [#include <netinet/in.h>])
 682
 683 GUILE_HEADER_LIBC_WITH_UNISTD
 684
 685 AC_TYPE_GETGROUPS
 686 AC_TYPE_SIGNAL
 687 AC_TYPE_MODE_T
 688
 689 # On mingw -lm is empty, so this test is unnecessary, but it's
 690 # harmless so we don't hard-code to suppress it.
 691 #
 692 AC_CHECK_LIB(m, cos)
 693
 694 AC_CHECK_FUNCS(gethostbyname)
 695 if test $ac_cv_func_gethostbyname = no; then
 696     AC_CHECK_LIB(nsl, gethostbyname)
 697 fi
 698
 699 AC_CHECK_FUNCS(connect)
 700 if test $ac_cv_func_connect = no; then
 701     AC_CHECK_LIB(socket, connect)
 702 fi
 703
 704 dnl
 705 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 706 dnl
 707 EXTRA_DEFS=""
 708 case $host in
 709   *-*-mingw*)
 710     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 711       [Define if you have the <winsock2.h> header file.])])
 712     AC_CHECK_LIB(ws2_32, main)
 713     AC_LIBOBJ([win32-uname])
 714     if test "$enable_networking" = yes ; then
 715       AC_LIBOBJ([win32-socket])
 716     fi
 717     if test "$enable_shared" = yes ; then
 718       EXTRA_DEFS="-DSCM_IMPORT"
 719       AC_DEFINE([USE_DLL_IMPORT], 1,
 720         [Define if you need additional CPP macros on Win32 platforms.])
 721     fi
 722     ;;
 723 esac
 724 AC_SUBST(EXTRA_DEFS)
 725
 726 # Reasons for testing:
 727 #   crt_externs.h - Darwin specific
 728 #
 729 AC_CHECK_HEADERS([assert.h crt_externs.h])
 730
 731 # Reasons for testing:
 732 #   DINFINITY - OSF specific
 733 #   DQNAN - OSF specific
 734 #       (DINFINITY and DQNAN are actually global variables, not functions)
 735 #   chsize - an MS-DOS-ism, found in mingw
 736 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 737 #       for gcc to provide the "complex double" type but the system to not
 738 #       have functions like cexp and clog
 739 #   clog10 - not in mingw (though others like clog and csqrt are)
 740 #   fesetround - available in C99, but not older systems
 741 #   ftruncate - posix, but probably not older systems (current mingw
 742 #               has it as an inline for chsize)
 743 #   ioctl - not in mingw.
 744 #   gmtime_r - recent posix, not on old systems
 745 #   pipe - not in mingw
 746 #   _pipe - specific to mingw, taking 3 args
 747 #   poll - since posix 2001
 748 #   readdir_r - recent posix, not on old systems
 749 #   readdir64_r - not available on HP-UX 11.11
 750 #   stat64 - SuS largefile stuff, not on old systems
 751 #   sysconf - not on old systems
 752 #   truncate - not in mingw
 753 #   isblank - available as a GNU extension or in C99
 754 #   _NSGetEnviron - Darwin specific
 755 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 756 #   utimensat: posix.1-2008
 757 #   sched_getaffinity, sched_setaffinity: GNU extensions (glibc)
 758 #
 759 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid getsid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe poll readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale utimensat sched_getaffinity sched_setaffinity])
 760
 761 # Reasons for testing:
 762 #   netdb.h - not in mingw
 763 #   sys/param.h - not in mingw
 764 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 765 #       check this specifically, we need it for the timespec test below.
 766 #   pthread_np.h - available on FreeBSD
 767 #   sethostname - the function itself check because it's not in mingw,
 768 #       the DECL is checked because Solaris 10 doens't have in any header
 769 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 770 #       declaration isn't anywhere.
 771 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 772 #       only with `_XOPEN_SOURCE' or some such.
 773 #
 774 AC_CHECK_HEADERS([crypt.h netdb.h pthread.h pthread_np.h sys/param.h sys/resource.h sys/file.h sys/mman.h])
 775 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 776 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 777
 778 # crypt() may or may not be available, for instance in some countries there
 779 # are restrictions on cryptography.
 780 #
 781 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 782 # -lcrypt library (eg. Debian GNU/Linux).
 783 #
 784 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 785 # be careful to avoid -lcrypt in this case, since libtool will see there's
 786 # only a static libcrypt and decide to build only a static libguile.
 787 #
 788 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 789 # libraries already in that list.
 790 #
 791 AC_SEARCH_LIBS(crypt, crypt,
 792   [AC_DEFINE([HAVE_CRYPT],1,
 793              [Define to 1 if you have the `crypt' function.])])
 794
 795 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 796 # work; in the reported cases so far, 1.0fi works well instead.  According
 797 # to the C99 spec, the complex.h header must provide a working definition
 798 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 799 # is a workaround for the failure of some systems to conform to C99.
 800 if test "$ac_cv_type_complex_double" = yes; then
 801   AC_MSG_CHECKING([for i])
 802   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 803 #if HAVE_COMPLEX_H
 804 #include <complex.h>
 805 #endif
 806 complex double z;
 807 ]], [[
 808 z = _Complex_I;
 809 ]])],
 810     [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).])
 811      AC_MSG_RESULT([_Complex_I])],
 812     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 813 #if HAVE_COMPLEX_H
 814 #include <complex.h>
 815 #endif
 816 complex double z;
 817 ]],[[
 818 z = 1.0fi;
 819 ]])],
 820   [AC_DEFINE([GUILE_I],1.0fi)
 821    AC_MSG_RESULT([1.0fi])],
 822   [ac_cv_type_complex_double=no
 823    AC_MSG_RESULT([not available])])])
 824 fi
 825
 826 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 827 # csqrt(-i) returned a negative real part, when it should be positive
 828 # for the principal root.
 829 #
 830 if test "$ac_cv_type_complex_double" = yes; then
 831
 832   AC_CACHE_CHECK([whether csqrt is usable],
 833     guile_cv_use_csqrt,
 834     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 835 #include <complex.h>
 836 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 837    constant, we want to test libc. */
 838 volatile complex double z = - _Complex_I;
 839 int
 840 main (void)
 841 {
 842   z = csqrt (z);
 843   if (creal (z) > 0.0)
 844     return 0;  /* good */
 845   else
 846     return 1;  /* bad */
 847 }]])],
 848     [guile_cv_use_csqrt=yes],
 849     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 850     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 851   case $guile_cv_use_csqrt in
 852     yes*)
 853       AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free])
 854       ;;
 855   esac
 856 fi
 857
 858 AC_CACHE_SAVE
 859
 860 dnl GMP tests
 861 AC_LIB_HAVE_LINKFLAGS([gmp],
 862   [],
 863   [#include <gmp.h>],
 864   [mpz_import (0, 0, 0, 0, 0, 0, 0);])
 865
 866 if test "x$HAVE_LIBGMP" != "xyes"; then
 867   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README])
 868 fi
 869
 870 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 871 if test "x$LTLIBUNISTRING" = "x"; then
 872   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 873 fi
 874
 875 GUILE_LIBUNISTRING_WITH_ICONV_SUPPORT
 876 if test "x$ac_cv_libunistring_with_iconv_support" != "xyes"; then
 877   AC_MSG_ERROR([No iconv support.  Please recompile libunistring with iconv enabled.])
 878 fi
 879
 880 dnl Libffi is needed to compile Guile's foreign function interface, but its
 881 dnl interface isn't exposed in Guile's API.
 882 PKG_CHECK_MODULES(LIBFFI, libffi)
 883 AC_SUBST(LIBFFI_CFLAGS)
 884 AC_SUBST(LIBFFI_LIBS)
 885
 886 dnl figure out approriate ffi type for size_t
 887 AC_CHECK_SIZEOF(size_t)
 888 AC_CHECK_SIZEOF(ssize_t)
 889 ffi_size_type=uint$(($ac_cv_sizeof_size_t*8))
 890 ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8))
 891 AC_DEFINE_UNQUOTED([ffi_type_size_t], ffi_type_${ffi_size_type},
 892                    [ffi type for size_t])
 893 AC_DEFINE_UNQUOTED([ffi_type_ssize_t], ffi_type_${ffi_ssize_type},
 894                    [ffi type for ssize_t])
 895
 896 dnl i18n tests
 897 #AC_CHECK_HEADERS([libintl.h])
 898 #AC_CHECK_FUNCS(gettext)
 899 #if test $ac_cv_func_gettext = no; then
 900 #   AC_CHECK_LIB(intl, gettext)
 901 #fi
 902 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 903 AM_GNU_GETTEXT([external], [need-ngettext])
 904
 905 ### Some systems don't declare some functions.  On such systems, we
 906 ### need to at least provide our own K&R-style declarations.
 907
 908 ### GUILE_FUNC_DECLARED(function, headerfile)
 909
 910 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 911 ### not there, #define MISSING_FUNCTION_DECL.
 912 AC_DEFUN([GUILE_FUNC_DECLARED], [
 913   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 914     AC_EGREP_HEADER($1, $2,
 915                     guile_cv_func_$1_declared=yes,
 916                     guile_cv_func_$1_declared=no))
 917   if test [x$guile_cv_func_]$1[_declared] = xno; then
 918     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 919       [Define if the operating system supplies $1 without declaring it.])
 920   fi
 921 ])
 922
 923 GUILE_FUNC_DECLARED(sleep, unistd.h)
 924 GUILE_FUNC_DECLARED(usleep, unistd.h)
 925
 926 AC_CHECK_DECLS([strptime],,,
 927 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 928 #include <time.h>])
 929
 930 ### On some systems usleep has no return value.  If it does have one,
 931 ### we'd like to return it; otherwise, we'll fake it.
 932 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 933   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 934                    unistd.h,
 935                    [guile_cv_func_usleep_return_type=void],
 936                    [guile_cv_func_usleep_return_type=int])])
 937 case "$guile_cv_func_usleep_return_type" in
 938   "void" )
 939     AC_DEFINE([USLEEP_RETURNS_VOID], 1,
 940       [Define if the system headers declare usleep to return void.])
 941   ;;
 942 esac
 943
 944 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 945 if test -n "$have_sys_un_h" ; then
 946   AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1,
 947     [Define if the system supports Unix-domain (file-domain) sockets.])
 948 fi
 949
 950 AC_CHECK_FUNCS(getrlimit setrlimit)
 951
 952 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 953
 954 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 955                setnetent    getnetent    endnetent    dnl
 956                setprotoent  getprotoent  endprotoent  dnl
 957                setservent   getservent   endservent   dnl
 958                getnetbyaddr getnetbyname dnl
 959                inet_lnaof inet_makeaddr inet_netof hstrerror)
 960
 961 AC_CHECK_MEMBERS([struct sockaddr_in.sin_len],,,
 962 [#ifdef HAVE_SYS_TYPES_H
 963 #include <sys/types.h>
 964 #endif
 965 #include <netinet/in.h>])
 966
 967 AC_MSG_CHECKING(for __libc_stack_end)
 968 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 969 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 970 extern char *__libc_stack_end;]],
 971    [[printf("%p", (char*) __libc_stack_end);]])],
 972    [guile_cv_have_libc_stack_end=yes],
 973    [guile_cv_have_libc_stack_end=no])])
 974 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 975
 976 if test $guile_cv_have_libc_stack_end = yes; then
 977   AC_DEFINE([HAVE_LIBC_STACK_END], 1,
 978            [Define if you have the __libc_stack_end variable.])
 979 fi
 980
 981 dnl Some systems do not declare this.  Some systems do declare it, as a
 982 dnl macro.  With cygwin it may be in a DLL.
 983
 984 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 985 AC_CACHE_VAL(guile_cv_have_h_errno,
 986   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 987                                       [[int a = h_errno;]])],
 988   [guile_cv_have_h_errno=yes],
 989   [guile_cv_have_h_errno=no])])
 990 AC_MSG_RESULT($guile_cv_have_h_errno)
 991 if test $guile_cv_have_h_errno = yes; then
 992   AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.])
 993 fi
 994
 995 AC_MSG_CHECKING(whether uint32_t is defined)
 996 AC_CACHE_VAL(guile_cv_have_uint32_t,
 997   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 998                    #if HAVE_STDINT_H
 999                    #include <stdint.h>
1000                    #endif
1001                    #ifndef HAVE_NETDB_H
1002                    #include <netdb.h>
1003                    #endif]],
1004                    [[uint32_t a;]])],
1005                    [guile_cv_have_uint32_t=yes],
1006                    [guile_cv_have_uint32_t=no])])
1007 AC_MSG_RESULT($guile_cv_have_uint32_t)
1008 if test $guile_cv_have_uint32_t = yes; then
1009   AC_DEFINE([HAVE_UINT32_T], 1,
1010     [Define if uint32_t typedef is defined when netdb.h is include.])
1011 fi
1012
1013 AC_MSG_CHECKING(for working IPv6 support)
1014 AC_CACHE_VAL(guile_cv_have_ipv6,
1015 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1016 #ifdef HAVE_SYS_TYPES_H
1017 #include <sys/types.h>
1018 #endif
1019 #include <netinet/in.h>
1020 #include <sys/socket.h>]],
1021 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
1022 [guile_cv_have_ipv6=yes],
1023 [guile_cv_have_ipv6=no])])
1024 AC_MSG_RESULT($guile_cv_have_ipv6)
1025 if test $guile_cv_have_ipv6 = yes; then
1026   AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.])
1027 fi
1028
1029 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
1030 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
1031 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
1032 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1033 #ifdef HAVE_SYS_TYPES_H
1034 #include <sys/types.h>
1035 #endif
1036 #include <netinet/in.h>]],
1037 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
1038 [guile_cv_have_sin6_scope_id=yes],
1039 [guile_cv_have_sin6_scope_id=no])])
1040 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
1041 if test $guile_cv_have_sin6_scope_id = yes; then
1042   AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1,
1043     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
1044 fi
1045
1046 # struct sockaddr_in6 field sin_len is only present on BSD systems
1047 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1048 [#ifdef HAVE_SYS_TYPES_H
1049 #include <sys/types.h>
1050 #endif
1051 #include <netinet/in.h>])
1052
1053 AC_MSG_CHECKING(whether localtime caches TZ)
1054 AC_CACHE_VAL(guile_cv_localtime_cache,
1055 [if test x$ac_cv_func_tzset = xyes; then
1056 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1057 #if STDC_HEADERS
1058 # include <stdlib.h>
1059 #endif
1060 extern char **environ;
1061 unset_TZ ()
1062 {
1063   char **from, **to;
1064   for (to = from = environ; (*to = *from); from++)
1065     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1066       to++;
1067 }
1068 char TZ_GMT0[] = "TZ=GMT0";
1069 char TZ_PST8[] = "TZ=PST8";
1070 main()
1071 {
1072   time_t now = time ((time_t *) 0);
1073   int hour_GMT0, hour_unset;
1074   if (putenv (TZ_GMT0) != 0)
1075     exit (1);
1076   hour_GMT0 = localtime (&now)->tm_hour;
1077   unset_TZ ();
1078   hour_unset = localtime (&now)->tm_hour;
1079   if (putenv (TZ_PST8) != 0)
1080     exit (1);
1081   if (localtime (&now)->tm_hour == hour_GMT0)
1082     exit (1);
1083   unset_TZ ();
1084   if (localtime (&now)->tm_hour != hour_unset)
1085     exit (1);
1086   exit (0);
1087 }]])],
1088 [guile_cv_localtime_cache=no],
1089 [guile_cv_localtime_cache=yes],
1090 [# If we have tzset, assume the worst when cross-compiling.
1091 guile_cv_localtime_cache=yes])
1092 else
1093         # If we lack tzset, report that localtime does not cache TZ,
1094         # since we can't invalidate the cache if we don't have tzset.
1095         guile_cv_localtime_cache=no
1096 fi])dnl
1097 AC_MSG_RESULT($guile_cv_localtime_cache)
1098 if test $guile_cv_localtime_cache = yes; then
1099   AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.])
1100 fi
1101
1102 if test "$enable_regex" = yes; then
1103    AC_LIBOBJ([regex-posix])
1104    AC_DEFINE([ENABLE_REGEX], 1, [Define when regex support is enabled.])
1105 fi
1106
1107 AC_REPLACE_FUNCS([strerror memmove mkstemp])
1108
1109 # Reasons for testing:
1110 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1111 #                                older systems
1112 #   sincos - GLIBC extension
1113 #
1114 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1115
1116 # C99 specifies isinf and isnan as macros.
1117 # HP-UX provides only macros, no functions.
1118 # glibc 2.3.2 provides both macros and functions.
1119 # IRIX 6.5 and Solaris 8 only provide functions.
1120 #
1121 # The following tests detect isinf and isnan either as functions or as
1122 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1123 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1124 #
1125 AC_MSG_CHECKING([for isinf])
1126 AC_LINK_IFELSE([AC_LANG_SOURCE(
1127 [[#include <math.h>
1128 volatile double x = 0.0;
1129 int main () { return (isinf(x) != 0); }]])],
1130   [AC_MSG_RESULT([yes])
1131    AC_DEFINE([HAVE_ISINF], 1,
1132              [Define to 1 if you have the `isinf' macro or function.])],
1133   [AC_MSG_RESULT([no])])
1134 AC_MSG_CHECKING([for isnan])
1135 AC_LINK_IFELSE([AC_LANG_SOURCE([[
1136 #include <math.h>
1137 volatile double x = 0.0;
1138 int main () { return (isnan(x) != 0); }]])],
1139   [AC_MSG_RESULT([yes])
1140    AC_DEFINE([HAVE_ISNAN], 1,
1141              [Define to 1 if you have the `isnan' macro or function.])],
1142   [AC_MSG_RESULT([no])])
1143
1144 # Reasons for checking:
1145 #
1146 #     st_rdev
1147 #     st_blksize
1148 #     st_blocks   not in mingw
1149 #     tm_gmtoff   BSD+GNU, not in C99
1150 #
1151 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1152 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1153 #
1154 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,,
1155                  [#define _GNU_SOURCE
1156 AC_INCLUDES_DEFAULT
1157 ])
1158
1159 AC_STRUCT_TIMEZONE
1160 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1161 [#include <time.h>
1162 #ifdef TIME_WITH_SYS_TIME
1163 # include <sys/time.h>
1164 # include <time.h>
1165 #else
1166 # if HAVE_SYS_TIME_H
1167 #  include <sys/time.h>
1168 # else
1169 #  include <time.h>
1170 # endif
1171 #endif
1172 ])
1173 GUILE_STRUCT_UTIMBUF
1174
1175
1176 #--------------------------------------------------------------------
1177 #
1178 # What values do the iconv error handlers have?
1179 #
1180 # The only place that we need iconv in our public interfaces is for
1181 # the error handlers, which are just ints.  So we weaken our
1182 # dependency by looking up those values at configure-time.
1183 #--------------------------------------------------------------------
1184 GUILE_UNISTRING_ICONVEH_VALUES
1185
1186 #--------------------------------------------------------------------
1187 #
1188 # Which way does the stack grow?
1189 #
1190 # Following code comes from Autoconf 2.69's internal _AC_LIBOBJ_ALLOCA
1191 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1192 # very similar code, so in future we could look at using that.
1193 #
1194 # An important detail is that the code involves find_stack_direction
1195 # calling _itself_ - which means that find_stack_direction (or at
1196 # least the second find_stack_direction() call) cannot be inlined.
1197 # If the code could be inlined, that might cause the test to give
1198 # an incorrect answer.
1199 #--------------------------------------------------------------------
1200
1201 SCM_I_GSC_STACK_GROWS_UP=0
1202 AC_RUN_IFELSE([AC_LANG_SOURCE(
1203 [AC_INCLUDES_DEFAULT
1204 int
1205 find_stack_direction (int *addr, int depth)
1206 {
1207   int dir, dummy = 0;
1208   if (! addr)
1209     addr = &dummy;
1210   *addr = addr < &dummy ? 1 : addr == &dummy ? 0 : -1;
1211   dir = depth ? find_stack_direction (addr, depth - 1) : 0;
1212   return dir + dummy;
1213 }
1214
1215 int
1216 main (int argc, char **argv)
1217 {
1218   return find_stack_direction (0, argc + !argv + 20) < 0;
1219 }])],
1220                [SCM_I_GSC_STACK_GROWS_UP=1],
1221                [],
1222                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1223
1224 #--------------------------------------------------------------------
1225 #
1226 # Boehm's GC library
1227 #
1228 #--------------------------------------------------------------------
1229 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1230
1231 save_LIBS="$LIBS"
1232 LIBS="$BDW_GC_LIBS $LIBS"
1233 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1234
1235 AC_CHECK_FUNCS([GC_do_blocking GC_call_with_gc_active GC_pthread_exit GC_pthread_cancel GC_allow_register_threads GC_pthread_sigmask GC_set_start_callback GC_get_suspend_signal GC_move_disappearing_link GC_get_heap_usage_safe GC_get_free_space_divisor GC_gcollect_and_unmap GC_get_unmapped_bytes GC_set_finalizer_notifier GC_set_finalize_on_demand])
1236
1237 # Though the `GC_do_blocking ()' symbol is present in GC 7.1, it is not
1238 # declared, and has a different type (returning void instead of
1239 # void*).
1240 AC_CHECK_DECL([GC_do_blocking],
1241   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1242     [Define this if the `GC_do_blocking ()' function is declared])],
1243   [],
1244   [#include <gc/gc.h>])
1245
1246 # `GC_fn_type' is not available in GC 7.1 and earlier.
1247 AC_CHECK_TYPE([GC_fn_type],
1248   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1249     [Define this if the `GC_fn_type' type is available.])],
1250   [],
1251   [#include <gc/gc.h>])
1252
1253 # `GC_stack_base' is not available in GC 7.1 and earlier.
1254 AC_CHECK_TYPE([struct GC_stack_base],
1255   [AC_DEFINE([HAVE_GC_STACK_BASE], [1],
1256     [Define this if the `GC_stack_base' type is available.])],
1257   [],
1258   [#include <gc/gc.h>])
1259
1260 LIBS="$save_LIBS"
1261
1262
1263 AC_CHECK_SIZEOF(float)
1264 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1265     AC_DEFINE([SCM_SINGLES], 1,
1266               [Define this if floats are the same size as longs.])
1267 fi
1268
1269 AC_MSG_CHECKING(for struct linger)
1270 AC_CACHE_VAL(scm_cv_struct_linger,
1271         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1272 #include <sys/types.h>
1273 #include <sys/socket.h>]],
1274                           [[struct linger lgr;  lgr.l_linger = 100]])],
1275                           [scm_cv_struct_linger="yes"],
1276                           [scm_cv_struct_linger="no"]))
1277 AC_MSG_RESULT($scm_cv_struct_linger)
1278 if test $scm_cv_struct_linger = yes; then
1279         AC_DEFINE([HAVE_STRUCT_LINGER], 1,
1280           [Define this if your system defines struct linger, for use with the
1281            getsockopt and setsockopt system calls.])
1282 fi
1283
1284
1285 # On mingw, struct timespec is in <pthread.h>.
1286 #
1287 AC_MSG_CHECKING(for struct timespec)
1288 AC_CACHE_VAL(scm_cv_struct_timespec,
1289         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1290 #include <time.h>
1291 #if HAVE_PTHREAD_H
1292 #include <pthread.h>
1293 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1294           [scm_cv_struct_timespec="yes"],
1295           [scm_cv_struct_timespec="no"]))
1296 AC_MSG_RESULT($scm_cv_struct_timespec)
1297 if test $scm_cv_struct_timespec = yes; then
1298   AC_DEFINE([HAVE_STRUCT_TIMESPEC], 1,
1299     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1300 fi
1301
1302 #--------------------------------------------------------------------
1303 #
1304 # Flags for thread support
1305 #
1306 #--------------------------------------------------------------------
1307
1308 SCM_I_GSC_USE_PTHREAD_THREADS=0
1309 SCM_I_GSC_USE_NULL_THREADS=0
1310 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1311 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1312
1313 ### What thread package has the user asked for?
1314 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1315             , with_threads=yes)
1316
1317 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1318 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1319
1320 case "$with_threads" in
1321   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1322
1323     build_pthread_support="yes"
1324
1325     ACX_PTHREAD([CC="$PTHREAD_CC"
1326        LIBS="$PTHREAD_LIBS $LIBS"
1327        SCM_I_GSC_USE_PTHREAD_THREADS=1
1328        with_threads="pthreads"],
1329       [with_threads="null"
1330        build_pthread_support="no"])
1331
1332     old_CFLAGS="$CFLAGS"
1333     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1334
1335     # Reasons for testing:
1336     #     pthread_getattr_np - "np" meaning "non portable" says it
1337     #         all; not present on MacOS X or Solaris 10
1338     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1339     #         all; specific to MacOS X
1340     #     pthread_attr_get_np - "np" meaning "non portable" says it
1341     #         all; specific to FreeBSD
1342     #     pthread_sigmask - not available on mingw
1343     #
1344     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_attr_get_np pthread_sigmask)
1345
1346     # On past versions of Solaris, believe 8 through 10 at least, you
1347     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1348     # This is contrary to POSIX:
1349     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1350     # Check here if this style is required.
1351     #
1352     # glibc (2.3.6 at least) works both with or without braces, so the
1353     # test checks whether it works without.
1354     #
1355
1356     if test "$GCC" = "yes"; then
1357       # Since GCC only issues a warning for missing braces, so we need
1358       # `-Werror' to catch it.
1359       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1360     fi
1361
1362     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1363       guile_cv_need_braces_on_pthread_once_init,
1364       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>
1365          pthread_once_t foo = PTHREAD_ONCE_INIT;]])],
1366         [guile_cv_need_braces_on_pthread_once_init=no],
1367         [guile_cv_need_braces_on_pthread_once_init=yes])])
1368     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1369       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1370     fi
1371
1372     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1373     # 6.5.30m with GCC 3.3.
1374     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1375       guile_cv_need_braces_on_pthread_mutex_initializer,
1376       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>
1377          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;]])],
1378         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1379         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1380     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1381       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1382     fi
1383
1384     CFLAGS="$old_CFLAGS"
1385
1386     # On Solaris, sched_yield lives in -lrt.
1387     AC_SEARCH_LIBS(sched_yield, rt)
1388
1389   ;;
1390 esac
1391
1392 case "$with_threads" in
1393   "pthreads")
1394   ;;
1395   "no" | "null")
1396     SCM_I_GSC_USE_NULL_THREADS=1
1397     SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
1398     with_threads="null-threads"
1399   ;;
1400   * )
1401     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1402   ;;
1403 esac
1404
1405 AC_MSG_CHECKING(what kind of threads to support)
1406 AC_MSG_RESULT($with_threads)
1407
1408 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1409   [test "x$build_pthread_support" = "xyes"])
1410
1411
1412 ## Check whether pthread_attr_getstack works for the main thread
1413
1414 if test "$with_threads" = pthreads; then
1415
1416 AC_MSG_CHECKING([whether pthread_attr_getstack works for the main thread])
1417 old_CFLAGS="$CFLAGS"
1418 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1419 if test "$cross_compiling" = "no"; then
1420   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1421   #if HAVE_PTHREAD_ATTR_GETSTACK
1422   #include <pthread.h>
1423
1424   int main ()
1425   {
1426     pthread_attr_t attr;
1427     void *start, *end;
1428     size_t size;
1429
1430     pthread_getattr_np (pthread_self (), &attr);
1431     pthread_attr_getstack (&attr, &start, &size);
1432     end = (char *)start + size;
1433
1434     if ((void *)&attr < start || (void *)&attr >= end)
1435       return 1;
1436     else
1437       return 0;
1438   }
1439   #else
1440   int main ()
1441   {
1442     return 1;
1443   }
1444   #endif
1445   ]])],
1446   [works=yes
1447    AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])],
1448   [works=no],
1449   [])
1450 else
1451   works="assuming it doesn't"
1452 fi
1453 CFLAGS="$old_CFLAGS"
1454 AC_MSG_RESULT($works)
1455
1456 GUILE_THREAD_LOCAL_STORAGE
1457
1458 fi # with_threads=pthreads
1459
1460
1461 ## Cross building
1462 if test "$cross_compiling" = "yes"; then
1463   AC_MSG_CHECKING(cc for build)
1464   ## /usr/bin/cc still uses wrong assembler
1465   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1466   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1467 else
1468   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1469 fi
1470
1471 ## AC_MSG_CHECKING("if we are cross compiling")
1472 ## AC_MSG_RESULT($cross_compiling)
1473 if test "$cross_compiling" = "yes"; then
1474    AC_MSG_RESULT($CC_FOR_BUILD)
1475 fi
1476
1477 ## No need as yet to be more elaborate
1478 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1479
1480 AC_SUBST(cross_compiling)
1481 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1482 AC_SUBST(CCLD_FOR_BUILD)
1483
1484 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1485 ## --HOST is the platform that PACKAGE is compiled for.
1486 HOST_CC="$CC_FOR_BUILD"
1487 AC_SUBST(HOST_CC)
1488
1489 GUILE_CHECK_GUILE_FOR_BUILD
1490
1491 ## If we're using GCC, ask for aggressive warnings.
1492 GCC_CFLAGS=""
1493 case "$GCC" in
1494   yes )
1495     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1496     ## much stuff with generic function pointers for that to really be
1497     ## less than exasperating.
1498     ## -Wundef was removed because Gnulib prevented it (see
1499     ## <http://thread.gmane.org/gmane.lisp.guile.bugs/5329>.)
1500
1501     ## Build with `-fno-strict-aliasing' to prevent miscompilation on
1502     ## some platforms.  See
1503     ## <http://lists.gnu.org/archive/html/guile-devel/2012-01/msg00487.html>.
1504
1505     POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \
1506       -Wdeclaration-after-statement -Wpointer-arith \
1507       -Wswitch-enum -fno-strict-aliasing"
1508     # Do this here so we don't screw up any of the tests above that might
1509     # not be "warning free"
1510     if test "${GUILE_ERROR_ON_WARNING}" = yes
1511     then
1512         POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror"
1513         enable_compile_warnings=no
1514     fi
1515
1516     for flag in $POTENTIAL_GCC_CFLAGS
1517     do
1518         gl_WARN_ADD([$flag], [GCC_CFLAGS])
1519     done
1520     ;;
1521 esac
1522
1523 AC_SUBST(GCC_CFLAGS)
1524
1525 # Check for GNU ld's "-z relro".
1526 GUILE_GNU_LD_RELRO
1527
1528
1529 ## If we're creating a shared library (using libtool!), then we'll
1530 ## need to generate a list of .lo files corresponding to the .o files
1531 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1532 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1533
1534 ## We also need to create corresponding .doc and .x files
1535 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1536 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1537
1538 # GNU Readline bindings.
1539 GUILE_READLINE
1540
1541 AC_SUBST(GUILE_MAJOR_VERSION)
1542 AC_SUBST(GUILE_MINOR_VERSION)
1543 AC_SUBST(GUILE_MICRO_VERSION)
1544 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1545 AC_SUBST(GUILE_VERSION)
1546
1547 #######################################################################
1548 # library versioning
1549
1550 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1551 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1552 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1553 AC_SUBST(LIBGUILE_INTERFACE)
1554
1555 AC_SUBST(LIBGUILE_I18N_MAJOR)
1556 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1557 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1558 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1559 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1560
1561
1562 #######################################################################
1563
1564 dnl Tell guile-config what flags guile users should compile and link
1565 dnl with, keeping only `-I' flags from $CPPFLAGS.
1566 GUILE_CFLAGS=""
1567 next_is_includedir=false
1568 for flag in $CPPFLAGS
1569 do
1570   if $next_is_includedir; then
1571     GUILE_CFLAGS="$GUILE_CFLAGS -I $flag"
1572     next_is_includedir=false
1573   else
1574     case "$flag" in
1575       -I)  next_is_includedir=true;;
1576       -I*) GUILE_CFLAGS="$GUILE_CFLAGS $flag";;
1577       *)   ;;
1578     esac
1579   fi
1580 done
1581
1582 GUILE_CFLAGS="$GUILE_CFLAGS $PTHREAD_CFLAGS"
1583 GUILE_LIBS="$LDFLAGS $LIBS"
1584
1585 AC_SUBST(GUILE_LIBS)
1586 AC_SUBST(GUILE_CFLAGS)
1587
1588 AC_SUBST(AWK)
1589 AC_SUBST(LIBLOBJS)
1590 AC_SUBST(EXTRA_DOT_DOC_FILES)
1591 AC_SUBST(EXTRA_DOT_X_FILES)
1592
1593 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1594 top_builddir_absolute=`pwd`
1595 AC_SUBST(top_builddir_absolute)
1596 top_srcdir_absolute=`(cd $srcdir && pwd)`
1597 AC_SUBST(top_srcdir_absolute)
1598
1599 dnl `sitedir' goes into libpath.h and the pkg-config file.
1600 pkgdatadir="$datadir/$PACKAGE_TARNAME"
1601 sitedir="$pkgdatadir/site/$GUILE_EFFECTIVE_VERSION"
1602 AC_SUBST([sitedir])
1603
1604 dnl Name of the `guile' program.
1605 guile_program_name="`echo guile | "$SED" "$program_transform_name"`"
1606 AC_SUBST([guile_program_name])
1607
1608 # Additional SCM_I_GSC definitions are above.
1609 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1610 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1611 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1612 AC_SUBST([SCM_I_GSC_C_INLINE])
1613 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1614
1615 AC_CONFIG_FILES([
1616   Makefile
1617   am/Makefile
1618   lib/Makefile
1619   benchmark-suite/Makefile
1620   gc-benchmarks/Makefile
1621   doc/Makefile
1622   doc/r5rs/Makefile
1623   doc/ref/Makefile
1624   emacs/Makefile
1625   examples/Makefile
1626   libguile/Makefile
1627   libguile/version.h
1628   guile-readline/Makefile
1629   test-suite/Makefile
1630   test-suite/standalone/Makefile
1631   test-suite/vm/Makefile
1632   meta/Makefile
1633   module/Makefile
1634 ])
1635
1636 AC_CONFIG_FILES([meta/guile-2.2.pc])
1637 AC_CONFIG_FILES([meta/guile-2.2-uninstalled.pc])
1638 AC_CONFIG_FILES([doc/ref/effective-version.texi])
1639
1640 GUILE_CONFIG_SCRIPT([check-guile])
1641 GUILE_CONFIG_SCRIPT([benchmark-guile])
1642 GUILE_CONFIG_SCRIPT([meta/guile])
1643 GUILE_CONFIG_SCRIPT([meta/uninstalled-env])
1644 GUILE_CONFIG_SCRIPT([meta/gdb-uninstalled-guile])
1645 GUILE_CONFIG_SCRIPT([meta/guild])
1646 GUILE_CONFIG_SCRIPT([libguile/guile-snarf])
1647 GUILE_CONFIG_SCRIPT([libguile/guile-snarf-docs])
1648 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-use-srfi])
1649 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-fast-slot-ref])
1650
1651 AC_OUTPUT
1652
1653 dnl Local Variables:
1654 dnl comment-start: "dnl "
1655 dnl comment-end: ""
1656 dnl comment-start-skip: "\\bdnl\\b\\s *"
1657 dnl End: