configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it under
  12 the terms of the GNU Lesser General Public License as published by the
  13 Free Software Foundation; either version 3, or (at your option) any
  14 later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but WITHOUT
  17 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  19 License for more details.
  20
  21 You should have received a copy of the GNU Lesser General Public
  22 License along with GUILE; see the file COPYING.LESSER.  If not, write
  23 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  24 Floor, Boston, MA 02110-1301, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.61)
  29
  30 AC_INIT([GNU Guile],
  31         m4_esyscmd([build-aux/git-version-gen                                   \
  32           .tarball-version                                                      \
  33           's/^release_\([0-9][0-9]*\)-\([0-9][0-9]*\)-\([0-9][0-9]*\)/v\1.\2\.\3/g']),
  34         [bug-guile@gnu.org])
  35 AC_CONFIG_AUX_DIR([build-aux])
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AC_CONFIG_SRCDIR(GUILE-VERSION)
  38
  39 AM_INIT_AUTOMAKE([gnu no-define -Wall -Wno-override])
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AC_SUBST([AM_DEFAULT_VERBOSITY],1)])
  41
  42 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  43 AC_CONFIG_SRCDIR([GUILE-VERSION])
  44
  45 . $srcdir/GUILE-VERSION
  46 GUILE_VERSION="$PACKAGE_VERSION"
  47
  48 AC_CONFIG_HEADERS([config.h])
  49 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  50
  51 #--------------------------------------------------------------------
  52
  53 AC_LANG([C])
  54
  55 dnl Some more checks for Win32
  56 AC_CANONICAL_HOST
  57
  58 AC_LIBTOOL_WIN32_DLL
  59
  60 AC_PROG_INSTALL
  61 AC_PROG_CC
  62 gl_EARLY
  63 AC_PROG_CPP
  64 AC_PROG_SED
  65 AC_PROG_AWK
  66
  67 dnl Gnulib.
  68 gl_INIT
  69
  70 AC_PROG_CC_C89
  71
  72 # for per-target cflags in the libguile subdir
  73 AM_PROG_CC_C_O
  74
  75 AC_LIBTOOL_DLOPEN
  76 AC_PROG_LIBTOOL
  77
  78 dnl Check for libltdl.
  79 AC_LIB_HAVE_LINKFLAGS([ltdl], [], [#include <ltdl.h>],
  80   [lt_dlopenext ("foo");])
  81 if test "x$HAVE_LIBLTDL" != "xyes"; then
  82   AC_MSG_ERROR([GNU libltdl (Libtool) not found, see README.])
  83 fi
  84
  85 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  86 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  87
  88 AM_PATH_LISPDIR
  89
  90 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
  91   [Define to the host's GNU triplet.])
  92
  93 #--------------------------------------------------------------------
  94 #
  95 # User options (after above tests that may set default CFLAGS etc.)
  96 #
  97 #--------------------------------------------------------------------
  98
  99 GUILE_ERROR_ON_WARNING="no"
 100
 101 AC_ARG_ENABLE(error-on-warning,
 102   [  --enable-error-on-warning    treat compile warnings as errors],
 103   [case "${enableval}" in
 104      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 105      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 106      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 107    esac])
 108
 109 AC_ARG_ENABLE(debug-malloc,
 110   [  --enable-debug-malloc   include malloc debugging code],
 111   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 112     AC_DEFINE([GUILE_DEBUG_MALLOC], 1,
 113       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 114   fi)
 115
 116 SCM_I_GSC_GUILE_DEBUG=0
 117 AC_ARG_ENABLE(guile-debug,
 118   [AS_HELP_STRING([--enable-guile-debug],
 119                   [include internal debugging functions])],
 120   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 121     SCM_I_GSC_GUILE_DEBUG=1
 122   fi)
 123
 124 AC_ARG_ENABLE(posix,
 125   [  --disable-posix         omit posix interfaces],,
 126   enable_posix=yes)
 127
 128 AC_ARG_ENABLE(networking,
 129   [  --disable-networking    omit networking interfaces],,
 130   enable_networking=yes)
 131
 132 AC_ARG_ENABLE(regex,
 133   [  --disable-regex         omit regular expression interfaces],,
 134   enable_regex=yes)
 135
 136 AC_ARG_ENABLE([deprecated],
 137   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 138
 139 if test "$enable_deprecated" = no; then
 140   SCM_I_GSC_ENABLE_DEPRECATED=0
 141   warn_default=no
 142 else
 143   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 144     warn_default=summary
 145   elif test "$enable_deprecated" = shutup; then
 146     warn_default=no
 147   else
 148     warn_default=$enable_deprecated
 149   fi
 150   SCM_I_GSC_ENABLE_DEPRECATED=1
 151 fi
 152 AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default",
 153 [Define this to control the default warning level for deprecated features.])
 154
 155 dnl  Added the following configure option in January 2008 following
 156 dnl  investigation of problems with "64" system and library calls on
 157 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 158 dnl  system has stat64, it will have all the other 64 APIs too; but on
 159 dnl  Darwin, stat64 is there but other APIs are missing.
 160 dnl
 161 dnl  It also appears, from the Darwin docs, that most system call APIs
 162 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 163 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 164 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 165 dnl
 166 dnl  A similar problem has been reported for HP-UX:
 167 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 168 dnl
 169 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 170 dnl  better than no Guile at all, we provide this option to suppress
 171 dnl  trying to use "64" calls.
 172 dnl
 173 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 174 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 175 dnl  missing out on that.  If so, someone can work on that in the future.
 176 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 177 dnl  wasn't building before.
 178 AC_MSG_CHECKING([whether to use system and library "64" calls])
 179 AC_ARG_WITH([64-calls],
 180   AS_HELP_STRING([--without-64-calls],
 181                  [don't attempt to use system and library calls with "64" in their names]),
 182   [use_64_calls=$withval],
 183   [use_64_calls=yes
 184    case $host in
 185      *-apple-darwin* )
 186        use_64_calls=no
 187        ;;
 188      powerpc-ibm-aix* )
 189        use_64_calls=no
 190        ;;
 191    esac])
 192 AC_MSG_RESULT($use_64_calls)
 193 case "$use_64_calls" in
 194   y* )
 195     AC_DEFINE([GUILE_USE_64_CALLS], 1,
 196       [Define to 1 in order to try to use "64" versions of system and library calls.])
 197     ;;
 198 esac
 199
 200 #--------------------------------------------------------------------
 201
 202 dnl Check for dynamic linking
 203
 204 use_modules=yes
 205 AC_ARG_WITH(modules,
 206 [  --with-modules[=FILES]  Add support for dynamic modules],
 207 use_modules="$withval")
 208 test -z "$use_modules" && use_modules=yes
 209 DLPREOPEN=
 210 if test "$use_modules" != no; then
 211   if test "$use_modules" = yes; then
 212     DLPREOPEN="-dlpreopen force"
 213   else
 214     DLPREOPEN="-export-dynamic"
 215     for module in $use_modules; do
 216       DLPREOPEN="$DLPREOPEN -dlopen $module"
 217     done
 218   fi
 219 fi
 220
 221 dnl files which are destined for separate modules.
 222
 223 if test "$use_modules" != no; then
 224    AC_LIBOBJ([dynl])
 225 fi
 226
 227 if test "$enable_posix" = yes; then
 228    AC_LIBOBJ([filesys])
 229    AC_LIBOBJ([posix])
 230    AC_DEFINE([HAVE_POSIX], 1,
 231      [Define this if you want support for POSIX system calls in Guile.])
 232 fi
 233
 234 if test "$enable_networking" = yes; then
 235    AC_LIBOBJ([net_db])
 236    AC_LIBOBJ([socket])
 237    AC_DEFINE([HAVE_NETWORKING], 1,
 238      [Define this if you want support for networking in Guile.])
 239 fi
 240
 241 if test "$enable_debug_malloc" = yes; then
 242    AC_LIBOBJ([debug-malloc])
 243 fi
 244
 245 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 246
 247 AC_C_CONST
 248
 249 # "volatile" is used in a couple of tests below.
 250 AC_C_VOLATILE
 251
 252 AC_C_INLINE
 253 if test "$ac_cv_c_inline" != no; then
 254   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 255 else
 256   SCM_I_GSC_C_INLINE=NULL
 257 fi
 258 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 259
 260 AC_C_BIGENDIAN
 261
 262 AC_C_LABELS_AS_VALUES
 263
 264 AC_CHECK_SIZEOF(char)
 265 AC_CHECK_SIZEOF(unsigned char)
 266 AC_CHECK_SIZEOF(short)
 267 AC_CHECK_SIZEOF(unsigned short)
 268 AC_CHECK_SIZEOF(int)
 269 AC_CHECK_SIZEOF(unsigned int)
 270 AC_CHECK_SIZEOF(long)
 271 AC_CHECK_SIZEOF(unsigned long)
 272 AC_CHECK_SIZEOF(size_t)
 273 AC_CHECK_SIZEOF(long long)
 274 AC_CHECK_SIZEOF(unsigned long long)
 275 AC_CHECK_SIZEOF(__int64)
 276 AC_CHECK_SIZEOF(unsigned __int64)
 277 AC_CHECK_SIZEOF(void *)
 278 AC_CHECK_SIZEOF(intptr_t)
 279 AC_CHECK_SIZEOF(uintptr_t)
 280 AC_CHECK_SIZEOF(ptrdiff_t)
 281 AC_CHECK_SIZEOF(size_t)
 282 AC_CHECK_SIZEOF(off_t)
 283
 284 if test "$ac_cv_sizeof_long" -gt "$ac_cv_sizeof_void_p"; then
 285   AC_MSG_ERROR(long does not fit into a void*)
 286 fi
 287
 288 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 289   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 290 else
 291   SCM_I_GSC_T_PTRDIFF='"long"'
 292 fi
 293 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 294
 295 AC_CHECK_HEADERS([stdint.h])
 296 AC_CHECK_HEADERS([inttypes.h])
 297
 298 AC_CHECK_SIZEOF(intmax_t)
 299
 300 SCM_I_GSC_NEEDS_STDINT_H=0
 301 SCM_I_GSC_NEEDS_INTTYPES_H=0
 302
 303 ### intptr and uintptr (try not to use inttypes if we don't have to)
 304 if test "$ac_cv_header_inttypes_h" = yes; then
 305   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 306     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 307 #include <stdio.h>])
 308     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 309       SCM_I_GSC_NEEDS_INTTYPES_H=1
 310     fi
 311   fi
 312   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 313     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 314 #include <stdio.h>])
 315     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 316       SCM_I_GSC_NEEDS_INTTYPES_H=1
 317     fi
 318   fi
 319 fi
 320
 321 ### See what's provided by stdint.h
 322 if test "$ac_cv_header_stdint_h" = yes; then
 323    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 324    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 325    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 326    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 327    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 328    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 329    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 330    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 331    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 332    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 333    AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>])
 334    AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>])
 335 fi
 336
 337 # so we don't get confused by the cache (wish there was a better way
 338 # to check particular headers for the same type...)
 339
 340 unset ac_cv_type_int8_t
 341 unset ac_cv_type_uint8_t
 342 unset ac_cv_type_int16_t
 343 unset ac_cv_type_uint16_t
 344 unset ac_cv_type_int32_t
 345 unset ac_cv_type_uint32_t
 346 unset ac_cv_type_int64_t
 347 unset ac_cv_type_uint64_t
 348 unset ac_cv_type_intmax_t
 349 unset ac_cv_type_uintmax_t
 350
 351 ### See what's provided by inttypes.h
 352 if test "$ac_cv_header_inttypes_h" = yes; then
 353   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 354   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 355   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 356   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 357   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 358   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 359   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 360   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 361   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 362   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 363   AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>])
 364   AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>])
 365 fi
 366
 367 # Try hard to find definitions for some required scm_t_*int* types.
 368
 369 ### Required type scm_t_int8
 370 if test "$scm_stdint_has_int8"; then
 371   SCM_I_GSC_T_INT8='"int8_t"'
 372   SCM_I_GSC_NEEDS_STDINT_H=1
 373 elif test "$scm_inttypes_has_int8"; then
 374   SCM_I_GSC_T_INT8='"int8_t"'
 375   SCM_I_GSC_NEEDS_INTTYPES_H=1
 376 elif test "$ac_cv_sizeof_char" -eq 1; then
 377   SCM_I_GSC_T_INT8='"signed char"'
 378 else
 379   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 380 fi
 381 AC_SUBST([SCM_I_GSC_T_INT8])
 382
 383 ### Required type scm_t_uint8
 384 if test "$scm_stdint_has_uint8"; then
 385   SCM_I_GSC_T_UINT8='"uint8_t"'
 386   SCM_I_GSC_NEEDS_STDINT_H=1
 387 elif test "$scm_inttypes_has_uint8"; then
 388   SCM_I_GSC_T_UINT8='"uint8_t"'
 389   SCM_I_GSC_NEEDS_INTTYPES_H=1
 390 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 391   SCM_I_GSC_T_UINT8='"unsigned char"'
 392 else
 393   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 394 fi
 395 AC_SUBST([SCM_I_GSC_T_UINT8])
 396
 397 ### Required type scm_t_int16 (ANSI C says int or short might work)
 398 if test "$scm_stdint_has_int16"; then
 399   SCM_I_GSC_T_INT16='"int16_t"'
 400   SCM_I_GSC_NEEDS_STDINT_H=1
 401 elif test "$scm_inttypes_has_int16"; then
 402   SCM_I_GSC_T_INT16='"int16_t"'
 403   SCM_I_GSC_NEEDS_INTTYPES_H=1
 404 elif test "$ac_cv_sizeof_int" -eq 2; then
 405   SCM_I_GSC_T_INT16='"int"'
 406 elif test "$ac_cv_sizeof_short" -eq 2; then
 407   SCM_I_GSC_T_INT16='"short"'
 408 else
 409   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 410 fi
 411 AC_SUBST([SCM_I_GSC_T_INT16])
 412
 413 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 414 if test "$scm_stdint_has_uint16"; then
 415   SCM_I_GSC_T_UINT16='"uint16_t"'
 416   SCM_I_GSC_NEEDS_STDINT_H=1
 417 elif test "$scm_inttypes_has_uint16"; then
 418   SCM_I_GSC_T_UINT16='"uint16_t"'
 419   SCM_I_GSC_NEEDS_INTTYPES_H=1
 420 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 421   SCM_I_GSC_T_UINT16='"unsigned int"'
 422 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 423   SCM_I_GSC_T_UINT16='"unsigned short"'
 424 else
 425   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 426 fi
 427 AC_SUBST([SCM_I_GSC_T_UINT16])
 428
 429
 430 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 431 if test "$scm_stdint_has_int32"; then
 432   SCM_I_GSC_T_INT32='"int32_t"'
 433   SCM_I_GSC_NEEDS_STDINT_H=1
 434 elif test "$scm_inttypes_has_int32"; then
 435   SCM_I_GSC_T_INT32='"int32_t"'
 436   SCM_I_GSC_NEEDS_INTTYPES_H=1
 437 elif test "$ac_cv_sizeof_int" -eq 4; then
 438   SCM_I_GSC_T_INT32='"int"'
 439 elif test "$ac_cv_sizeof_long" -eq 4; then
 440   SCM_I_GSC_T_INT32='"long"'
 441 elif test "$ac_cv_sizeof_short" -eq 4; then
 442   SCM_I_GSC_T_INT32='"short"'
 443 else
 444   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 445 fi
 446 AC_SUBST([SCM_I_GSC_T_INT32])
 447
 448 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 449 if test "$scm_stdint_has_uint32"; then
 450   SCM_I_GSC_T_UINT32='"uint32_t"'
 451   SCM_I_GSC_NEEDS_STDINT_H=1
 452 elif test "$scm_inttypes_has_uint32"; then
 453   SCM_I_GSC_T_UINT32='"uint32_t"'
 454   SCM_I_GSC_NEEDS_INTTYPES_H=1
 455 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 456   SCM_I_GSC_T_UINT32='"unsigned int"'
 457 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 458   SCM_I_GSC_T_UINT32='"unsigned long"'
 459 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 460   SCM_I_GSC_T_UINT32='"unsigned short"'
 461 else
 462   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 463 fi
 464 AC_SUBST([SCM_I_GSC_T_UINT32])
 465
 466 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 467 ### Also try 'long long' and '__int64' if we have it.
 468 SCM_I_GSC_T_INT64=0
 469 if test "$scm_stdint_has_int64"; then
 470   SCM_I_GSC_T_INT64='"int64_t"'
 471   SCM_I_GSC_NEEDS_STDINT_H=1
 472 elif test "$scm_inttypes_has_int64"; then
 473   SCM_I_GSC_T_INT64='"int64_t"'
 474   SCM_I_GSC_NEEDS_INTTYPES_H=1
 475 elif test "$ac_cv_sizeof_int" -eq 8; then
 476   SCM_I_GSC_T_INT64='"int"'
 477 elif test "$ac_cv_sizeof_long" -eq 8; then
 478   SCM_I_GSC_T_INT64='"long"'
 479 elif test "$ac_cv_sizeof_short" -eq 8; then
 480   SCM_I_GSC_T_INT64='"short"'
 481 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 482   SCM_I_GSC_T_INT64='"long long"'
 483 elif test "$ac_cv_sizeof___int64" -eq 8; then
 484   SCM_I_GSC_T_INT64='"__int64"'
 485 else
 486   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 487 fi
 488 AC_SUBST([SCM_I_GSC_T_INT64])
 489
 490
 491 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 492 ### Also try 'long long' and '__int64' if we have it.
 493 SCM_I_GSC_T_UINT64=0
 494 if test "$scm_stdint_has_uint64"; then
 495   SCM_I_GSC_T_UINT64='"uint64_t"'
 496   SCM_I_GSC_NEEDS_STDINT_H=1
 497 elif test "$scm_inttypes_has_uint64"; then
 498   SCM_I_GSC_T_UINT64='"uint64_t"'
 499   SCM_I_GSC_NEEDS_INTTYPES_H=1
 500 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 501   SCM_I_GSC_T_UINT64='"unsigned int"'
 502 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 503   SCM_I_GSC_T_UINT64='"unsigned long"'
 504 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 505   SCM_I_GSC_T_UINT64='"unsigned short"'
 506 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 507   SCM_I_GSC_T_UINT64='"unsigned long long"'
 508 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 509   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 510 else
 511   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 512 fi
 513 AC_SUBST([SCM_I_GSC_T_UINT64])
 514
 515 ### Required type scm_t_intmax
 516 ###
 517 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 518 ### none of them is available, we use 'long'.
 519 ###
 520 SCM_I_GSC_T_INTMAX=0
 521 if test "$scm_stdint_has_intmax"; then
 522   SCM_I_GSC_T_INTMAX='"intmax_t"'
 523   SCM_I_GSC_NEEDS_STDINT_H=1
 524 elif test "$scm_inttypes_has_intmax"; then
 525   SCM_I_GSC_T_INTMAX='"intmax_t"'
 526   SCM_I_GSC_NEEDS_INTTYPES_H=1
 527 elif test "$ac_cv_sizeof___int64" -ne 0; then
 528   SCM_I_GSC_T_INTMAX='"__int64"'
 529 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 530   SCM_I_GSC_T_INTMAX='"long long"'
 531 else
 532   SCM_I_GSC_T_INTMAX='"long"'
 533 fi
 534 AC_SUBST([SCM_I_GSC_T_INTMAX])
 535
 536 ### Required type scm_t_uintmax
 537 ###
 538 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 539 ### this order.  When none of them is available, we use 'unsigned long'.
 540 ###
 541 SCM_I_GSC_T_UINTMAX=0
 542 if test "$scm_stdint_has_uintmax"; then
 543   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 544   SCM_I_GSC_NEEDS_STDINT_H=1
 545 elif test "$scm_inttypes_has_uintmax"; then
 546   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 547   SCM_I_GSC_NEEDS_INTTYPES_H=1
 548 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 549   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 550 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 551   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 552 else
 553   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 554 fi
 555 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 556
 557 ### Required type scm_t_intptr
 558 ###
 559 SCM_I_GSC_T_INTPTR=0
 560 if test "$scm_stdint_has_intptr"; then
 561   SCM_I_GSC_T_INTPTR='"intptr_t"'
 562   SCM_I_GSC_NEEDS_STDINT_H=1
 563 elif test "$scm_inttypes_has_intptr"; then
 564   SCM_I_GSC_T_INTPTR='"intptr_t"'
 565   SCM_I_GSC_NEEDS_INTTYPES_H=1
 566 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 567   SCM_I_GSC_T_INTPTR='"int"'
 568 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 569   SCM_I_GSC_T_INTPTR='"long"'
 570 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 571   SCM_I_GSC_T_INTPTR='"long long"'
 572 else
 573   AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.])
 574 fi
 575 AC_SUBST([SCM_I_GSC_T_INTPTR])
 576
 577 ### Required type scm_t_uintptr
 578 ###
 579 SCM_I_GSC_T_UINTPTR=0
 580 if test "$scm_stdint_has_uintptr"; then
 581   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 582   SCM_I_GSC_NEEDS_STDINT_H=1
 583 elif test "$scm_inttypes_has_uintptr"; then
 584   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 585   SCM_I_GSC_NEEDS_INTTYPES_H=1
 586 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 587   SCM_I_GSC_T_UINTPTR='"unsigned int"'
 588 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 589   SCM_I_GSC_T_UINTPTR='"unsigned long"'
 590 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 591   SCM_I_GSC_T_UINTPTR='"unsigned long long"'
 592 else
 593   AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.])
 594 fi
 595 AC_SUBST([SCM_I_GSC_T_UINTPTR])
 596
 597
 598 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 599 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 600
 601 AC_HEADER_STDC
 602 AC_HEADER_TIME
 603 AC_HEADER_SYS_WAIT
 604 AC_HEADER_DIRENT
 605
 606 # Reason for checking:
 607 #
 608 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 609 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 610 #
 611 AC_CHECK_MEMBER([struct dirent64.d_name],
 612   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 613   [ #ifndef _LARGEFILE64_SOURCE
 614     # define _LARGEFILE64_SOURCE
 615     #endif
 616
 617     /* Per Autoconf manual.  */
 618     #include <sys/types.h>
 619     #ifdef HAVE_DIRENT_H
 620     # include <dirent.h>
 621     #else
 622     # define dirent direct
 623     # ifdef HAVE_SYS_NDIR_H
 624     #  include <sys/ndir.h>
 625     # endif
 626     # ifdef HAVE_SYS_DIR_H
 627     #  include <sys/dir.h>
 628     # endif
 629     # ifdef HAVE_NDIR_H
 630     #  include <ndir.h>
 631     # endif
 632     #endif ])
 633 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 634
 635 # Reasons for testing:
 636 #   complex.h - new in C99
 637 #   fenv.h - available in C99, but not older systems
 638 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 639 #     this file instead of <fenv.h>
 640 #   process.h - mingw specific
 641 #   langinfo.h, nl_types.h - SuS v2
 642 #
 643 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 644 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 645 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 646 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 647 direct.h langinfo.h nl_types.h machine/fpu.h poll.h])
 648
 649 # Reasons for testing:
 650 #   nl_item - lacking on Cygwin
 651 AC_CHECK_TYPES([nl_item], [], [],
 652   [[#ifdef HAVE_LANGINFO_H
 653     # include <langinfo.h>
 654     #endif
 655     #ifdef HAVE_NL_TYPES_H
 656     # include <nl_types.h>
 657     #endif]])
 658
 659 # "complex double" is new in C99, and "complex" is only a keyword if
 660 # <complex.h> is included
 661 AC_CHECK_TYPES(complex double,,,
 662 [#if HAVE_COMPLEX_H
 663 #include <complex.h>
 664 #endif])
 665
 666 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 667 # when testing.
 668 AC_CHECK_TYPE(socklen_t, ,
 669   [AC_DEFINE_UNQUOTED([socklen_t], int,
 670                       [Define to `int' if <sys/socket.h> does not define.])],
 671   [#if HAVE_SYS_TYPES_H
 672 #include <sys/types.h>
 673 #endif
 674 #include <sys/socket.h>
 675 ])
 676
 677 AC_CHECK_TYPES([struct ip_mreq], , , [#include <netinet/in.h>])
 678
 679 GUILE_HEADER_LIBC_WITH_UNISTD
 680
 681 AC_TYPE_GETGROUPS
 682 AC_TYPE_SIGNAL
 683 AC_TYPE_MODE_T
 684
 685 # On mingw -lm is empty, so this test is unnecessary, but it's
 686 # harmless so we don't hard-code to suppress it.
 687 #
 688 AC_CHECK_LIB(m, cos)
 689
 690 AC_CHECK_FUNCS(gethostbyname)
 691 if test $ac_cv_func_gethostbyname = no; then
 692     AC_CHECK_LIB(nsl, gethostbyname)
 693 fi
 694
 695 AC_CHECK_FUNCS(connect)
 696 if test $ac_cv_func_connect = no; then
 697     AC_CHECK_LIB(socket, connect)
 698 fi
 699
 700 dnl
 701 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 702 dnl
 703 EXTRA_DEFS=""
 704 case $host in
 705   *-*-mingw*)
 706     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 707       [Define if you have the <winsock2.h> header file.])])
 708     AC_CHECK_LIB(ws2_32, main)
 709     AC_LIBOBJ([win32-uname])
 710     AC_LIBOBJ([win32-dirent])
 711     if test "$enable_networking" = yes ; then
 712       AC_LIBOBJ([win32-socket])
 713     fi
 714     if test "$enable_shared" = yes ; then
 715       EXTRA_DEFS="-DSCM_IMPORT"
 716       AC_DEFINE([USE_DLL_IMPORT], 1,
 717         [Define if you need additional CPP macros on Win32 platforms.])
 718     fi
 719     ;;
 720 esac
 721 AC_SUBST(EXTRA_DEFS)
 722
 723 # Reasons for testing:
 724 #   crt_externs.h - Darwin specific
 725 #
 726 AC_CHECK_HEADERS([assert.h crt_externs.h])
 727
 728 # Reasons for testing:
 729 #   DINFINITY - OSF specific
 730 #   DQNAN - OSF specific
 731 #       (DINFINITY and DQNAN are actually global variables, not functions)
 732 #   chsize - an MS-DOS-ism, found in mingw
 733 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 734 #       for gcc to provide the "complex double" type but the system to not
 735 #       have functions like cexp and clog
 736 #   clog10 - not in mingw (though others like clog and csqrt are)
 737 #   fesetround - available in C99, but not older systems
 738 #   ftruncate - posix, but probably not older systems (current mingw
 739 #               has it as an inline for chsize)
 740 #   ioctl - not in mingw.
 741 #   gmtime_r - recent posix, not on old systems
 742 #   pipe - not in mingw
 743 #   _pipe - specific to mingw, taking 3 args
 744 #   poll - since posix 2001
 745 #   readdir_r - recent posix, not on old systems
 746 #   readdir64_r - not available on HP-UX 11.11
 747 #   stat64 - SuS largefile stuff, not on old systems
 748 #   sysconf - not on old systems
 749 #   truncate - not in mingw
 750 #   isblank - available as a GNU extension or in C99
 751 #   _NSGetEnviron - Darwin specific
 752 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 753 #   nl_langinfo - X/Open, not available on Windows.
 754 #   utimensat: posix.1-2008
 755 #   sched_getaffinity, sched_setaffinity: GNU extensions (glibc)
 756 #
 757 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid getsid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe poll readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo utimensat sched_getaffinity sched_setaffinity])
 758
 759 # Reasons for testing:
 760 #   netdb.h - not in mingw
 761 #   sys/param.h - not in mingw
 762 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 763 #       check this specifically, we need it for the timespec test below.
 764 #   sethostname - the function itself check because it's not in mingw,
 765 #       the DECL is checked because Solaris 10 doens't have in any header
 766 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 767 #       declaration isn't anywhere.
 768 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 769 #       only with `_XOPEN_SOURCE' or some such.
 770 #
 771 AC_CHECK_HEADERS([crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h])
 772 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 773 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 774
 775 # crypt() may or may not be available, for instance in some countries there
 776 # are restrictions on cryptography.
 777 #
 778 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 779 # -lcrypt library (eg. Debian GNU/Linux).
 780 #
 781 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 782 # be careful to avoid -lcrypt in this case, since libtool will see there's
 783 # only a static libcrypt and decide to build only a static libguile.
 784 #
 785 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 786 # libraries already in that list.
 787 #
 788 AC_SEARCH_LIBS(crypt, crypt,
 789   [AC_DEFINE([HAVE_CRYPT],1,
 790              [Define to 1 if you have the `crypt' function.])])
 791
 792 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 793 # work; in the reported cases so far, 1.0fi works well instead.  According
 794 # to the C99 spec, the complex.h header must provide a working definition
 795 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 796 # is a workaround for the failure of some systems to conform to C99.
 797 if test "$ac_cv_type_complex_double" = yes; then
 798   AC_MSG_CHECKING([for i])
 799   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 800 #if HAVE_COMPLEX_H
 801 #include <complex.h>
 802 #endif
 803 complex double z;
 804 ]], [[
 805 z = _Complex_I;
 806 ]])],
 807     [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).])
 808      AC_MSG_RESULT([_Complex_I])],
 809     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 810 #if HAVE_COMPLEX_H
 811 #include <complex.h>
 812 #endif
 813 complex double z;
 814 ]],[[
 815 z = 1.0fi;
 816 ]])],
 817   [AC_DEFINE([GUILE_I],1.0fi)
 818    AC_MSG_RESULT([1.0fi])],
 819   [ac_cv_type_complex_double=no
 820    AC_MSG_RESULT([not available])])])
 821 fi
 822
 823 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 824 # csqrt(-i) returned a negative real part, when it should be positive
 825 # for the principal root.
 826 #
 827 if test "$ac_cv_type_complex_double" = yes; then
 828
 829   AC_CACHE_CHECK([whether csqrt is usable],
 830     guile_cv_use_csqrt,
 831     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 832 #include <complex.h>
 833 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 834    constant, we want to test libc. */
 835 volatile complex double z = - _Complex_I;
 836 int
 837 main (void)
 838 {
 839   z = csqrt (z);
 840   if (creal (z) > 0.0)
 841     return 0;  /* good */
 842   else
 843     return 1;  /* bad */
 844 }]])],
 845     [guile_cv_use_csqrt=yes],
 846     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 847     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 848   case $guile_cv_use_csqrt in
 849     yes*)
 850       AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free])
 851       ;;
 852   esac
 853 fi
 854
 855
 856 dnl GMP tests
 857 AC_LIB_HAVE_LINKFLAGS([gmp],
 858   [],
 859   [#include <gmp.h>],
 860   [mpz_import (0, 0, 0, 0, 0, 0, 0);])
 861
 862 if test "x$HAVE_LIBGMP" != "xyes"; then
 863   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README])
 864 fi
 865
 866 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 867 if test "x$LTLIBUNISTRING" = "x"; then
 868   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 869 fi
 870
 871 dnl Libffi is needed to compile Guile's foreign function interface, but its
 872 dnl interface isn't exposed in Guile's API.
 873 PKG_CHECK_MODULES(LIBFFI, libffi)
 874 AC_SUBST(LIBFFI_CFLAGS)
 875 AC_SUBST(LIBFFI_LIBS)
 876
 877 dnl figure out approriate ffi type for size_t
 878 AC_CHECK_SIZEOF(size_t)
 879 AC_CHECK_SIZEOF(ssize_t)
 880 ffi_size_type=uint$(($ac_cv_sizeof_size_t*8))
 881 ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8))
 882 AC_DEFINE_UNQUOTED([ffi_type_size_t], ffi_type_${ffi_size_type},
 883                    [ffi type for size_t])
 884 AC_DEFINE_UNQUOTED([ffi_type_ssize_t], ffi_type_${ffi_ssize_type},
 885                    [ffi type for ssize_t])
 886
 887 dnl i18n tests
 888 #AC_CHECK_HEADERS([libintl.h])
 889 #AC_CHECK_FUNCS(gettext)
 890 #if test $ac_cv_func_gettext = no; then
 891 #   AC_CHECK_LIB(intl, gettext)
 892 #fi
 893 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 894 AM_GNU_GETTEXT([external], [need-ngettext])
 895
 896 ### Some systems don't declare some functions.  On such systems, we
 897 ### need to at least provide our own K&R-style declarations.
 898
 899 ### GUILE_FUNC_DECLARED(function, headerfile)
 900
 901 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 902 ### not there, #define MISSING_FUNCTION_DECL.
 903 AC_DEFUN([GUILE_FUNC_DECLARED], [
 904   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 905     AC_EGREP_HEADER($1, $2,
 906                     guile_cv_func_$1_declared=yes,
 907                     guile_cv_func_$1_declared=no))
 908   if test [x$guile_cv_func_]$1[_declared] = xno; then
 909     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 910       [Define if the operating system supplies $1 without declaring it.])
 911   fi
 912 ])
 913
 914 GUILE_FUNC_DECLARED(sleep, unistd.h)
 915 GUILE_FUNC_DECLARED(usleep, unistd.h)
 916
 917 AC_CHECK_DECLS([strptime],,,
 918 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 919 #include <time.h>])
 920
 921 ### On some systems usleep has no return value.  If it does have one,
 922 ### we'd like to return it; otherwise, we'll fake it.
 923 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 924   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 925                    unistd.h,
 926                    [guile_cv_func_usleep_return_type=void],
 927                    [guile_cv_func_usleep_return_type=int])])
 928 case "$guile_cv_func_usleep_return_type" in
 929   "void" )
 930     AC_DEFINE([USLEEP_RETURNS_VOID], 1,
 931       [Define if the system headers declare usleep to return void.])
 932   ;;
 933 esac
 934
 935 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 936 if test -n "$have_sys_un_h" ; then
 937   AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1,
 938     [Define if the system supports Unix-domain (file-domain) sockets.])
 939 fi
 940
 941 AC_CHECK_FUNCS(getrlimit setrlimit)
 942
 943 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 944
 945 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 946                setnetent    getnetent    endnetent    dnl
 947                setprotoent  getprotoent  endprotoent  dnl
 948                setservent   getservent   endservent   dnl
 949                getnetbyaddr getnetbyname dnl
 950                inet_lnaof inet_makeaddr inet_netof hstrerror)
 951
 952 # struct sockaddr field sin_len is only present on BSD systems.
 953 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 954 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 955 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 956 [#ifdef HAVE_SYS_TYPES_H
 957 #include <sys/types.h>
 958 #endif
 959 #include <netinet/in.h>])
 960
 961 AC_MSG_CHECKING(for __libc_stack_end)
 962 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 963 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 964 extern char *__libc_stack_end;]],
 965    [[printf("%p", (char*) __libc_stack_end);]])],
 966    [guile_cv_have_libc_stack_end=yes],
 967    [guile_cv_have_libc_stack_end=no])])
 968 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 969
 970 if test $guile_cv_have_libc_stack_end = yes; then
 971   AC_DEFINE([HAVE_LIBC_STACK_END], 1,
 972            [Define if you have the __libc_stack_end variable.])
 973 fi
 974
 975 dnl Some systems do not declare this.  Some systems do declare it, as a
 976 dnl macro.  With cygwin it may be in a DLL.
 977
 978 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 979 AC_CACHE_VAL(guile_cv_have_h_errno,
 980   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 981                                       [[int a = h_errno;]])],
 982   [guile_cv_have_h_errno=yes],
 983   [guile_cv_have_h_errno=no])])
 984 AC_MSG_RESULT($guile_cv_have_h_errno)
 985 if test $guile_cv_have_h_errno = yes; then
 986   AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.])
 987 fi
 988
 989 AC_MSG_CHECKING(whether uint32_t is defined)
 990 AC_CACHE_VAL(guile_cv_have_uint32_t,
 991   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 992                    #if HAVE_STDINT_H
 993                    #include <stdint.h>
 994                    #endif
 995                    #ifndef HAVE_NETDB_H
 996                    #include <netdb.h>
 997                    #endif]],
 998                    [[uint32_t a;]])],
 999                    [guile_cv_have_uint32_t=yes],
1000                    [guile_cv_have_uint32_t=no])])
1001 AC_MSG_RESULT($guile_cv_have_uint32_t)
1002 if test $guile_cv_have_uint32_t = yes; then
1003   AC_DEFINE([HAVE_UINT32_T], 1,
1004     [Define if uint32_t typedef is defined when netdb.h is include.])
1005 fi
1006
1007 AC_MSG_CHECKING(for working IPv6 support)
1008 AC_CACHE_VAL(guile_cv_have_ipv6,
1009 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1010 #ifdef HAVE_SYS_TYPES_H
1011 #include <sys/types.h>
1012 #endif
1013 #include <netinet/in.h>
1014 #include <sys/socket.h>]],
1015 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
1016 [guile_cv_have_ipv6=yes],
1017 [guile_cv_have_ipv6=no])])
1018 AC_MSG_RESULT($guile_cv_have_ipv6)
1019 if test $guile_cv_have_ipv6 = yes; then
1020   AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.])
1021 fi
1022
1023 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
1024 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
1025 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
1026 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1027 #ifdef HAVE_SYS_TYPES_H
1028 #include <sys/types.h>
1029 #endif
1030 #include <netinet/in.h>]],
1031 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
1032 [guile_cv_have_sin6_scope_id=yes],
1033 [guile_cv_have_sin6_scope_id=no])])
1034 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
1035 if test $guile_cv_have_sin6_scope_id = yes; then
1036   AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1,
1037     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
1038 fi
1039
1040 # struct sockaddr_in6 field sin_len is only present on BSD systems
1041 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1042 [#ifdef HAVE_SYS_TYPES_H
1043 #include <sys/types.h>
1044 #endif
1045 #include <netinet/in.h>])
1046
1047 AC_MSG_CHECKING(whether localtime caches TZ)
1048 AC_CACHE_VAL(guile_cv_localtime_cache,
1049 [if test x$ac_cv_func_tzset = xyes; then
1050 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1051 #if STDC_HEADERS
1052 # include <stdlib.h>
1053 #endif
1054 extern char **environ;
1055 unset_TZ ()
1056 {
1057   char **from, **to;
1058   for (to = from = environ; (*to = *from); from++)
1059     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1060       to++;
1061 }
1062 char TZ_GMT0[] = "TZ=GMT0";
1063 char TZ_PST8[] = "TZ=PST8";
1064 main()
1065 {
1066   time_t now = time ((time_t *) 0);
1067   int hour_GMT0, hour_unset;
1068   if (putenv (TZ_GMT0) != 0)
1069     exit (1);
1070   hour_GMT0 = localtime (&now)->tm_hour;
1071   unset_TZ ();
1072   hour_unset = localtime (&now)->tm_hour;
1073   if (putenv (TZ_PST8) != 0)
1074     exit (1);
1075   if (localtime (&now)->tm_hour == hour_GMT0)
1076     exit (1);
1077   unset_TZ ();
1078   if (localtime (&now)->tm_hour != hour_unset)
1079     exit (1);
1080   exit (0);
1081 }]])],
1082 [guile_cv_localtime_cache=no],
1083 [guile_cv_localtime_cache=yes],
1084 [# If we have tzset, assume the worst when cross-compiling.
1085 guile_cv_localtime_cache=yes])
1086 else
1087         # If we lack tzset, report that localtime does not cache TZ,
1088         # since we can't invalidate the cache if we don't have tzset.
1089         guile_cv_localtime_cache=no
1090 fi])dnl
1091 AC_MSG_RESULT($guile_cv_localtime_cache)
1092 if test $guile_cv_localtime_cache = yes; then
1093   AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.])
1094 fi
1095
1096 if test "$enable_regex" = yes; then
1097    if test "$ac_cv_header_regex_h" = yes ||
1098       test "$ac_cv_header_rxposix_h" = yes ||
1099       test "$ac_cv_header_rx_rxposix_h" = yes; then
1100      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1101      [AC_CHECK_LIB(rx, main)
1102       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1103      [AC_CHECK_LIB(regex, main)
1104       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1105      )
1106      dnl The following should not be necessary, but for some reason
1107      dnl autoheader misses it if we don't include it!
1108      if test "$ac_cv_func_regcomp_norx" = yes ||
1109         test "$ac_cv_func_regcomp_regex" = yes ||
1110         test "$ac_cv_func_regcomp_rx" = yes; then
1111        AC_DEFINE([HAVE_REGCOMP], 1,
1112          [This is included as part of a workaround for a autoheader bug.])
1113      fi
1114    fi
1115 fi
1116
1117 AC_REPLACE_FUNCS([strerror memmove mkstemp])
1118
1119 # Reasons for testing:
1120 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1121 #                                older systems
1122 #   sincos - GLIBC extension
1123 #
1124 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1125
1126 # C99 specifies isinf and isnan as macros.
1127 # HP-UX provides only macros, no functions.
1128 # glibc 2.3.2 provides both macros and functions.
1129 # IRIX 6.5 and Solaris 8 only provide functions.
1130 #
1131 # The following tests detect isinf and isnan either as functions or as
1132 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1133 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1134 #
1135 AC_MSG_CHECKING([for isinf])
1136 AC_LINK_IFELSE(AC_LANG_SOURCE(
1137 [[#include <math.h>
1138 volatile double x = 0.0;
1139 int main () { return (isinf(x) != 0); }]]),
1140   [AC_MSG_RESULT([yes])
1141    AC_DEFINE([HAVE_ISINF], 1,
1142              [Define to 1 if you have the `isinf' macro or function.])],
1143   [AC_MSG_RESULT([no])])
1144 AC_MSG_CHECKING([for isnan])
1145 AC_LINK_IFELSE(AC_LANG_SOURCE(
1146 [[#include <math.h>
1147 volatile double x = 0.0;
1148 int main () { return (isnan(x) != 0); }]]),
1149   [AC_MSG_RESULT([yes])
1150    AC_DEFINE([HAVE_ISNAN], 1,
1151              [Define to 1 if you have the `isnan' macro or function.])],
1152   [AC_MSG_RESULT([no])])
1153
1154 # Reasons for checking:
1155 #
1156 #     st_rdev
1157 #     st_blksize
1158 #     st_blocks   not in mingw
1159 #     tm_gmtoff   BSD+GNU, not in C99
1160 #
1161 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1162 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1163 #
1164 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,,
1165                  [#define _GNU_SOURCE
1166 AC_INCLUDES_DEFAULT
1167 ])
1168
1169 AC_STRUCT_TIMEZONE
1170 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1171 [#include <time.h>
1172 #ifdef TIME_WITH_SYS_TIME
1173 # include <sys/time.h>
1174 # include <time.h>
1175 #else
1176 # if HAVE_SYS_TIME_H
1177 #  include <sys/time.h>
1178 # else
1179 #  include <time.h>
1180 # endif
1181 #endif
1182 ])
1183 GUILE_STRUCT_UTIMBUF
1184
1185
1186 #--------------------------------------------------------------------
1187 #
1188 # Which way does the stack grow?
1189 #
1190 # Following code comes from Autoconf 2.61's internal _AC_LIBOBJ_ALLOCA
1191 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1192 # very similar code, so in future we could look at using that.
1193 #
1194 # An important detail is that the code involves find_stack_direction
1195 # calling _itself_ - which means that find_stack_direction (or at
1196 # least the second find_stack_direction() call) cannot be inlined.
1197 # If the code could be inlined, that might cause the test to give
1198 # an incorrect answer.
1199 #--------------------------------------------------------------------
1200
1201 SCM_I_GSC_STACK_GROWS_UP=0
1202 AC_RUN_IFELSE([AC_LANG_SOURCE(
1203 [AC_INCLUDES_DEFAULT
1204 int
1205 find_stack_direction ()
1206 {
1207   static char *addr = 0;
1208   auto char dummy;
1209   if (addr == 0)
1210     {
1211       addr = &dummy;
1212       return find_stack_direction ();
1213     }
1214   else
1215     return (&dummy > addr) ? 1 : -1;
1216 }
1217
1218 int
1219 main ()
1220 {
1221   return find_stack_direction () < 0;
1222 }])],
1223                [SCM_I_GSC_STACK_GROWS_UP=1],
1224                [],
1225                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1226
1227 #--------------------------------------------------------------------
1228 #
1229 # Boehm's GC library
1230 #
1231 #--------------------------------------------------------------------
1232 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1233
1234 save_LIBS="$LIBS"
1235 LIBS="$BDW_GC_LIBS $LIBS"
1236 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1237
1238 # `GC_do_blocking ()' is available in GC 7.1 but not declared.
1239 AC_CHECK_FUNCS([GC_do_blocking])
1240 AC_CHECK_DECL([GC_do_blocking],
1241   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1242     [Define this if the `GC_do_blocking ()' function is declared])],
1243   [],
1244   [#include <gc/gc.h>])
1245
1246 # `GC_fn_type' is not available in GC 7.1 and earlier.
1247 AC_CHECK_TYPE([GC_fn_type],
1248   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1249     [Define this if the `GC_fn_type' type is available.])],
1250   [],
1251   [#include <gc/gc.h>])
1252
1253 LIBS="$save_LIBS"
1254
1255
1256 AC_CHECK_SIZEOF(float)
1257 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1258     AC_DEFINE([SCM_SINGLES], 1,
1259               [Define this if floats are the same size as longs.])
1260 fi
1261
1262 AC_MSG_CHECKING(for struct linger)
1263 AC_CACHE_VAL(scm_cv_struct_linger,
1264         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1265 #include <sys/types.h>
1266 #include <sys/socket.h>]],
1267                           [[struct linger lgr;  lgr.l_linger = 100]])],
1268                           [scm_cv_struct_linger="yes"],
1269                           [scm_cv_struct_linger="no"]))
1270 AC_MSG_RESULT($scm_cv_struct_linger)
1271 if test $scm_cv_struct_linger = yes; then
1272         AC_DEFINE([HAVE_STRUCT_LINGER], 1,
1273           [Define this if your system defines struct linger, for use with the
1274            getsockopt and setsockopt system calls.])
1275 fi
1276
1277
1278 # On mingw, struct timespec is in <pthread.h>.
1279 #
1280 AC_MSG_CHECKING(for struct timespec)
1281 AC_CACHE_VAL(scm_cv_struct_timespec,
1282         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1283 #include <time.h>
1284 #if HAVE_PTHREAD_H
1285 #include <pthread.h>
1286 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1287           [scm_cv_struct_timespec="yes"],
1288           [scm_cv_struct_timespec="no"]))
1289 AC_MSG_RESULT($scm_cv_struct_timespec)
1290 if test $scm_cv_struct_timespec = yes; then
1291   AC_DEFINE([HAVE_STRUCT_TIMESPEC], 1,
1292     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1293 fi
1294
1295 #--------------------------------------------------------------------
1296 #
1297 # Flags for thread support
1298 #
1299 #--------------------------------------------------------------------
1300
1301 SCM_I_GSC_USE_PTHREAD_THREADS=0
1302 SCM_I_GSC_USE_NULL_THREADS=0
1303 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1304 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1305
1306 ### What thread package has the user asked for?
1307 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1308             , with_threads=yes)
1309
1310 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1311 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1312
1313 case "$with_threads" in
1314   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1315
1316     build_pthread_support="yes"
1317
1318     ACX_PTHREAD([CC="$PTHREAD_CC"
1319        LIBS="$PTHREAD_LIBS $LIBS"
1320        SCM_I_GSC_USE_PTHREAD_THREADS=1
1321        with_threads="pthreads"],
1322       [with_threads="null"
1323        build_pthread_support="no"])
1324
1325     old_CFLAGS="$CFLAGS"
1326     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1327
1328     # Reasons for testing:
1329     #     pthread_getattr_np - "np" meaning "non portable" says it
1330     #         all; not present on MacOS X or Solaris 10
1331     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1332     #         all; specific to MacOS X
1333     #     pthread_sigmask - not available on mingw
1334     #
1335     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1336
1337     # On past versions of Solaris, believe 8 through 10 at least, you
1338     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1339     # This is contrary to POSIX:
1340     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1341     # Check here if this style is required.
1342     #
1343     # glibc (2.3.6 at least) works both with or without braces, so the
1344     # test checks whether it works without.
1345     #
1346
1347     if test "$GCC" = "yes"; then
1348       # Since GCC only issues a warning for missing braces, so we need
1349       # `-Werror' to catch it.
1350       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1351     fi
1352
1353     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1354       guile_cv_need_braces_on_pthread_once_init,
1355       [AC_COMPILE_IFELSE([#include <pthread.h>
1356          pthread_once_t foo = PTHREAD_ONCE_INIT;],
1357         [guile_cv_need_braces_on_pthread_once_init=no],
1358         [guile_cv_need_braces_on_pthread_once_init=yes])])
1359     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1360       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1361     fi
1362
1363     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1364     # 6.5.30m with GCC 3.3.
1365     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1366       guile_cv_need_braces_on_pthread_mutex_initializer,
1367       [AC_COMPILE_IFELSE([#include <pthread.h>
1368          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;],
1369         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1370         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1371     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1372       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1373     fi
1374
1375     CFLAGS="$old_CFLAGS"
1376
1377     # On Solaris, sched_yield lives in -lrt.
1378     AC_SEARCH_LIBS(sched_yield, rt)
1379
1380   ;;
1381 esac
1382
1383 case "$with_threads" in
1384   "pthreads")
1385   ;;
1386   "no" | "null")
1387     SCM_I_GSC_USE_NULL_THREADS=1
1388     SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
1389     with_threads="null-threads"
1390   ;;
1391   * )
1392     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1393   ;;
1394 esac
1395
1396 AC_MSG_CHECKING(what kind of threads to support)
1397 AC_MSG_RESULT($with_threads)
1398
1399 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1400   [test "x$build_pthread_support" = "xyes"])
1401
1402
1403 ## Check whether pthread_attr_getstack works for the main thread
1404
1405 if test "$with_threads" = pthreads; then
1406
1407 AC_MSG_CHECKING([whether pthread_attr_getstack works for the main thread])
1408 old_CFLAGS="$CFLAGS"
1409 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1410 if test "$cross_compiling" = "no"; then
1411   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1412   #if HAVE_PTHREAD_ATTR_GETSTACK
1413   #include <pthread.h>
1414
1415   int main ()
1416   {
1417     pthread_attr_t attr;
1418     void *start, *end;
1419     size_t size;
1420
1421     pthread_getattr_np (pthread_self (), &attr);
1422     pthread_attr_getstack (&attr, &start, &size);
1423     end = (char *)start + size;
1424
1425     if ((void *)&attr < start || (void *)&attr >= end)
1426       return 1;
1427     else
1428       return 0;
1429   }
1430   #else
1431   int main ()
1432   {
1433     return 1;
1434   }
1435   #endif
1436   ]])],
1437   [works=yes
1438    AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])],
1439   [works=no],
1440   [])
1441 else
1442   works="assuming it doesn't"
1443 fi
1444 CFLAGS="$old_CFLAGS"
1445 AC_MSG_RESULT($works)
1446
1447 GUILE_THREAD_LOCAL_STORAGE
1448
1449 fi # with_threads=pthreads
1450
1451
1452 ## Cross building
1453 if test "$cross_compiling" = "yes"; then
1454   AC_MSG_CHECKING(cc for build)
1455   ## /usr/bin/cc still uses wrong assembler
1456   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1457   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1458 else
1459   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1460 fi
1461
1462 ## AC_MSG_CHECKING("if we are cross compiling")
1463 ## AC_MSG_RESULT($cross_compiling)
1464 if test "$cross_compiling" = "yes"; then
1465    AC_MSG_RESULT($CC_FOR_BUILD)
1466 fi
1467
1468 ## No need as yet to be more elaborate
1469 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1470
1471 AC_SUBST(cross_compiling)
1472 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1473 AC_SUBST(CCLD_FOR_BUILD)
1474
1475 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1476 ## --HOST is the platform that PACKAGE is compiled for.
1477 HOST_CC="$CC_FOR_BUILD"
1478 AC_SUBST(HOST_CC)
1479
1480 if test "$cross_compiling" = "yes"; then
1481   AC_MSG_CHECKING(guile for build)
1482   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1483 else
1484   GUILE_FOR_BUILD='$(preinstguile)'
1485 fi
1486
1487 ## AC_MSG_CHECKING("if we are cross compiling")
1488 ## AC_MSG_RESULT($cross_compiling)
1489 if test "$cross_compiling" = "yes"; then
1490    AC_MSG_RESULT($GUILE_FOR_BUILD)
1491 fi
1492 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1493 AC_SUBST(GUILE_FOR_BUILD)
1494
1495 ## If we're using GCC, ask for aggressive warnings.
1496 GCC_CFLAGS=""
1497 case "$GCC" in
1498   yes )
1499     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1500     ## much stuff with generic function pointers for that to really be
1501     ## less than exasperating.
1502     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1503     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1504     POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \
1505       -Wdeclaration-after-statement -Wundef \
1506       -Wswitch-enum"
1507     # Do this here so we don't screw up any of the tests above that might
1508     # not be "warning free"
1509     if test "${GUILE_ERROR_ON_WARNING}" = yes
1510     then
1511         POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror"
1512         enable_compile_warnings=no
1513     fi
1514
1515     for flag in $POTENTIAL_GCC_CFLAGS
1516     do
1517         gl_WARN_ADD([$flag], [GCC_CFLAGS])
1518     done
1519     ;;
1520 esac
1521
1522 AC_SUBST(GCC_CFLAGS)
1523
1524 # Check for GNU ld's "-z relro".
1525 GUILE_GNU_LD_RELRO
1526
1527
1528 ## If we're creating a shared library (using libtool!), then we'll
1529 ## need to generate a list of .lo files corresponding to the .o files
1530 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1531 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1532
1533 ## We also need to create corresponding .doc and .x files
1534 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1535 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1536
1537 # GNU Readline bindings.
1538 GUILE_READLINE
1539
1540 AC_SUBST(GUILE_MAJOR_VERSION)
1541 AC_SUBST(GUILE_MINOR_VERSION)
1542 AC_SUBST(GUILE_MICRO_VERSION)
1543 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1544 AC_SUBST(GUILE_VERSION)
1545
1546 #######################################################################
1547 # library versioning
1548
1549 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1550 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1551 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1552 AC_SUBST(LIBGUILE_INTERFACE)
1553
1554 AC_SUBST(LIBGUILE_I18N_MAJOR)
1555 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1556 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1557 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1558 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1559
1560
1561 #######################################################################
1562
1563 dnl Tell guile-config what flags guile users should compile and link with.
1564 GUILE_LIBS="$LDFLAGS $LIBS"
1565 GUILE_CFLAGS="$CPPFLAGS $PTHREAD_CFLAGS"
1566 AC_SUBST(GUILE_LIBS)
1567 AC_SUBST(GUILE_CFLAGS)
1568
1569 AC_SUBST(AWK)
1570 AC_SUBST(LIBLOBJS)
1571 AC_SUBST(EXTRA_DOT_DOC_FILES)
1572 AC_SUBST(EXTRA_DOT_X_FILES)
1573
1574 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1575 top_builddir_absolute=`pwd`
1576 AC_SUBST(top_builddir_absolute)
1577 top_srcdir_absolute=`(cd $srcdir && pwd)`
1578 AC_SUBST(top_srcdir_absolute)
1579
1580 dnl `sitedir' goes into libpath.h and the pkg-config file.
1581 pkgdatadir="$datadir/$PACKAGE_TARNAME"
1582 sitedir="$pkgdatadir/site/$GUILE_EFFECTIVE_VERSION"
1583 AC_SUBST([sitedir])
1584
1585 # Additional SCM_I_GSC definitions are above.
1586 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1587 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1588 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1589 AC_SUBST([SCM_I_GSC_C_INLINE])
1590 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1591
1592 AC_CONFIG_FILES([
1593   Makefile
1594   am/Makefile
1595   lib/Makefile
1596   benchmark-suite/Makefile
1597   doc/Makefile
1598   doc/r5rs/Makefile
1599   doc/ref/Makefile
1600   emacs/Makefile
1601   examples/Makefile
1602   libguile/Makefile
1603   libguile/version.h
1604   guile-readline/Makefile
1605   test-suite/Makefile
1606   test-suite/standalone/Makefile
1607   test-suite/vm/Makefile
1608   meta/Makefile
1609   module/Makefile
1610 ])
1611
1612 AC_CONFIG_FILES([meta/guile-2.0.pc])
1613 AC_CONFIG_FILES([meta/guile-2.0-uninstalled.pc])
1614 AC_CONFIG_FILES([doc/ref/effective-version.texi])
1615
1616 GUILE_CONFIG_SCRIPT([check-guile])
1617 GUILE_CONFIG_SCRIPT([benchmark-guile])
1618 GUILE_CONFIG_SCRIPT([meta/guile])
1619 GUILE_CONFIG_SCRIPT([meta/uninstalled-env])
1620 GUILE_CONFIG_SCRIPT([meta/gdb-uninstalled-guile])
1621 GUILE_CONFIG_SCRIPT([meta/guile-tools])
1622 GUILE_CONFIG_SCRIPT([libguile/guile-snarf])
1623 GUILE_CONFIG_SCRIPT([libguile/guile-snarf-docs])
1624 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-use-srfi])
1625 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-fast-slot-ref])
1626
1627 AC_OUTPUT
1628
1629 dnl Local Variables:
1630 dnl comment-start: "dnl "
1631 dnl comment-end: ""
1632 dnl comment-start-skip: "\\bdnl\\b\\s *"
1633 dnl End: