configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_INIT(Makefile.in)
  24 . $srcdir/GUILE-VERSION
  25 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  26 AM_MAINTAINER_MODE
  27 AM_CONFIG_HEADER(libguile/scmconfig.h)
  28
  29 #--------------------------------------------------------------------
  30 #
  31 # Independent Subdirectories
  32 #
  33 #--------------------------------------------------------------------
  34
  35 AC_CONFIG_SUBDIRS(guile-readline)
  36
  37 #--------------------------------------------------------------------
  38 #
  39 # User options
  40 #
  41 #--------------------------------------------------------------------
  42
  43 AC_ARG_ENABLE(debug-freelist,
  44   [  --enable-debug-freelist  include garbage collector freelist debugging code],
  45   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  46     AC_DEFINE(GUILE_DEBUG_FREELIST)
  47   fi)
  48
  49 AC_ARG_ENABLE(debug-malloc,
  50   [  --enable-debug-malloc    include malloc debugging code],
  51   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
  52     AC_DEFINE(GUILE_DEBUG_MALLOC)
  53   fi)
  54
  55 AC_ARG_ENABLE(guile-debug,
  56   [  --enable-guile-debug    include internal debugging functions],
  57   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  58     AC_DEFINE(GUILE_DEBUG)
  59   fi)
  60
  61 AC_ARG_ENABLE(arrays,
  62   [  --disable-arrays        omit array and uniform array support],,
  63   enable_arrays=yes)
  64
  65 AC_ARG_ENABLE(posix,
  66   [  --disable-posix         omit posix interfaces],,
  67   enable_posix=yes)
  68
  69 AC_ARG_ENABLE(networking,
  70   [  --disable-networking    omit networking interfaces],,
  71   enable_networking=yes)
  72
  73 AC_ARG_ENABLE(regex,
  74   [  --disable-regex         omit regular expression interfaces],,
  75   enable_regex=yes)
  76
  77 AC_ARG_ENABLE(htmldoc,
  78   [  --enable-htmldoc        build HTML documentation as well as Info],
  79   [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
  80      htmldoc_enabled=yes
  81      AC_PATH_PROG(TEXI2HTML, texi2html, not found)
  82      if test "$TEXI2HTML" = "not found"; then
  83        echo
  84        echo Building HTML documentation requires the \`texi2html\' program,
  85        echo which appears not to be present on your machine.
  86        echo
  87        echo \`texi2html\' is available from
  88        echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
  89        echo
  90        echo In the meantime, to build the guile-doc distribution
  91        echo without HTML enabled, please rerun \`./configure\' without
  92        echo the \`--enable-htmldoc\' option.
  93        exit -1
  94      fi
  95    fi])
  96
  97 AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)
  98
  99 dnl The --disable-debug used to control these two.  But now they are
 100 dnl a required part of the distribution.
 101 AC_DEFINE(DEBUG_EXTENSIONS)
 102 AC_DEFINE(READER_EXTENSIONS)
 103
 104 dnl files which are destined for separate modules.
 105
 106 if test "$enable_arrays" = yes; then
 107    LIBOBJS="$LIBOBJS ramap.o unif.o"
 108    AC_DEFINE(HAVE_ARRAYS)
 109 fi
 110
 111 if test "$enable_posix" = yes; then
 112    LIBOBJS="$LIBOBJS filesys.o posix.o"
 113    AC_DEFINE(HAVE_POSIX)
 114 fi
 115
 116 if test "$enable_networking" = yes; then
 117    LIBOBJS="$LIBOBJS net_db.o socket.o"
 118    AC_DEFINE(HAVE_NETWORKING)
 119 fi
 120
 121 if test "$enable_debug_malloc" = yes; then
 122    LIBOBJS="$LIBOBJS debug-malloc.o"
 123 fi
 124
 125 #--------------------------------------------------------------------
 126
 127 AC_LIBLTDL_CONVENIENCE
 128 AC_CONFIG_SUBDIRS(libltdl)
 129
 130 AC_PROG_CC
 131 AC_PROG_CPP
 132 AC_LIBTOOL_DLOPEN
 133
 134 AC_AIX
 135 AC_ISC_POSIX
 136 AC_MINIX
 137
 138 AM_PROG_CC_STDC
 139 AM_PROG_LIBTOOL
 140
 141 AC_C_CONST
 142 AC_C_INLINE
 143 AC_C_BIGENDIAN
 144
 145 AC_CHECK_SIZEOF(int)
 146 AC_CHECK_SIZEOF(long)
 147 AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
 148                AC_TRY_COMPILE(,
 149                               [long long a],
 150                               scm_cv_long_longs=yes,
 151                               scm_cv_long_longs=no))
 152 if test "$scm_cv_long_longs" = yes; then
 153   AC_DEFINE(HAVE_LONG_LONGS)
 154 fi
 155
 156 AC_HEADER_STDC
 157 AC_HEADER_DIRENT
 158 AC_HEADER_TIME
 159 AC_HEADER_SYS_WAIT
 160 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
 161 GUILE_HEADER_LIBC_WITH_UNISTD
 162
 163 AC_TYPE_GETGROUPS
 164 AC_TYPE_SIGNAL
 165 AC_TYPE_MODE_T
 166
 167 AC_CHECK_LIB(m, main)
 168 AC_CHECK_FUNCS(gethostbyname)
 169 if test $ac_cv_func_gethostbyname = no; then
 170     AC_CHECK_LIB(nsl, gethostbyname)
 171 fi
 172 AC_CHECK_FUNCS(connect)
 173 if test $ac_cv_func_connect = no; then
 174     AC_CHECK_LIB(socket, connect)
 175 fi
 176
 177 # Check for dynamic linking
 178
 179 use_modules=yes
 180 AC_ARG_WITH(modules,
 181 [  --with-modules[=FILES]  Add support for dynamic modules],
 182 use_modules="$withval")
 183 test -z "$use_modules" && use_modules=yes
 184 DLPREOPEN=
 185 if test "$use_modules" != no; then
 186   AC_DEFINE(DYNAMIC_LINKING)
 187   if test "$use_modules" = yes; then
 188     DLPREOPEN="-dlpreopen force"
 189   else
 190     DLPREOPEN="-export-dynamic"
 191     for module in $use_modules; do
 192       DLPREOPEN="$DLPREOPEN -dlopen $module"
 193     done
 194   fi
 195 fi
 196 AC_SUBST(INCLTDL)
 197 AC_SUBST(LIBLTDL)
 198 AC_SUBST(DLPREOPEN)
 199
 200 AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit)
 201
 202 AC_CHECK_HEADERS(crypt.h sys/resource.h sys/file.h)
 203 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 204 AC_CHECK_LIB(crypt, crypt)
 205
 206 ### Some systems don't declare some functions.  On such systems, we
 207 ### need to at least provide our own K&R-style declarations.
 208
 209 ### GUILE_FUNC_DECLARED(function, headerfile)
 210
 211 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 212 ### not there, #define MISSING_FUNCTION_DECL.
 213 AC_DEFUN(GUILE_FUNC_DECLARED, [
 214   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 215     AC_EGREP_HEADER($1, $2,
 216                     guile_cv_func_$1_declared=yes,
 217                     guile_cv_func_$1_declared=no))
 218   if test [x$guile_cv_func_]$1[_declared] = xno; then
 219     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 220   fi
 221 ])
 222
 223 GUILE_FUNC_DECLARED(strptime, time.h)
 224 GUILE_FUNC_DECLARED(sleep, unistd.h)
 225 GUILE_FUNC_DECLARED(usleep, unistd.h)
 226
 227 ### On some systems usleep has no return value.  If it does have one,
 228 ### we'd like to return it; otherwise, we'll fake it.
 229 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 230   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 231                    /usr/include/unistd.h,
 232                    [guile_cv_func_usleep_return_type=void],
 233                    [guile_cv_func_usleep_return_type=int])])
 234 case "$guile_cv_func_usleep_return_type" in
 235   "void" )
 236     AC_DEFINE(USLEEP_RETURNS_VOID)
 237   ;;
 238 esac
 239
 240 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 241 if test -n "$have_sys_un_h" ; then
 242 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 243 fi
 244
 245 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 246
 247 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 248                setnetent    getnetent    endnetent    dnl
 249                setprotoent  getprotoent  endprotoent  dnl
 250                setservent   getservent   endservent   dnl
 251                getnetbyaddr getnetbyname dnl
 252                inet_lnaof inet_makeaddr inet_netof hstrerror)
 253
 254 dnl Some systems do not declare this.  Some systems do declare it, as a
 255 dnl macro.  With cygwin it may be in a DLL.
 256
 257 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 258 AC_CACHE_VAL(guile_cv_have_h_errno,
 259 [AC_TRY_COMPILE([#include <netdb.h>],
 260 [int a = h_errno;],
 261 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 262 AC_MSG_RESULT($guile_cv_have_h_errno)
 263 if test $guile_cv_have_h_errno = yes; then
 264   AC_DEFINE(HAVE_H_ERRNO)
 265 fi
 266
 267 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 268 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 269 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 270 [AC_TRY_COMPILE([#include <netinet/in.h>],
 271 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 272 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 273 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 274 if test $guile_cv_have_sin6_scope_id = yes; then
 275   AC_DEFINE(HAVE_SIN6_SCOPE_ID)
 276 fi
 277
 278 AC_MSG_CHECKING(whether localtime caches TZ)
 279 AC_CACHE_VAL(guile_cv_localtime_cache,
 280 [if test x$ac_cv_func_tzset = xyes; then
 281 AC_TRY_RUN([#include <time.h>
 282 #if STDC_HEADERS
 283 # include <stdlib.h>
 284 #endif
 285 extern char **environ;
 286 unset_TZ ()
 287 {
 288   char **from, **to;
 289   for (to = from = environ; (*to = *from); from++)
 290     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 291       to++;
 292 }
 293 char TZ_GMT0[] = "TZ=GMT0";
 294 char TZ_PST8[] = "TZ=PST8";
 295 main()
 296 {
 297   time_t now = time ((time_t *) 0);
 298   int hour_GMT0, hour_unset;
 299   if (putenv (TZ_GMT0) != 0)
 300     exit (1);
 301   hour_GMT0 = localtime (&now)->tm_hour;
 302   unset_TZ ();
 303   hour_unset = localtime (&now)->tm_hour;
 304   if (putenv (TZ_PST8) != 0)
 305     exit (1);
 306   if (localtime (&now)->tm_hour == hour_GMT0)
 307     exit (1);
 308   unset_TZ ();
 309   if (localtime (&now)->tm_hour != hour_unset)
 310     exit (1);
 311   exit (0);
 312 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 313 [# If we have tzset, assume the worst when cross-compiling.
 314 guile_cv_localtime_cache=yes])
 315 else
 316         # If we lack tzset, report that localtime does not cache TZ,
 317         # since we can't invalidate the cache if we don't have tzset.
 318         guile_cv_localtime_cache=no
 319 fi])dnl
 320 AC_MSG_RESULT($guile_cv_localtime_cache)
 321 if test $guile_cv_localtime_cache = yes; then
 322   AC_DEFINE(LOCALTIME_CACHE)
 323 fi
 324
 325 dnl Test whether system calls are restartable by default on the
 326 dnl current system.  If they are not, we put a loop around every system
 327 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 328 dnl change from the default behaviour.  On the other hand, if signals
 329 dnl are restartable then the loop is not installed and when libguile
 330 dnl initialises it also resets the behaviour of each signal to cause a
 331 dnl restart (in case a different runtime had a different default
 332 dnl behaviour for some reason: e.g., different versions of linux seem
 333 dnl to behave differently.)
 334
 335 AC_SYS_RESTARTABLE_SYSCALLS
 336
 337 if test "$enable_regex" = yes; then
 338    if test "$ac_cv_header_regex_h" = yes ||
 339       test "$ac_cv_header_rxposix_h" = yes ||
 340       test "$ac_cv_header_rx_rxposix_h" = yes; then
 341      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 342      [AC_CHECK_LIB(rx, main)
 343       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 344      )
 345      dnl The following should not be necessary, but for some reason
 346      dnl autoheader misses it if we don't include it!
 347      if test "$ac_cv_func_regcomp_norx" = yes ||
 348         test "$ac_cv_func_regcomp_rx" = yes; then
 349        AC_DEFINE(HAVE_REGCOMP)
 350      fi
 351    fi
 352 fi
 353
 354 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove)
 355
 356 # When testing for the presence of alloca, we need to add alloca.o
 357 # explicitly to LIBOBJS to make sure that it is translated to
 358 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 359 AC_FUNC_ALLOCA
 360 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 361
 362 AC_STRUCT_ST_RDEV
 363 AC_STRUCT_ST_BLKSIZE
 364
 365 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 366 # LIBOBJS, which we don't need.  This seems more direct.
 367 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 368 [AC_TRY_COMPILE([#include <sys/types.h>
 369 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 370 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 371 if test $ac_cv_struct_st_blocks = yes; then
 372   AC_DEFINE(HAVE_ST_BLOCKS)
 373 fi
 374
 375 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 376   [AC_TRY_CPP([#include <sys/stat.h>
 377                #ifndef S_ISLNK
 378                #error no S_ISLNK
 379                #endif],
 380                ac_cv_macro_S_ISLNK=yes,
 381                ac_cv_macro_S_ISLNK=no)])
 382 if test $ac_cv_macro_S_ISLNK = yes; then
 383   AC_DEFINE(HAVE_S_ISLNK)
 384 fi
 385
 386 AC_STRUCT_TIMEZONE
 387 GUILE_STRUCT_UTIMBUF
 388
 389 #--------------------------------------------------------------------
 390 #
 391 # Which way does the stack grow?
 392 #
 393 #--------------------------------------------------------------------
 394
 395 AC_TRY_RUN(aux (l) unsigned long l;
 396              { int x; exit (l >= ((unsigned long)&x)); }
 397            main () { int q; aux((unsigned long)&q); },
 398            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 399
 400 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 401     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 402                 [guile_cv_type_float_fits_long=yes],
 403                 [guile_cv_type_float_fits_long=no],
 404                 [guile_cv_type_float_fits_long=guess-yes])])
 405 case $guile_cv_type_float_fits_long in
 406   "yes" )
 407     AC_DEFINE(SCM_SINGLES)
 408   ;;
 409   "guess-yes" )
 410     AC_DEFINE(SCM_SINGLES)
 411     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 412     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 413   ;;
 414 esac
 415
 416
 417 AC_MSG_CHECKING(for struct linger)
 418 AC_CACHE_VAL(scm_cv_struct_linger,
 419         AC_TRY_COMPILE([
 420 #include <sys/types.h>
 421 #include <sys/socket.h>],
 422                         [struct linger lgr;  lgr.l_linger = 100],
 423                         scm_cv_struct_linger="yes",
 424                         scm_cv_struct_linger="no"))
 425 AC_MSG_RESULT($scm_cv_struct_linger)
 426 if test $scm_cv_struct_linger = yes; then
 427         AC_DEFINE(HAVE_STRUCT_LINGER)
 428 fi
 429
 430
 431 AC_MSG_CHECKING(for struct timespec)
 432 AC_CACHE_VAL(scm_cv_struct_timespec,
 433         AC_TRY_COMPILE([
 434 #include <time.h>],
 435                         [struct timespec t;  t.tv_nsec = 100],
 436                         scm_cv_struct_timespec="yes",
 437                         scm_cv_struct_timespec="no"))
 438 AC_MSG_RESULT($scm_cv_struct_timespec)
 439 if test $scm_cv_struct_timespec = yes; then
 440         AC_DEFINE(HAVE_STRUCT_TIMESPEC)
 441 fi
 442
 443 #--------------------------------------------------------------------
 444 #
 445 # Flags for thread support
 446 #
 447 #--------------------------------------------------------------------
 448
 449 ### What thread package has the user asked for?
 450 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 451             , with_threads=no)
 452
 453 ### Turn $with_threads into either the name of a threads package, like
 454 ### `qt', or `no', meaning that threads should not be supported.
 455 AC_MSG_CHECKING(whether to support threads)
 456 case "$with_threads" in
 457   "yes" | "qt" | "coop" | "")
 458     with_threads=qt
 459   ;;
 460   "no" )
 461   ;;
 462   * )
 463     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 464   ;;
 465 esac
 466 AC_MSG_RESULT($with_threads)
 467
 468 ## Make sure the threads package we've chosen is actually supported on
 469 ## the present platform.
 470 case "${with_threads}" in
 471   "qt" )
 472     ## This configures the QuickThreads package, and sets or clears
 473     ## the THREAD_PACKAGE variable if qthreads don't configure
 474     ## correctly.
 475     QTHREADS_CONFIGURE
 476    ;;
 477 esac
 478
 479 ## If we're using threads, bring in some other parts of Guile which
 480 ## work with them.
 481 if test "${THREAD_PACKAGE}" != "" ; then
 482   AC_DEFINE(USE_THREADS, 1)
 483
 484   ## Include the Guile thread interface in the library...
 485   LIBOBJS="$LIBOBJS threads.o"
 486
 487   ## ... and tell it which package to talk to.
 488   case "${THREAD_PACKAGE}" in
 489     "QT" )
 490       AC_DEFINE(USE_COOP_THREADS, 1)
 491     ;;
 492     * )
 493       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 494     ;;
 495   esac
 496
 497   ## Bring in scm_internal_select, if appropriate.
 498   if test $ac_cv_func_gettimeofday = yes &&
 499      test $ac_cv_func_select = yes; then
 500     AC_DEFINE(GUILE_ISELECT, 1)
 501   fi
 502
 503   ## Workaround for linuxthreads (currently disabled)
 504   if test $host_os = linux-gnu; then
 505     AC_DEFINE(GUILE_PTHREAD_COMPAT, 1)
 506     AC_CHECK_LIB(pthread, main)
 507   fi
 508 fi
 509 AC_SUBST(LIBGUILEQTHREADS_MAJOR_VERSION)
 510 AC_SUBST(LIBGUILEQTHREADS_MINOR_VERSION)
 511 AC_SUBST(LIBGUILEQTHREADS_REVISION_VERSION)
 512 AC_SUBST(LIBGUILEQTHREADS_VERSION)
 513
 514 ## If we're using GCC, ask for aggressive warnings.
 515 case "$GCC" in
 516   yes )
 517     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 518     ## much stuff with generic function pointers for that to really be
 519     ## less than exasperating.
 520     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 521     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 522     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 523 esac
 524
 525 AC_PROG_AWK
 526
 527 ## If we're creating a shared library (using libtool!), then we'll
 528 ## need to generate a list of .lo files corresponding to the .o files
 529 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 530 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 531
 532 ## We also need to create corresponding .doc and .x files
 533 EXTRA_DOT_DOC_FILES="`echo ${LIBOBJS} | sed 's/\.o/.doc/g'`"
 534 EXTRA_DOT_X_FILES="`echo ${LIBOBJS} | sed 's/\.o/.x/g'`"
 535
 536 AC_SUBST(GUILE_MAJOR_VERSION)
 537 AC_SUBST(GUILE_MINOR_VERSION)
 538 AC_SUBST(GUILE_VERSION)
 539 AC_SUBST(LIBGUILE_MAJOR_VERSION)
 540 AC_SUBST(LIBGUILE_MINOR_VERSION)
 541 AC_SUBST(LIBGUILE_REVISION_VERSION)
 542 AC_SUBST(LIBGUILE_VERSION)
 543
 544 dnl Tell guile-config what flags guile users should link against.
 545 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 546 AC_SUBST(GUILE_LIBS)
 547
 548 AC_SUBST(AWK)
 549 AC_SUBST(LIBLOBJS)
 550 AC_SUBST(EXTRA_DOT_DOC_FILES)
 551 AC_SUBST(EXTRA_DOT_X_FILES)
 552
 553 AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check libguile/guile-snarf.awk libguile/versiondat.h ice-9/Makefile oop/Makefile oop/goops/Makefile qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile guile-config/Makefile doc/Makefile check-guile], [chmod +x libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check check-guile])
 554
 555 dnl Local Variables:
 556 dnl comment-start: "dnl "
 557 dnl comment-end: ""
 558 dnl comment-start-skip: "\\bdnl\\b\\s *"
 559 dnl End: