configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it
  12 under the terms of the GNU General Public License as published by
  13 the Free Software Foundation; either version 2, or (at your
  14 option) any later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but
  17 WITHOUT ANY WARRANTY; without even the implied warranty of
  18 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 General Public License for more details.
  20
  21 You should have received a copy of the GNU General Public License
  22 along with GUILE; see the file COPYING.  If not, write to the
  23 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 Boston, MA 02111-1307, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.53)
  29
  30 AC_INIT
  31 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  32 AC_CONFIG_SRCDIR([GUILE-VERSION])
  33 . $srcdir/GUILE-VERSION
  34 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  35 AM_MAINTAINER_MODE
  36 AM_CONFIG_HEADER([config.h])
  37 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  38
  39 #--------------------------------------------------------------------
  40 #
  41 # Independent Subdirectories
  42 #
  43 #--------------------------------------------------------------------
  44
  45 AC_CONFIG_SUBDIRS(guile-readline)
  46
  47 #--------------------------------------------------------------------
  48
  49 dnl Some more checks for Win32
  50 AC_CYGWIN
  51 AC_MINGW32
  52 AC_LIBTOOL_WIN32_DLL
  53
  54 AC_PROG_INSTALL
  55 AC_PROG_CC
  56 AC_PROG_CPP
  57 AC_PROG_AWK
  58
  59 AC_AIX
  60 AC_ISC_POSIX
  61 AC_MINIX
  62
  63 AM_PROG_CC_STDC
  64
  65 AC_LIBTOOL_DLOPEN
  66 AC_PROG_LIBTOOL
  67 AC_LIB_LTDL
  68
  69 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  70 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  71
  72 AM_PATH_LISPDIR
  73
  74 #--------------------------------------------------------------------
  75 #
  76 # User options (after above tests that may set default CFLAGS etc.)
  77 #
  78 #--------------------------------------------------------------------
  79
  80 GUILE_ERROR_ON_WARNING="yes"
  81
  82 AC_ARG_ENABLE(error-on-warning,
  83   [  --enable-error-on-warning    treat compile warnings as errors],
  84   [case "${enableval}" in
  85      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
  86      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
  87      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  88    esac])
  89
  90 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
  91 AC_ARG_ENABLE(debug-freelist,
  92   [  --enable-debug-freelist include garbage collector freelist debugging code],
  93   if test "$enable_debug_freelist" = y \
  94      || test "$enable_debug_freelist" = yes; then
  95     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
  96   fi)
  97
  98 AC_ARG_ENABLE(debug-malloc,
  99   [  --enable-debug-malloc   include malloc debugging code],
 100   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 101     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 102       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 103   fi)
 104
 105 SCM_I_GSC_GUILE_DEBUG=0
 106 AC_ARG_ENABLE(guile-debug,
 107   [AC_HELP_STRING([--enable-guile-debug],
 108                   [include internal debugging functions])],
 109   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 110     SCM_I_GSC_GUILE_DEBUG=1
 111   fi)
 112
 113 AC_ARG_ENABLE(arrays,
 114   [AC_HELP_STRING([--disable-arrays],[omit array and uniform array support])],
 115   ,
 116   enable_arrays=yes)
 117
 118 AC_ARG_ENABLE(posix,
 119   [  --disable-posix         omit posix interfaces],,
 120   enable_posix=yes)
 121
 122 AC_ARG_ENABLE(networking,
 123   [  --disable-networking    omit networking interfaces],,
 124   enable_networking=yes)
 125
 126 AC_ARG_ENABLE(regex,
 127   [  --disable-regex         omit regular expression interfaces],,
 128   enable_regex=yes)
 129
 130 AC_ARG_ENABLE(htmldoc,
 131   [  --enable-htmldoc        build HTML documentation as well as Info],
 132   [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
 133      htmldoc_enabled=yes
 134      AC_PATH_PROG(TEXI2HTML, texi2html, not found)
 135      if test "$TEXI2HTML" = "not found"; then
 136        echo
 137        echo Building HTML documentation requires the \`texi2html\' program,
 138        echo which appears not to be present on your machine.
 139        echo
 140        echo \`texi2html\' is available from
 141        echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
 142        echo
 143        echo In the meantime, to build the guile-doc distribution
 144        echo without HTML enabled, please rerun \`./configure\' without
 145        echo the \`--enable-htmldoc\' option.
 146        exit -1
 147      fi
 148    fi])
 149
 150 AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)
 151
 152 AC_ARG_ENABLE([deprecated],
 153   AC_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 154
 155 if test "$enable_deprecated" = no; then
 156   SCM_I_GSC_ENABLE_DEPRECATED=0
 157 else
 158   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 159     warn_default=summary
 160   elif test "$enable_deprecated" = shutup; then
 161     warn_default=no
 162   else
 163     warn_default=$enable_deprecated
 164   fi
 165   SCM_I_GSC_ENABLE_DEPRECATED=1
 166   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 167   [Define this to control the default warning level for deprecated features.])
 168 fi
 169
 170 AC_ARG_ENABLE(elisp,
 171   [  --disable-elisp         omit Emacs Lisp support],,
 172   enable_elisp=yes)
 173
 174 #--------------------------------------------------------------------
 175
 176 dnl Check for dynamic linking
 177
 178 use_modules=yes
 179 AC_ARG_WITH(modules,
 180 [  --with-modules[=FILES]  Add support for dynamic modules],
 181 use_modules="$withval")
 182 test -z "$use_modules" && use_modules=yes
 183 DLPREOPEN=
 184 if test "$use_modules" != no; then
 185   if test "$use_modules" = yes; then
 186     DLPREOPEN="-dlpreopen force"
 187   else
 188     DLPREOPEN="-export-dynamic"
 189     for module in $use_modules; do
 190       DLPREOPEN="$DLPREOPEN -dlopen $module"
 191     done
 192   fi
 193 fi
 194
 195 dnl files which are destined for separate modules.
 196
 197 if test "$use_modules" != no; then
 198    AC_LIBOBJ([dynl])
 199 fi
 200
 201 SCM_I_GSC_HAVE_ARRAYS=0
 202 if test "$enable_arrays" = yes; then
 203    AC_LIBOBJ([ramap])
 204    AC_LIBOBJ([unif])
 205    SCM_I_GSC_HAVE_ARRAYS=1
 206 fi
 207
 208 if test "$enable_posix" = yes; then
 209    AC_LIBOBJ([filesys])
 210    AC_LIBOBJ([posix])
 211    AC_DEFINE(HAVE_POSIX, 1,
 212      [Define this if you want support for POSIX system calls in Guile.])
 213 fi
 214
 215 if test "$enable_networking" = yes; then
 216    AC_LIBOBJ([net_db])
 217    AC_LIBOBJ([socket])
 218    AC_DEFINE(HAVE_NETWORKING, 1,
 219      [Define this if you want support for networking in Guile.])
 220 fi
 221
 222 if test "$enable_debug_malloc" = yes; then
 223    AC_LIBOBJ([debug-malloc])
 224 fi
 225
 226 if test "$enable_elisp" = yes; then
 227   SCM_I_GSC_ENABLE_ELISP=1
 228 else
 229   SCM_I_GSC_ENABLE_ELISP=0
 230 fi
 231
 232 AC_C_CONST
 233
 234 AC_C_INLINE
 235 if test "$ac_cv_c_inline" != no; then
 236   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 237 else
 238   SCM_I_GSC_C_INLINE=NULL
 239 fi
 240
 241 AC_C_BIGENDIAN
 242
 243 AC_CHECK_SIZEOF(char)
 244 AC_CHECK_SIZEOF(unsigned char)
 245 AC_CHECK_SIZEOF(short)
 246 AC_CHECK_SIZEOF(unsigned short)
 247 AC_CHECK_SIZEOF(int)
 248 AC_CHECK_SIZEOF(unsigned int)
 249 AC_CHECK_SIZEOF(long)
 250 AC_CHECK_SIZEOF(unsigned long)
 251 AC_CHECK_SIZEOF(size_t)
 252 AC_CHECK_SIZEOF(long long)
 253 AC_CHECK_SIZEOF(unsigned long long)
 254 AC_CHECK_SIZEOF(__int64)
 255 AC_CHECK_SIZEOF(unsigned __int64)
 256 AC_CHECK_SIZEOF(void *)
 257 AC_CHECK_SIZEOF(intptr_t)
 258 AC_CHECK_SIZEOF(uintptr_t)
 259 AC_CHECK_SIZEOF(ptrdiff_t)
 260
 261 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 262   AC_MSG_ERROR(sizes of long and void* are not identical)
 263 fi
 264
 265 if test "$ac_cv_sizeof_ptrdiff_t" -eq 0; then
 266   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 267 else
 268   SCM_I_GSC_T_PTRDIFF='"long"'
 269 fi
 270 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 271
 272 AC_CHECK_HEADERS([stdint.h])
 273 AC_CHECK_HEADERS([inttypes.h])
 274
 275 SCM_I_GSC_NEEDS_STDINT_H=0
 276 SCM_I_GSC_NEEDS_INTTYPES_H=0
 277
 278 ### intptr and uintptr (try not to use inttypes if we don't have to)
 279 if test "$ac_cv_header_inttypes_h" = yes; then
 280   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 281     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 282 #include <stdio.h>])
 283     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 284       SCM_I_GSC_NEEDS_INTTYPES_H=1
 285     fi
 286   fi
 287   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 288     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 289 #include <stdio.h>])
 290     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 291       SCM_I_GSC_NEEDS_INTTYPES_H=1
 292     fi
 293   fi
 294 fi
 295
 296 ### See what's provided by stdint.h
 297 if test "$ac_cv_header_stdint_h" = yes; then
 298    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 299    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 300    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 301    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 302    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 303    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 304    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 305    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 306    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 307    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 308 fi
 309
 310 # so we don't get confused by the cache (wish there was a better way
 311 # to check particular headers for the same type...)
 312
 313 unset ac_cv_type_int8_t
 314 unset ac_cv_type_uint8_t
 315 unset ac_cv_type_int16_t
 316 unset ac_cv_type_uint16_t
 317 unset ac_cv_type_int32_t
 318 unset ac_cv_type_uint32_t
 319 unset ac_cv_type_int64_t
 320 unset ac_cv_type_uint64_t
 321 unset ac_cv_type_intmax_t
 322 unset ac_cv_type_uintmax_t
 323
 324 ### See what's provided by inttypes.h
 325 if test "$ac_cv_header_inttypes_h" = yes; then
 326   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 327   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 328   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 329   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 330   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 331   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 332   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 333   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 334   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 335   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 336 fi
 337
 338 # Try hard to find definitions for some required scm_t_*int* types.
 339
 340 ### Required type scm_t_int8
 341 if test "$ac_cv_sizeof_char" -eq 1; then
 342   SCM_I_GSC_T_INT8='"char"'
 343 elif test "$scm_stdint_has_int8"; then
 344   SCM_I_GSC_T_INT8='"int8_t"'
 345   SCM_I_GSC_NEEDS_STDINT_H=1
 346 elif test "$scm_inttypes_has_int8"; then
 347   SCM_I_GSC_T_INT8='"int8_t"'
 348   SCM_I_GSC_NEEDS_INTTYPES_H=1
 349 else
 350   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 351 fi
 352 AC_SUBST([SCM_I_GSC_T_INT8])
 353
 354 ### Required type scm_t_uint8
 355 if test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 356   SCM_I_GSC_T_UINT8='"unsigned char"'
 357 elif test "$scm_stdint_has_uint8"; then
 358   SCM_I_GSC_T_UINT8='"uint8_t"'
 359   SCM_I_GSC_NEEDS_STDINT_H=1
 360 elif test "$scm_inttypes_has_uint8"; then
 361   SCM_I_GSC_T_UINT8='"uint8_t"'
 362   SCM_I_GSC_NEEDS_INTTYPES_H=1
 363 else
 364   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 365 fi
 366 AC_SUBST([SCM_I_GSC_T_UINT8])
 367
 368
 369 ### Required type scm_t_int16 (ANSI C says int or short might work)
 370 if test "$ac_cv_sizeof_int" -eq 2; then
 371   SCM_I_GSC_T_INT16='"int"'
 372 elif test "$ac_cv_sizeof_short" -eq 2; then
 373   SCM_I_GSC_T_INT16='"short"'
 374 elif test "$scm_stdint_has_int16"; then
 375   SCM_I_GSC_T_INT16='"int16_t"'
 376   SCM_I_GSC_NEEDS_STDINT_H=1
 377 elif test "$scm_inttypes_has_int16"; then
 378   SCM_I_GSC_T_INT16='"int16_t"'
 379   SCM_I_GSC_NEEDS_INTTYPES_H=1
 380 else
 381   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 382 fi
 383 AC_SUBST([SCM_I_GSC_T_INT16])
 384
 385 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 386 if test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 387   SCM_I_GSC_T_UINT16='"unsigned int"'
 388 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 389   SCM_I_GSC_T_UINT16='"unsigned short"'
 390 elif test "$scm_stdint_has_uint16"; then
 391   SCM_I_GSC_T_UINT16='"uint16_t"'
 392   SCM_I_GSC_NEEDS_STDINT_H=1
 393 elif test "$scm_inttypes_has_uint16"; then
 394   SCM_I_GSC_T_UINT16='"uint16_t"'
 395   SCM_I_GSC_NEEDS_INTTYPES_H=1
 396 else
 397   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 398 fi
 399 AC_SUBST([SCM_I_GSC_T_UINT16])
 400
 401
 402 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 403 if test "$ac_cv_sizeof_int" -eq 4; then
 404   SCM_I_GSC_T_INT32='"int"'
 405 elif test "$ac_cv_sizeof_long" -eq 4; then
 406   SCM_I_GSC_T_INT32='"long"'
 407 elif test "$ac_cv_sizeof_short" -eq 4; then
 408   SCM_I_GSC_T_INT32='"short"'
 409 elif test "$scm_stdint_has_int32"; then
 410   SCM_I_GSC_T_INT32='"int32_t"'
 411   SCM_I_GSC_NEEDS_STDINT_H=1
 412 elif test "$scm_inttypes_has_int32"; then
 413   SCM_I_GSC_T_INT32='"int32_t"'
 414   SCM_I_GSC_NEEDS_INTTYPES_H=1
 415 else
 416   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 417 fi
 418 AC_SUBST([SCM_I_GSC_T_INT32])
 419
 420 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 421 if test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 422   SCM_I_GSC_T_UINT32='"unsigned int"'
 423 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 424   SCM_I_GSC_T_UINT32='"unsigned long"'
 425 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 426   SCM_I_GSC_T_UINT32='"unsigned short"'
 427 elif test "$scm_stdint_has_uint32"; then
 428   SCM_I_GSC_T_UINT32='"uint32_t"'
 429   SCM_I_GSC_NEEDS_STDINT_H=1
 430 elif test "$scm_inttypes_has_uint32"; then
 431   SCM_I_GSC_T_UINT32='"uint32_t"'
 432   SCM_I_GSC_NEEDS_INTTYPES_H=1
 433 else
 434   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 435 fi
 436 AC_SUBST([SCM_I_GSC_T_UINT32])
 437
 438 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 439 ### Also try 'long long' and '__int64' if we have it.
 440 SCM_I_GSC_T_INT64=0
 441 if test "$ac_cv_sizeof_int" -eq 8; then
 442   SCM_I_GSC_T_INT64='"int"'
 443 elif test "$ac_cv_sizeof_long" -eq 8; then
 444   SCM_I_GSC_T_INT64='"long"'
 445 elif test "$ac_cv_sizeof_short" -eq 8; then
 446   SCM_I_GSC_T_INT64='"short"'
 447 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 448   SCM_I_GSC_T_INT64='"long long"'
 449 elif test "$ac_cv_sizeof___int64" -eq 8; then
 450   SCM_I_GSC_T_INT64='"__int64"'
 451 elif test "$scm_stdint_has_int64"; then
 452   SCM_I_GSC_T_INT64='"int64_t"'
 453   SCM_I_GSC_NEEDS_STDINT_H=1
 454 elif test "$scm_inttypes_has_int64"; then
 455   SCM_I_GSC_T_INT64='"int64_t"'
 456   SCM_I_GSC_NEEDS_INTTYPES_H=1
 457 else
 458   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 459 fi
 460 AC_SUBST([SCM_I_GSC_T_INT64])
 461
 462 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 463 ### Also try 'long long' and '__int64' if we have it.
 464 SCM_I_GSC_T_UINT64=0
 465 if test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 466   SCM_I_GSC_T_UINT64='"unsigned int"'
 467 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 468   SCM_I_GSC_T_UINT64='"unsigned long"'
 469 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 470   SCM_I_GSC_T_UINT64='"unsigned short"'
 471 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 472   SCM_I_GSC_T_UINT64='"unsigned long long"'
 473 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 474   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 475 elif test "$scm_stdint_has_uint64"; then
 476   SCM_I_GSC_T_UINT64='"uint64_t"'
 477   SCM_I_GSC_NEEDS_STDINT_H=1
 478 elif test "$scm_inttypes_has_uint64"; then
 479   SCM_I_GSC_T_UINT64='"uint64_t"'
 480   SCM_I_GSC_NEEDS_INTTYPES_H=1
 481 else
 482   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 483 fi
 484 AC_SUBST([SCM_I_GSC_T_UINT64])
 485
 486 ### Required type scm_t_intmax
 487 ###
 488 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 489 ### none of them is available, we use 'long'.
 490 ###
 491 SCM_I_GSC_T_INTMAX=0
 492 if test "$scm_stdint_has_intmax"; then
 493   SCM_I_GSC_T_INTMAX='"intmax_t"'
 494   SCM_I_GSC_NEEDS_STDINT_H=1
 495 elif test "$scm_inttypes_has_intmax"; then
 496   SCM_I_GSC_T_INTMAX='"intmax_t"'
 497   SCM_I_GSC_NEEDS_INTTYPES_H=1
 498 elif test "$ac_cv_sizeof___int64" -ne 0; then
 499   SCM_I_GSC_T_INTMAX='"__int64"'
 500 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 501   SCM_I_GSC_T_INTMAX='"long long"'
 502 else
 503   SCM_I_GSC_T_INTMAX='"long"'
 504 fi
 505 AC_SUBST([SCM_I_GSC_T_INTMAX])
 506
 507 ### Required type scm_t_uintmax
 508 ###
 509 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 510 ### this order.  When none of them is available, we use 'unsigned long'.
 511 ###
 512 SCM_I_GSC_T_UINTMAX=0
 513 if test "$scm_stdint_has_uintmax"; then
 514   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 515   SCM_I_GSC_NEEDS_STDINT_H=1
 516 elif test "$scm_inttypes_has_uintmax"; then
 517   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 518   SCM_I_GSC_NEEDS_INTTYPES_H=1
 519 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 520   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 521 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 522   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 523 else
 524   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 525 fi
 526 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 527
 528
 529 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 530 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 531
 532 AC_HEADER_STDC
 533 AC_HEADER_DIRENT
 534 AC_HEADER_TIME
 535 AC_HEADER_SYS_WAIT
 536
 537 AC_CHECK_HEADERS([io.h libc.h limits.h malloc.h memory.h string.h \
 538 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 539 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 540 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 541 direct.h])
 542
 543 GUILE_HEADER_LIBC_WITH_UNISTD
 544
 545 AC_TYPE_GETGROUPS
 546 AC_TYPE_SIGNAL
 547 AC_TYPE_MODE_T
 548
 549 if test $MINGW32 = no; then
 550         AC_CHECK_LIB(m, main)
 551 fi
 552 AC_CHECK_FUNCS(gethostbyname)
 553 if test $ac_cv_func_gethostbyname = no; then
 554     AC_CHECK_LIB(nsl, gethostbyname)
 555 fi
 556
 557 AC_CHECK_FUNCS(connect)
 558 if test $ac_cv_func_connect = no; then
 559     AC_CHECK_LIB(socket, connect)
 560 fi
 561
 562 dnl
 563 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 564 dnl
 565 EXTRA_DEFS=""
 566 if test "$MINGW32" = "yes" ; then
 567     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 568       [Define if you have the <winsock2.h> header file.])])
 569     AC_CHECK_LIB(ws2_32, main)
 570     AC_LIBOBJ([win32-uname])
 571     AC_LIBOBJ([win32-dirent])
 572     if test "$enable_networking" = yes ; then
 573       AC_LIBOBJ([win32-socket])
 574     fi
 575     if test "$enable_shared" = yes ; then
 576       EXTRA_DEFS="-DSCM_IMPORT"
 577       AC_DEFINE(USE_DLL_IMPORT, 1,
 578         [Define if you need additional CPP macros on Win32 platforms.])
 579     fi
 580     if test x"$enable_ltdl_install" = x"yes" ; then
 581       INCLTDL="-DLIBLTDL_DLL_IMPORT $INCLTDL"
 582     fi
 583 fi
 584 AC_SUBST(EXTRA_DEFS)
 585
 586 # FIXME: check to see if we still need these.
 587 #AC_SUBST(INCLTDL)
 588 #AC_SUBST(LIBLTDL)
 589
 590 AC_SUBST(DLPREOPEN)
 591
 592 # Reasons for testing:
 593 #   crt_externs.h - Darwin specific
 594 #
 595 AC_CHECK_HEADERS([assert.h crt_externs.h])
 596
 597 # Reasons for testing:
 598 #   DINFINITY - OSF specific
 599 #   DQNAN - OSF specific
 600 #       (DINFINITY and DQNAN are actually global variables, not functions)
 601 #   gmtime_r - recent posix, not on old systems
 602 #   readdir_r - recent posix, not on old systems
 603 #   sysconf - not on old systems
 604 #   _NSGetEnviron - Darwin specific
 605 #
 606 AC_CHECK_FUNCS([DINFINITY DQNAN ctermid ftime fchown getcwd geteuid gettimeofday gmtime_r lstat mkdir mknod nice readdir_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex unsetenv _NSGetEnviron])
 607
 608 # Reasons for testing:
 609 #   netdb.h - not in mingw
 610 #   sys/param.h - not in mingw
 611 #
 612 AC_CHECK_HEADERS(crypt.h netdb.h sys/param.h sys/resource.h sys/file.h)
 613 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 614
 615 # crypt() may or may not be available, for instance in some countries there
 616 # are restrictions on cryptography.
 617 #
 618 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 619 # -lcrypt library (eg. Debian GNU/Linux).
 620 #
 621 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 622 # be careful to avoid -lcrypt in this case, since libtool will see there's
 623 # only a static libcrypt and decide to build only a static libguile.
 624 #
 625 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 626 # libraries already in that list.
 627 #
 628 AC_SEARCH_LIBS(crypt, crypt,
 629   [AC_DEFINE(HAVE_CRYPT,1,
 630              [Define to 1 if you have the `crypt' function.])])
 631
 632 dnl GMP tests
 633 AC_CHECK_LIB([gmp], [__gmpz_init], ,
 634   [AC_MSG_ERROR([GNU MP not found, see http://swox.com/gmp])])
 635
 636 # mpz_import is a macro so we need to include <gmp.h>
 637 AC_TRY_LINK([#include <gmp.h>],
 638             [mpz_import (0, 0, 0, 0, 0, 0, 0);] , ,
 639   [AC_MSG_ERROR([At least GNU MP 4.1 is required, see http://swox.com/gmp])])
 640
 641 ### Some systems don't declare some functions.  On such systems, we
 642 ### need to at least provide our own K&R-style declarations.
 643
 644 ### GUILE_FUNC_DECLARED(function, headerfile)
 645
 646 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 647 ### not there, #define MISSING_FUNCTION_DECL.
 648 AC_DEFUN([GUILE_FUNC_DECLARED], [
 649   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 650     AC_EGREP_HEADER($1, $2,
 651                     guile_cv_func_$1_declared=yes,
 652                     guile_cv_func_$1_declared=no))
 653   if test [x$guile_cv_func_]$1[_declared] = xno; then
 654     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 655       [Define if the operating system supplies $1 without declaring it.])
 656   fi
 657 ])
 658
 659 GUILE_FUNC_DECLARED(sleep, unistd.h)
 660 GUILE_FUNC_DECLARED(usleep, unistd.h)
 661
 662 AC_CHECK_DECLS([strptime],,,
 663 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 664 #include <time.h>])
 665
 666 ### On some systems usleep has no return value.  If it does have one,
 667 ### we'd like to return it; otherwise, we'll fake it.
 668 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 669   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 670                    unistd.h,
 671                    [guile_cv_func_usleep_return_type=void],
 672                    [guile_cv_func_usleep_return_type=int])])
 673 case "$guile_cv_func_usleep_return_type" in
 674   "void" )
 675     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 676       [Define if the system headers declare usleep to return void.])
 677   ;;
 678 esac
 679
 680 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 681 if test -n "$have_sys_un_h" ; then
 682   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 683     [Define if the system supports Unix-domain (file-domain) sockets.])
 684 fi
 685
 686 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 687
 688 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 689                setnetent    getnetent    endnetent    dnl
 690                setprotoent  getprotoent  endprotoent  dnl
 691                setservent   getservent   endservent   dnl
 692                getnetbyaddr getnetbyname dnl
 693                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 694                inet_pton inet_ntop)
 695
 696 AC_MSG_CHECKING(for __libc_stack_end)
 697 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 698 [AC_TRY_LINK([#include <stdio.h>
 699 extern char *__libc_stack_end;],
 700              [printf("%p", (char*) __libc_stack_end);],
 701              guile_cv_have_libc_stack_end=yes,
 702              guile_cv_have_libc_stack_end=no)])
 703 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 704
 705 if test $guile_cv_have_libc_stack_end = yes; then
 706   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 707            [Define if you have the __libc_stack_end variable.])
 708 fi
 709
 710 dnl Some systems do not declare this.  Some systems do declare it, as a
 711 dnl macro.  With cygwin it may be in a DLL.
 712
 713 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 714 AC_CACHE_VAL(guile_cv_have_h_errno,
 715 [AC_TRY_COMPILE([#include <netdb.h>],
 716 [int a = h_errno;],
 717 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 718 AC_MSG_RESULT($guile_cv_have_h_errno)
 719 if test $guile_cv_have_h_errno = yes; then
 720   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 721 fi
 722
 723 AC_MSG_CHECKING(whether uint32_t is defined)
 724 AC_CACHE_VAL(guile_cv_have_uint32_t,
 725   [AC_TRY_COMPILE([#include <sys/types.h>
 726                    #if HAVE_STDINT_H
 727                    #include <stdint.h>
 728                    #endif
 729                    #ifndef __MINGW32__
 730                    #include <netdb.h>
 731                    #endif],
 732                   [uint32_t a;],
 733                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 734 AC_MSG_RESULT($guile_cv_have_uint32_t)
 735 if test $guile_cv_have_uint32_t = yes; then
 736   AC_DEFINE(HAVE_UINT32_T, 1,
 737     [Define if uint32_t typedef is defined when netdb.h is include.])
 738 fi
 739
 740 AC_MSG_CHECKING(for working IPv6 support)
 741 AC_CACHE_VAL(guile_cv_have_ipv6,
 742 [AC_TRY_COMPILE([
 743 #ifdef HAVE_SYS_TYPES_H
 744 #include <sys/types.h>
 745 #endif
 746 #include <netinet/in.h>
 747 #include <sys/socket.h>],
 748 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 749 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 750 AC_MSG_RESULT($guile_cv_have_ipv6)
 751 if test $guile_cv_have_ipv6 = yes; then
 752   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 753 fi
 754
 755 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 756 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 757 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 758 [AC_TRY_COMPILE([
 759 #ifdef HAVE_SYS_TYPES_H
 760 #include <sys/types.h>
 761 #endif
 762 #include <netinet/in.h>],
 763 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 764 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 765 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 766 if test $guile_cv_have_sin6_scope_id = yes; then
 767   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 768     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 769 fi
 770
 771 AC_MSG_CHECKING(whether localtime caches TZ)
 772 AC_CACHE_VAL(guile_cv_localtime_cache,
 773 [if test x$ac_cv_func_tzset = xyes; then
 774 AC_TRY_RUN([#include <time.h>
 775 #if STDC_HEADERS
 776 # include <stdlib.h>
 777 #endif
 778 extern char **environ;
 779 unset_TZ ()
 780 {
 781   char **from, **to;
 782   for (to = from = environ; (*to = *from); from++)
 783     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 784       to++;
 785 }
 786 char TZ_GMT0[] = "TZ=GMT0";
 787 char TZ_PST8[] = "TZ=PST8";
 788 main()
 789 {
 790   time_t now = time ((time_t *) 0);
 791   int hour_GMT0, hour_unset;
 792   if (putenv (TZ_GMT0) != 0)
 793     exit (1);
 794   hour_GMT0 = localtime (&now)->tm_hour;
 795   unset_TZ ();
 796   hour_unset = localtime (&now)->tm_hour;
 797   if (putenv (TZ_PST8) != 0)
 798     exit (1);
 799   if (localtime (&now)->tm_hour == hour_GMT0)
 800     exit (1);
 801   unset_TZ ();
 802   if (localtime (&now)->tm_hour != hour_unset)
 803     exit (1);
 804   exit (0);
 805 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 806 [# If we have tzset, assume the worst when cross-compiling.
 807 guile_cv_localtime_cache=yes])
 808 else
 809         # If we lack tzset, report that localtime does not cache TZ,
 810         # since we can't invalidate the cache if we don't have tzset.
 811         guile_cv_localtime_cache=no
 812 fi])dnl
 813 AC_MSG_RESULT($guile_cv_localtime_cache)
 814 if test $guile_cv_localtime_cache = yes; then
 815   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
 816 fi
 817
 818 dnl Test whether system calls are restartable by default on the
 819 dnl current system.  If they are not, we put a loop around every system
 820 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 821 dnl change from the default behaviour.  On the other hand, if signals
 822 dnl are restartable then the loop is not installed and when libguile
 823 dnl initialises it also resets the behaviour of each signal to cause a
 824 dnl restart (in case a different runtime had a different default
 825 dnl behaviour for some reason: e.g., different versions of linux seem
 826 dnl to behave differently.)
 827
 828 AC_SYS_RESTARTABLE_SYSCALLS
 829
 830 if test "$enable_regex" = yes; then
 831    if test "$ac_cv_header_regex_h" = yes ||
 832       test "$ac_cv_header_rxposix_h" = yes ||
 833       test "$ac_cv_header_rx_rxposix_h" = yes; then
 834      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
 835      [AC_CHECK_LIB(rx, main)
 836       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
 837      [AC_CHECK_LIB(regex, main)
 838       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
 839      )
 840      dnl The following should not be necessary, but for some reason
 841      dnl autoheader misses it if we don't include it!
 842      if test "$ac_cv_func_regcomp_norx" = yes ||
 843         test "$ac_cv_func_regcomp_regex" = yes ||
 844         test "$ac_cv_func_regcomp_rx" = yes; then
 845        AC_DEFINE(HAVE_REGCOMP, 1,
 846          [This is included as part of a workaround for a autoheader bug.])
 847      fi
 848    fi
 849 fi
 850
 851 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 852
 853 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
 854
 855 # Reasons for testing:
 856 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
 857 #                                older systems
 858 #   sincos - GLIBC extension
 859 #
 860 AC_CHECK_FUNCS(asinh acosh atanh copysign finite isinf isnan sincos trunc)
 861
 862 # When testing for the presence of alloca, we need to add alloca.o
 863 # explicitly to LIBOBJS to make sure that it is translated to
 864 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 865 AC_FUNC_ALLOCA
 866 if test "$ALLOCA" = "alloca.o"
 867 then
 868   AC_LIBOBJ([alloca])
 869 fi
 870
 871 AC_CHECK_MEMBERS([struct stat.st_rdev])
 872 AC_CHECK_MEMBERS([struct stat.st_blksize])
 873
 874 AC_STRUCT_ST_BLOCKS
 875
 876 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 877   [AC_TRY_CPP([#include <sys/stat.h>
 878                #ifndef S_ISLNK
 879                #error no S_ISLNK
 880                #endif],
 881                ac_cv_macro_S_ISLNK=yes,
 882                ac_cv_macro_S_ISLNK=no)])
 883 if test $ac_cv_macro_S_ISLNK = yes; then
 884   AC_DEFINE(HAVE_S_ISLNK, 1,
 885     [Define this if your system defines S_ISLNK in sys/stat.h.])
 886 fi
 887
 888 AC_STRUCT_TIMEZONE
 889 GUILE_STRUCT_UTIMBUF
 890
 891 #--------------------------------------------------------------------
 892 #
 893 # Which way does the stack grow?
 894 #
 895 #--------------------------------------------------------------------
 896
 897 SCM_I_GSC_STACK_GROWS_UP=0
 898 AC_TRY_RUN(aux (l) unsigned long l;
 899              { int x; exit (l >= ((unsigned long)&x)); }
 900            main () { int q; aux((unsigned long)&q); },
 901            [SCM_I_GSC_STACK_GROWS_UP=1],
 902            [],
 903            [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
 904
 905 AC_CHECK_SIZEOF(float)
 906 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
 907     AC_DEFINE(SCM_SINGLES, 1,
 908               [Define this if floats are the same size as longs.])
 909 fi
 910
 911 AC_MSG_CHECKING(for struct linger)
 912 AC_CACHE_VAL(scm_cv_struct_linger,
 913         AC_TRY_COMPILE([
 914 #include <sys/types.h>
 915 #include <sys/socket.h>],
 916                         [struct linger lgr;  lgr.l_linger = 100],
 917                         scm_cv_struct_linger="yes",
 918                         scm_cv_struct_linger="no"))
 919 AC_MSG_RESULT($scm_cv_struct_linger)
 920 if test $scm_cv_struct_linger = yes; then
 921         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
 922           [Define this if your system defines struct linger, for use with the
 923            getsockopt and setsockopt system calls.])
 924 fi
 925
 926
 927 AC_MSG_CHECKING(for struct timespec)
 928 AC_CACHE_VAL(scm_cv_struct_timespec,
 929         AC_TRY_COMPILE([
 930 #include <time.h>],
 931                         [struct timespec t;  t.tv_nsec = 100],
 932                         scm_cv_struct_timespec="yes",
 933                         scm_cv_struct_timespec="no"))
 934 AC_MSG_RESULT($scm_cv_struct_timespec)
 935 if test $scm_cv_struct_timespec = yes; then
 936   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
 937     [Define this if your system defines struct timespec via <time.h>.])
 938 fi
 939
 940 #--------------------------------------------------------------------
 941 #
 942 # Flags for thread support
 943 #
 944 #--------------------------------------------------------------------
 945
 946 SCM_I_GSC_USE_PTHREAD_THREADS=0
 947 SCM_I_GSC_USE_NULL_THREADS=0
 948 SCM_I_GSC_USE_COOP_THREADS=0
 949 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
 950 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
 951 AC_SUBST([SCM_I_GSC_USE_COOP_THREADS])
 952
 953 ### What thread package has the user asked for?
 954 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 955             , with_threads=yes)
 956
 957 case "$with_threads" in
 958   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
 959     AC_CHECK_LIB(pthread, main,
 960       LIBS="-lpthread $LIBS"
 961       SCM_I_GSC_USE_PTHREAD_THREADS=1
 962       with_threads="pthreads",
 963       with_threads="null")
 964
 965     if test $GCC = yes; then
 966     AC_DEFINE(_THREAD_SAFE, 1,
 967       [Use thread safe versions of GNU Libc functions.])
 968     fi
 969
 970     AC_MSG_CHECKING(if pthread_mutexattr_settype is declared)
 971     AC_CACHE_VAL(guile_cv_mutexattr_settype_declared,
 972       [AC_TRY_COMPILE([#include <pthread.h>],
 973           [int pthread_mutexattr_settype (int, int);],
 974           guile_cv_mutexattr_settype_declared=no,
 975           guile_cv_mutexattr_settype_declared=yes)])
 976     AC_MSG_RESULT($guile_cv_mutexattr_settype_declared)
 977     if test $guile_cv_mutexattr_settype_declared = yes; then
 978       AC_DEFINE(SCM_MUTEXATTR_SETTYPE_DECLARED, 1,
 979           [Define if pthread.h declares pthread_mutexattr_settype.])
 980     fi
 981
 982     AC_MSG_CHECKING(how to get a fast mutex)
 983     AC_CACHE_VAL(guile_cv_have_mutex_fast,
 984       [AC_TRY_COMPILE([#include <pthread.h>],
 985           [int a = PTHREAD_MUTEX_ADAPTIVE_NP;],
 986           guile_cv_have_mutex_fast=PTHREAD_MUTEX_ADAPTIVE_NP,
 987           guile_cv_have_mutex_fast=none)])
 988     AC_MSG_RESULT($guile_cv_have_mutex_fast)
 989     if test ! $guile_cv_have_mutex_fast = none; then
 990       AC_DEFINE_UNQUOTED(SCM_MUTEX_FAST, $guile_cv_have_mutex_fast,
 991           [The mutex kind enum for fast mutexes.])
 992     fi
 993
 994     AC_MSG_CHECKING(how to get a recursive mutex)
 995     AC_CACHE_VAL(guile_cv_have_mutex_recursive,
 996       [AC_TRY_COMPILE([#include <pthread.h>],
 997         [int a = PTHREAD_MUTEX_RECURSIVE_NP;],
 998          guile_cv_have_mutex_recursive=PTHREAD_MUTEX_RECURSIVE_NP)
 999       if test -z "$guile_cv_have_mutex_recursive"; then
1000           AC_TRY_COMPILE([#include <pthread.h>],
1001             [int a = PTHREAD_MUTEX_RECURSIVE;],
1002             guile_cv_have_mutex_recursive=PTHREAD_MUTEX_RECURSIVE,
1003             guile_cv_have_mutex_recursive=none)
1004         fi])
1005     AC_MSG_RESULT($guile_cv_have_mutex_recursive)
1006     if test ! $guile_cv_have_mutex_recursive = none; then
1007       AC_DEFINE_UNQUOTED(SCM_MUTEX_RECURSIVE, $guile_cv_have_mutex_recursive,
1008          [The mutex kind enum for recursive mutexes.])
1009     fi
1010
1011     # On Solaris, sched_yield lives in -lrt.
1012     AC_SEARCH_LIBS(sched_yield, rt)
1013
1014   ;;
1015 esac
1016
1017 case "$with_threads" in
1018   "pthreads")
1019   ;;
1020   "no" | "null")
1021     SCM_I_GSC_USE_NULL_THREADS=1
1022     with_threads="null-threads"
1023   ;;
1024   * )
1025     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1026   ;;
1027 esac
1028
1029 AC_MSG_CHECKING(what kind of threads to support)
1030 AC_MSG_RESULT($with_threads)
1031
1032 ## Cross building
1033 if test "$cross_compiling" = "yes"; then
1034   AC_MSG_CHECKING(cc for build)
1035   ## /usr/bin/cc still uses wrong assembler
1036   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1037   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1038 else
1039   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1040 fi
1041
1042 ## AC_MSG_CHECKING("if we are cross compiling")
1043 ## AC_MSG_RESULT($cross_compiling)
1044 if test "$cross_compiling" = "yes"; then
1045    AC_MSG_RESULT($CC_FOR_BUILD)
1046 fi
1047
1048 ## No need as yet to be more elaborate
1049 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1050
1051 AC_SUBST(cross_compiling)
1052 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1053 AC_SUBST(CCLD_FOR_BUILD)
1054
1055 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1056 ## --HOST is the platform that PACKAGE is compiled for.
1057 HOST_CC="$CC_FOR_BUILD"
1058 AC_SUBST(HOST_CC)
1059
1060 if test "$cross_compiling" = "yes"; then
1061   AC_MSG_CHECKING(guile for build)
1062   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1063 else
1064   GUILE_FOR_BUILD='$(preinstguile)'
1065 fi
1066
1067 ## AC_MSG_CHECKING("if we are cross compiling")
1068 ## AC_MSG_RESULT($cross_compiling)
1069 if test "$cross_compiling" = "yes"; then
1070    AC_MSG_RESULT($GUILE_FOR_BUILD)
1071 fi
1072 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1073 AC_SUBST(GUILE_FOR_BUILD)
1074
1075 ## If we're using GCC, ask for aggressive warnings.
1076 case "$GCC" in
1077   yes )
1078     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1079     ## much stuff with generic function pointers for that to really be
1080     ## less than exasperating.
1081     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1082     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1083     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
1084     # Do this here so we don't screw up any of the tests above that might
1085     # not be "warning free"
1086     if test "${GUILE_ERROR_ON_WARNING}" = yes
1087     then
1088         CFLAGS="${CFLAGS} -Werror"
1089         enable_compile_warnings=no
1090     fi
1091     ;;
1092 esac
1093
1094 ## NOTE the code below sets LIBOBJS directly and so is now forbidden
1095 ## -- I'm disabling it for now in the hopes that the newer autoconf
1096 ## will DTRT -- if not, we need to fix up the sed command to match the
1097 ## others...
1098 ##
1099 ## Remove fileblocks.o from the object list.  This file gets added by
1100 ## the Autoconf macro AC_STRUCT_ST_BLOCKS.  But there is no need.
1101 #LIBOBJS="`echo ${LIBOBJS} | sed 's/fileblocks\.o//g'`"
1102
1103 ## If we're creating a shared library (using libtool!), then we'll
1104 ## need to generate a list of .lo files corresponding to the .o files
1105 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1106 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1107
1108 ## We also need to create corresponding .doc and .x files
1109 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1110 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1111
1112 AC_SUBST(GUILE_MAJOR_VERSION)
1113 AC_SUBST(GUILE_MINOR_VERSION)
1114 AC_SUBST(GUILE_MICRO_VERSION)
1115 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1116 AC_SUBST(GUILE_VERSION)
1117
1118 #######################################################################
1119 # library versioning
1120
1121 AC_SUBST(LIBQTHREADS_INTERFACE_CURRENT)
1122 AC_SUBST(LIBQTHREADS_INTERFACE_REVISION)
1123 AC_SUBST(LIBQTHREADS_INTERFACE_AGE)
1124 AC_SUBST(LIBQTHREADS_INTERFACE)
1125
1126 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1127 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1128 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1129 AC_SUBST(LIBGUILE_INTERFACE)
1130
1131 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1132 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1133 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1134 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1135
1136 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1137 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1138 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1139 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1140
1141 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1142 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1143 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1144 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1145
1146 #######################################################################
1147
1148 dnl Tell guile-config what flags guile users should link against.
1149 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
1150 AC_SUBST(GUILE_LIBS)
1151
1152 AC_SUBST(AWK)
1153 AC_SUBST(LIBLOBJS)
1154 AC_SUBST(EXTRA_DOT_DOC_FILES)
1155 AC_SUBST(EXTRA_DOT_X_FILES)
1156
1157 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1158 top_builddir_absolute=`pwd`
1159 AC_SUBST(top_builddir_absolute)
1160 top_srcdir_absolute=`(cd $srcdir && pwd)`
1161 AC_SUBST(top_srcdir_absolute)
1162
1163 # Additional SCM_I_GSC definitions are above.
1164 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1165 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1166 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1167 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1168 AC_SUBST([SCM_I_GSC_HAVE_ARRAYS])
1169 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1170 AC_SUBST([SCM_I_GSC_C_INLINE])
1171 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1172
1173 AC_CONFIG_FILES([
1174   Makefile
1175   am/Makefile
1176   benchmark-suite/Makefile
1177   doc/Makefile
1178   doc/goops/Makefile
1179   doc/r5rs/Makefile
1180   doc/ref/Makefile
1181   doc/tutorial/Makefile
1182   emacs/Makefile
1183   examples/Makefile
1184   examples/box-dynamic-module/Makefile
1185   examples/box-dynamic/Makefile
1186   examples/box-module/Makefile
1187   examples/box/Makefile
1188   examples/modules/Makefile
1189   examples/safe/Makefile
1190   examples/scripts/Makefile
1191   guile-config/Makefile
1192   ice-9/Makefile
1193   ice-9/debugger/Makefile
1194   ice-9/debugger/breakpoints/Makefile
1195   lang/Makefile
1196   lang/elisp/Makefile
1197   lang/elisp/internals/Makefile
1198   lang/elisp/primitives/Makefile
1199   libguile-ltdl/Makefile
1200   libguile-ltdl/upstream/Makefile
1201   libguile/Makefile
1202   oop/Makefile
1203   oop/goops/Makefile
1204   scripts/Makefile
1205   srfi/Makefile
1206   test-suite/Makefile
1207   test-suite/standalone/Makefile
1208 ])
1209
1210 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1211 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1212 AC_CONFIG_FILES([guile-tools], [chmod +x guile-tools])
1213 AC_CONFIG_FILES([pre-inst-guile], [chmod +x pre-inst-guile])
1214 AC_CONFIG_FILES([pre-inst-guile-env], [chmod +x pre-inst-guile-env])
1215 AC_CONFIG_FILES([libguile/guile-snarf],
1216                 [chmod +x libguile/guile-snarf])
1217 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1218                 [chmod +x libguile/guile-doc-snarf])
1219 AC_CONFIG_FILES([libguile/guile-func-name-check],
1220                 [chmod +x libguile/guile-func-name-check])
1221 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1222                 [chmod +x libguile/guile-snarf-docs])
1223
1224 AC_OUTPUT
1225
1226 dnl Local Variables:
1227 dnl comment-start: "dnl "
1228 dnl comment-end: ""
1229 dnl comment-start-skip: "\\bdnl\\b\\s *"
1230 dnl End: