configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   8   2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   9
  10 This file is part of GUILE
  11
  12 GUILE is free software; you can redistribute it and/or modify it under
  13 the terms of the GNU Lesser General Public License as published by the
  14 Free Software Foundation; either version 3, or (at your option) any
  15 later version.
  16
  17 GUILE is distributed in the hope that it will be useful, but WITHOUT
  18 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  19 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  20 License for more details.
  21
  22 You should have received a copy of the GNU Lesser General Public
  23 License along with GUILE; see the file COPYING.LESSER.  If not, write
  24 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  25 Floor, Boston, MA 02110-1301, USA.
  26
  27 ]])
  28
  29 AC_PREREQ(2.61)
  30
  31 AC_INIT([GNU Guile],
  32         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  33         [bug-guile@gnu.org])
  34 AC_CONFIG_AUX_DIR([build-aux])
  35 AC_CONFIG_MACRO_DIR([m4])
  36 AC_CONFIG_SRCDIR(GUILE-VERSION)
  37
  38 dnl `AM_SUBST_NOTMAKE' was introduced in Automake 1.11.
  39 AM_INIT_AUTOMAKE([1.11 gnu no-define -Wall -Wno-override dist-xz])
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AC_SUBST([AM_DEFAULT_VERBOSITY],1)])
  41
  42 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  43 AC_CONFIG_SRCDIR([GUILE-VERSION])
  44
  45 . $srcdir/GUILE-VERSION
  46 GUILE_VERSION="$PACKAGE_VERSION"
  47
  48 AC_CONFIG_HEADERS([config.h])
  49 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  50
  51 #--------------------------------------------------------------------
  52
  53 AC_LANG([C])
  54
  55 dnl Some more checks for Win32
  56 AC_CANONICAL_HOST
  57
  58 AC_LIBTOOL_WIN32_DLL
  59
  60 AC_PROG_INSTALL
  61 AC_PROG_CC
  62 gl_EARLY
  63 AC_PROG_CPP
  64 AC_PROG_SED
  65 AC_PROG_AWK
  66 AC_PROG_LN_S
  67
  68 dnl Gnulib.
  69 gl_INIT
  70 dnl FIXME: remove me and the acinclude.m4 code when clock-gettime is
  71 dnl fixed for clock_getcpuclockid and can be imported normally from
  72 dnl gnulib.  See
  73 dnl <http://lists.gnu.org/archive/html/bug-gnulib/2011-06/msg00227.html>
  74 dnl for details.
  75 gl_CLOCK_TIME
  76
  77 AC_PROG_CC_C89
  78
  79 # for per-target cflags in the libguile subdir
  80 AM_PROG_CC_C_O
  81
  82 AC_LIBTOOL_DLOPEN
  83 AC_PROG_LIBTOOL
  84
  85 AM_CONDITIONAL([HAVE_SHARED_LIBRARIES], [test "x$enable_shared" = "xyes"])
  86
  87 AC_DEFINE_UNQUOTED([SHARED_LIBRARY_PATH_VARIABLE], ["$shlibpath_var"],
  88   [Name of the environment variable that tells the dynamic linker where
  89 to find shared libraries.])
  90
  91 dnl Check for libltdl.
  92 AC_LIB_HAVE_LINKFLAGS([ltdl], [], [#include <ltdl.h>],
  93   [lt_dlopenext ("foo");])
  94 if test "x$HAVE_LIBLTDL" != "xyes"; then
  95   AC_MSG_ERROR([GNU libltdl (Libtool) not found, see README.])
  96 fi
  97
  98 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  99 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
 100
 101 AM_PATH_LISPDIR
 102
 103 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
 104   [Define to the host's GNU triplet.])
 105
 106 #--------------------------------------------------------------------
 107 #
 108 # User options (after above tests that may set default CFLAGS etc.)
 109 #
 110 #--------------------------------------------------------------------
 111
 112 GUILE_ERROR_ON_WARNING="no"
 113
 114 AC_ARG_ENABLE(error-on-warning,
 115   [  --enable-error-on-warning    treat compile warnings as errors],
 116   [case "${enableval}" in
 117      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 118      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 119      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 120    esac])
 121
 122 AC_ARG_ENABLE(debug-malloc,
 123   [  --enable-debug-malloc   include malloc debugging code],
 124   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 125     AC_DEFINE([GUILE_DEBUG_MALLOC], 1,
 126       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 127   fi)
 128
 129 SCM_I_GSC_GUILE_DEBUG=0
 130 AC_ARG_ENABLE(guile-debug,
 131   [AS_HELP_STRING([--enable-guile-debug],
 132                   [include internal debugging functions])],
 133   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 134     SCM_I_GSC_GUILE_DEBUG=1
 135   fi)
 136
 137 AC_ARG_ENABLE(posix,
 138   [  --disable-posix         omit non-essential POSIX interfaces],,
 139   enable_posix=yes)
 140
 141 AC_ARG_ENABLE(networking,
 142   [  --disable-networking    omit networking interfaces],,
 143   enable_networking=yes)
 144
 145 AC_ARG_ENABLE(regex,
 146   [  --disable-regex         omit regular expression interfaces],,
 147   enable_regex=yes)
 148
 149 AC_ARG_ENABLE([deprecated],
 150   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 151
 152 if test "$enable_deprecated" = no; then
 153   SCM_I_GSC_ENABLE_DEPRECATED=0
 154   warn_default=no
 155 else
 156   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 157     warn_default=summary
 158   elif test "$enable_deprecated" = shutup; then
 159     warn_default=no
 160   else
 161     warn_default=$enable_deprecated
 162   fi
 163   SCM_I_GSC_ENABLE_DEPRECATED=1
 164 fi
 165 AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default",
 166 [Define this to control the default warning level for deprecated features.])
 167
 168 dnl  Added the following configure option in January 2008 following
 169 dnl  investigation of problems with "64" system and library calls on
 170 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 171 dnl  system has stat64, it will have all the other 64 APIs too; but on
 172 dnl  Darwin, stat64 is there but other APIs are missing.
 173 dnl
 174 dnl  It also appears, from the Darwin docs, that most system call APIs
 175 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 176 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 177 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 178 dnl
 179 dnl  A similar problem has been reported for HP-UX:
 180 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 181 dnl
 182 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 183 dnl  better than no Guile at all, we provide this option to suppress
 184 dnl  trying to use "64" calls.
 185 dnl
 186 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 187 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 188 dnl  missing out on that.  If so, someone can work on that in the future.
 189 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 190 dnl  wasn't building before.
 191 AC_MSG_CHECKING([whether to use system and library "64" calls])
 192 AC_ARG_WITH([64-calls],
 193   AS_HELP_STRING([--without-64-calls],
 194                  [don't attempt to use system and library calls with "64" in their names]),
 195   [use_64_calls=$withval],
 196   [use_64_calls=yes
 197    case $host in
 198      *-apple-darwin* )
 199        use_64_calls=no
 200        ;;
 201      powerpc-ibm-aix* )
 202        use_64_calls=no
 203        ;;
 204    esac])
 205 AC_MSG_RESULT($use_64_calls)
 206 case "$use_64_calls" in
 207   y* )
 208     AC_DEFINE([GUILE_USE_64_CALLS], 1,
 209       [Define to 1 in order to try to use "64" versions of system and library calls.])
 210     ;;
 211 esac
 212
 213 #--------------------------------------------------------------------
 214
 215 dnl Check for dynamic linking
 216
 217 use_modules=yes
 218 AC_ARG_WITH(modules,
 219 [  --with-modules[=FILES]  Add support for dynamic modules],
 220 use_modules="$withval")
 221 test -z "$use_modules" && use_modules=yes
 222 DLPREOPEN=
 223 if test "$use_modules" != no; then
 224   if test "$use_modules" = yes; then
 225     DLPREOPEN="-dlpreopen force"
 226   else
 227     DLPREOPEN="-export-dynamic"
 228     for module in $use_modules; do
 229       DLPREOPEN="$DLPREOPEN -dlopen $module"
 230     done
 231   fi
 232 fi
 233
 234 dnl files which are destined for separate modules.
 235
 236 if test "$use_modules" != no; then
 237    AC_LIBOBJ([dynl])
 238    AC_DEFINE([HAVE_MODULES], 1,
 239      [Define this if you want support for dynamically loaded modules in Guile.])
 240 fi
 241
 242 if test "$enable_posix" = yes; then
 243    AC_LIBOBJ([posix])
 244    AC_DEFINE([HAVE_POSIX], 1,
 245      [Define this if you want support for non-essential POSIX system calls in Guile.])
 246 fi
 247
 248 if test "$enable_networking" = yes; then
 249    AC_LIBOBJ([net_db])
 250    AC_LIBOBJ([socket])
 251    AC_DEFINE([HAVE_NETWORKING], 1,
 252      [Define this if you want support for networking in Guile.])
 253 fi
 254
 255 if test "$enable_debug_malloc" = yes; then
 256    AC_LIBOBJ([debug-malloc])
 257 fi
 258
 259 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 260
 261 AC_C_CONST
 262
 263 # "volatile" is used in a couple of tests below.
 264 AC_C_VOLATILE
 265
 266 AC_C_INLINE
 267 if test "$ac_cv_c_inline" != no; then
 268   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 269 else
 270   SCM_I_GSC_C_INLINE=NULL
 271 fi
 272 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 273
 274 AC_C_BIGENDIAN
 275
 276 AC_C_LABELS_AS_VALUES
 277
 278 AC_CHECK_SIZEOF(char)
 279 AC_CHECK_SIZEOF(unsigned char)
 280 AC_CHECK_SIZEOF(short)
 281 AC_CHECK_SIZEOF(unsigned short)
 282 AC_CHECK_SIZEOF(int)
 283 AC_CHECK_SIZEOF(unsigned int)
 284 AC_CHECK_SIZEOF(long)
 285 AC_CHECK_SIZEOF(unsigned long)
 286 AC_CHECK_SIZEOF(size_t)
 287 AC_CHECK_SIZEOF(long long)
 288 AC_CHECK_SIZEOF(unsigned long long)
 289 AC_CHECK_SIZEOF(__int64)
 290 AC_CHECK_SIZEOF(unsigned __int64)
 291 AC_CHECK_SIZEOF(void *)
 292 AC_CHECK_SIZEOF(intptr_t)
 293 AC_CHECK_SIZEOF(uintptr_t)
 294 AC_CHECK_SIZEOF(ptrdiff_t)
 295 AC_CHECK_SIZEOF(size_t)
 296 AC_CHECK_SIZEOF(off_t)
 297
 298 if test "$ac_cv_sizeof_long" -gt "$ac_cv_sizeof_void_p"; then
 299   AC_MSG_ERROR(long does not fit into a void*)
 300 fi
 301
 302 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 303   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 304 else
 305   SCM_I_GSC_T_PTRDIFF='"long"'
 306 fi
 307 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 308
 309 AC_CHECK_HEADERS([stdint.h])
 310 AC_CHECK_HEADERS([inttypes.h])
 311
 312 AC_CHECK_SIZEOF(intmax_t)
 313
 314 SCM_I_GSC_NEEDS_STDINT_H=0
 315 SCM_I_GSC_NEEDS_INTTYPES_H=0
 316
 317 ### intptr and uintptr (try not to use inttypes if we don't have to)
 318 if test "$ac_cv_header_inttypes_h" = yes; then
 319   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 320     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 321 #include <stdio.h>])
 322     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 323       SCM_I_GSC_NEEDS_INTTYPES_H=1
 324     fi
 325   fi
 326   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 327     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 328 #include <stdio.h>])
 329     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 330       SCM_I_GSC_NEEDS_INTTYPES_H=1
 331     fi
 332   fi
 333 fi
 334
 335 ### See what's provided by stdint.h
 336 if test "$ac_cv_header_stdint_h" = yes; then
 337    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 338    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 339    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 340    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 341    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 342    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 343    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 344    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 345    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 346    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 347    AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>])
 348    AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>])
 349 fi
 350
 351 # so we don't get confused by the cache (wish there was a better way
 352 # to check particular headers for the same type...)
 353
 354 unset ac_cv_type_int8_t
 355 unset ac_cv_type_uint8_t
 356 unset ac_cv_type_int16_t
 357 unset ac_cv_type_uint16_t
 358 unset ac_cv_type_int32_t
 359 unset ac_cv_type_uint32_t
 360 unset ac_cv_type_int64_t
 361 unset ac_cv_type_uint64_t
 362 unset ac_cv_type_intmax_t
 363 unset ac_cv_type_uintmax_t
 364
 365 ### See what's provided by inttypes.h
 366 if test "$ac_cv_header_inttypes_h" = yes; then
 367   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 368   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 369   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 370   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 371   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 372   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 373   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 374   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 375   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 376   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 377   AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>])
 378   AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>])
 379 fi
 380
 381 # Try hard to find definitions for some required scm_t_*int* types.
 382
 383 ### Required type scm_t_int8
 384 if test "$scm_stdint_has_int8"; then
 385   SCM_I_GSC_T_INT8='"int8_t"'
 386   SCM_I_GSC_NEEDS_STDINT_H=1
 387 elif test "$scm_inttypes_has_int8"; then
 388   SCM_I_GSC_T_INT8='"int8_t"'
 389   SCM_I_GSC_NEEDS_INTTYPES_H=1
 390 elif test "$ac_cv_sizeof_char" -eq 1; then
 391   SCM_I_GSC_T_INT8='"signed char"'
 392 else
 393   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 394 fi
 395 AC_SUBST([SCM_I_GSC_T_INT8])
 396
 397 ### Required type scm_t_uint8
 398 if test "$scm_stdint_has_uint8"; then
 399   SCM_I_GSC_T_UINT8='"uint8_t"'
 400   SCM_I_GSC_NEEDS_STDINT_H=1
 401 elif test "$scm_inttypes_has_uint8"; then
 402   SCM_I_GSC_T_UINT8='"uint8_t"'
 403   SCM_I_GSC_NEEDS_INTTYPES_H=1
 404 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 405   SCM_I_GSC_T_UINT8='"unsigned char"'
 406 else
 407   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 408 fi
 409 AC_SUBST([SCM_I_GSC_T_UINT8])
 410
 411 ### Required type scm_t_int16 (ANSI C says int or short might work)
 412 if test "$scm_stdint_has_int16"; then
 413   SCM_I_GSC_T_INT16='"int16_t"'
 414   SCM_I_GSC_NEEDS_STDINT_H=1
 415 elif test "$scm_inttypes_has_int16"; then
 416   SCM_I_GSC_T_INT16='"int16_t"'
 417   SCM_I_GSC_NEEDS_INTTYPES_H=1
 418 elif test "$ac_cv_sizeof_int" -eq 2; then
 419   SCM_I_GSC_T_INT16='"int"'
 420 elif test "$ac_cv_sizeof_short" -eq 2; then
 421   SCM_I_GSC_T_INT16='"short"'
 422 else
 423   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 424 fi
 425 AC_SUBST([SCM_I_GSC_T_INT16])
 426
 427 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 428 if test "$scm_stdint_has_uint16"; then
 429   SCM_I_GSC_T_UINT16='"uint16_t"'
 430   SCM_I_GSC_NEEDS_STDINT_H=1
 431 elif test "$scm_inttypes_has_uint16"; then
 432   SCM_I_GSC_T_UINT16='"uint16_t"'
 433   SCM_I_GSC_NEEDS_INTTYPES_H=1
 434 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 435   SCM_I_GSC_T_UINT16='"unsigned int"'
 436 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 437   SCM_I_GSC_T_UINT16='"unsigned short"'
 438 else
 439   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 440 fi
 441 AC_SUBST([SCM_I_GSC_T_UINT16])
 442
 443
 444 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 445 if test "$scm_stdint_has_int32"; then
 446   SCM_I_GSC_T_INT32='"int32_t"'
 447   SCM_I_GSC_NEEDS_STDINT_H=1
 448 elif test "$scm_inttypes_has_int32"; then
 449   SCM_I_GSC_T_INT32='"int32_t"'
 450   SCM_I_GSC_NEEDS_INTTYPES_H=1
 451 elif test "$ac_cv_sizeof_int" -eq 4; then
 452   SCM_I_GSC_T_INT32='"int"'
 453 elif test "$ac_cv_sizeof_long" -eq 4; then
 454   SCM_I_GSC_T_INT32='"long"'
 455 elif test "$ac_cv_sizeof_short" -eq 4; then
 456   SCM_I_GSC_T_INT32='"short"'
 457 else
 458   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 459 fi
 460 AC_SUBST([SCM_I_GSC_T_INT32])
 461
 462 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 463 if test "$scm_stdint_has_uint32"; then
 464   SCM_I_GSC_T_UINT32='"uint32_t"'
 465   SCM_I_GSC_NEEDS_STDINT_H=1
 466 elif test "$scm_inttypes_has_uint32"; then
 467   SCM_I_GSC_T_UINT32='"uint32_t"'
 468   SCM_I_GSC_NEEDS_INTTYPES_H=1
 469 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 470   SCM_I_GSC_T_UINT32='"unsigned int"'
 471 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 472   SCM_I_GSC_T_UINT32='"unsigned long"'
 473 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 474   SCM_I_GSC_T_UINT32='"unsigned short"'
 475 else
 476   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 477 fi
 478 AC_SUBST([SCM_I_GSC_T_UINT32])
 479
 480 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 481 ### Also try 'long long' and '__int64' if we have it.
 482 SCM_I_GSC_T_INT64=0
 483 if test "$scm_stdint_has_int64"; then
 484   SCM_I_GSC_T_INT64='"int64_t"'
 485   SCM_I_GSC_NEEDS_STDINT_H=1
 486 elif test "$scm_inttypes_has_int64"; then
 487   SCM_I_GSC_T_INT64='"int64_t"'
 488   SCM_I_GSC_NEEDS_INTTYPES_H=1
 489 elif test "$ac_cv_sizeof_int" -eq 8; then
 490   SCM_I_GSC_T_INT64='"int"'
 491 elif test "$ac_cv_sizeof_long" -eq 8; then
 492   SCM_I_GSC_T_INT64='"long"'
 493 elif test "$ac_cv_sizeof_short" -eq 8; then
 494   SCM_I_GSC_T_INT64='"short"'
 495 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 496   SCM_I_GSC_T_INT64='"long long"'
 497 elif test "$ac_cv_sizeof___int64" -eq 8; then
 498   SCM_I_GSC_T_INT64='"__int64"'
 499 else
 500   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 501 fi
 502 AC_SUBST([SCM_I_GSC_T_INT64])
 503
 504
 505 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 506 ### Also try 'long long' and '__int64' if we have it.
 507 SCM_I_GSC_T_UINT64=0
 508 if test "$scm_stdint_has_uint64"; then
 509   SCM_I_GSC_T_UINT64='"uint64_t"'
 510   SCM_I_GSC_NEEDS_STDINT_H=1
 511 elif test "$scm_inttypes_has_uint64"; then
 512   SCM_I_GSC_T_UINT64='"uint64_t"'
 513   SCM_I_GSC_NEEDS_INTTYPES_H=1
 514 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 515   SCM_I_GSC_T_UINT64='"unsigned int"'
 516 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 517   SCM_I_GSC_T_UINT64='"unsigned long"'
 518 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 519   SCM_I_GSC_T_UINT64='"unsigned short"'
 520 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 521   SCM_I_GSC_T_UINT64='"unsigned long long"'
 522 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 523   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 524 else
 525   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 526 fi
 527 AC_SUBST([SCM_I_GSC_T_UINT64])
 528
 529 ### Required type scm_t_intmax
 530 ###
 531 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 532 ### none of them is available, we use 'long'.
 533 ###
 534 SCM_I_GSC_T_INTMAX=0
 535 if test "$scm_stdint_has_intmax"; then
 536   SCM_I_GSC_T_INTMAX='"intmax_t"'
 537   SCM_I_GSC_NEEDS_STDINT_H=1
 538 elif test "$scm_inttypes_has_intmax"; then
 539   SCM_I_GSC_T_INTMAX='"intmax_t"'
 540   SCM_I_GSC_NEEDS_INTTYPES_H=1
 541 elif test "$ac_cv_sizeof___int64" -ne 0; then
 542   SCM_I_GSC_T_INTMAX='"__int64"'
 543 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 544   SCM_I_GSC_T_INTMAX='"long long"'
 545 else
 546   SCM_I_GSC_T_INTMAX='"long"'
 547 fi
 548 AC_SUBST([SCM_I_GSC_T_INTMAX])
 549
 550 ### Required type scm_t_uintmax
 551 ###
 552 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 553 ### this order.  When none of them is available, we use 'unsigned long'.
 554 ###
 555 SCM_I_GSC_T_UINTMAX=0
 556 if test "$scm_stdint_has_uintmax"; then
 557   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 558   SCM_I_GSC_NEEDS_STDINT_H=1
 559 elif test "$scm_inttypes_has_uintmax"; then
 560   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 561   SCM_I_GSC_NEEDS_INTTYPES_H=1
 562 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 563   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 564 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 565   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 566 else
 567   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 568 fi
 569 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 570
 571 ### Required type scm_t_intptr
 572 ###
 573 SCM_I_GSC_T_INTPTR=0
 574 if test "$scm_stdint_has_intptr"; then
 575   SCM_I_GSC_T_INTPTR='"intptr_t"'
 576   SCM_I_GSC_NEEDS_STDINT_H=1
 577 elif test "$scm_inttypes_has_intptr"; then
 578   SCM_I_GSC_T_INTPTR='"intptr_t"'
 579   SCM_I_GSC_NEEDS_INTTYPES_H=1
 580 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 581   SCM_I_GSC_T_INTPTR='"int"'
 582 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 583   SCM_I_GSC_T_INTPTR='"long"'
 584 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 585   SCM_I_GSC_T_INTPTR='"long long"'
 586 else
 587   AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.])
 588 fi
 589 AC_SUBST([SCM_I_GSC_T_INTPTR])
 590
 591 ### Required type scm_t_uintptr
 592 ###
 593 SCM_I_GSC_T_UINTPTR=0
 594 if test "$scm_stdint_has_uintptr"; then
 595   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 596   SCM_I_GSC_NEEDS_STDINT_H=1
 597 elif test "$scm_inttypes_has_uintptr"; then
 598   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 599   SCM_I_GSC_NEEDS_INTTYPES_H=1
 600 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 601   SCM_I_GSC_T_UINTPTR='"unsigned int"'
 602 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 603   SCM_I_GSC_T_UINTPTR='"unsigned long"'
 604 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 605   SCM_I_GSC_T_UINTPTR='"unsigned long long"'
 606 else
 607   AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.])
 608 fi
 609 AC_SUBST([SCM_I_GSC_T_UINTPTR])
 610
 611
 612 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 613 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 614
 615 AC_HEADER_STDC
 616 AC_HEADER_TIME
 617 AC_HEADER_SYS_WAIT
 618 AC_HEADER_DIRENT
 619
 620 # Reason for checking:
 621 #
 622 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 623 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 624 #
 625 AC_CHECK_MEMBER([struct dirent64.d_name],
 626   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 627   [ #ifndef _LARGEFILE64_SOURCE
 628     # define _LARGEFILE64_SOURCE
 629     #endif
 630
 631     /* Per Autoconf manual.  */
 632     #include <sys/types.h>
 633     #ifdef HAVE_DIRENT_H
 634     # include <dirent.h>
 635     #else
 636     # define dirent direct
 637     # ifdef HAVE_SYS_NDIR_H
 638     #  include <sys/ndir.h>
 639     # endif
 640     # ifdef HAVE_SYS_DIR_H
 641     #  include <sys/dir.h>
 642     # endif
 643     # ifdef HAVE_NDIR_H
 644     #  include <ndir.h>
 645     # endif
 646     #endif ])
 647 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 648
 649 # Reasons for testing:
 650 #   complex.h - new in C99
 651 #   fenv.h - available in C99, but not older systems
 652 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 653 #     this file instead of <fenv.h>
 654 #   process.h - mingw specific
 655 #   langinfo.h, nl_types.h - SuS v2
 656 #   sched.h - missing on MinGW
 657 #
 658 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 659 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 660 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 661 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 662 direct.h langinfo.h nl_types.h machine/fpu.h poll.h sched.h])
 663
 664 # Reasons for testing:
 665 #   nl_item - lacking on Cygwin
 666 AC_CHECK_TYPES([nl_item], [], [],
 667   [[#ifdef HAVE_LANGINFO_H
 668     # include <langinfo.h>
 669     #endif
 670     #ifdef HAVE_NL_TYPES_H
 671     # include <nl_types.h>
 672     #endif]])
 673
 674 # "complex double" is new in C99, and "complex" is only a keyword if
 675 # <complex.h> is included
 676 AC_CHECK_TYPES(complex double,,,
 677 [#if HAVE_COMPLEX_H
 678 #include <complex.h>
 679 #endif])
 680
 681 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 682 # when testing.
 683 AC_CHECK_TYPE(socklen_t, ,
 684   [AC_DEFINE_UNQUOTED([socklen_t], int,
 685                       [Define to `int' if <sys/socket.h> does not define.])],
 686   [#if HAVE_SYS_TYPES_H
 687 #include <sys/types.h>
 688 #endif
 689 #include <sys/socket.h>
 690 ])
 691
 692 AC_CHECK_TYPES([struct ip_mreq], , , [#include <netinet/in.h>])
 693
 694 GUILE_HEADER_LIBC_WITH_UNISTD
 695
 696 AC_TYPE_GETGROUPS
 697 AC_TYPE_SIGNAL
 698 AC_TYPE_MODE_T
 699
 700 # On mingw -lm is empty, so this test is unnecessary, but it's
 701 # harmless so we don't hard-code to suppress it.
 702 #
 703 AC_CHECK_LIB(m, cos)
 704
 705 AC_CHECK_FUNCS(gethostbyname)
 706 if test $ac_cv_func_gethostbyname = no; then
 707     AC_CHECK_LIB(nsl, gethostbyname)
 708 fi
 709
 710 AC_CHECK_FUNCS(connect)
 711 if test $ac_cv_func_connect = no; then
 712     AC_CHECK_LIB(socket, connect)
 713 fi
 714
 715 dnl
 716 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 717 dnl
 718 EXTRA_DEFS=""
 719 case $host in
 720   *-*-mingw*)
 721     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 722       [Define if you have the <winsock2.h> header file.])])
 723     AC_CHECK_LIB(ws2_32, main)
 724     AC_LIBOBJ([win32-uname])
 725     if test "$enable_networking" = yes ; then
 726       AC_LIBOBJ([win32-socket])
 727     fi
 728     if test "$enable_shared" = yes ; then
 729       EXTRA_DEFS="-DSCM_IMPORT"
 730       AC_DEFINE([USE_DLL_IMPORT], 1,
 731         [Define if you need additional CPP macros on Win32 platforms.])
 732     fi
 733     ;;
 734 esac
 735 AC_SUBST(EXTRA_DEFS)
 736
 737 # Reasons for testing:
 738 #   crt_externs.h - Darwin specific
 739 #
 740 AC_CHECK_HEADERS([assert.h crt_externs.h])
 741
 742 # Reasons for testing:
 743 #   DINFINITY - OSF specific
 744 #   DQNAN - OSF specific
 745 #       (DINFINITY and DQNAN are actually global variables, not functions)
 746 #   chsize - an MS-DOS-ism, found in mingw
 747 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 748 #       for gcc to provide the "complex double" type but the system to not
 749 #       have functions like cexp and clog
 750 #   clog10 - not in mingw (though others like clog and csqrt are)
 751 #   fesetround - available in C99, but not older systems
 752 #   ftruncate - posix, but probably not older systems (current mingw
 753 #               has it as an inline for chsize)
 754 #   ioctl - not in mingw.
 755 #   gmtime_r - recent posix, not on old systems
 756 #   pipe - not in mingw
 757 #   _pipe - specific to mingw, taking 3 args
 758 #   poll - since posix 2001
 759 #   readdir_r - recent posix, not on old systems
 760 #   readdir64_r - not available on HP-UX 11.11
 761 #   stat64 - SuS largefile stuff, not on old systems
 762 #   sysconf - not on old systems
 763 #   truncate - not in mingw
 764 #   isblank - available as a GNU extension or in C99
 765 #   _NSGetEnviron - Darwin specific
 766 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 767 #   nl_langinfo - X/Open, not available on Windows.
 768 #   utimensat: posix.1-2008
 769 #   sched_getaffinity, sched_setaffinity: GNU extensions (glibc)
 770 #
 771 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid getsid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe poll readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo utimensat sched_getaffinity sched_setaffinity])
 772
 773 # Reasons for testing:
 774 #   netdb.h - not in mingw
 775 #   sys/param.h - not in mingw
 776 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 777 #       check this specifically, we need it for the timespec test below.
 778 #   sethostname - the function itself check because it's not in mingw,
 779 #       the DECL is checked because Solaris 10 doens't have in any header
 780 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 781 #       declaration isn't anywhere.
 782 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 783 #       only with `_XOPEN_SOURCE' or some such.
 784 #
 785 AC_CHECK_HEADERS([crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h sys/mman.h])
 786 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 787 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 788
 789 # crypt() may or may not be available, for instance in some countries there
 790 # are restrictions on cryptography.
 791 #
 792 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 793 # -lcrypt library (eg. Debian GNU/Linux).
 794 #
 795 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 796 # be careful to avoid -lcrypt in this case, since libtool will see there's
 797 # only a static libcrypt and decide to build only a static libguile.
 798 #
 799 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 800 # libraries already in that list.
 801 #
 802 AC_SEARCH_LIBS(crypt, crypt,
 803   [AC_DEFINE([HAVE_CRYPT],1,
 804              [Define to 1 if you have the `crypt' function.])])
 805
 806 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 807 # work; in the reported cases so far, 1.0fi works well instead.  According
 808 # to the C99 spec, the complex.h header must provide a working definition
 809 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 810 # is a workaround for the failure of some systems to conform to C99.
 811 if test "$ac_cv_type_complex_double" = yes; then
 812   AC_MSG_CHECKING([for i])
 813   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 814 #if HAVE_COMPLEX_H
 815 #include <complex.h>
 816 #endif
 817 complex double z;
 818 ]], [[
 819 z = _Complex_I;
 820 ]])],
 821     [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).])
 822      AC_MSG_RESULT([_Complex_I])],
 823     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 824 #if HAVE_COMPLEX_H
 825 #include <complex.h>
 826 #endif
 827 complex double z;
 828 ]],[[
 829 z = 1.0fi;
 830 ]])],
 831   [AC_DEFINE([GUILE_I],1.0fi)
 832    AC_MSG_RESULT([1.0fi])],
 833   [ac_cv_type_complex_double=no
 834    AC_MSG_RESULT([not available])])])
 835 fi
 836
 837 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 838 # csqrt(-i) returned a negative real part, when it should be positive
 839 # for the principal root.
 840 #
 841 if test "$ac_cv_type_complex_double" = yes; then
 842
 843   AC_CACHE_CHECK([whether csqrt is usable],
 844     guile_cv_use_csqrt,
 845     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 846 #include <complex.h>
 847 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 848    constant, we want to test libc. */
 849 volatile complex double z = - _Complex_I;
 850 int
 851 main (void)
 852 {
 853   z = csqrt (z);
 854   if (creal (z) > 0.0)
 855     return 0;  /* good */
 856   else
 857     return 1;  /* bad */
 858 }]])],
 859     [guile_cv_use_csqrt=yes],
 860     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 861     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 862   case $guile_cv_use_csqrt in
 863     yes*)
 864       AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free])
 865       ;;
 866   esac
 867 fi
 868
 869 AC_CACHE_SAVE
 870
 871 dnl GMP tests
 872 AC_LIB_HAVE_LINKFLAGS([gmp],
 873   [],
 874   [#include <gmp.h>],
 875   [mpz_import (0, 0, 0, 0, 0, 0, 0);])
 876
 877 if test "x$HAVE_LIBGMP" != "xyes"; then
 878   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README])
 879 fi
 880
 881 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 882 if test "x$LTLIBUNISTRING" = "x"; then
 883   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 884 fi
 885
 886 GUILE_LIBUNISTRING_WITH_ICONV_SUPPORT
 887 if test "x$ac_cv_libunistring_with_iconv_support" != "xyes"; then
 888   AC_MSG_ERROR([No iconv support.  Please recompile libunistring with iconv enabled.])
 889 fi
 890
 891 dnl Libffi is needed to compile Guile's foreign function interface, but its
 892 dnl interface isn't exposed in Guile's API.
 893 PKG_CHECK_MODULES(LIBFFI, libffi)
 894 AC_SUBST(LIBFFI_CFLAGS)
 895 AC_SUBST(LIBFFI_LIBS)
 896
 897 dnl figure out approriate ffi type for size_t
 898 AC_CHECK_SIZEOF(size_t)
 899 AC_CHECK_SIZEOF(ssize_t)
 900 ffi_size_type=uint$(($ac_cv_sizeof_size_t*8))
 901 ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8))
 902 AC_DEFINE_UNQUOTED([ffi_type_size_t], ffi_type_${ffi_size_type},
 903                    [ffi type for size_t])
 904 AC_DEFINE_UNQUOTED([ffi_type_ssize_t], ffi_type_${ffi_ssize_type},
 905                    [ffi type for ssize_t])
 906
 907 dnl i18n tests
 908 #AC_CHECK_HEADERS([libintl.h])
 909 #AC_CHECK_FUNCS(gettext)
 910 #if test $ac_cv_func_gettext = no; then
 911 #   AC_CHECK_LIB(intl, gettext)
 912 #fi
 913 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 914 AM_GNU_GETTEXT([external], [need-ngettext])
 915
 916 ### Some systems don't declare some functions.  On such systems, we
 917 ### need to at least provide our own K&R-style declarations.
 918
 919 ### GUILE_FUNC_DECLARED(function, headerfile)
 920
 921 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 922 ### not there, #define MISSING_FUNCTION_DECL.
 923 AC_DEFUN([GUILE_FUNC_DECLARED], [
 924   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 925     AC_EGREP_HEADER($1, $2,
 926                     guile_cv_func_$1_declared=yes,
 927                     guile_cv_func_$1_declared=no))
 928   if test [x$guile_cv_func_]$1[_declared] = xno; then
 929     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 930       [Define if the operating system supplies $1 without declaring it.])
 931   fi
 932 ])
 933
 934 GUILE_FUNC_DECLARED(sleep, unistd.h)
 935 GUILE_FUNC_DECLARED(usleep, unistd.h)
 936
 937 AC_CHECK_DECLS([strptime],,,
 938 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 939 #include <time.h>])
 940
 941 ### On some systems usleep has no return value.  If it does have one,
 942 ### we'd like to return it; otherwise, we'll fake it.
 943 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 944   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 945                    unistd.h,
 946                    [guile_cv_func_usleep_return_type=void],
 947                    [guile_cv_func_usleep_return_type=int])])
 948 case "$guile_cv_func_usleep_return_type" in
 949   "void" )
 950     AC_DEFINE([USLEEP_RETURNS_VOID], 1,
 951       [Define if the system headers declare usleep to return void.])
 952   ;;
 953 esac
 954
 955 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 956 if test -n "$have_sys_un_h" ; then
 957   AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1,
 958     [Define if the system supports Unix-domain (file-domain) sockets.])
 959 fi
 960
 961 AC_CHECK_FUNCS(getrlimit setrlimit)
 962
 963 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 964
 965 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 966                setnetent    getnetent    endnetent    dnl
 967                setprotoent  getprotoent  endprotoent  dnl
 968                setservent   getservent   endservent   dnl
 969                getnetbyaddr getnetbyname dnl
 970                inet_lnaof inet_makeaddr inet_netof hstrerror)
 971
 972 AC_CHECK_MEMBERS([struct sockaddr_in.sin_len],,,
 973 [#ifdef HAVE_SYS_TYPES_H
 974 #include <sys/types.h>
 975 #endif
 976 #include <netinet/in.h>])
 977
 978 AC_MSG_CHECKING(for __libc_stack_end)
 979 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 980 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 981 extern char *__libc_stack_end;]],
 982    [[printf("%p", (char*) __libc_stack_end);]])],
 983    [guile_cv_have_libc_stack_end=yes],
 984    [guile_cv_have_libc_stack_end=no])])
 985 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 986
 987 if test $guile_cv_have_libc_stack_end = yes; then
 988   AC_DEFINE([HAVE_LIBC_STACK_END], 1,
 989            [Define if you have the __libc_stack_end variable.])
 990 fi
 991
 992 dnl Some systems do not declare this.  Some systems do declare it, as a
 993 dnl macro.  With cygwin it may be in a DLL.
 994
 995 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 996 AC_CACHE_VAL(guile_cv_have_h_errno,
 997   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 998                                       [[int a = h_errno;]])],
 999   [guile_cv_have_h_errno=yes],
1000   [guile_cv_have_h_errno=no])])
1001 AC_MSG_RESULT($guile_cv_have_h_errno)
1002 if test $guile_cv_have_h_errno = yes; then
1003   AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.])
1004 fi
1005
1006 AC_MSG_CHECKING(whether uint32_t is defined)
1007 AC_CACHE_VAL(guile_cv_have_uint32_t,
1008   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1009                    #if HAVE_STDINT_H
1010                    #include <stdint.h>
1011                    #endif
1012                    #ifndef HAVE_NETDB_H
1013                    #include <netdb.h>
1014                    #endif]],
1015                    [[uint32_t a;]])],
1016                    [guile_cv_have_uint32_t=yes],
1017                    [guile_cv_have_uint32_t=no])])
1018 AC_MSG_RESULT($guile_cv_have_uint32_t)
1019 if test $guile_cv_have_uint32_t = yes; then
1020   AC_DEFINE([HAVE_UINT32_T], 1,
1021     [Define if uint32_t typedef is defined when netdb.h is include.])
1022 fi
1023
1024 AC_MSG_CHECKING(for working IPv6 support)
1025 AC_CACHE_VAL(guile_cv_have_ipv6,
1026 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1027 #ifdef HAVE_SYS_TYPES_H
1028 #include <sys/types.h>
1029 #endif
1030 #include <netinet/in.h>
1031 #include <sys/socket.h>]],
1032 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
1033 [guile_cv_have_ipv6=yes],
1034 [guile_cv_have_ipv6=no])])
1035 AC_MSG_RESULT($guile_cv_have_ipv6)
1036 if test $guile_cv_have_ipv6 = yes; then
1037   AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.])
1038 fi
1039
1040 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
1041 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
1042 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
1043 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1044 #ifdef HAVE_SYS_TYPES_H
1045 #include <sys/types.h>
1046 #endif
1047 #include <netinet/in.h>]],
1048 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
1049 [guile_cv_have_sin6_scope_id=yes],
1050 [guile_cv_have_sin6_scope_id=no])])
1051 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
1052 if test $guile_cv_have_sin6_scope_id = yes; then
1053   AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1,
1054     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
1055 fi
1056
1057 # struct sockaddr_in6 field sin_len is only present on BSD systems
1058 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1059 [#ifdef HAVE_SYS_TYPES_H
1060 #include <sys/types.h>
1061 #endif
1062 #include <netinet/in.h>])
1063
1064 AC_MSG_CHECKING(whether localtime caches TZ)
1065 AC_CACHE_VAL(guile_cv_localtime_cache,
1066 [if test x$ac_cv_func_tzset = xyes; then
1067 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1068 #if STDC_HEADERS
1069 # include <stdlib.h>
1070 #endif
1071 extern char **environ;
1072 unset_TZ ()
1073 {
1074   char **from, **to;
1075   for (to = from = environ; (*to = *from); from++)
1076     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1077       to++;
1078 }
1079 char TZ_GMT0[] = "TZ=GMT0";
1080 char TZ_PST8[] = "TZ=PST8";
1081 main()
1082 {
1083   time_t now = time ((time_t *) 0);
1084   int hour_GMT0, hour_unset;
1085   if (putenv (TZ_GMT0) != 0)
1086     exit (1);
1087   hour_GMT0 = localtime (&now)->tm_hour;
1088   unset_TZ ();
1089   hour_unset = localtime (&now)->tm_hour;
1090   if (putenv (TZ_PST8) != 0)
1091     exit (1);
1092   if (localtime (&now)->tm_hour == hour_GMT0)
1093     exit (1);
1094   unset_TZ ();
1095   if (localtime (&now)->tm_hour != hour_unset)
1096     exit (1);
1097   exit (0);
1098 }]])],
1099 [guile_cv_localtime_cache=no],
1100 [guile_cv_localtime_cache=yes],
1101 [# If we have tzset, assume the worst when cross-compiling.
1102 guile_cv_localtime_cache=yes])
1103 else
1104         # If we lack tzset, report that localtime does not cache TZ,
1105         # since we can't invalidate the cache if we don't have tzset.
1106         guile_cv_localtime_cache=no
1107 fi])dnl
1108 AC_MSG_RESULT($guile_cv_localtime_cache)
1109 if test $guile_cv_localtime_cache = yes; then
1110   AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.])
1111 fi
1112
1113 if test "$enable_regex" = yes; then
1114    if test "$ac_cv_header_regex_h" = yes ||
1115       test "$ac_cv_header_rxposix_h" = yes ||
1116       test "$ac_cv_header_rx_rxposix_h" = yes; then
1117      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1118      [AC_CHECK_LIB(rx, main)
1119       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1120      [AC_CHECK_LIB(regex, main)
1121       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1122      )
1123      dnl The following should not be necessary, but for some reason
1124      dnl autoheader misses it if we don't include it!
1125      if test "$ac_cv_func_regcomp_norx" = yes ||
1126         test "$ac_cv_func_regcomp_regex" = yes ||
1127         test "$ac_cv_func_regcomp_rx" = yes; then
1128        AC_DEFINE([HAVE_REGCOMP], 1,
1129          [This is included as part of a workaround for a autoheader bug.])
1130      fi
1131    fi
1132 fi
1133
1134 AC_REPLACE_FUNCS([strerror memmove mkstemp])
1135
1136 # Reasons for testing:
1137 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1138 #                                older systems
1139 #   sincos - GLIBC extension
1140 #
1141 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1142
1143 # C99 specifies isinf and isnan as macros.
1144 # HP-UX provides only macros, no functions.
1145 # glibc 2.3.2 provides both macros and functions.
1146 # IRIX 6.5 and Solaris 8 only provide functions.
1147 #
1148 # The following tests detect isinf and isnan either as functions or as
1149 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1150 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1151 #
1152 AC_MSG_CHECKING([for isinf])
1153 AC_LINK_IFELSE([AC_LANG_SOURCE(
1154 [[#include <math.h>
1155 volatile double x = 0.0;
1156 int main () { return (isinf(x) != 0); }]])],
1157   [AC_MSG_RESULT([yes])
1158    AC_DEFINE([HAVE_ISINF], 1,
1159              [Define to 1 if you have the `isinf' macro or function.])],
1160   [AC_MSG_RESULT([no])])
1161 AC_MSG_CHECKING([for isnan])
1162 AC_LINK_IFELSE([AC_LANG_SOURCE([[
1163 #include <math.h>
1164 volatile double x = 0.0;
1165 int main () { return (isnan(x) != 0); }]])],
1166   [AC_MSG_RESULT([yes])
1167    AC_DEFINE([HAVE_ISNAN], 1,
1168              [Define to 1 if you have the `isnan' macro or function.])],
1169   [AC_MSG_RESULT([no])])
1170
1171 # Reasons for checking:
1172 #
1173 #     st_rdev
1174 #     st_blksize
1175 #     st_blocks   not in mingw
1176 #     tm_gmtoff   BSD+GNU, not in C99
1177 #
1178 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1179 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1180 #
1181 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,,
1182                  [#define _GNU_SOURCE
1183 AC_INCLUDES_DEFAULT
1184 ])
1185
1186 AC_STRUCT_TIMEZONE
1187 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1188 [#include <time.h>
1189 #ifdef TIME_WITH_SYS_TIME
1190 # include <sys/time.h>
1191 # include <time.h>
1192 #else
1193 # if HAVE_SYS_TIME_H
1194 #  include <sys/time.h>
1195 # else
1196 #  include <time.h>
1197 # endif
1198 #endif
1199 ])
1200 GUILE_STRUCT_UTIMBUF
1201
1202
1203 #--------------------------------------------------------------------
1204 #
1205 # What values do the iconv error handlers have?
1206 #
1207 # The only place that we need iconv in our public interfaces is for
1208 # the error handlers, which are just ints.  So we weaken our
1209 # dependency by looking up those values at configure-time.
1210 #--------------------------------------------------------------------
1211 GUILE_UNISTRING_ICONVEH_VALUES
1212
1213 #--------------------------------------------------------------------
1214 #
1215 # Which way does the stack grow?
1216 #
1217 # Following code comes from Autoconf 2.69's internal _AC_LIBOBJ_ALLOCA
1218 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1219 # very similar code, so in future we could look at using that.
1220 #
1221 # An important detail is that the code involves find_stack_direction
1222 # calling _itself_ - which means that find_stack_direction (or at
1223 # least the second find_stack_direction() call) cannot be inlined.
1224 # If the code could be inlined, that might cause the test to give
1225 # an incorrect answer.
1226 #--------------------------------------------------------------------
1227
1228 SCM_I_GSC_STACK_GROWS_UP=0
1229 AC_RUN_IFELSE([AC_LANG_SOURCE(
1230 [AC_INCLUDES_DEFAULT
1231 int
1232 find_stack_direction (int *addr, int depth)
1233 {
1234   int dir, dummy = 0;
1235   if (! addr)
1236     addr = &dummy;
1237   *addr = addr < &dummy ? 1 : addr == &dummy ? 0 : -1;
1238   dir = depth ? find_stack_direction (addr, depth - 1) : 0;
1239   return dir + dummy;
1240 }
1241
1242 int
1243 main (int argc, char **argv)
1244 {
1245   return find_stack_direction (0, argc + !argv + 20) < 0;
1246 }])],
1247                [SCM_I_GSC_STACK_GROWS_UP=1],
1248                [],
1249                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1250
1251 #--------------------------------------------------------------------
1252 #
1253 # Boehm's GC library
1254 #
1255 #--------------------------------------------------------------------
1256 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1257
1258 save_LIBS="$LIBS"
1259 LIBS="$BDW_GC_LIBS $LIBS"
1260 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1261
1262 AC_CHECK_FUNCS([GC_do_blocking GC_call_with_gc_active GC_pthread_exit GC_pthread_cancel GC_allow_register_threads GC_pthread_sigmask GC_set_start_callback GC_get_heap_usage_safe GC_get_free_space_divisor])
1263
1264 # Though the `GC_do_blocking ()' symbol is present in GC 7.1, it is not
1265 # declared, and has a different type (returning void instead of
1266 # void*).
1267 AC_CHECK_DECL([GC_do_blocking],
1268   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1269     [Define this if the `GC_do_blocking ()' function is declared])],
1270   [],
1271   [#include <gc/gc.h>])
1272
1273 # `GC_fn_type' is not available in GC 7.1 and earlier.
1274 AC_CHECK_TYPE([GC_fn_type],
1275   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1276     [Define this if the `GC_fn_type' type is available.])],
1277   [],
1278   [#include <gc/gc.h>])
1279
1280 # `GC_stack_base' is not available in GC 7.1 and earlier.
1281 AC_CHECK_TYPE([struct GC_stack_base],
1282   [AC_DEFINE([HAVE_GC_STACK_BASE], [1],
1283     [Define this if the `GC_stack_base' type is available.])],
1284   [],
1285   [#include <gc/gc.h>])
1286
1287 LIBS="$save_LIBS"
1288
1289
1290 AC_CHECK_SIZEOF(float)
1291 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1292     AC_DEFINE([SCM_SINGLES], 1,
1293               [Define this if floats are the same size as longs.])
1294 fi
1295
1296 AC_MSG_CHECKING(for struct linger)
1297 AC_CACHE_VAL(scm_cv_struct_linger,
1298         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1299 #include <sys/types.h>
1300 #include <sys/socket.h>]],
1301                           [[struct linger lgr;  lgr.l_linger = 100]])],
1302                           [scm_cv_struct_linger="yes"],
1303                           [scm_cv_struct_linger="no"]))
1304 AC_MSG_RESULT($scm_cv_struct_linger)
1305 if test $scm_cv_struct_linger = yes; then
1306         AC_DEFINE([HAVE_STRUCT_LINGER], 1,
1307           [Define this if your system defines struct linger, for use with the
1308            getsockopt and setsockopt system calls.])
1309 fi
1310
1311
1312 # On mingw, struct timespec is in <pthread.h>.
1313 #
1314 AC_MSG_CHECKING(for struct timespec)
1315 AC_CACHE_VAL(scm_cv_struct_timespec,
1316         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1317 #include <time.h>
1318 #if HAVE_PTHREAD_H
1319 #include <pthread.h>
1320 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1321           [scm_cv_struct_timespec="yes"],
1322           [scm_cv_struct_timespec="no"]))
1323 AC_MSG_RESULT($scm_cv_struct_timespec)
1324 if test $scm_cv_struct_timespec = yes; then
1325   AC_DEFINE([HAVE_STRUCT_TIMESPEC], 1,
1326     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1327 fi
1328
1329 #--------------------------------------------------------------------
1330 #
1331 # Flags for thread support
1332 #
1333 #--------------------------------------------------------------------
1334
1335 SCM_I_GSC_USE_PTHREAD_THREADS=0
1336 SCM_I_GSC_USE_NULL_THREADS=0
1337 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1338 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1339
1340 ### What thread package has the user asked for?
1341 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1342             , with_threads=yes)
1343
1344 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1345 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1346
1347 case "$with_threads" in
1348   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1349
1350     build_pthread_support="yes"
1351
1352     ACX_PTHREAD([CC="$PTHREAD_CC"
1353        LIBS="$PTHREAD_LIBS $LIBS"
1354        SCM_I_GSC_USE_PTHREAD_THREADS=1
1355        with_threads="pthreads"],
1356       [with_threads="null"
1357        build_pthread_support="no"])
1358
1359     old_CFLAGS="$CFLAGS"
1360     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1361
1362     # Reasons for testing:
1363     #     pthread_getattr_np - "np" meaning "non portable" says it
1364     #         all; not present on MacOS X or Solaris 10
1365     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1366     #         all; specific to MacOS X
1367     #     pthread_sigmask - not available on mingw
1368     #
1369     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1370
1371     # On past versions of Solaris, believe 8 through 10 at least, you
1372     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1373     # This is contrary to POSIX:
1374     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1375     # Check here if this style is required.
1376     #
1377     # glibc (2.3.6 at least) works both with or without braces, so the
1378     # test checks whether it works without.
1379     #
1380
1381     if test "$GCC" = "yes"; then
1382       # Since GCC only issues a warning for missing braces, so we need
1383       # `-Werror' to catch it.
1384       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1385     fi
1386
1387     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1388       guile_cv_need_braces_on_pthread_once_init,
1389       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>
1390          pthread_once_t foo = PTHREAD_ONCE_INIT;]])],
1391         [guile_cv_need_braces_on_pthread_once_init=no],
1392         [guile_cv_need_braces_on_pthread_once_init=yes])])
1393     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1394       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1395     fi
1396
1397     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1398     # 6.5.30m with GCC 3.3.
1399     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1400       guile_cv_need_braces_on_pthread_mutex_initializer,
1401       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>
1402          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;]])],
1403         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1404         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1405     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1406       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1407     fi
1408
1409     CFLAGS="$old_CFLAGS"
1410
1411     # On Solaris, sched_yield lives in -lrt.
1412     AC_SEARCH_LIBS(sched_yield, rt)
1413
1414   ;;
1415 esac
1416
1417 case "$with_threads" in
1418   "pthreads")
1419   ;;
1420   "no" | "null")
1421     SCM_I_GSC_USE_NULL_THREADS=1
1422     SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
1423     with_threads="null-threads"
1424   ;;
1425   * )
1426     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1427   ;;
1428 esac
1429
1430 AC_MSG_CHECKING(what kind of threads to support)
1431 AC_MSG_RESULT($with_threads)
1432
1433 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1434   [test "x$build_pthread_support" = "xyes"])
1435
1436
1437 ## Check whether pthread_attr_getstack works for the main thread
1438
1439 if test "$with_threads" = pthreads; then
1440
1441 AC_MSG_CHECKING([whether pthread_attr_getstack works for the main thread])
1442 old_CFLAGS="$CFLAGS"
1443 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1444 if test "$cross_compiling" = "no"; then
1445   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1446   #if HAVE_PTHREAD_ATTR_GETSTACK
1447   #include <pthread.h>
1448
1449   int main ()
1450   {
1451     pthread_attr_t attr;
1452     void *start, *end;
1453     size_t size;
1454
1455     pthread_getattr_np (pthread_self (), &attr);
1456     pthread_attr_getstack (&attr, &start, &size);
1457     end = (char *)start + size;
1458
1459     if ((void *)&attr < start || (void *)&attr >= end)
1460       return 1;
1461     else
1462       return 0;
1463   }
1464   #else
1465   int main ()
1466   {
1467     return 1;
1468   }
1469   #endif
1470   ]])],
1471   [works=yes
1472    AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])],
1473   [works=no],
1474   [])
1475 else
1476   works="assuming it doesn't"
1477 fi
1478 CFLAGS="$old_CFLAGS"
1479 AC_MSG_RESULT($works)
1480
1481 GUILE_THREAD_LOCAL_STORAGE
1482
1483 fi # with_threads=pthreads
1484
1485
1486 ## Cross building
1487 if test "$cross_compiling" = "yes"; then
1488   AC_MSG_CHECKING(cc for build)
1489   ## /usr/bin/cc still uses wrong assembler
1490   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1491   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1492 else
1493   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1494 fi
1495
1496 ## AC_MSG_CHECKING("if we are cross compiling")
1497 ## AC_MSG_RESULT($cross_compiling)
1498 if test "$cross_compiling" = "yes"; then
1499    AC_MSG_RESULT($CC_FOR_BUILD)
1500 fi
1501
1502 ## No need as yet to be more elaborate
1503 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1504
1505 AC_SUBST(cross_compiling)
1506 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1507 AC_SUBST(CCLD_FOR_BUILD)
1508
1509 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1510 ## --HOST is the platform that PACKAGE is compiled for.
1511 HOST_CC="$CC_FOR_BUILD"
1512 AC_SUBST(HOST_CC)
1513
1514 GUILE_CHECK_GUILE_FOR_BUILD
1515
1516 ## If we're using GCC, ask for aggressive warnings.
1517 GCC_CFLAGS=""
1518 case "$GCC" in
1519   yes )
1520     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1521     ## much stuff with generic function pointers for that to really be
1522     ## less than exasperating.
1523     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1524     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1525     ## -Wundef was removed because Gnulib prevented it (see
1526     ## <http://thread.gmane.org/gmane.lisp.guile.bugs/5329>.)
1527     POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \
1528       -Wdeclaration-after-statement \
1529       -Wswitch-enum"
1530     # Do this here so we don't screw up any of the tests above that might
1531     # not be "warning free"
1532     if test "${GUILE_ERROR_ON_WARNING}" = yes
1533     then
1534         POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror"
1535         enable_compile_warnings=no
1536     fi
1537
1538     for flag in $POTENTIAL_GCC_CFLAGS
1539     do
1540         gl_WARN_ADD([$flag], [GCC_CFLAGS])
1541     done
1542     ;;
1543 esac
1544
1545 AC_SUBST(GCC_CFLAGS)
1546
1547 # Check for GNU ld's "-z relro".
1548 GUILE_GNU_LD_RELRO
1549
1550
1551 ## If we're creating a shared library (using libtool!), then we'll
1552 ## need to generate a list of .lo files corresponding to the .o files
1553 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1554 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1555
1556 ## We also need to create corresponding .doc and .x files
1557 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1558 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1559
1560 # GNU Readline bindings.
1561 GUILE_READLINE
1562
1563 AC_SUBST(GUILE_MAJOR_VERSION)
1564 AC_SUBST(GUILE_MINOR_VERSION)
1565 AC_SUBST(GUILE_MICRO_VERSION)
1566 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1567 AC_SUBST(GUILE_VERSION)
1568
1569 #######################################################################
1570 # library versioning
1571
1572 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1573 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1574 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1575 AC_SUBST(LIBGUILE_INTERFACE)
1576
1577 AC_SUBST(LIBGUILE_I18N_MAJOR)
1578 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1579 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1580 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1581 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1582
1583
1584 #######################################################################
1585
1586 dnl Tell guile-config what flags guile users should compile and link
1587 dnl with, keeping only `-I' flags from $CPPFLAGS.
1588 GUILE_CFLAGS=""
1589 next_is_includedir=false
1590 for flag in $CPPFLAGS
1591 do
1592   if $next_is_includedir; then
1593     GUILE_CFLAGS="$GUILE_CFLAGS -I $flag"
1594     next_is_includedir=false
1595   else
1596     case "$flag" in
1597       -I)  next_is_includedir=true;;
1598       -I*) GUILE_CFLAGS="$GUILE_CFLAGS $flag";;
1599       *)   ;;
1600     esac
1601   fi
1602 done
1603
1604 GUILE_CFLAGS="$GUILE_CFLAGS $PTHREAD_CFLAGS"
1605 GUILE_LIBS="$LDFLAGS $LIBS"
1606
1607 AC_SUBST(GUILE_LIBS)
1608 AC_SUBST(GUILE_CFLAGS)
1609
1610 AC_SUBST(AWK)
1611 AC_SUBST(LIBLOBJS)
1612 AC_SUBST(EXTRA_DOT_DOC_FILES)
1613 AC_SUBST(EXTRA_DOT_X_FILES)
1614
1615 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1616 top_builddir_absolute=`pwd`
1617 AC_SUBST(top_builddir_absolute)
1618 top_srcdir_absolute=`(cd $srcdir && pwd)`
1619 AC_SUBST(top_srcdir_absolute)
1620
1621 dnl `sitedir' goes into libpath.h and the pkg-config file.
1622 pkgdatadir="$datadir/$PACKAGE_TARNAME"
1623 sitedir="$pkgdatadir/site/$GUILE_EFFECTIVE_VERSION"
1624 AC_SUBST([sitedir])
1625
1626 dnl Name of the `guile' program.
1627 guile_program_name="`echo guile | "$SED" "$program_transform_name"`"
1628 AC_SUBST([guile_program_name])
1629
1630 # Additional SCM_I_GSC definitions are above.
1631 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1632 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1633 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1634 AC_SUBST([SCM_I_GSC_C_INLINE])
1635 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1636
1637 AC_CONFIG_FILES([
1638   Makefile
1639   am/Makefile
1640   lib/Makefile
1641   benchmark-suite/Makefile
1642   gc-benchmarks/Makefile
1643   doc/Makefile
1644   doc/r5rs/Makefile
1645   doc/ref/Makefile
1646   emacs/Makefile
1647   examples/Makefile
1648   libguile/Makefile
1649   libguile/version.h
1650   guile-readline/Makefile
1651   test-suite/Makefile
1652   test-suite/standalone/Makefile
1653   test-suite/vm/Makefile
1654   meta/Makefile
1655   module/Makefile
1656 ])
1657
1658 AC_CONFIG_FILES([meta/guile-2.0.pc])
1659 AC_CONFIG_FILES([meta/guile-2.0-uninstalled.pc])
1660 AC_CONFIG_FILES([doc/ref/effective-version.texi])
1661
1662 GUILE_CONFIG_SCRIPT([check-guile])
1663 GUILE_CONFIG_SCRIPT([benchmark-guile])
1664 GUILE_CONFIG_SCRIPT([meta/guile])
1665 GUILE_CONFIG_SCRIPT([meta/uninstalled-env])
1666 GUILE_CONFIG_SCRIPT([meta/gdb-uninstalled-guile])
1667 GUILE_CONFIG_SCRIPT([meta/guild])
1668 GUILE_CONFIG_SCRIPT([libguile/guile-snarf])
1669 GUILE_CONFIG_SCRIPT([libguile/guile-snarf-docs])
1670 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-use-srfi])
1671 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-fast-slot-ref])
1672
1673 AC_OUTPUT
1674
1675 dnl Local Variables:
1676 dnl comment-start: "dnl "
1677 dnl comment-end: ""
1678 dnl comment-start-skip: "\\bdnl\\b\\s *"
1679 dnl End: